TEKSTI-funktiolla voit muuttaa numeroiden ulkonäköä muotoilemalla niitä muotoilukoodeilla. Tämä on hyödyllistä tilanteissa, joissa haluat näyttää numerot luettavammassa muodossa tai haluat yhdistää numerot tekstin tai symbolien kanssa.
Huomautus: TEKSTI-funktio muuntaa luvut tekstiksi, mikä voi vaikeuttaa viittausta myöhemissä laskutoimituksissa. Alkuperäinen arvo kannattaa säilyttää yhdessä solussa ja käyttää sitten TEKSTI-funktiota toisessa solussa. Tämän jälkeen voit tarvittaessa luoda muita kaavoja viittaamalla aina alkuperäiseen arvoon, ei TEKSTI-funktion tulokseen.
Syntaksi
TEKSTI(arvo, muoto_teksti)
TEKSTI-funktion syntaksissa on seuraavat argumentit:
|
Argumentin nimi |
Kuvaus |
|
arvo |
Numeerinen arvo, jonka haluat muuntaa tekstiksi. |
|
muoto_teksti |
Tekstimerkkijono, joka määrittää muotoilun, jota haluat käyttää annettuun arvoon. |
Yleistä
Yksinkertaisimmillaan TEKSTI-funktio on seuraavanlainen:
-
=TEKSTI(muotoiltava arvo, "käytettävä muotoilukoodi")
Tässä on muutamia suosittuja esimerkkejä, jotka voit kopioida suoraan Exceliin, jotta voit kokeilla itse. Huomaa, että muotoilukoodit ovat lainausmerkeissä.
|
Kaava |
Kuvaus |
|---|---|
|
=TEKSTI(1234.567,"$#,##0.00") |
Valuutta, jossa on tuhaterotin ja kaksi desimaalia, kuten $1,234.57. Huomaa, että Excel pyöristää arvon kahden desimaalin tarkkuudella. |
|
=TEKSTI(TÄMÄ.PÄIVÄ(),"P.K.VVVV") |
Tämän päivän päivämäärä muodossa P.K.VVVV, esimerkiksi 14.3.2012 |
|
=TEKSTI(TÄMÄ.PÄIVÄ(),"PPPP") |
Tämän päivän viikonpäivä, kuten maanantai |
|
=TEKSTI(NYT(),"T:MM") |
Nykyinen kellonaika, esimerkiksi 13:29 |
|
=TEKSTI(0.285,"0.0%") |
Prosentti, esimerkiksi 28,5 % |
|
=TEKSTI(4.34 ,"# ?/?") |
Murtoluku, esimerkiksi 4 1/3 |
|
=POISTA.VÄLIT(TEKSTI(0.34,"# ?/?")) |
Murtoluku, esimerkiksi 1/3 Huomaa, että POISTA.VÄLIT-funktiolla voi poistaa desimaaliarvon alussa olevat välilyönnit. |
|
=TEKSTI(12200000,"0.00E+00") |
Tieteellinen merkintätapa, esimerkiksi 1.22E+07 |
|
=TEKSTI(1234567898,"[<=9999999]###-####;(###) ###-####") |
Erikoismuotoilu (puhelinnumero), esimerkiksi (123) 456-7898 |
|
=TEKSTI(1234,"0000000") |
Lisää nollia (0) alkuun, esimerkiksi 0001234 |
|
=TEKSTI(123456,"##0° 00' 00''") |
Mukautettu – leveys-/pituusaste |
Huomautus: TEKSTI-funktiolla voidaan muuttaa muotoilua, mutta se ei ole kuitenkaan ainoa tapa. Voit muuttaa muotoilua ilman kaavaa painamalla näppäinyhdistelmää CTRL+1 (tai 
Lataa Microsoftin esimerkkejä
Voit ladata esimerkkityökirjan, joka sisältää kaikki tästä artikkelista löytyvät TEKSTI-funktioita koskevat esimerkit sekä muutaman lisäesimerkin. Voit seurata tai luoda omia TEKSTI-funktion muotoilukoodeja.
Lataa esimerkkejä Excelin TEKSTI-funktioista
Muut käytettävissä olevat muotoilukoodit
Voit etsiä muut käytettävissä olevat muotoilukoodit Muotoile solut -valintaikkunan avulla:
-
Avaa Muotoile solut -valintaikkuna painamalla näppäinyhdistelmää Ctrl+1 (
-
Valitse haluamasi muoto Luku-välilehdeltä.
-
Valitse Mukautettu-vaihtoehto .
-
Haluamasi muotoilukoodi näkyy nyt Laji-ruudussa. Valitse tässä tapauksessa koko Laji-ruudun sisältö, lukuun ottamatta puolipistettä (;) ja @-merkkiä. Seuraavassa esimerkissä valittuna ja kopioituna on vain p.k.vvvv.
-
Kopioi muotoilukoodi painamalla näppäinyhdistelmää Ctrl+C ja hylkää muotoile solut -valintaikkuna painamalla Peruuta.
-
Nyt sinun tarvitsee vain liittää muotoilukoodi TEKSTI-kaavaan painamalla näppäinyhdistelmää Ctrl+V, esimerkki: =TEKSTI(B2,"p.k.vvvv"). Varmista, että liität muotoilukoodin lainausmerkeissä ("muotoilukoodi"), muuten Excel antaa virhesanoman.
Muotoilukoodit luokittain
Seuraavassa on esimerkkejä siitä, miten voit käyttää arvoissa eri lukumuotoiluja Muotoile solut -valintaikkunan avulla ja kopioida sitten muotoilukooditTEKSTI-funktioonMukautettu-vaihtoehdon avulla.
Miksi Excel poistaa alussa olevat nollat (0)?
Excelin tehtävänä on etsiä soluihin kirjoitettavia numeroita, ei tekstiltä näyttäviä numeroita, kuten osanumerot tai SKU:t. Jos haluat säilyttää etunollat, muotoile syöttöalue tekstiksi ennen arvojen liittämistä tai syöttämistä. Valitse sarake tai alue, johon lisäät arvot, ja paina näppäinyhdistelmää CTRL+1, jolloin Muotoile solut -valintaikkuna avautuu. Valitse Luku-välilehdelläTeksti. Nyt Excel säilyttää alussa olevat nollat.
Jos olet jo syöttänyt tiedot ja Excel on poistanut etunollat, voit lisätä ne takaisin käyttämällä TEKSTI-funktiota. Voit viitata arvot sisältävään ylärivin soluun ja käyttää muotoa =TEKSTI(arvo,”00000”), jossa kaavassa olevien nollien määrä ilmoittaa halutun merkkien kokonaismäärän. Kopioi ja liitä tämä alueen loppuosaan.
Jos sinun on jostain syystä muunnettava tekstiarvot takaisin luvuiksi, voit kertoa ne luvulla 1, esimerkiksi =D4*1, tai käyttää kaksoisunaarioperaattoria (--), esimerkiksi =--D4.
Excel käyttää tuhaterottimena pilkkua, jos kaavassa on pilkku (,) numeromerkkien (#) tai nollien ympäröimänä. Jos muotoilumerkkijono on esimerkiksi "#,###", Excel näyttää luvun 12200000 muodossa 12,200,000.
Lukupaikkamerkin jälkeen tuleva pilkku skaalaa luvun tuhannella. Jos muotoilumerkkijono on esimerkiksi "#,###.0,", Excel näyttää luvun 12200000 muodossa 12,200.0.
Huomautukset:
-
Tuhaterotin riippuu aluekohtaisista asetuksista. Yhdysvalloissa se on pilkku, mutta muilla alueilla se voi olla piste (.).
-
Tuhaterotin on saatavilla luku-, valuutta- ja laskentamuotoiluissa.
Seuraavassa on esimerkkejä tavallisista luku- (vain tuhaterotin ja desimaalit), valuutta- ja laskentamuotoiluista. Valuuttamuotoilun avulla voit lisätä haluamasi valuuttasymbolin ja liittää sen arvon viereen. Laskentamuotoilu tasaa valuuttasymbolin solun vasemmalle puolelle ja arvon oikealle. Huomaa, että alla olevissa valuutta- ja laskentamuotoilukoodeissa on eroa, sillä laskennassa käytetään tähteä (*) symbolin ja arvon erottamiseksi.
Etsi valuuttasymbolin muotoilukoodi painamalla ensin näppäinyhdistelmää Ctrl+1 (tai
Valitse sitten Oma vasemmalta Luokka-osasta ja kopioi muotoilukoodi, mukaan lukien valuuttasymboli.
Huomautus: TEKSTI-funktio ei tue värimuotoilua, joten jos kopioit Muotoile solut -valintaikkunasta värin sisältävän numeromuotoilukoodin, kuten: $#,##0.00_);[Punainen]($#,##0.00), TEKSTI-funktio hyväksyy muotoilukoodin, mutta ei näytä väriä.
Voit muuttaa päivämäärän näyttötapaa käyttämällä kirjaimia "P" (päivä), "K" (kuukausi) ja "V" (vuosi).
TEKSTI-funktion muotoilukoodit eivät tee eroa isojen ja pienten kirjainten välillä, joten voit käyttää joko muotoa "P" tai "p", "K" tai "k" ja "V" tai "v".
|
|
Mynda suosittelee... Jos jaat Excel-tiedostoja ja -raportteja eri maista kotoisin oleville käyttäjille, haluat ehkä tarjota raportin heille heidän omalla kielellään. Excel-MVP-asiantuntija Mynda Treacy esittää tähän kätevän ratkaisun artikkelissa Excel-päivämäärien näyttäminen eri kielillä. Artikkelissa on myös mallityökirja, jonka voit ladata. |
Voit muuttaa kellonajan näyttötapaa käyttämällä kirjaimia "T" (tunti), "M" (minuutti) ja "S" (sekunti) sekä "AM/PM"-merkintää 12 tunnin järjestelmässä.
Jos jätät "AM/PM"- tai "A/P"-merkinnän pois, aika näytetään 24 tunnin järjestelmän mukaan.
TEKSTI-funktion muotoilukoodit eivät tee eroa isojen ja pienten kirjainten välillä, joten voit käyttää joko muotoa "T" tai "t", "M" tai "m", "S" tai "s" ja "AM/PM" tai "am/pm".
Voit muuttaa desimaaliarvojen näyttötapaa prosenttimuodoissa (%).
Voit muuttaa desimaaliarvojen näyttötapaa murtoluvuissa (?/?). Muodoissa.
Tieteellinen merkintätapa on lukujen näyttötapa desimaalin ollessa 1–10 kerrottuna 10:llä. Sitä käytetään usein lyhentämään suurten lukujen näyttötapaa.
Excelissä on neljä erikoismuotoilua:
-
Postinumero – "00000"
-
Postinumero + 4 – "00000-0000"
-
Puhelinnumero – "[<=9999999]###-####;(###) ###-####"
-
Henkilötunnus – "000-00-0000"
Erikoismuotoilut ovat aluekohtaisia, mutta jos omalla alueellasi ei ole mitään erikoismuotoiluja tai jos nämä erikoismuotoilut eivät vastaa tarpeitasi, voit luoda omat muotoilut Muotoile solut > Oma-valintaikkunassa.
Yleinen skenaario
TEKSTI-funktiota käytetään vain harvoin yksinään. Yleensä sitä käytetään yhdessä jonkin muun funktion kanssa. Oletetaan, että haluat yhdistää tekstin ja numeroarvon, kuten ”Raportti tulostettu 03/14/12” tai ”Viikkotuotto: $66,348.72”. Voit kirjoittaa tiedot Exceliin manuaalisesti, mutta tällöin Excel ei tee sitä puolestasi. Kun yhdistät tekstin ja muotoillut luvut, kuten päivämäärän, kellonajan tai valuutan, Excel ei valitettavasti tiedä, miten haluat näyttää ne, joten se ei muotoile lukuja. Tässä kohdassa TEKSTI-funktio muuttuu korvaamattomaksi, koska sen avulla voit pakottaa Excelin muotoilemaan arvot haluamallasi tavalla käyttämällä muotoilukoodia, kuten "P.K.VVVV" päivämäärän muotoilussa.
Seuraavassa esimerkissä näkyy, mitä tapahtuu, jos yrität yhdistää tekstin ja luvun käyttämättä TEKSTI-funktiota. Tässä tapauksessa käytämme et-merkkiä (&), jotta tekstimerkkijono, välilyönti (" ") ja arvo voidaan liittää yhteen =A2&" "&B2.
Kuten näet, Excel poisti solun B2 päivämäärän muotoilun. Seuraavassa esimerkissä näet, miten voit käyttää haluamaasi muotoilua TEKSTI-funktion avulla.
Päivitetty kaava on seuraava:
-
Solu C2:=A2&" "&TEKSTI(B2,"p.k.vvvv") – päivämäärämuoto
Usein kysyttyjä kysymyksiä
Valitettavasti et voi tehdä sitä TEKSTI-funktiolla; sinun on käytettävä Visual Basic for Applications (VBA) -koodia. Seuraavassa linkissä on menetelmä: Numeerisen arvon muuntaminen englanninkieliseksi sanaksi Excelissä.
Kyllä, mutta se vaatii muutamia vaiheita. Valitse ensin solu tai solut, joissa haluat tämän tapahtuvan, ja avaa Muotoile > solut -valintaikkuna Painamalla näppäinyhdistelmää Ctrl+1. Valitse sitten Tasaus > Teksti-ohjausobjekti > valitse Rivitä teksti -vaihtoehto. Säädä seuraavaksi valmista TEKSTI-funktiotasi siten, että se sisältää ASCII-funktion MERKKI(10) kohdassa, johon haluat lisätä rivinvaihdon. Sarakkeen leveyttä on ehkä muutettava lopputuloksena syntyvän tasauksen mukaan.
Tässä tapauksessa käytetty kaava: ="Tänään on: "&MERKKI(10)&TEKSTI(TÄMÄ.PÄIVÄ(),"p.k.vvvv")
Tätä kutsutaan Funktiolaskin-merkinnäksi, ja Excel muuntaa automaattisesti yli 12 numeroa pidemmät luvut, jos solut on muotoiltu yleisiksi, ja 15 numeroa, jos solut on muotoiltu luvuiksi. Jos haluat kirjoittaa pitkiä numeerisia merkkijonoja, mutta et halua muuntaa niitä, muotoile kyseiset solut tekstiksi , ennen kuin syötät tai liität arvot Exceliin.
|
|
Mynda suosittelee... Jos jaat Excel-tiedostoja ja -raportteja eri maista kotoisin oleville käyttäjille, haluat ehkä tarjota raportin heille heidän omalla kielellään. Excel-MVP-asiantuntija Mynda Treacy esittää tähän kätevän ratkaisun artikkelissa Excel-päivämäärien näyttäminen eri kielillä. Artikkelissa on myös mallityökirja, jonka voit ladata. |
Katso myös
Mukautetun lukumuotoilun luominen tai poistaminen
