Maksujen ja säästöjen suunnittelu Excel-kaavojen avulla.

Omien raha-asioiden hoitaminen voi olla haaste, erityisesti silloin, kun yrität suunnitella maksuja ja säästöjä. Excel-kaavojen avulla voit laskea velkojesi ja sijoitustesi tulevan arvon, jotta sinun on helpompi laskea, kuinka kauan tavoitteiden saavuttaminen vie. Käytä seuraavia funktioita:

  • MAKSU laskee maksuerän lainalle, joka perustuu säännöllisiin maksueriin ja kiinteään korkoon.

  • NJAKSO laskee maksukausien määrän sijoitukselle, joka perustuu säännöllisiin, kiinteisiin maksueriin ja kiinteään korkoon.

  • NA palauttaa sijoituksen nykyarvon. Nykyarvo on tulevien maksuerien kokonaissumman arvo tällä hetkellä.

  • TULEVA.ARVO palauttaa säännöllisiin vakiomaksueriin ja kiinteään korkoon perustuvan sijoituksen tulevan arvon.

Luottokorttivelan kuukausierän laskeminen

Oletetaan, että erääntyvä saldo on 5 400 € ja vuosikorko 17 %. Kortilla ei osteta mitään muuta sillä aikaa, kun velka maksetaan pois.

Funktiolla MAKSU(korko;NJAKSO;NA)

=MAKSU(17%/12;2*12;5400)

saadaan tulokseksi kuukausierä 266,99 €, jolla velka maksetaan kahdessa vuodessa.

  • Korko-argumentti on laina-ajan korko. Esimerkiksi tässä kaavassa vuosikorko 17 % jaetaan 12:lla eli vuoden kuukausien määrällä.

  • NJAKSO-argumentilla 2*12 annetaan lainan maksukausien kokonaismäärä.

  • NA-argumentti (nykyarvo) on 5400.

Asuntolainan kuukausierän laskeminen

Käytetään esimerkkinä asuntoa, jonka hinta on 180 000 €, korko 5 % ja laina-aika 30 vuotta.

Funktiolla MAKSU(korko;NJAKSO;NA)

=MAKSU(5%/12;30*12;180000)

saadaan tulokseksi kuukausierä, joka on 966,28 € (ilman vakuutusta ja veroja).

  • Korko-argumentti on 5 % jaettuna vuoden 12 kuukaudella.

  • NJAKSO-argumentti on 30*12 eli 30 vuoden laina kerrottuna kunkin vuoden 12 kuukausierällä.

  • NA-argumentti on 180000 (lainan nykyarvo).

Unelmalomaa varten säästettävän kuukausittaisen summan laskeminen

Haluat säästää rahaa lomamatkaan, jolle lähdet kolmen vuoden päästä ja joka maksaa 8 500 €. Säästöjen vuosikorko on 1,5 %.

Funktiolla MAKSU(korko;NJAKSO;NA;TULEVA.ARVO)

=MAKSU(1,5%/12;3*12;0;8500)

saat tulokseksi, että 8 500 €:n säästäminen kolmessa vuodessa edellyttää 230,99 €:n säästämistä kuukausittain kolmen vuoden ajan.

  • Korko-argumentti on 1,5% jaettuna 12:lla eli vuoden kuukausien määrällä.

  • NJAKSO-argumentti on 3*12 kahdelletoista kuukausierälle kolmen vuoden ajalla.

  • NA (nykyarvo) on 0, koska tilin saldo on alussa nolla.

  • TULEVA.ARVO, jonka haluat säästää, on 8500.

Kuvitellaan, että säästät 8 500 €:n lomaan kolmen vuoden ajan, ja mietit, kuinka paljon sinun on siirrettävä tilillesi, jotta kuukausittainen säästö on 175,00 €. NA-funktio laskee, millainen alkutalletus tuottaa tulevan arvon.

Funktiolla NA(korko;NJAKSO;MAKSU;TULEVA.ARVO)

=NA(1,5%/12;3*12;-175;8500)

saadaan tulokseksi, että tarvitaan 1 969,62 €:n alkutalletus, jotta maksamalla kuukausittain 175,00 € voidaan säästää 8 500 € kolmessa vuodessa.

  • Korko-argumentti on 1,5%/12.

  • NJAKSO-argumentti on 3*12 (tai kaksitoista kuukausierää kolmen vuoden aikana).

  • MAKSU on -175 (maksat 175 € kuukaudessa).

  • TULEVA.ARVO on 8500.

Kulutusluoton maksamiseen menevän ajan laskeminen

Oletetaan, että sinulla on 2 500 €:n kulutusluotto, ja sopimuksen mukaan maksat 150 € kuussa 3 % vuosikorolla.

Funktiolla NJAKSO(korko;MAKSU;NA)

=NJAKSO(3%/12;-150;2500)

saat tulokseksi, että sinulta vie 17 kuukautta ja muutamia päiviä maksaa laina.

  • Korko-argumentti on 3%/12 vuoden kuukausierille.

  • MAKSU-argumentti on -150.

  • NA-argumentti (nykyarvo) on 2500.

Käsirahan laskeminen

Oletetaan, että haluat ostaa 19 000 €:n auton 2,9 % korolla kolmessa vuodessa. Haluat pitää kuukausierän 350 €:ssa, joten sinun on laskettava käsiraha. Tässä kaavassa NA-funktion tulos on lainasumma, joka vähennetään ostohinnasta, jotta saadaan käsiraha.

Funktiolla NA(korko;NJAKSO;MAKSU)

=19000-NA(2,9%/12;3*12;-350)

saadaan tulokseksi, että vaadittu käsiraha olisi 6 946,48 €.

  • Kaavassa annetaan ensin ostohinta 19 000 €. NA-funktion tulos vähennetään ostohinnasta.

  • Korko-argumentti on 2,9 % jaettuna 12:lla.

  • NJAKSO-argumentti on 3*12 (eli kaksitoista kuukausierää kolmen vuoden aikana).

  • MAKSU on -350 (maksat 350 € kuukaudessa).

Tietyn ajan säästökertymän laskeminen

Kun tililläsi on 500 €, kuinka paljon sinulla on 10 kuukauden kuluttua, jos talletat 200 € kuukaudessa 1,5 % korolla?

Funktiolla TULEVA.ARVO(korko;NJAKSO;MAKSU;NA)

=TULEVA.ARVO(1,5%/12;10;-200;-500)

saat tulokseksi, että 10 kuukauden kuluttua sinulla olisi 2 517,57 €:n säästöt.

  • Korko-argumentti on 1,5%/12.

  • NJAKSO-argumentti on 10 (kuukautta).

  • MAKSU-argumentti on -200.

  • NA-argumentti (nykyarvo) on -500.

Tutustu myös seuraaviin ohjeaiheisiin

MAKSU-funktio

NJAKSO-funktio

NA-funktio

TULEVA.ARVO-funktio

Kehitä taitojasi
Tutustu koulutusmateriaaliin
Saat uudet ominaisuudet ensimmäisten joukossa
Liity Office Insider -käyttäjiin

Oliko näistä tiedoista hyötyä?

Kiitos palautteesta!

Kiitos palautteestasi! Näyttää siltä, että Office-tukiedustajamme avusta voi olla sinulle hyötyä.

×