Kahe kuupäeva vahe arvutamine

Kasutage funktsiooni DATEDIF, kui soovite arvutada kahe kuupäeva vahe. Sisestage ühte lahtrisse alguskuupäev ja siis teise lahtrisse lõppkuupäev. Seejärel tippige valem, nagu üks järgmistest.

Vahe päevades

=DATEDIF(D9,E9,"d") tulemiga 856

Selles näites on alguskuupäev lahtris D9 ja lõppkuupäev lahtris E9. Valem on lahtris F9. “d” annab vastuseks täispäevade arvu kahe kuupäeva vahel.

Vahe nädalates

=(DATEDIF(D13,E13,"d")/7) ja tulem: 122.29

Selles näites on alguskuupäev lahtris D13 ja lõppkuupäev lahtris E13. "d" annab vastuseks päevade arvu. Kuid pöörake tähelepanu, et lõpus on /7. See jagab päevade arvu seitsmega, kuna nädalas on seitse päeva. Arvestage, et see tulem on vaja vormindada arvuna. Vajutage klahvikombinatsiooni Ctrl+1. Seejärel valige Arv > Kohti pärast koma: 2.

Vahe kuudes

=DATEDIF(D5,E5,"m") ja tulem: 28

Selles näites on alguskuupäev lahtris D5 ja lõppkuupäev lahtris E5. Valemis annab “m” vastuseks täiskuude arvu kahe kuupäeva vahel.

Vahe aastates

=DATEDIF(D2,E2,"y") ja tulem: 2

Selles näites on alguskuupäev lahtris D2 ja lõppkuupäev lahtris E2. “y” annab vastuseks täisaastate arvu kahe kuupäeva vahel.

Vanuse arvutamine aastates, kuudes ja päevades

Samuti saate arvutada näiteks töö- või teenistusaja pikkuse. Tulem esitatakse sarnasel kujul: "2 aastat, 4 kuud, 5 päeva".

1. Funktsiooni DATEDIF abil aastate koguarvu arvutamine.

=DATEDIF(D17,E17,"y") ja tulem: 2

Selles näites on alguskuupäev lahtris D17 ja lõppkuupäev lahtris E17. Valemis annab “y” vastuseks täisaastate arvu kahe kuupäeva vahel.

2. Funktsiooniga DATEDIF ja parameetriga "ym" kuude arvutamine.

=DATEDIF(D17,E17,"ym") ja tulem: 4

Teises lahtris kasutage funktsiooni DATEDIF koos parameetriga “ym”. "ym" annab vastuseks viimasest täisaastast üle jäävate kuude arvu.

3. Teise valemi abil päevade arvutamine.

=DATEDIF(D17,E17,"md") ja tulem: 5

Nüüd tuleb arvutada ülejäänud päevade arv. Selleks kasutame erinevat valemit, mis on toodud ülal. Valemi abil lahutatakse lahtris E17 olevast algsest lõpukuupäevast (6.5.2016) lõpukuu (1.5.2016) esimene päev. Selleks tehakse järgmist. Kõigepealt luuakse funktsiooni DATE abil kuupäev 1.5.2016. Kuupäev luuakse lahtris E17 oleva aasta ja kuu põhjal. Number 1 tähistab selle kuu esimest päeva. Funktsiooni DATE tulem on 1.5.2016. Seejärel lahutatakse see lahtris E17 olevast algsest lõpukuupäevast 6.5.2016: lahutades kuupäeva 1.5.2016 kuupäevast 6.5.2016 saame vastuseks viis päeva.

Märkus. : Me ei soovita kasutada funktsiooni DATEDIF argumenti "md", kuna see võib arvutada ebatäpseid tulemeid.

4. Valikuline. Saate ühendada kolm valemit üheks.

=DATEDIF(D17,E17,"y")&" aastad, "&DATEDIF(D17,E17,"ym")&" kuud, "&DATEDIF(D17,E17,"md")&" päevad" ja tulem: 2 aastat, 4 kuud, 5 päeva

Kõik kolm arvutust saab paigutada ühte lahtrisse, nagu siinses näites. Kasutage ja-märke, jutumärke ja teksti. Tippida tuleb pikem valem, kuid see-eest on kõik vajalik üheskoos. Näpunäide. Valemisse reapiiride lisamiseks vajutage klahvikombinatsiooni Alt+Enter. Nii on valemit hõlpsam lugeda. Kui terve valem pole nähtav, vajutage klahvikombinatsiooni Ctrl+Shift+U.

Näidiste allalaadimine

Saate alla laadida näidistöövihiku, mis sisaldab kõiki siin artiklis kirjeldatud näiteid. Võite neid näiteid täpselt järgida või luua nende põhjal oma valemeid.

Laadi alla kuupäeva arvutamise näited

Muud kuupäeva ja kellaaja arvutused

Nagu eespool selgus, arvutab funktsioon DATEDIF alguskuupäeva ja lõppkuupäeva vahe. Kuid konkreetsete kuupäevade tippimise asemel saate valemi sees kasutada ka funktsiooni TODAY(). Funktsiooni TODAY() kasutamisel võtab Excel kuupäevaks teie arvuti tänase kuupäeva. Arvestage, et faili avamisel tulevikus see kuupäev muutub.

=DATEDIF(TODAY(),D28,"y") ja tulem: 984

Pidage silmas, et käesoleva artikli kirjutamise ajal oli tänane kuupäev 6. oktoober 2016.

Kui soovite arvutada kahe kuupäeva vahele jäävate tööpäevade arvu, kasutage funktsiooni NETWORKDAYS.INTL. Soovi korral saate lasta funktsioonil välja jätta nädalavahetused ja ka pühad ja puhkused.

Enne alustamist. Otsustage, kas soovite puhkepäevad välja jätta. Kui jah, siis tippige eraldi alale või lehele puhkepäevade kuupäevade loend. Lisage iga kuupäev eraldi lahtrisse. Seejärel valige need lahtrid ja klõpsake Valemid > Nime määratlus. Määrake vahemiku nimeks Minupuhkepäevad ja klõpsake nuppu OK. Seejärel looge allolevaid juhiseid järgides valem.

1. Tippige alguskuupäev ja lõppkuupäev.

Alguskuupäev lahtris D53 on 01.01.2016, lõppkuupäev on lahtris E53 31.12.2016

Selles näites on alguskuupäev lahtris D53 ja lõppkuupäev lahtris E53.

2. Teise lahtrisse tippige selline valem:

=NETWORKDAYS.INTL(D53,E53,1) ja tulem: 261

Tippige ülaltoodud näitele sarnane valem. Valemis olev väärtus 1 määratleb laupäevad ja pühapäevad nädalavahetusena ja välistab need arvutusest.

Märkus. Rakenduses Excel 2007 puudub funktsioon NETWORKDAYS.INTL. Kuid selles on funktsioon NETWORKDAYS. Rakenduses Excel 2007 on ülaltoodud näide selline: =NETWORKDAYS(D53,E53). Väärtust 1 ei määratleta, kuna NETWORKDAYS eeldab, et laupäev ja pühapäev on nädalavahetus.

3. Vajaduse korral muutke väärtust 1.

IntelliSense’i loend, mis näitab 2 – pühapäev, esmaspäev; 3 – esmaspäev, teisipäev jne

Kui laupäev ja pühapäev pole teie vabad nädalavahetuse päevad, siis asendage väärtus 1 mõne teise IntelliSense'i loendis oleva arvuga. Näiteks väärtus 2 määratleb nädalavahetusena pühapäevad ja esmaspäevad.

Kui kasutate rakendust Excel 2007, jätke see samm vahele. Rakenduses Excel 2007 eeldab funktsioon NETWORKDAYS alati, et nädalavahetuse päevad on laupäev ja pühapäev.

4. Tippige puhkepäevade vahemiku nimi.

=NETWORKDAYS.INTL(D53,E53,1,MyHolidays) ja tulem: 252

Kui andsite puhkepäevade vahemikule nime juba eespool sammu „Enne alustamist“ käigus, siis tippige see niimoodi lõppu. Kui teil puhkepäevi pole, jätke koma ja Minupuhkepäevad välja. Kui kasutate rakendust Excel 2007, on ülaltoodud näide selline: =NETWORKDAYS(D53,E53,Minupuhkepäevad).

Näpunäide. Kui te ei soovi viidata puhkepäevade vahemiku nimele, saate selle asemel vahemiku tippida (näiteks D35:E39). Samuti võite tippida iga puhkepäeva valemi sisse. Näiteks kui teie puhkepäevad on 1. ja 2. jaanuar 2016, tippige need valemisse nii: =NETWORKDAYS.INTL(D53,E53,1,{"1/1/2016","1/2/2016"}). Rakenduses Excel 2007 näeb valem välja selline: =NETWORKDAYS(D53,E53,{"1/1/2016","1/2/2016"})

Saate arvutada kulunud aja, lahutades ühe ajaväärtuse teisest. Sisestage ühte lahtrisse alguskellaaeg ja siis teise lahtrisse lõppkellaaeg. Tippige kellaaeg kindlasti täiskujul (nii tunnid kui minutid) ja lisage AM-i või PM-i ette tühik. Selleks tehke järgmist.

1. Tippige algus- ja lõppkellaaeg.

Alguskuupäev/-kellaaeg 7:15 AM, lõppkuupäev/-kellaaeg 4:30 PM

Selles näites on alguskellaaeg lahtris D80 ja lõppkellaaeg lahtris E80. Tippige kindlasti tunnid ja minutid ning tühik AM-i või PM-i ette.

2. Määrake vorming h:mm AM/PM.

Dialoogiboks Lahtrite vormindamine, kohandatud käsk, tüüp h:mm AM/PM

Valige mõlemad kuupäevad ja vajutage klahvikombinatsiooni Ctrl+1 (või Mac-arvutis Mac-arvuti käsunupu ikoon + 1). Valige kindlasti Kohandatud > h:mm AM/PM (kui see pole juba määratud).

3. Lahutage kaks kellaaega.

=E80-D80 ja tulem: 09.15

Teises lahtris lahutage alguskellaaja lahter lõppkellaaja lahtrist.

4. Määrake vorming h:mm.

Dialoogiboks Lahtrite vormindamine, kohandatud käsk, tüüp h:mm

Vajutage klahvikombinatsiooni Ctrl + 1 (või Mac-arvutis Mac-arvuti käsunupu ikoon + 1). Valige Kohandatud > h:mm, et tulemist arvataks välja AM ja PM.

Kahe kuupäeva ja kellaaja vahel kulunud aja arvutamiseks saate lihtsalt ühe ajaväärtuse teisest lahutada. Kuid et Excel annaks vastuseks sobiva tulemi, on kõikidele lahtritele tarvis määrata vorming.

1. Tippige kaks täielikku kuupäeva ja kellaaega.

Alguskuupäev 1/1/16 1:00 PM; lõppkuupäev 1/2/16 2:00 PM

Ühte lahtrisse tippige täielik alguskuupäev ja -kellaaeg. teise lahtrisse tippige täielik lõppkuupäev ja -kellaaeg. Igas lahtris peab olema kuu, päev, aasta, tund, minut, ja tühik enne AM-i või PM-i.

2. Määrake vorming 3/14/12 1:30 PM.

Dialoogiboks Lahtrite vormindamine, kuupäeva käsk, tüüp 3/14/12 1:30 PM

Valige mõlemad lahtrid ja vajutage klahvikombinatsiooni Ctrl+1 (või Mac-arvutis Mac-arvuti käsunupu ikoon + 1). Seejärel valige Kuupäev > 3/14/12 1:30 PM. See pole mitte määratav kuupäev, vaid üksnes kuupäeva vormingu näidis. Arvestage, et rakendusest Excel 2016 varasemates versioonides võib sellel vormingul olla erinev näidiskuupäev (nt 3/14/01 1:30 PM).

3. Lahutage kaks ajaväärtust.

=E84-D84 ja tulem 1.041666667

Teises lahtris lahutage alguskuupäev/-kellaaeg lõppkuupäevast/-kellaajast. Tulem on tõenäoliselt kümnendkohaga arv. Selle muudate ära järgmise sammuga.

4. Määrake vorming [h]:mm.

Dialoogiboks Lahtrite vormindamine, kohandatud käsk, tüüp [h]:mm

Vajutage klahvikombinatsiooni Ctrl + 1 (või Mac-arvutis Mac-arvuti käsunupu ikoon + 1). Valige Kohandatud. Tippige väljale Tüüp väärtus [h]:mm.

Vt ka

Funktsioon DATEDIF

Funktsioon NETWORKDAYS.INTL

NETWORKDAYS

Veel kuupäeva- ja kellaajafunktsioone

Kahe kellaaja vahe arvutamine

Täiendage oma oskusi
Tutvuge koolitusmaterjalidega
Kasutage uusi funktsioone enne teisi
Liituge Office Insideri programmiga

Kas sellest teabest oli abi?

Täname tagasiside eest!

Täname tagasiside eest! Tundub, et võiksime teid kokku viia ühega meie Office'i tugiagentidest, kes aitab teil probleemi lahendada.

×