SUMMA (SUMMA-funktio)

SUMMA-funktio on yksi matemaattisista ja trigonometrisista funktiosta. Se laskee arvot yhteen. Voit lisätä yksittäisiä arvoja, soluviittauksia tai -alueita tai näiden kaikkien kolmen yhdistelmän.

Esimerkki:

  • =SUMMA(A2:A10)

  • =SUMMA(A2:A10, C2:C10)

Selaimesi ei tue videotoimintoa. Asenna Microsoft Silverlight, Adobe Flash Player tai Internet Explorer 9.

Tämä video on osa Lukujen laskeminen yhteen Excel 2013:ssa -harjoituskurssia.

SUMMA(luku1,[luku2],...)

Argumentin nimi

Kuvaus

luku1    . (Pakollinen)

Ensimmäinen yhteenlaskettava luku. Luku voi olla esimerkiksi 4, soluviittaus, kuten B6, tai solu, alue, kuten B2:B8.

luku2–255    (Valinnainen)

Tämä on toinen yhteenlaskettava luku. Voit määrittää tällä tavalla enintään 255 lukua.

Jos haluat saada solualueen summan nopeasti, sinun tarvitsee vain valita alue ja katsoa Excel-ikkunan oikea alakulma.

Näyttökuva solualueen valitsemisesta ja sitten tilarivistä
Tilarivi


Tämä on tilarivi. Siinä näkyy tietoja valitusta kohteesta riippumatta siitä, onko kyseessä yksittäinen solu vai useita soluja. Jos napsautat tilariviä hiiren kakkospainikkeella, ominaisuuden valintaikkuna avautuu. Avautuvassa ikkunassa näkyvät kaikki valittavissa olevat vaihtoehdot. Huomaa, että tilarivillä näkyvät myös valitun alueen arvot, jos kyseiset määritteet ovat valittuina. Lue lisätietoja tilarivistä.

Ohjattu automaattisen summan toiminto on helpoin tapa lisätä SUMMA-kaava laskentataulukkoon. Valitse tyhjä solu yhteenlaskettavan alueen ylä- tai alapuolelta ja valitse valintanauhan Aloitus- tai Kaava-välilehdestä Automaattinen summa > Summa. Ohjattu automaattisen summan toiminto tunnistaa automaattisesti yhteenlaskettavan alueen ja luo kaavan puolestasi. Se toimii myös vaakasuunnassa, jos valitset solun yhteenlaskettavan alueen vasemmalta tai oikealta puolelta. Huomaa, että toiminto ei toimi alueille, jotka eivät ole yhtenäisiä, mutta saat ohjeet siihen seuraavassa osiossa.

Voit luoda SUMMA-kaavan ohjatulla automaattisen summan toiminnolla.  Valitse solualue yhteen laskettavan alueen ylä- tai alapuolella tai vasemmalla tai oikealla puolella. Siirry sitten valintanauhan Kaava-välilehteen ja valitse Automaattinen summa & SUMMA.
Yhtenäisten alueiden laskeminen nopeasti yhteen käyttämällä ohjattua automaattisen summan toimintoa


Voit valita automaattisen summan valintaikkunassa myös muita yleisiä toimintoja, kuten:

Automaattinen summa pystysuunnassa

Solussa B6 näkyy automaattisen summan SUMMA-kaava: =SUMMA(B2:B5)

Ohjattu automaattisen summan toiminto on tunnistanut automaattisesti solut B2:B5 yhteenlaskettavaksi alueeksi. Sinun tarvitsee vain vahvistaa se painamalla Enter-näppäintä. Jos haluat lisätä tai poistaa lisää soluja, paina näppäinyhdistelmää Vaihto+nuolinäppäin, kunnes valinta on haluamasi. Paina lopuksi Enter-näppäintä.

IntelliSense-funktion opas: funktion alla oleva irrallinen SUMMA(luku1,[luku2], …) tunniste on sen Intellisense-opas. Jos napsautat SUMMA-kohtaa tai funktion nimeä, se muuttuu siniseksi hyperlinkiksi, joka johtaa kyseisen funktion ohjeaiheeseen. Jos napsautat yksittäisiä funktio-osia, niitä vastaavat kaavan osat korostetaan. Tässä tapauksessa vain B2:B5 korostetaan, koska kaavassa on vain yksi lukuviittaus. IntelliSense-tunniste näkyy kaikissa funktioissa.

Automaattinen summa vaakasuunnassa

Solussa D2 näkyy automaattisen summan SUMMA-kaava: =SUMMA(B2:C2)

SUMMA-funktion käyttäminen erillisissä alueissa  Solussa C8 oleva kaava on =SUMMA(C2:C3,C5:C6). Voit käyttää myös nimettyjä alueita, jolloin kaava on muodossa =SUMMA(Viikko1,Viikko2).

Ohjattu automaattisen summan toiminto toimii yleensä vain yhtenäisissä solualueissa, joten jos summan alueella on tyhjiä rivejä tai sarakkeita, Excel pysähtyy niistä ensimmäiseen. Tässä tapauksessa SUMMA-funktiossa on käytettävä valintaa, jossa lisäät erilliset alueet yksitellen. Jos tässä esimerkissä tietoja on solussa B4, Excel luo kaavan =SUMMA(C2:C6), koska se tunnistaa yhtenäisen solualueen.

Voit valita nopeasti useita erillisiä alueita Ctrl + napsautus vasemmalla painikkeella -yhdistelmällä. Kirjoita ensin ”=SUMMA(” ja valitse sitten haluamasi alueet. Excel lisää automaattisesti pilkkuerottimen alueiden väliin. Paina Enter-näppäintä, kun olet valmis.

VIHJE: Voit lisätä SUMMA-funktion nopeasti soluun näppäinyhdistelmällä ALT+ =. Sen jälkeen sinun tarvitsee vain valita alue tai alueet.

Huomautus: Saatat huomata, että Excel on korostanut eri solualueet väreillä, jotka vastaavat kaavassa olevia värejä, joten C2:C3 on tietyn värinen ja C5:C6 on toisen värinen. Excel tekee tämän kaikille funktioille, kunhan viitattu alue ei ole toisessa laskentataulukossa tai toisessa työkirjassa. Voit parantaa helppokäyttöisyyttä helppokäyttöohjelmien yhteydessä käyttämällä nimettyjä alueita, kuten ”Viikko1” ja ”Viikko2”. Sen jälkeen voit viitata niihin kaavassa:

=SUMMA(Viikko1,Viikko2)

Voit suorittaa Excelissä yksinkertaisia laskutoimituksia erikseen ja yhdessä Excel-funktioiden, kuten SUMMA-funktion kanssa. Seuraavassa taulukossa on lueteltu operaattorit, joita voit käyttää, sekä joitakin niihin liittyviä funktioita. Voit syöttää operaattorit joko näppäimistön numeroriviltä tai numeronäppäimistöltä. Esimerkiksi Vaihto+8 syöttää tähden (*) kertolaskua varten.

Operaattori

Toiminto

Esimerkkejä

+

Yhteenlasku

=1+1

=A1+B1

=SUMMA(A1:A10)+10

=SUMMA(A1:A10)+B1

-

Vähennyslasku

=1-1

=A1-B1

=SUMMA(A1:A10)-10

=SUMMA(A1:A10)-B1

*

Kertolasku

=1*1

=A1*B1

=SUMMA(A1:A10)*10

=SUMMA(A1:A10)*B1

=TULO(1;1) - TULO-funktio

/

Jakolasku

=1/1

=A1/B1

=SUMMA(A1:A10)/10

=SUMMA(A1:A10)/B1

=OSAMÄÄRÄ(1;1) - OSAMÄÄRÄ-funktio

^

Potenssiin korotus

=1^1

=A1^B1

=SUMMA(A1:A10)^10

=SUMMA(A1:A10)^B1

=POTENSSI(1;1) - POTENSSI-funktio

Lisätietoja on artikkelissa Excelin käyttäminen laskimena.

Muita esimerkkejä

  1. Oletetaan, että haluat käyttää prosenttialennusta solualueeseen, jonka olet laskenut yhteen.

    Operaattorien käyttäminen SUMMA-funktion kanssa  Solussa B16 oleva kaava on =SUMMA(A2:A14)*-25%.  Kaava olisi rakenteeltaan oikein, jos -25% olisi soluviittaus, esimerkiksi =SUMMA(A2:A14)*E2
    • =SUMMA(A2:A14)*-25%

    Tämä kaava antaa yhteenlasketusta alueesta 25 %, mutta 25 % on kovakoodattu kaavaan, joten sen löytäminen ja muuttaminen myöhemmin voi olla hankalaa. Paljon parempi vaihtoehto on kirjoittaa 25 % soluun ja viitata siihen. Tällöin arvo on näkyvissä ja helposti muutettavissa seuraavasti:

    • =SUMMA(A2:A14)*E2

    Jos haluat jakaa kertomisen sijaan, korvaa *-merkki /-merkillä: =SUMMA(A2:A14)/E2

  2. Lisääminen tai vähentäminen SUMMA-funktiossa

    i. Voit helposti lisätä tai vähentää SUMMA-funktiossa käyttämällä merkkejä + ja - seuraavasti:

    • =SUMMA(A1:A10)+E2

    • =SUMMA(A1:A10)-E2

Tässä osassa käydään läpi SUMMA-funktion käyttöön liittyviä parhaita käytäntöjä. Näistä monia voi soveltaa myös muiden funktioiden käyttöön.

Menetelmä =1+2 tai =A+B: Vaikka syöttämällä =1+2+3 tai =A1+B1+C2 saa tarkkoja tuloksia, nämä menetelmät ovat virhealttiita useista syistä:

  1. Kirjoitusvirheet: kuvittele, millaista on syöttää useita ja/tai paljon suurempia arvoja, kuten

    • =14598,93+65437,90+78496,23

    Yritä sen jälkeen vahvistaa, että olet syöttänyt oikeat tiedot. On paljon helpompaa syöttää arvot omiin soluihinsa ja käyttää SUMMA-kaavaa. Voit lisäksi muotoilla arvot, kun ne ovat soluissa, jolloin ne ovat paljon luettavammassa muodossa kuin kaavassa.

    Käytä SUMMA-funktiota sen sijaan, että koodaat arvot kiinteästi kaavoihin.  Solussa D5 oleva kaava on =SUMMA(D2:D4)
  2. #ARVO!-virheet viitattaessa tekstiin numeroiden sijasta.

    Jos käytät esimerkiksi seuraavanlaista kaavaa:

    • =A1+B1+C1 tai =A1+A2+A3

    Esimerkki kaavan huonosta rakenteesta  Solussa D2 oleva kaava on =A2+B2+C2

    Kaava voi rikkoutua, jos viitatuissa soluissa on muita kuin numeroarvoja (tekstiä). Tällöin tuloksena on #ARVO!-virhe. SUMMA-funktio ohittaa tekstiarvot ja ilmoittaa vain numeeristen arvojen summan.

    Kaavan oikea rakenne  Kaavan =A2+B2+C2 sijasta solun D2 kaava on =SUMMA(A2:C2)
  3. #VIITTAUS!-virhe rivien tai sarakkeiden poistamisen takia

    Sarakkeen poistamisesta johtuva #VIITTAUS!-virhe  Kaava on muuttunut muotoon =A2+#VIITTAUS!+B2

    Jos poistat rivin tai sarakkeen, kaava ei päivity ja sulje pois poistettua riviä. Tuloksena on #VIITTAUS!-virhe. SUMMA-funktio sen sijaan päivittyy automaattisesti.

    SUMMA-funktio säätyy automaattisesti lisättyjen tai poistettujen rivien ja sarakkeiden mukaan.
  4. Kaavat eivät päivitä viittauksia lisättäessä rivejä tai sarakkeita

    Muodossa =A+B+C olevat kaavat eivät päivity, kun rivejä lisätään.

    Jos lisäät rivin tai sarakkeen, kaava ei päivity ja sisällytä lisättyä riviä. SUMMA-funktio puolestaan päivittyy automaattisesti (kunhan olet kaavassa viitatulla alueella). Tämä on erityisen tärkeää, jos oletat, että kaava päivittyy mutta se ei päivitykään. Tällöin saat puutteelliset tulokset, mikä saattaa jäädä huomaamatta.

    Esimerkissä kuvataan SUMMA-kaava, joka laajenee automaattisesti muodosta =SUMMA(A2:C2) muotoon =SUMMA(A2:D2), kun sarake lisätään.
  5. SUMMA ja yksittäiset soluviittaukset vs. alueet

    Seuraavanlaisen kaavan käyttäminen:

    • =SUMMA(A1,A2,A3,B1,B2,B3)

    Tällainen kaava on yhtä virhealtis lisättäessä tai poistettaessa rivejä viitatulta alueelta samoista syistä. On paljon parempi käyttää yksittäisiä alueita, kuten:

    • =SUMMA(A1:A3,B1:B3)

    Ne päivittyvät, kun rivejä lisätään tai poistetaan.

  1. Voit käyttää SUMMA-kaavaa myös muiden funktioiden kanssa. Tässä on esimerkki, jossa lasketaan kuukausittainen keskiarvo:

    SUMMA-kaavan käyttäminen muiden funktioiden kanssa  Solussa M2 oleva kaava on =SUMMA(A2:L2)/LASKE.A(A2:L2) .  Huomautus: sarakkeet toukokuusta marraskuuhun on piilotettu selvyyden vuoksi.
    • =SUMMA(A2:L2)/LASKE.A(A2:L2)

  2. Kaavassa alueen A2:L2 SUMMA jaetaan muiden kuin tyhjien solujen määrällä alueelta A2:L2 (solut ovat tyhjiä toukokuusta joulukuuhun).

  1. Joskus tietty solu on laskettava yhteen useissa laskentataulukoissa. Jokaisen taulukon ja solun napsauttaminen sekä soluarvojen laskeminen yhteen käyttämällä +-merkkiä voi tuntua houkuttelevalta, mutta kyseinen tapa on työläs ja virhealtis.

    • =Taul1!A1+Taul2!A1+Taul3!A1

    Tämä onnistuu paljon helpommin 3D SUMMA -funktiolla (3-ulotteinen summa):

    3D SUMMA – solussa D2 oleva kaava on =SUMMA(Taul1:Taul3!A2)
    • =SUMMA(Taul1:Taul3!A1)

    Tämä laskee yhteen solun A1 kaikissa taulukoissa Taulukosta 1 Taulukkoon 3.

    Tästä on hyötyä erityisesti silloin, kun jokaiselle kuukaudelle (tammikuu–joulukuu) on oma taulukko ja ne on laskettava yhteen yhteenvetotaulukossa.

    3D SUMMA nimetyissä laskentataulukoissa  Solussa D2 oleva kaava on =SUMMA(Tammikuu:Joulukuu!A2)
    • =SUMMA(Tammikuu:Joulukuu!A2)

    Tämä laskee yhteen solun A2 jokaisessa taulukossa Tammikuusta Joulukuuhun.

    Huomautukset: Jos laskentataulukoiden nimissä on välilyöntejä, kuten ”Tammikuun myynti”, taulukon nimeen viitattaessa kaavassa on käytettävä heittomerkkiä: Huomaa, että ensimmäisen laskentataulukon nimen EDESSÄ ja viimeisen laskentataulukon PERÄSSÄ on heittomerkki.

    • =SUMMA(‘Tammikuun myynti:Joulukuun myynti’!A2)

    3D-menetelmä toimii myös muiden funktioiden, kuten KESKIARVO, MIN ja MAKS, kanssa:

    • =KESKIARVO(Taul1:Taul3!A1)

    • =MIN(Taul1:Taul3!A1)

    • =MAKS(Taul1:Taul3!A1)

Ongelma

Mistä ongelma johtuu?

SUMMA-funktioni ei näytä tulosta, vaan merkkijonon #####.

Tarkista sarakeleveydet. ##### tarkoittaa yleensä, että sarake on niin kapea, ettei kaavan tulos mahdu siihen.

SUMMA-funktio näyttää kaavan itsensä tekstinä, ei tulosta.

Tarkista, ettei solua ole muotoiltu tekstiksi. Valitse kyseinen solu tai solualue ja paina Ctrl + 1, jolloin Muotoile solut -valintaikkuna avautuu, valitse Luku-välilehti ja valitse haluamasi muoto. Jos solu on muotoiltu tekstiksi eikä se muutu, kun muutat muotoilua, pakota muotoilun muutos painamalla F2 > Enter.

SUMMA-funktioni ei päivity.

Varmista, että Laskenta-asetukseksi on määritetty Automaattinen. Siirry Kaava-välilehdessä kohtaan Laskenta-asetukset. Voit myös pakottaa laskentataulukon laskennan painamalla F9.

Varmista, että laskennan asetukseksi on määritetty Automaattinen.  Siirry Kaava-välilehdessä kohtaan Laskenta-asetukset.

Joitakin arvoja ei lisätä.

Ainoastaan funktioviittauksen tai alueen lukuarvot voidaan laskea. Tyhjät solut, totuusarvot, kuten TOSI, ja teksti ohitetaan.

Virhe #NIMI? tulee näkyviin odotetun tuloksen sijaan.

Tämä tarkoittaa yleensä, että kaavassa on kirjoitusvirhe, kuten =sume(A1:A10) kaavan =SUMMA(A1:A10) sijaan.

SUMMA-funktioni näyttää kokonaisluvun, mutta sen pitäisi näyttää desimaaleja

Varmista, että desimaalien näyttö on käytössä solumuotoilussa. Valitse kyseinen solu tai solualue ja painamalla Ctrl+1, jolloin Muotoile solut -valintaikkuna avautuu, valitse Luku-välilehti ja valitse haluamasi muoto. Varmista, että määrität haluamasi desimaalien määrän.

  1. Haluan vain laske yhteen, vähentää, kertoa tai jakaa lukuja Katso videosarja Excelin matemaattiset perustoiminnot tai Excelin käyttäminen laskimena.

  2. Miten voin näyttää enemmän tai vähemmän desimaaleja? – Voit muuttaa lukumuotoilua. Valitse kyseinen solu tai solualue ja paina Ctrl+1, jolloin Muotoile solut -valintaikkuna avautuu, valitse Luku-välilehti ja valitse haluamasi muoto. Varmista, että määrität haluamasi desimaalien määrän.

  3. Miten aikoja lasketaan yhteen ja vähennetään? Voit laskea yhteen ja vähentää aikamääriä muutamilla eri tavoilla. Jos esimerkiksi haluaisit palkanlaskua varten laskea erotuksen välillä 8.00–12.00, käyttäisit kaavaa =("12.00"-"8.00")*24, eli vähentäisit päättymisajasta alkamisajan. Huomaa, että Excel laskee ajat vuorokauden murto-osina, joten tuntien määrän saamiseksi on käytettävä kertoimena arvoa 24. Ensimmäisessä esimerkissä lasketaan kaavan =((B2-A2)+(D2-C2))*24 avulla yhteen tunnit alusta loppuun ilman lounastaukoa (yhteenä 8,50 tuntia).

    Jos vain lasket yhteen tunteja ja haluat näyttää laskutoimituksen niin, voit käyttää yhteenlaskua ilman kerrointa 24. Siksi toisessa esimerkissä käytetään kaavaa =SUMMA(A6:C6), koska annetuista tehtävistä tarvitaan vain tuntien ja minuuttien kokonaismäärä (5.36 tai 5 tuntia 36 minuuttia).

    Aikojen laskeminen

    Lisätietoja on seuraavissa artikkeleissa: Ajan lisääminen tai vähentäminen

  4. Miten voi laskea päivämäärien välisen eron? Voit laske yhteen ja vähentää päivämääriä kellonaikojen tapaan. Seuraavassa on hyvin yleinen esimerkki kahden päivämäärän välisten päivien määrän laskennasta. Kaava on yksinkertainen: =B2-A2. Avain sekä päivämäärien että kellonaikojen laskemiseen on, että aloitetaan päättymispäivästä tai -ajasta ja vähennetään siitä alkamispäivä tai -aika.

    Päivämääräerojen laskemisen

    Lisätietoja päivämäärien laskennasta on seuraavissa artikkeleissa: Laske kahden päivämäärän välissä olevien päivien määrä.

  5. Miten lasken yhteen vain näkyvät solut? Joskus, kun piilotat rivejä manuaalisesti tai näytät vain tietyt tiedot Pikasuodata-toiminnon avulla, voit halutessasi myös laskea yhteen vain näkyvät solut. Voit käyttää VÄLISUMMA-toimintoa. Jos käytät Excel-taulukossa summariviä, mikä tahansa avattavasta Summa-valikosta valitsemasi funktio syötetään automaattisesti välisummaksi. Lisätietoja on artikkelissa Excel-taulukon tietojen laskeminen yhteen.

Tarvitsetko lisätietoja?

Voit aina kysyä neuvoa Excel Tech Community -yhteisön asiantuntijalta, saada tukea yhteisön vastauksista tai ehdottaa uutta ominaisuutta tai parannusta Excel User Voice -sivustolla.

Tutustu myös seuraaviin ohjeaiheisiin

Katso video SUMMA-funktion käyttämisestä

SUMMA.JOS-funktio laskee yhteen ainoastaan yhden ehdon täyttävät arvot

SUMMA.JOS.JOUKKO-funktio laskee yhteen ainoastaan useita ehtoja täyttävät arvot

LASKE.JOS-funktio laskee ainoastaan yhden ehdon täyttävät arvot

LASKE.JOS.JOUKKO-funktio laskee ainoastaan useita ehtoja täyttävät arvot

Yleiskuva kaavoista Excelissä

Viallisten kaavojen ratkaiseminen

Kaavojen virheiden etsiminen ja korjaaminen

Excel for Windowsin pikanäppäimet

Excel for Macin pikanäppäimet

Matemaattiset ja trigonometriset funktiot

Excelin funktiot (aakkosjärjestyksessä)

Excelin funktiot (luokittain)

Kehitä taitojasi
Tutustu koulutusmateriaaliin
Saat uudet ominaisuudet ensimmäisten joukossa
Liity Office Insider -käyttäjiin

Oliko näistä tiedoista hyötyä?

Kiitos palautteesta!

Kiitos palautteestasi! Näyttää siltä, että Office-tukiedustajamme avusta voi olla sinulle hyötyä.

×