Logige sisse Microsofti kontoga
Logige sisse või looge konto.
Tere!
Valige mõni muu konto.
Teil on mitu kontot
Valige konto, millega soovite sisse logida.
Teksti tükeldamine eraldi veergudesse funktsioonide abil

Tekstifunktsioone LEFT, MID, RIGHT, SEARCH ja LEN saate kasutada andmete tekstistringide töötlemiseks. Näiteks saate ühe lahtri ees-, kesk- ja perekonnanimed jaotada kolme eraldi veergu.

Tekstifunktsioonidega nimekomponentide levitamise võti on iga märgi asukoht tekstistringis. Tühikute asukohad tekstistringis on samuti olulised, kuna need tähistavad stringi nimekomponentide algust või lõppu.

Näiteks lahtris, mis sisaldab ainult ees- ja perekonnanime, algab perekonnanimi pärast tühiku esimest eksemplari. Mõni loendis olev nimi võib sisaldada keskmist nime, misjuhul algab perekonnanimi pärast tühiku teist eksemplari.

Selles artiklis kirjeldatakse, kuidas nende käepäraste funktsioonide abil mitmesugustest nimevormingutest erinevaid komponente ekstraktida. Teksti veergudeks teisendamise viisardi abil saate teksti tükeldada ka erinevateks veergudeks.

Näidisnimi

Kirjeldus

Eesnimi

Teine nimi

Perekonnanimi

Sufiks

1

Jeff Smith

Teine nimi puudub

Jeff

Sepp

2

Eric S. Kurjan

Ühe keskele algne

Eric

S.

Kurjan

3

Janaina B. G. Bueno

Kaks keskmist initsiaali

Janaina

B. G.

Bueno

4

Kahn, Wendy Beth

Eesnimi perekonnanimi koos komaga

Wendy

Beth

Kahn

5

Mary Kay D. Andersen

Kaheosaline eesnimi

Mary Kay

D.

Andersen

6

Paula Barreto de Mattos

Kolmeosaline perekonnanimi

Paula

Barreto de Mattos

7

James van Eaton

Kaheosaline perekonnanimi

James

van Eaton

8

Bacon Jr., Dan K.

Perekonnanimi ja eesliide koos komaga

Dan

K.

Peekon

Jr.

9

Gary Altman III

Järelliidetega

Gary

Altman

III

10

Hr Ryan Ihrig

Eesliide

Ryan

Ihrig

11

Julie Taft-Rider

Poolitatud perekonnanimi

Julia

Taft-Rider

Märkus.: Järgmiste näidete piltidel kuvatakse täisnime esiletõstmisel märk, mida vastav otsinguvalem otsib.

Selles näites on eraldatud kaks komponenti: eesnimi ja perekonnanimi. Kahte nime eraldab üks tühik.

Kopeerige tabeli lahtrid ja kleepige need Exceli töölehele lahtris A1. Vasakul kuvatav valem kuvatakse viitamiseks, Excel teisendab paremal asuva valemi automaatselt sobivaks tulemiks.

Vihje.    Enne andmete töölehele kleepimist määrake veergude A ja B laiuseks 250.

Näidisnimi

Kirjeldus

Jeff Smith

Teine nimi puudub

Valem

Tulem (eesnimi)

'=LEFT(A2; SEARCH(" ";A2;1))

=LEFT(A2; SEARCH(" ";A2;1))

Valem

Tulem (perekonnanimi)

'=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;1))

=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;1))

  1. Eesnimi

    Eesnimi algab stringi esimese märgiga (J) ja lõpeb viienda märgi juures (tühik). Valem tagastab lahtris A2 vasakult alates viis märki.

    Valem eesnime ekstraktimiseks

    Funktsiooni SEARCH kasutamine argumendi märkide_arv väärtuse leidmiseks:

    Otsige tühiku arvulist asukohta lahtris A2, alustades vasakult.

  2. Perekonnanimi

    Perekonnanimi algab tühiku kohalt, viie märgi kauguselt paremalt ja lõpeb viimase märgiga paremal (h). Valem ekstraktib lahtrist A2 viis märki alates paremalt.

    Valem perekonnanime ekstraktimiseks

    Funktsioonide SEARCH ja LEN kasutamine argumendi märkide_arv väärtuse leidmiseks:

    Otsige tühiku arvulist asukohta lahtris A2, alustades vasakult. (5)

  3. Arvutage tekstistringi kogupikkus ja lahutage sellest esimesest tühikust vasakule jäävate leitud märkide arv nagu juhises 1.

Selles näites kasutatakse eesnime, keskmist initsiaali ja perekonnanime. Tühik eraldab iga nimekomponendi.

Kopeerige tabeli lahtrid ja kleepige need Exceli töölehele lahtris A1. Vasakul kuvatav valem kuvatakse viitamiseks, Excel teisendab paremal asuva valemi automaatselt sobivaks tulemiks.

Vihje.    Enne andmete töölehele kleepimist määrake veergude A ja B laiuseks 250.

Näidisnimi

Kirjeldus

Eric S. Kurjan

Ühe keskele algne

Valem

Tulem (eesnimi)

'=LEFT(A2; SEARCH(" ";A2;1))

=LEFT(A2; SEARCH(" ";A2;1))

Valem

Tulem (keskmine algne)

'=MID(A2;SEARCH(" ";A2;1)+1;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)-SEARCH(" ";A2;1))

=MID(A2;SEARCH(" ";A2;1)+1;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)-SEARCH(" ";A2;1))

Valem

Reaalajas tulem (perekonnanimi)

'=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;1)+1))

=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;1)+1))

  1. Eesnimi

    Eesnimi algab vasakult esimese märgiga (E) ja lõpeb viienda märgi juures (esimene tühik). Valem ekstraktib lahtris A2 esimesed viis märki alates vasakult.

    Valem ees- ja perekonnanime eraldamiseks pluss teine initsiaal

    Funktsiooni SEARCH kasutamine argumendi märkide_arv väärtuse leidmiseks:

    Otsige tühiku arvulist asukohta lahtris A2, alustades vasakult. (5)

  2. Teine nimi

    Teine nimi algab kuuendast märgist (S) ja lõpeb kaheksandal kohal (teine tühik). See valem hõlmab funktsiooni SEARCH pesastamist, et leida tühiku teine eksemplar.

    Valem ekstraktib kolm märki alates kuuendast asukohast.

    Eesnime, teise nime ja perekonnanime eraldava valemi üksikasjad

    Funktsiooni SEARCH kasutamine argumendi algusnr väärtuse leidmiseks:

    Otsige stringi A2 esimese tühiku asukohta, alates vasakult esimesest märgist. (5).

  3. Esimesele tühikule järgneva märgi asukoha (S) saamiseks lisage 1. See arvuline asukoht on keskmise nime alguspositsioon. (5 + 1 = 6)

    Pesastatud funktsioonide SEARCH kasutamine argumendi märkide_arv väärtuse leidmiseks:

    Otsige stringi A2 esimese tühiku asukohta, alates vasakult esimesest märgist. (5)

  4. Esimesele tühikule järgneva märgi asukoha (S) saamiseks lisage 1. Tulemuseks on tühiku teise eksemplari otsimiseks soovitud märginumber. (5 + 1 = 6)

  5. Otsige lahtris A2 teist tühikut, alustades 4. juhises leitud kuuendast positsioonist (S). See märginumber on keskmise nime lõpukoht. (8)

  6. Otsige lahtris A2 asuvat tühiku asukohta, alustades vasakult esimesest märgist. (5)

  7. Võtke juhises 5 leitud teise tühiku asukoht ja lahutage sellest juhises 6 leitud esimese tühiku asukoht. Tulemuseks on märkide arv, mille funktsioon MID ekstraktib tekstistringist alates juhises 2 leitud kuuendast asukohast. (8 – 5 = 3)

  8. Perekonnanimi

    Perekonnanimi algab paremalt kuue märgi kauguselt (K) ja lõpeb paremalt esimese märgi juures (n). See valem hõlmab funktsiooni SEARCH funktsioonide pesastamist, et leida tühiku teine ja kolmas eksemplar (vasakult viiendal ja kaheksandal positsioonil).

    Valem ekstraktib lahtris A2 kuus märki alates paremalt.

    Ees-, teise ja perekonnanime eraldava valemi teine funktsioon SEARCH
  9. Funktsioonide LEN ja pesastatud SEARCH abil saate leida num_chars.

    Otsige lahtris A2 asuvat tühiku asukohta, alustades vasakult esimesest märgist. (5)

  10. Esimesele tühikule järgneva märgi asukoha (S) saamiseks lisage 1. Tulemuseks on tühiku teise eksemplari otsimiseks soovitud märginumber. (5 + 1 = 6)

  11. Otsige teist tühikut lahtris A2, alustades 2. juhises leitud kuuendast positsioonist (S). See märginumber on keskmise nime lõpukoht. (8)

  12. Loendage lahtris A2 oleva tekstistringi kogupikkus ja lahutage 3. juhises leitud tühikute arv vasakult kuni teise tühikuni. Tulemuseks on täisnimest paremalt ekstraktimist vajav märkide arv. (14 – 8 = 6).

Siin on näide kahe keskmise initsiaali ekstraktimise kohta. Nimekomponente eraldavad tühikute esimesed ja kolmandad eksemplarid.

Kopeerige tabeli lahtrid ja kleepige need Exceli töölehele lahtris A1. Vasakul kuvatav valem kuvatakse viitamiseks, Excel teisendab paremal asuva valemi automaatselt sobivaks tulemiks.

Vihje.    Enne andmete töölehele kleepimist määrake veergude A ja B laiuseks 250.

Näidisnimi

Kirjeldus

Janaina B. G. Bueno

Kaks keskmist initsiaali

Valem

Tulem (eesnimi)

'=LEFT(A2; SEARCH(" ";A2;1))

=LEFT(A2; SEARCH(" ";A2;1))

Valem

Tulemus (keskmised initsiaalid)

'=MID(A2;SEARCH(" ";A2;1)+1;SEARCH(" ";A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1)-SEARCH(" ";A2;1))

=MID(A2;SEARCH(" ";A2;1)+1;SEARCH(" ";A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1)-SEARCH(" ";A2;1))

Valem

Reaalajas tulem (perekonnanimi)

'=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1))

=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1))

  1. Eesnimi

    Eesnimi algab vasakult esimese märgiga (J) ja lõpeb kaheksanda märgiga (esimene tühik). Valem ekstraktib lahtris A2 esimesed kaheksa märki alates vasakult.

    Valem ees- ja perekonnanime (ning kahe lisa-eesnime esitähe) eraldamiseks

    Funktsiooni SEARCH kasutamine argumendi märkide_arv väärtuse leidmiseks:

    Otsige lahtris A2 esimese tühiku numbrilist asukohta, alustades vasakult. (8)

  2. Teine nimi

    Teine nimi algab üheksandast positsioonist (B) ja lõpeb neljateistkümnendal positsioonil (kolmas tühik). See valem hõlmab funktsiooni SEARCH pesastamist, et leida kaheksandal, üheteistkümnendal ja neljateistkümnendal positsioonil ruumi esimene, teine ja kolmas eksemplar.

    Valem ekstraktib viis märki alates üheksandast asukohast.

    Valem ees- ja perekonnanime (ning kahe lisa-eesnime esitähe) eraldamiseks

    Funktsiooni SEARCH kasutamine argumendi algusnr väärtuse leidmiseks:

    Otsige stringi A2 esimese tühiku asukohta, alates vasakult esimesest märgist. (8)

  3. Esimesele tühikule järgneva märgi asukoha (B) saamiseks lisage 1. See arvuline asukoht on keskmise nime alguspositsioon. (8 + 1 = 9)

    Pesastatud funktsioonide SEARCH kasutamine argumendi märkide_arv väärtuse leidmiseks:

    Otsige stringi A2 esimese tühiku asukohta, alates vasakult esimesest märgist. (8)

  4. Esimesele tühikule järgneva märgi asukoha (B) saamiseks lisage 1. Tulemuseks on tühiku teise eksemplari otsimiseks soovitud märginumber. (8 + 1 = 9)

  5. Otsige teist tühikut lahtris A2, alustades 4. juhises leitud üheksandast positsioonist (B). (11).

  6. Teise tühiku järele märgi asukoha (G) saamiseks lisage 1. See märginumber on alguskoht, kust soovite alustada kolmanda tühiku otsimist. (11 + 1 = 12)

  7. Otsige kolmandat tühikut lahtris A2, alustades 6. juhises leitud kaheteistkümnendast kohast. (14)

  8. Otsige lahtris A2 esimese tühiku numbrilist asukohta. (8)

  9. Võtke juhises 7 leitud kolmanda tühiku märginumber ja lahutage juhises 6 leitud esimese tühiku tühik. Tulemuseks on märkide arv, mille funktsioon MID ekstraktib tekstistringist alates 2. juhises leitud üheksandast asukohast.

  10. Perekonnanimi

    Perekonnanimi algab viie märgiga paremalt (B) ja lõpeb paremalt esimese märgi juures (o). See valem hõlmab funktsiooni SEARCH pesastamist esimese, teise ja kolmanda tühiku leidmiseks.

    Valem ekstraktib lahtris A2 viis märki alates täisnimest paremalt.

    Valem ees- ja perekonnanime (ning kahe lisa-eesnime esitähe) eraldamiseks

    Pesastatud funktsioonide SEARCH ja LEN abil saate leida num_chars väärtuse.

    Otsige stringi A2 esimese tühiku asukohta, alates vasakult esimesest märgist. (8)

  11. Esimesele tühikule järgneva märgi asukoha (B) saamiseks lisage 1. Tulemuseks on tühiku teise eksemplari otsimiseks soovitud märginumber. (8 + 1 = 9)

  12. Otsige teist tühikut lahtris A2, alustades 2. juhises leitud üheksandast positsioonist (B). (11)

  13. Teise tühiku järele märgi asukoha (G) saamiseks lisage 1. See märginumber on alguskoht, kust soovite alustada kolmandat tühikueksemplari otsimist. (11 + 1 = 12)

  14. Otsige lahtrist A2 kolmandat tühikut, alustades 6. juhises leitud kaheteistkümnendast positsioonist (G). (14)

  15. Loendage lahtris A2 oleva tekstistringi kogupikkus ja lahutage juhises 5 leitud märkide arv vasakult kuni kolmanda tühikuni. Tulemuseks on täisnimest paremalt ekstraktimist vajav märkide arv. (19 - 14 = 5)

Selles näites on perekonnanimi eesnimest eespool ja teine nimi on lõpus. Koma tähistab perekonnanime lõppu ja iga nimekomponenti eraldab tühik.

Kopeerige tabeli lahtrid ja kleepige need Exceli töölehele lahtris A1. Vasakul kuvatav valem kuvatakse viitamiseks, Excel teisendab paremal asuva valemi automaatselt sobivaks tulemiks.

Vihje.    Enne andmete töölehele kleepimist määrake veergude A ja B laiuseks 250.

Näidisnimi

Kirjeldus

Kahn, Wendy Beth

Eesnimi perekonnanimi koos komaga

Valem

Tulem (eesnimi)

'=MID(A2;SEARCH(" ";A2;1)+1;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)-SEARCH(" ";A2;1))

=MID(A2;SEARCH(" ";A2;1)+1;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)-SEARCH(" ";A2;1))

Valem

Tulem (teine nimi)

'=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;1)+1))

=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;1)+1))

Valem

Reaalajas tulem (perekonnanimi)

'=LEFT(A2; SEARCH(" ";A2;1)-2)

=LEFT(A2; SEARCH(" ";A2;1)-2)

  1. Eesnimi

    Eesnimi algab vasakult seitsmenda märgiga (W) ja lõpeb kaheteistkümnenda märgi kohal (teine tühik). Kuna eesnimi on täisnime keskel, tuleb eesnime ekstraktimiseks kasutada funktsiooni MID.

    Valem ekstraktib kuus märki alates seitsmendast asukohast.

    Valem sellise nime osade eraldamiseks, kus perekonnanimele järgnevad eesnimi ja teine nimi

    Funktsiooni SEARCH kasutamine argumendi algusnr väärtuse leidmiseks:

    Otsige stringi A2 esimese tühiku asukohta, alates vasakult esimesest märgist. (6)

  2. Esimesele tühikule järgneva märgi (W) asukoha saamiseks liitke 1. Tulemuseks on märginumber, millest algab eesnimi. (6 + 1 = 7)

    Pesastatud funktsioonide SEARCH kasutamine argumendi märkide_arv väärtuse leidmiseks:

    Otsige stringi A2 esimese tühiku asukohta, alates vasakult esimesest märgist. (6)

  3. Esimesele tühikule järgneva esimese märgi (W) asukoha saamiseks liitke 1. Tulemuseks on selle märgi arv, millest soovite alustada järgmise tühiku otsimist. (6 + 1 = 7)

    Otsige teist tühikut lahtris A2, alustades seitsmendast asukohast (W), mis leiti juhises 4. (12)

  4. Otsige stringi A2 esimese tühiku asukohta, alates vasakult esimesest märgist. (6)

  5. Võtke juhises 5 leitud teise tühiku asukoht ja lahutage sellest juhises 6 leitud esimese tühiku asukoht. Tulemuseks on märkide arv, mille funktsioon MID ekstraktib tekstistringist alustades juhises 2 leitud seitsmendast positsioonist. (12 - 6 = 6)

  6. Teine nimi

    Teine eesnimi nimi algab paremalt nelja märgi kauguselt (B) ja lõpeb paremalt esimese märgi juures (h). See valem kasutab funktsiooni SEARCH pesastamist leidmaks tühiku esimest ja teist asukohta vasakult kuuendal ja kaheteistkümnendalt asukohal.

    Valem ekstraktib neli märki alates paremalt.

    Valem sellise nime osade eraldamiseks, kus perekonnanimele järgnevad eesnimi ja teine nimi

    Pesastatud funktsioonide SEARCH ja LEN kasutamine argumendi algusnr väärtuse leidmiseks:

    Otsige stringi A2 esimese tühiku asukohta, alates vasakult esimesest märgist. (6)

  7. Esimesele tühikule järgneva esimese märgi (W) asukoha saamiseks liitke 1. Tulemuseks on selle märgi arv, millest soovite alustada järgmise tühiku otsimist. (6 + 1 = 7)

  8. Otsige teist tühikut lahtris A2, alustades seitsmendast asukohast (W), mis leiti juhises 2. (12)

  9. Loendage lahtri A2 tekstistringi täispikkus ja lahutage sellest juhises 3 leitud märkide arv vasakult kuni teise tühikuni. Tulemuseks on täisnimest paremalt ekstraktimist vajav märkide arv. (16 - 12 = 4)

  10. Perekonnanimi

    Perekonnanimi algab vasakult esimese märgiga (K) ja lõpeb neljanda märgi kohal (n). Valem ekstraktib neli märki lahtrist A2, alustades vasakult.

    Valem sellise nime osade eraldamiseks, kus perekonnanimele järgnevad eesnimi ja teine nimi

    Funktsiooni SEARCH kasutamine argumendi märkide_arv väärtuse leidmiseks:

    Otsige stringi A2 esimese tühiku asukohta, alates vasakult esimesest märgist. (6)

  11. Perekonnanime (n) lõpumärgi numbrilise asukoha saamiseks lahutage 2. Tulemuseks on märkide arv, mille soovite funktsiooniga LEFT ekstraktida. (6 - 2 =4)

Selles näites kasutatakse kaheosalist eesnime Mary Kay. Nimekomponendid on eraldatud teise ja kolmanda tühikuga.

Kopeerige tabeli lahtrid ja kleepige need Exceli töölehele lahtris A1. Vasakul kuvatav valem kuvatakse viitamiseks, Excel teisendab paremal asuva valemi automaatselt sobivaks tulemiks.

Vihje.    Enne andmete töölehele kleepimist määrake veergude A ja B laiuseks 250.

Näidisnimi

Kirjeldus

Mary Kay D. Andersen

Kaheosaline eesnimi

Valem

Tulem (eesnimi)

LEFT(A2; SEARCH(" ";A2;SEARCH(" ";A2;1)+1))

=LEFT(A2; SEARCH(" ";A2;SEARCH(" ";A2;1)+1))

Valem

Tulem (keskmine algne)

'=MID(A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1;SEARCH(" ";A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1)+1)-(SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1)))

=MID(A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1;SEARCH(" ";A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1)-(SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1)))

Valem

Reaalajas tulem (perekonnanimi)

'=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1))

=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1))

  1. Eesnimi

    Eesnimi algab vasakult esimese märgiga ja lõpeb üheksanda märgi juures (teine tühik). See valem hõlmab funktsiooni SEARCH pesastamist, et leida vasakult teine tühikueksemplar.

    Valem ekstraktib üheksa märki alates vasakult.

    Valem eesnime, teise nime, lisa-eesnime esitähe ja perekonnanime eraldamiseks

    Pesastatud funktsioonide SEARCH kasutamine argumendi märkide_arv väärtuse leidmiseks:

    Otsige stringi A2 esimese tühiku asukohta, alates vasakult esimesest märgist. (5)

  2. Esimesele tühikule järgneva märgi asukoha (K) saamiseks lisage 1. Tulemuseks on tühiku teise eksemplari otsimiseks soovitud märginumber. (5 + 1 = 6)

  3. Otsige teist tühikut lahtris A2, alustades kuuendast positsioonist (K), mis leiti juhises 2. Tulemuseks on märkide arv, mida LEFT tekstistringist ekstraktib. (9)

  4. Teine nimi

    Teine nimi algab kümnendast positsioonist (D) ja lõpeb kaheteistkümnendas asukohas (kolmas tühik). See valem hõlmab funktsiooni SEARCH pesastamist esimese, teise ja kolmanda tühiku leidmiseks.

    Valem ekstraktib keskelt kaks märki alates kümnendast asukohast.

    Valem eesnime, teise nime, lisa-eesnime esitähe ja perekonnanime eraldamiseks

    Pesastatud SEARCH-funktsioonide abil saate leida start_num väärtuse.

    Otsige stringi A2 esimese tühiku asukohta, alates vasakult esimesest märgist. (5)

  5. Esimesele tühikule järgneva märgi (K) saamiseks lisage 1. Tulemuseks on selle märgi arv, millest soovite alustada järgmise tühiku otsimist. (5 + 1 = 6)

  6. Otsige teise tühiku esinemisjuhu asukohta lahtris A2, alustades 2. juhises leitud kuuendast positsioonist (K). Tulemuseks on vasakult ekstraktitavate märkide arv LEFT. (9)

  7. Teise tühiku järele märgi (D) saamiseks lisage 1. Tulemuseks on keskmise nime alguspositsioon. (9 + 1 = 10)

    Pesastatud funktsioonide SEARCH kasutamine argumendi märkide_arv väärtuse leidmiseks:

    Otsige märgi numbrilist asukohta pärast teist tühikut (D). Tulemuseks on märginumber, millest soovite alustada kolmanda tühiku otsimist. (10)

  8. Otsige lahtris A2 kolmanda tühiku numbrilist asukohta, alustades vasakult. Tulemuseks on keskmise nime lõpukoht. (12)

  9. Otsige märgi numbrilist asukohta pärast teist tühikut (D). Tulemuseks on keskmise nime alguspositsioon. (10)

  10. Võtke kolmanda tühiku 6. juhises leitud tühiku number ja lahutage 7. juhises leitud "D"-tühik. Tulemuseks on märkide arv, mille funktsioon MID ekstraktib tekstistringist alates juhises 4 leitud kümnendast asukohast. (12 - 10 = 2)

  11. Perekonnanimi

    Perekonnanimi algab kaheksa märgi kauguselt paremalt. See valem hõlmab funktsiooni SEARCH pesastamist, et leida viies, üheksandas ja kaheteistkümnendas asukohas esimene, teine ja kolmas ruumieksemplar.

    Valem ekstraktib paremalt kaheksa märki.

    Valem eesnime, teise nime, lisa-eesnime esitähe ja perekonnanime eraldamiseks

    Pesastatud funktsioonide SEARCH ja LEN abil saate leida num_chars väärtuse.

    Otsige lahtris A2 esimese tühiku numbrilist asukohta, alustades vasakult. (5)

  12. Esimesele tühikule järgneva märgi (K) saamiseks lisage 1. Tulemuseks on tühiku otsimiseks soovitud märginumber. (5 + 1 = 6)

  13. Otsige teist tühikut lahtris A2 alates kuuendast positsioonist (K), mis leiti juhises 2. (9)

  14. Teise tühiku järele märgi asukoha (D) saamiseks lisage 1. Tulemuseks on keskmise nime alguspositsioon. (9 + 1 = 10)

  15. Otsige lahtris A2 kolmanda tühiku numbrilist asukohta, alustades vasakult. Tulemuseks on keskmise nime lõpukoht. (12)

  16. Loendage lahtris A2 oleva tekstistringi kogupikkus ja lahutage juhises 5 leitud märkide arv vasakult kuni kolmanda tühikuni. Tulemuseks on täisnimest paremalt ekstraktimist vajav märkide arv. (20 - 12 = 8)

Selles näites kasutatakse kolmeosalist perekonnanime: Barreto de Mattos. Esimene tühik tähistab eesnime lõppu ja perekonnanime algust.

Kopeerige tabeli lahtrid ja kleepige need Exceli töölehele lahtris A1. Vasakul kuvatav valem kuvatakse viitamiseks, Excel teisendab paremal asuva valemi automaatselt sobivaks tulemiks.

Vihje.    Enne andmete töölehele kleepimist määrake veergude A ja B laiuseks 250.

Näidisnimi

Kirjeldus

Paula Barreto de Mattos

Kolmeosaline perekonnanimi

Valem

Tulem (eesnimi)

'=LEFT(A2; SEARCH(" ";A2;1))

=LEFT(A2; SEARCH(" ";A2;1))

Valem

Tulem (perekonnanimi)

RIGHT(A2;LEN(A2)-SEARCH(" ";A2;1))

=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;1))

  1. Eesnimi

    Eesnimi algab vasakult esimese märgiga (P) ja lõpeb kuuenda märgiga (esimene tühik). Valem ekstraktib vasakult kuus märki.

    Valem eesnime ja kolmeosalise perekonnanime eraldamiseks

    Kasutage num_chars väärtuse leidmiseks funktsiooni Search.

    Otsige lahtris A2 esimese tühiku numbrilist asukohta, alustades vasakult. (6)

  2. Perekonnanimi

    Perekonnanimi algab seitseteist märki paremalt (B) ja lõpeb paremalt esimese märgiga (s). Valem ekstraktib paremalt seitseteist märki.

    Valem eesnime ja kolmeosalise perekonnanime eraldamiseks

    Funktsioonide LEN ja SEARCH abil saate leida num_chars.

    Otsige lahtris A2 esimese tühiku numbrilist asukohta, alustades vasakult. (6)

  3. Loendage lahtris A2 oleva tekstistringi kogupikkus ja lahutage 1. juhises leitud märkide arv vasakult kuni esimese tühikuni. Tulemuseks on täisnimest paremalt ekstraktimist vajav märkide arv. (23 - 6 = 17)

Selles näites kasutatakse kaheosalist perekonnanime: van Eaton. Esimene tühik tähistab eesnime lõppu ja perekonnanime algust.

Kopeerige tabeli lahtrid ja kleepige need Exceli töölehele lahtris A1. Vasakul kuvatav valem kuvatakse viitamiseks, Excel teisendab paremal asuva valemi automaatselt sobivaks tulemiks.

Vihje.    Enne andmete töölehele kleepimist määrake veergude A ja B laiuseks 250.

Näidisnimi

Kirjeldus

James van Eaton

Kaheosaline perekonnanimi

Valem

Tulem (eesnimi)

'=LEFT(A2; SEARCH(" ";A2;1))

=LEFT(A2; SEARCH(" ";A2;1))

Valem

Tulem (perekonnanimi)

'=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;1))

=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;1))

  1. Eesnimi

    Eesnimi algab vasakult esimese märgiga (J) ja lõpeb kaheksanda märgiga (esimene tühik). Valem ekstraktib vasakult kuus märki.

    Valem eesnime ja kaheosalise perekonnanime eraldamiseks

    Funktsiooni SEARCH kasutamine argumendi märkide_arv väärtuse leidmiseks:

    Otsige lahtris A2 esimese tühiku numbrilist asukohta, alustades vasakult. (6)

  2. Perekonnanimi

    Perekonnanimi algab paremalt üheksanda märgiga (v) ja lõpeb paremalt esimese märgi juures (n). Valem ekstraktib täisnimest paremalt üheksa märki.

    Valem eesnime ja kaheosalise perekonnanime eraldamiseks

    Funktsioonide LEN ja SEARCH abil saate leida num_chars.

    Otsige lahtris A2 esimese tühiku numbrilist asukohta, alustades vasakult. (6)

  3. Loendage lahtris A2 oleva tekstistringi kogupikkus ja lahutage 1. juhises leitud märkide arv vasakult kuni esimese tühikuni. Tulemuseks on täisnimest paremalt ekstraktimist vajav märkide arv. (15 - 6 = 9)

Selles näites on perekonnanimi eesnimi, millele järgneb järelliide. Koma eraldab perekonnanime ja järelliite eesnimest ja nime algustähest.

Kopeerige tabeli lahtrid ja kleepige need Exceli töölehele lahtris A1. Vasakul kuvatav valem kuvatakse viitamiseks, Excel teisendab paremal asuva valemi automaatselt sobivaks tulemiks.

Vihje.    Enne andmete töölehele kleepimist määrake veergude A ja B laiuseks 250.

Näidisnimi

Kirjeldus

Bacon Jr., Dan K.

Perekonnanimi ja eesliide koos komaga

Valem

Tulem (eesnimi)

'=MID(A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1;SEARCH(" ";A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1)-SEARCH(" ";A2;SEARCH(" ";A2;1)+1))

=MID(A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1;SEARCH(" ";A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1)-SEARCH(" ";A2;SEARCH(" ";A2;1)+1))

Valem

Tulem (keskmine algne)

'=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1))

=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1))

Valem

Tulem (perekonnanimi)

'=LEFT(A2; SEARCH(" ";A2;1))

=LEFT(A2; SEARCH(" ";A2;1))

Valem

Tulem (järelliide)

'=MID(A2;SEARCH(" "; A2;1)+1;(SEARCH(" ";A2;SEARCH(" ";A2;1)+1)-2)-SEARCH(" ";A2;1))

=MID(A2;SEARCH(" "; A2;1)+1;(SEARCH(" ";A2;SEARCH(" ";A2;1)+1)-2)-SEARCH(" ";A2;1))

  1. Eesnimi

    Eesnimi algab kaheteistkümnenda märgiga (D) ja lõpeb 15. märgiga (kolmas tühik). Valem ekstraktib kolm märki alates kaheteistkümnendast asukohast.

    Valem eesnime ja järelliidete eraldamiseks komaga

    Pesastatud SEARCH-funktsioonide abil saate leida start_num väärtuse.

    Otsige lahtris A2 esimese tühiku numbrilist asukohta, alustades vasakult. (6)

  2. Esimesele tühikule järgneva märgi (J) saamiseks lisage 1. Tulemuseks on selle märgi arv, millest soovite alustada järgmise tühiku otsimist. (6 + 1 = 7)

  3. Otsige teist tühikut lahtris A2, alustades seitsmendast positsioonist (J), mis leiti juhises 2. (11)

  4. Teise tühiku järele märgi (D) saamiseks lisage 1. Tulemuseks on eesnime alguspositsioon. (11 + 1 = 12)

    Pesastatud funktsioonide SEARCH kasutamine argumendi märkide_arv väärtuse leidmiseks:

    Otsige märgi numbrilist asukohta pärast teist tühikut (D). Tulemuseks on märginumber, millest soovite alustada kolmanda tühiku otsimist. (12)

  5. Otsige lahtris A2 kolmanda tühiku numbrilist asukohta, alustades vasakult. Tulemuseks on eesnime lõpukoht. (15)

  6. Otsige märgi numbrilist asukohta pärast teist tühikut (D). Tulemuseks on eesnime alguspositsioon. (12)

  7. Võtke kolmanda tühiku 6. juhises leitud tühiku number ja lahutage 7. juhises leitud "D"-tühik. Tulemuseks on märkide arv, mille funktsioon MID ekstraktib tekstistringist alates kaheteistkümnendast positsioonist, mis leiti juhises 4. (15 - 12 = 3)

  8. Teine nimi

    Teine nimi algab paremalt teise märgiga (K). Valem ekstraktib paremalt kaks märki.

    Valem eesnime ja järelliidete eraldamiseks komaga

    Otsige lahtris A2 esimese tühiku numbrilist asukohta, alustades vasakult. (6)

  9. Esimesele tühikule järgneva märgi (J) saamiseks lisage 1. Tulemuseks on selle märgi arv, millest soovite alustada järgmise tühiku otsimist. (6 + 1 = 7)

  10. Otsige teist tühikut lahtris A2, alustades seitsmendast positsioonist (J), mis leiti juhises 2. (11)

  11. Teise tühiku järele märgi (D) saamiseks lisage 1. Tulemuseks on eesnime alguspositsioon. (11 + 1 = 12)

  12. Otsige lahtris A2 kolmanda tühiku numbrilist asukohta, alustades vasakult. Tulemuseks on keskmise nime lõpukoht. (15)

  13. Loendage lahtris A2 oleva tekstistringi kogupikkus ja lahutage 5. juhises leitud märkide arv vasakult kuni kolmanda tühikuni. Tulemuseks on täisnimest paremalt ekstraktimist vajav märkide arv. (17 - 15 = 2)

  14. Perekonnanimi

    Perekonnanimi algab vasakult esimesest märgist (B) ja lõpeb kuuenda märgiga (esimene tühik). Seetõttu ekstraktib valem vasakult kuus märki.

    Valem eesnime ja järelliidete eraldamiseks komaga

    Funktsiooni SEARCH kasutamine argumendi märkide_arv väärtuse leidmiseks:

    Otsige lahtris A2 esimese tühiku numbrilist asukohta, alustades vasakult. (6)

  15. Sufiks

    Järelliide algab vasakult seitsmendast märgist (J) ja lõpeb vasakult üheksanda märgiga (.). Valem ekstraktib kolm märki alates seitsmendast märgist.

    Valem eesnime ja järelliidete eraldamiseks komaga

    Funktsiooni SEARCH kasutamine argumendi algusnr väärtuse leidmiseks:

    Otsige lahtris A2 esimese tühiku numbrilist asukohta, alustades vasakult. (6)

  16. Esimesele tühikule järgneva märgi (J) saamiseks lisage 1. Tulemuseks on järelliide alguspositsioon. (6 + 1 = 7)

    Pesastatud funktsioonide SEARCH kasutamine argumendi märkide_arv väärtuse leidmiseks:

    Otsige lahtris A2 esimese tühiku numbrilist asukohta, alustades vasakult. (6)

  17. Esimesele tühikule järgneva märgi numbrilise asukoha (J) saamiseks lisage 1. Tulemuseks on selle märgi arv, millest soovite alustada järgmise tühiku otsimist. (7)

  18. Otsige lahtris A2 teise tühiku numbrilist asukohta, alustades juhises 4 leitud seitsmendast märgist. (11)

  19. Juhises 4 leitud teise tühiku märginumbrist arvu "," saamiseks lahutage 1. Tulemuseks on järelliide lõpppositsioon. (11 - 1 = 10)

  20. Otsige esimese tühiku numbrilist asukohta. (6)

  21. Pärast esimese tühiku leidmist lisage 1, et leida järgmine märk (J), mille leiate ka juhistest 3 ja 4. (7)

  22. Võtke juhises 6 leitud "", ja lahutage 3. ja 4. juhises leitud "J" märginumber. Tulemuseks on märkide arv, mille funktsioon MID ekstraktib tekstistringist alates seitsmendast positsioonist, mis leiti juhises 2. (10 -7 = 3)

Selles näites on eesnimi stringi alguses ja järelliide on lõpus, nii et saate kasutada näitega 2 sarnaseid valemeid: kasutage eesnime ekstraktimiseks funktsiooni LEFT, perekonnanime ekstraktimiseks funktsiooni MID ja järelliite ekstraktimiseks funktsiooni RIGHT.

Kopeerige tabeli lahtrid ja kleepige need Exceli töölehele lahtris A1. Vasakul kuvatav valem kuvatakse viitamiseks, Excel teisendab paremal asuva valemi automaatselt sobivaks tulemiks.

Vihje.    Enne andmete töölehele kleepimist määrake veergude A ja B laiuseks 250.

Näidisnimi

Kirjeldus

Gary Altman III

Ees- ja perekonnanimi koos järelliidetega

Valem

Tulem (eesnimi)

'=LEFT(A2; SEARCH(" ";A2;1))

=LEFT(A2; SEARCH(" ";A2;1))

Valem

Tulem (perekonnanimi)

'=MID(A2;SEARCH(" ";A2;1)+1;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)-(SEARCH(" ";A2;1)+1))

=MID(A2;SEARCH(" ";A2;1)+1;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)-(SEARCH(" ";A2;1)+1))

Valem

Tulem (järelliide)

'=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;1)+1))

=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;1)+1))

  1. Eesnimi

    Eesnimi algab vasakult esimesest märgist (G) ja lõpeb viienda märgi juures (esimene tühik). Seetõttu ekstraktib valem täisnimest vasakult viis märki.

    Valem ees- ja perekonnanime eraldamiseks, millele järgneb järelliide

    Otsige lahtris A2 esimese tühiku numbrilist asukohta, alustades vasakult. (5)

  2. Perekonnanimi

    Perekonnanimi algab vasakult kuuendast märgist (A) ja lõpeb üheteistkümnenda märgi juures (teine tühik). See valem hõlmab tühikute asukohtade leidmiseks funktsiooni SEARCH pesastamist.

    Valem ekstraktib keskelt kuus märki alates kuuendast märgist.

    Valem ees- ja perekonnanime eraldamiseks, millele järgneb järelliide

    Funktsiooni SEARCH kasutamine argumendi algusnr väärtuse leidmiseks:

    Otsige lahtris A2 esimese tühiku numbrilist asukohta, alustades vasakult. (5)

  3. Esimesele tühikule järgneva märgi asukoha (A) saamiseks lisage 1. Tulemuseks on perekonnanime alguspositsioon. (5 + 1 = 6)

    Pesastatud funktsioonide SEARCH kasutamine argumendi märkide_arv väärtuse leidmiseks:

    Otsige lahtris A2 esimese tühiku numbrilist asukohta, alustades vasakult. (5)

  4. Esimesele tühikule järgneva märgi asukoha (A) saamiseks lisage 1. Tulemuseks on selle märgi arv, millest soovite alustada järgmise tühiku otsimist. (5 + 1 = 6)

  5. Otsige lahtris A2 teise tühiku numbrilist asukohta alates juhises 4 leitud kuuendast märgist. See märginumber on perekonnanime lõpukoht. (12)

  6. Otsige esimese tühiku numbrilist asukohta. (5)

  7. Esimesele tühikule järgneva märgi numbrilise asukoha (A) leidmiseks lisage 1, mille leiate ka juhistest 3 ja 4. (6)

  8. Võtke juhises 5 leitud teise tühiku number ja lahutage seejärel sammudes 6 ja 7 leitud "A" märginumber. Tulemuseks on märkide arv, mille funktsioon MID ekstraktib tekstistringist alates kuuendast asukohast, mis leiti juhises 2. (12 - 6 = 6)

  9. Sufiks

    Järelliide algab paremalt kolme märgiga. See valem hõlmab tühikute asukohtade leidmiseks funktsiooni SEARCH pesastamist.

    Valem ees- ja perekonnanime eraldamiseks, millele järgneb järelliide

    Pesastatud funktsioonide SEARCH ja LEN abil saate leida num_chars väärtuse.

    Otsige lahtris A2 esimese tühiku numbrilist asukohta, alustades vasakult. (5)

  10. Esimesele tühikule järgneva märgi (A) saamiseks lisage 1. Tulemuseks on selle märgi arv, millest soovite alustada järgmise tühiku otsimist. (5 + 1 = 6)

  11. Otsige teist tühikut lahtris A2 alates kuuendast positsioonist (A), mis leiti juhises 2. (12)

  12. Loendake lahtris A2 oleva tekstistringi kogupikkus ja lahutage 3. juhises leitud märkide arv vasakult kuni teise tühikuni. Tulemuseks on täisnimest paremalt ekstraktimist vajav märkide arv. (15 - 12 = 3)

Selles näites eelneb täisnimele eesliide ja kasutate 2. näitega sarnaseid valemeid: eesnime ekstraktimiseks kasutatakse funktsiooni MID, perekonnanime ekstraktimiseks funktsiooni RIGHT.

Kopeerige tabeli lahtrid ja kleepige need Exceli töölehele lahtris A1. Vasakul kuvatav valem kuvatakse viitamiseks, Excel teisendab paremal asuva valemi automaatselt sobivaks tulemiks.

Vihje.    Enne andmete töölehele kleepimist määrake veergude A ja B laiuseks 250.

Näidisnimi

Kirjeldus

Hr Ryan Ihrig

Eesliide

Valem

Tulem (eesnimi)

'=MID(A2;SEARCH(" ";A2;1)+1;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)-(SEARCH(" ";A2;1)+1))

=MID(A2;SEARCH(" ";A2;1)+1;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)-(SEARCH(" ";A2;1)+1))

Valem

Tulem (perekonnanimi)

'=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;1)+1))

=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;1)+1))

  1. Eesnimi

    Eesnimi algab vasakult viiendast märgist (R) ja lõpeb üheksanda märgi juures (teine tühik). Valem pesastab tühikute asukoha leidmiseks funktsiooni SEARCH. See ekstraktib neli märki alates viiendast positsioonist.

    Valem eesliideega eelneva eesnime eraldamiseks

    Kasutage start_num väärtuse leidmiseks funktsiooni SEARCH.

    Otsige lahtris A2 esimese tühiku numbrilist asukohta, alustades vasakult. (4)

  2. Esimesele tühikule järgneva märgi asukoha (R) saamiseks lisage 1. Tulemuseks on eesnime alguspositsioon. (4 + 1 = 5)

    Pesastatud funktsiooni SEARCH abil saate leida num_chars väärtuse:

    Otsige lahtris A2 esimese tühiku numbrilist asukohta, alustades vasakult. (4)

  3. Esimesele tühikule järgneva märgi asukoha (R) saamiseks lisage 1. Tulemuseks on selle märgi arv, millest soovite alustada järgmise tühiku otsimist. (4 + 1 = 5)

  4. Otsige lahtris A2 teise tühiku numbrilist asukohta alates viiendast märgist, mille leiate juhistest 3 ja 4. See märginumber on eesnime lõpukoht. (9)

  5. Otsige esimest tühikut. (4)

  6. Esimese tühiku järele märgi numbrilise asukoha (R) leidmiseks lisage 1, mille leiate ka juhistest 3 ja 4. (5)

  7. Võtke juhises 5 leitud teise tühiku number ja lahutage sammudes 6 ja 7 leitud "R"-i märkide arv. Tulemuseks on märkide arv, mille funktsioon MID tekstistringist ekstraktib, alustades juhises 2 leitud viiendast kohast. (9 - 5 = 4)

  8. Perekonnanimi

    Perekonnanimi algab viie märgi kauguselt paremalt. See valem hõlmab tühikute asukohtade leidmiseks funktsiooni SEARCH pesastamist.

    Valem eesliideega eelneva eesnime eraldamiseks

    Pesastatud funktsioonide SEARCH ja LEN abil saate leida num_chars väärtuse.

    Otsige lahtris A2 esimese tühiku numbrilist asukohta, alustades vasakult. (4)

  9. Esimesele tühikule järgneva märgi asukoha (R) saamiseks lisage 1. Tulemuseks on selle märgi arv, millest soovite alustada järgmise tühiku otsimist. (4 + 1 = 5)

  10. Otsige teist tühikut lahtris A2 alates viiendast positsioonist (R), mis leiti juhises 2. (9)

  11. Loendake lahtris A2 oleva tekstistringi kogupikkus ja lahutage 3. juhises leitud märkide arv vasakult kuni teise tühikuni. Tulemuseks on täisnimest paremalt ekstraktimist vajav märkide arv. (14 - 9 = 5)

Selles näites kasutatakse poolitatud perekonnanime. Tühik eraldab iga nimekomponendi.

Kopeerige tabeli lahtrid ja kleepige need Exceli töölehele lahtris A1. Vasakul kuvatav valem kuvatakse viitamiseks, Excel teisendab paremal asuva valemi automaatselt sobivaks tulemiks.

Vihje.    Enne andmete töölehele kleepimist määrake veergude A ja B laiuseks 250.

Näidisnimi

Kirjeldus

Julie Taft-Rider

Poolitatud perekonnanimi

Valem

Tulem (eesnimi)

'=LEFT(A2; SEARCH(" ";A2;1))

=LEFT(A2; SEARCH(" ";A2;1))

Valem

Tulem (perekonnanimi)

'=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;1))

=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;1))

  1. Eesnimi

    Eesnimi algab vasakult esimesest märgist ja lõpeb kuuendal kohal (esimene tühik). Valem ekstraktib vasakult kuus märki.

    Valem ees- ja poolitatud perekonnanime eraldamiseks

    Kasutage funktsiooni SEARCH num_chars väärtuse leidmiseks.

    Otsige lahtris A2 esimese tühiku numbrilist asukohta, alustades vasakult. (6)

  2. Perekonnanimi

    Kogu perekonnanimi algab paremalt kümme märki (T) ja lõpeb paremalt esimese märgi juures (r).

    Valem ees- ja poolitatud perekonnanime eraldamiseks

    Funktsioonide LEN ja SEARCH abil saate leida num_chars.

    Otsige lahtris A2 asuva tühiku numbrilist asukohta, alustades vasakult esimesest märgist. (6)

  3. Loendage ekstraktitava tekstistringi kogupikkus ja lahutage 1. juhises leitud märkide arv vasakult kuni esimese tühikuni. (16 - 6 = 10)

Teksti tükeldamine eraldi veergudesse viisardi „Tekst veergudesse“ abil

Kas vajate veel abi?

Kas soovite rohkem valikuvariante?

Siin saate tutvuda tellimusega kaasnevate eelistega, sirvida koolituskursusi, õppida seadet kaitsma ja teha veel palju muud.

Kogukonnad aitavad teil küsimusi esitada ja neile vastuseid saada, anda tagasisidet ja saada nõu rikkalike teadmistega asjatundjatelt.

Kas sellest teabest oli abi?

Kui rahul te keelekvaliteediga olete?
Mis mõjutas teie hinnangut?
Kui klõpsate nuppu Edasta, kasutatakse teie tagasisidet Microsofti toodete ja teenuste täiustamiseks. IT-administraator saab neid andmeid koguda. Privaatsusavaldus.

Täname tagasiside eest!

×