Rakenduskoht
|
Objekt Application |
Tagastab objekti FileDialog, mis tähistab failidialoogiboksi ühte eksemplari.
expression.FileDialog(dialogType)
avaldis Nõutav. Avaldis, mis tagastab loendi Rakenduskoht objekti.
dialogType Nõutav MsoFileDialogType. Failitüübi dialoogiboks.
|
MsoFileDialogType’i väärtus võib olla üks järgmistest MsoFileDialogType’i konstantidest. |
|
msoFileDialogFilePicker |
|
msoFileDialogFolderPicker |
|
msoFileDialogOpen Microsoft Access ei toeta seda. |
|
msoFileDialogSaveAs Microsoft Access ei toeta seda. |
Kommentaarid
Microsoft Office Access 2007 ei toeta konstante msoFileDialogOpen ja msoFileDialogSaveAs.
Näide.
See näide selgitab objekti FileDialog kasutamist sellise dialoogiboksi kuvamiseks, mis lubab kasutajal valida ühe või mitu faili. Valitud failid lisatakse seejärel loendiboksi nimega FileList.
Private Sub cmdFileDialog_Click()
' Requires reference to Microsoft Office 11.0 Object Library.
Dim fDialog As Office.FileDialog
Dim varFile As Variant
' Clear listbox contents.
Me.FileList.RowSource = ""
' Set up the File Dialog.
Set fDialog = Application.FileDialog(msoFileDialogFilePicker)
With fDialog
' Allow user to make multiple selections in dialog box
.AllowMultiSelect = True
' Set the title of the dialog box.
.Title = "Please select one or more files"
' Clear out the current filters, and add our own.
.Filters.Clear
.Filters.Add "Access Databases", "*.ACCDB"
.Filters.Add "Access Projects", "*.ADP"
.Filters.Add "All Files", "*.*"
' Show the dialog box. If the .Show method returns True, the
' user picked at least one file. If the .Show method returns
' False, the user clicked Cancel.
If .Show = True Then
'Loop through each file selected and add it to our list box.
For Each varFile In .SelectedItems
Me.FileList.AddItem varFile
Next
Else
MsgBox "You clicked Cancel in the file dialog box."
End If
End With
End Sub
