Mukautettujen arvopisteiden otsikoiden määrittäminen kaaviossa

Seuraavien VBA (Visual Basic for Applications) -ohjeiden avulla voit käyttää soluarvoja arvopisteiden otsikoina kaavioissa Excel for Mac. Voit käyttää toimintosarjaa seuraavasti:

1. Valitse Excelissä Työkalut , > Makrot > Tallenna uusi makro.

2. Valitse avattavasta Tallenna makro: -ruudusta Oma makrotyökirja.

   Huomautus: Tallentamalla VBA-toimintosarjan Omaan makrotyökirjaan voit käyttää sitä missä tahansa Excel-ilmentymässä. Tämä tarkoittaa, että sitä ei voi käyttää vain yhdessä työkirjassa.

3. Paina OK.

4. Siirry kohtaan Työkalut ,> Makrot > Lopeta tallennus.

5. Siirry kohtaan Työkalut > Makrot > Visual Basic Editor.

6. Visual Basic Editor (VBE) avautuu Excelin yläpuolelle. Laajenna vasemmassa siirtymisruudussa VBAProject (PERSONAL). XLSB) -kansio, jossa näkyy Moduuli1.

7. Kaksoisnapsauta Moduuli1,jolloin näkyviin tulee Koodi-ruutu, joka avautuu VBE-ikkunan oikeaan reunaan.

8. VBA-koodia, joka luotiin, kun tallensit uuden makron, ei tarvita, joten valitse kaikki ja paina sitten Delete-näppäintä. 

9. Valitse seuraavaksi VBA-koodi alla olevasta tekstiruudusta, kopioi se painamalla CMD+C ja liitä se sitten takaisin Koodi-ruutuuncmd+V-näppäimellä. Voit nyt poistua Visual Basic Editorista ja palata Exceliin.

10. Testaa makroa luomalla arvopisteiden otsikoita sisältävä kaavio. Valitse seuraavaksi mikä tahansa arvopisteen otsikko kaaviossa ja suorita makro valitsemalla Työkalut > Makrot > Makrot. Valitse SetCustomDataLabels ja paina sitten Suorita. Sinua pyydetään automaattisesti valitsemaan arvopisteen otsikkoalue, joten tee se ja paina sitten OK.  

    Huomautus: VBA-toimintosyistä ei voi kumota, joten kokeile tätä työkirjan kopiossa. Jos suoritat koodin etkä halua säilyttää tuloksia, sinun on suljettava työkirja tallentamatta sitä.

11. Kun suljet Excelin, varmista, että tallennat muutokset HENKILÖKOHTAISEEN. XLSB, jotta makro on käytettävissä tulevaisuudessa.

12. Kun haluat lisätä tai poistaa arvopisteiden otsikoita kaaviosta, valitse arvopisteiden otsikot ja suorita makro.

13. Excel >Asetukset > valintanauhan & työkalurivin avulla voit lisätä painikkeen makron suorittamiseen valintanauhasta tai työkaluriviltä.

Option Explicit

Sub SetCustomDataLabels()
' make sure a series is selected
    If TypeOf Selection Is DataLabels Or TypeOf Selection Is Point Then
        Selection.Parent.Select
    ElseIf TypeOf Selection Is DataLabel Then
        Selection.Parent.Parent.Select
    End If

    If TypeOf Selection Is Series Then
        Else
        MsgBox "Select a chart series and try again."
        Exit Sub
    End If

    If Selection.HasDataLabels Then
        'If the data labels from cells are already showing, stop showing them and exit.
        'If labels include other info (e.g., values or categories) this will still appear
        If Selection.DataLabels.ShowRange Then
            Selection.DataLabels.ShowRange = False
            Exit Sub
        End If
    End If
 
'Use the InputBox dialog to set the range for the data labels
    On Error Resume Next
        Dim rng As Range
        Set rng = Application.InputBox(Prompt:="Select data label range.", Title:="Data Label Range", Type:=8)
    On Error GoTo 0

    If rng Is Nothing Then Exit Sub ' clicked cancel
        If Selection.HasDataLabels Then
            'This will include the new text from cells into existing data labels
        Else
        'Otherwise add data labels (empty labels)
            Selection.HasDataLabels = True
            Selection.DataLabels.ShowValue = False
        End If
    
    'Create a string that includes the sheet name and range reference.
    Dim rngAddress As String
        rngAddress = "='" & rng.Worksheet.Name & "'!" & rng.Address(RowAbsolute:=True, ColumnAbsolute:=True, External:=False)
        Selection.DataLabels.Format.TextFrame2.TextRange.InsertChartField msoChartFieldRange, rngAddress, 0
        Selection.DataLabels.ShowRange = True

End Sub