Aiheeseen liittyvää
×
Kaavat ja funktiot
Kirjaudu sisään Microsoft-tilillä
Kirjaudu sisään tai luo tili.
Hei,
Käytä toista tiliä.
Sinulla on useita tilejä
Valitse tili, jolla haluat kirjautua sisään.
Kaavat ja funktiot

LASKE.JOS-funktio

LASKE.JOS-funktiolla, joka on tilastollinen funktio, voit laskea ehdot täyttävien solujen määrän. Voit laskea esimerkiksi, miten monta kertaa tietty kaupunki mainitaan asiakasluettelossa.

Yksinkertaisimmassa muodossaan LASKE.JOS näyttää tältä:

  • =LASKE.JOS(Mistä haluat hakea?, Mitä haluat hakea?)

Esimerkki:

  • =LASKE.JOS(A2:A5,"Lontoo")

  • =LASKE.JOS(A2:A5,A4)

Selaimesi ei tue videotoimintoa. Asenna Microsoft Silverlight, Adobe Flash Player tai Internet Explorer 9.

LASKE.JOS(alue, ehdot)

Argumentin nimi

Kuvaus

alue    (pakollinen)

Laskettavien solujen alue. Alue voi sisältää numeroita, matriiseja, nimetyn alueen tai viittauksia, jotka sisältävät numeroita. Tekstiarvot ja tyhjät arvot ohitetaan.

Katso lisätietoja laskentataulukon alueiden valitsemisesta.

ehdot    (pakollinen)

Luku, lauseke, soluviittaus tai tekstimerkkijono, joka määrittää, mitkä solut lasketaan.

Voit käyttää esimerkiksi lukua 32, vertailua >32, solua B4 tai sanaa "omenat".

LASKE.JOS-funktiossa käytetään vain yhtä ehtoa. Käytä LASKE.JOS.JOUKKO-funktiota, jos haluat käyttää useita ehtoja.

Esimerkkejä

Jos haluat kokeilla näitä esimerkkejä Excelissä, kopioi seuraavan taulukon tiedot ja liitä ne uuden laskentataulukon soluun A1.

Tiedot

Tiedot

omenat

32

appelsiinit

54

persikat

75

omenat

86

Kaava

Kuvaus

=LASKE.JOS(A2:A5,"omenat")

Laskee omenoita sisältävien solujen määrän soluissa A2–A5. Tulos on 2.

=LASKE.JOS(A2:A5,A4)

Laskee persikoita (solun A4 arvo) sisältävien solujen määrän soluissa A2–A5. Tulos on 1.

=LASKE.JOS(A2:A5,A2)+LASKE.JOS(A2:A5,A3)

Laskee omenoiden (solun A2 arvo) ja appelsiinien (solun A3 arvo) lukumäärän soluissa A2–A5. Tulos on 3. Tämä kaava käyttää LASKE.JOS-funktiota kahdesti useiden ehtojen määrittämiseen siten, että kutakin lauseketta kohti on yksi ehto. Voit käyttää myös LASKE.JOS.JOUKKO-funktiota.

=LASKE.JOS(B2:B5,">55")

Laskee lukua 55 suuremman arvon sisältävien solujen määrän soluissa B2–B5. Tulos on 2.

=LASKE.JOS(B2:B5,"<>"&B4)

Laskee sellaisten solujen määrän, joiden arvo ei ole 75, soluissa B2–B5. Et-merkki (&) yhdistää vertailuoperaattorin <> (ei yhtä suuri kuin) ja solun B4 arvon, joten kaava on =LASKE.JOS(B2:B5;"<>75"). Tulos on 3.

=LASKE.JOS(B2:B5,">=32")-LASKE.JOS(B2:B5,"<=85")

Laskee sellaisten solujen määrän, joiden arvo on suurempi (>) tai yhtä suuri (=) kuin 32 ja pienempi (<) tai yhtä suuri (=) kuin 85, soluissa B2–B5. Tulos on 1.

=LASKE.JOS(A2:A5;"*")

Laskee mitä tahansa tekstiä sisältävien solujen määrän soluissa A2–A5. Tähtikertomerkkiä (*) käytetään yleismerkkinä, joka vastaa mitä tahansa merkkiä. Tulos on 4.

=LASKE.JOS(A2:A5;"?????es")

Laskee sellaisten solujen määrän, joissa on täsmälleen 7 merkkiä ja joiden merkkijonon lopussa on merkit "es", soluissa A2–A5. Kysymysmerkkiä (?) käytetään yleismerkkinä, joka vastaa yksittäisiä merkkejä. Tulos on 2.

Yleisiä ongelmia

Ongelma

Mistä ongelma johtuu?

Väärä arvo palautettiin pitkien merkkijonojen yhteydessä.

LASKE.JOS-funktio palauttaa vääriä tuloksia, kun käytät sitä yli 255 merkin merkkijonojen yhteydessä.

Jos haluat laskea yli 255 merkin merkkijonojen määrän, käytä KETJUTA-funktiota tai ketjutusoperaattoria &. Esimerkki: =LASKE.JOS(A2:A5;"pitkä merkkijono"&"toinen pitkä merkkijono").

Funktio ei palauta arvoa, vaikka odotat sitä.

Muista kirjoittaa ehdon argumentti lainausmerkkeihin.

LASKE.JOS-kaava saa #VALUE! -virhe, kun viittaat toiseen laskentataulukkoon.

Tämä virhe ilmenee, kun funktion sisältävä kaava viittaa soluihin tai alueeseen suljetussa työkirjassa ja solut lasketaan. Jotta toiminto toimii, toisen työkirjan on oltava avoinna.

Parhaat käytännöt

Tee näin

Miksi

Muista, että LASKE.JOS-funktio ei huomioi kirjainkokoa tekstimerkkijonoissa.

Ehdoissa kirjainkoko ei ole merkitsevä. Esimerkiksi merkkijonot "omenat" ja "OMENAT" antavat tulokseksi samat solut.

Yleismerkkien käyttäminen

Ehdoissa voidaan käyttää yleismerkkejä eli kysymysmerkkiä (?) ja tähteä (*). Kysymysmerkki vastaa mitä tahansa yksittäistä merkkiä. Tähti vastaa mitä tahansa merkkijonoa. Jos haluat löytää tekstissä olevan kysymysmerkin tai tähden, kirjoita tilde (~) ennen kysymysmerkkiä.

Esimerkiksi kaava =LASKE.JOS(A2:A5;"omena?") laskee kaikki omena-sanan esiintymät, joissa sanan viimeinen kirjain voi vaihdella.

Varmista, ettei tiedoissa ole virheellisiä merkkejä.

Kun lasket tekstiarvoja, tarkista, ettei tietojen alussa tai lopussa ole välilyöntejä, ettei tiedoissa ole käytetty epäyhtenäisesti suoria ja kaarevia lainausmerkkejä ja ettei mukana ole tulostumattomia merkkejä. Muussa tapauksessa LASKE.JOS-funktio saattaa palauttaa odottamattoman arvon.

Kokeile SIIVOA-funktiota tai POISTA.VÄLIT-funktiota.

Käytä kätevyyden takia nimettyjä alueita

LASKE.JOS tukee kaavassa nimettyjä alueita (kuten =LASKE.JOS(hedelmät,">=32")-LASKE.JOS(hedelmät,">85"). Nimetty alue voi olla nykyisessä laskentataulukossa, saman työkirjan toisessa laskentataulukossa tai eri työkirjassa. Jos viittauksessa käytetään toista työkirjaa, myös toisen työkirjan on oltava avoinna.

Huomautus: LASKE.JOS-funktio ei laske soluja solun taustan tai fontin värin perusteella. Excel tukee kuitenkin käyttäjän määrittämiä funktioita (UDF), kun käytetään Microsoft Visual Basic for Applications (VBA) -toimintoja soluihin niiden taustan tai fontin värin perusteella. Seuraavassa on esimerkki siitä, miten voit laskea tietyn väristen solujen määrän VBA-toimintojen avulla.

Tarvitsetko lisätietoja?

Voit aina kysyä neuvoa Excel Tech Community -yhteisön asiantuntijalta tai saada tukea tukiyhteisöltä.

Tutustu myös seuraaviin ohjeaiheisiin

LASKE.JOS.JOUKKO-funktio

JOS-funktio

LASKE.A-funktio

Yleiskuva kaavoista Excelissä

JOSS-funktio

SUMIF function

Tarvitsetko lisäohjeita?

Haluatko lisää vaihtoehtoja?

Tutustu tilausetuihin, selaa harjoituskursseja, opi suojaamaan laitteesi ja paljon muuta.

Osallistumalla yhteisöihin voit kysyä kysymyksiä ja vastata niihin, antaa palautetta sekä kuulla lisää asiantuntijoilta, joilla on runsaasti tietoa.

Oliko näistä tiedoista hyötyä?

Kuinka tyytyväinen olet käännöksen laatuun?
Mikä vaikutti kokemukseesi?
Kun valitset Lähetä, palautettasi käytetään Microsoftin tuotteiden ja palveluiden parantamiseen. IT-järjestelmänvalvojasi voi kerätä nämä tiedot. Tietosuojatiedot.

Kiitos palautteesta!

×