Funktsioon SUM

Funktsioon SUM, mis on üks matemaatika- ja trigonomeetriafunktsioonidest, liidab väärtusi. Saate liita üksikväärtusi, lahtriviiteid või -vahemikke või kõiki kolme koos.

Siin on mõned näited.

  • =SUM(A2:A10)

  • =SUM(A2:A10, C2:C10)

Teie brauser ei toeta videot. Installige Microsoft Silverlight, Adobe Flash Player või Internet Explorer 9.

See video on osa koolituskursusest Numbrite lisamine rakenduses Excel 2013.

SUM(arv1,[arv2],...)

Argumendi nimi

Kirjeldus

arv1    (nõutav)

Esimene arv, mida soovite liita. Arvuks võib olla 4, nagu on lahtriviide lahtris B6 või lahtri tähis vahemik nagu B2: B8.

arv 2-255    (Valikuline)

See on teine arv, mida soovite liita. Sel viisil saate määrata kuni 255 täiendavat arvu.

Kui soovite saada kiiresti lahtrivahemiku väärtuste summa, tuleb teil ainult valida vahemik ja vaadata Exceli akna paremasse allserva.

Kuvatõmmis lahtrivahemiku valimisest ja seejärel olekuriba
Olekuriba


See on olekuriba ja siin kuvatakse teave teie valiku kohta olenemata sellest, kas tegu on ühe või mitme lahtriga. Olekuriba paremklõpsamise korral kuvatakse funktsiooni dialoogiboks, kus saate valida soovitud suvandid. Kui olete märkinud vastavad atribuudid, kuvatakse seal ka teie valitud vahemiku väärtused. Lisateave olekuriba kohta.

Lihtsaim võimalus valemi SUM töölehele lisamiseks on kasutada automaatsumma viisardit. Valige tühi lahter vahetult liidetava vahemiku all või peal ja tehke lindi menüüs Avaleht või Valemid valik Automaatsumma > Summa. Automaatsumma viisard saab automaatselt aru, millist vahemikku liita, ja koostab teile valemi. Samuti töötab see horisontaalselt, kui valite lahtri liidetavast vahemikust vasakul või paremal. Viisard ei toimi mittekülgnevate vahemike korral, neid vaatame lähemalt järgmises jaotises.

Automaatsumma viisardi abil saate automaatselt koostada Sum-valemi.  Valige vahemik, mis on liidetava vahemiku peal/all või sellest vasakul/paremal, ja avage ribal menüü Valemid, seejärel valige AutoSum & SUM.
Kasutage automaatsumma viisardit külgnevate vahemike kiireks liitmiseks


Automaatsumma dialoogiboksi abil saate valida ka muid levinud funktsioone, nt:

Automaatsumma vertikaalselt

Lahtris B6 on näidatud automaatsumma valem: =SUM(B2:B5)

Automaatsumma viisard on automaatselt tuvastanud liitmiseks lahtrid B2:B5. Kinnitamiseks tuleb teil vajutada ainult sisestusklahvi Enter. Kui teil on vaja lisada / välja jätta veel lahtreid, hoidke all tõstuklahvi ja vastavat nooleklahvi, kuni soovitud valik on tehtud, ja vajutage siis sisestusklahvi Enter.

IntelliSense’i funktsiooni juhis: ujuv silt SUM(arv1,[arv2], …) funktsiooni all on selle Intellisense’i juhis. Kui klõpsate SUM või funktsiooni nime, muutub see siniseks hüperlingiks, mis suunab teid selle funktsiooni kohta käiva spikriteema juurde. Kui klõpsate funktsioonielemente, tõstetakse esile vastav osa valemist. Praegusel juhul tõstetaks esile ainult B2: B5, sest selles valemis on ainult üks arvviide. IntelliSense’i silt kuvatakse kõigi funktsioonide puhul.

Automaatsumma horisontaalselt

Lahtris D2 on näidatud automaatsumma valem: =SUM(B2:C2)

Funktsiooni SUM kasutamine mittekülgnevate vahemikega.  Lahtris C8 on valem: = SUM(C2:C3,C5:C6). Võite kasutada ka nimega vahemikke: = SUM(Nädal1,Nädal2).

Automaatsumma viisard töötab üldjuhul vaid külgnevate lahtrivahemikega, nii et kui teie liidetavas vahemikus on tühje ridu või veerge, peatub Excel esimese tühja lahtri juures. Sel juhul peaksite liitmisel lisama ühekaupa üksikud vahemikud. Kui praeguses näites oleks teil andmeid lahtris B4, moodustaks Excel valemi =SUM(C2:C6) , kuna Excel tunneb ära külgnevatest lahtritest koosneva vahemiku.

Ctrl + vasakklõpsu abil saate valida mitu mittekülgnevat vahemikku. Esmalt sisestage valemiribale „= SUM(”, seejärel valige vahemikud ja Excel lisab automaatselt vahemike vahele eraldava semikooloni. Kui kõik on valmis, vajutage sisestusklahvi (Enter).

NÄPUNÄIDE: Klahvide ALT +  = abil saate kiiresti lisada lahtrile funktsiooni SUM. Siis on teil vaja ainult vahemikud valida.

Märkus: pange tähele, kuidas Excel on eri funktsioonivahemikud eri värvidega esile tõstnud ja ka valemis endas on kasutatud vastavat värvi, nt C2:C3 on ühte ja C5:C6 teist värvi. Excel teeb seda kõigi funktsioonide puhul, v.a juhul, kui viidatud vahemik on mõnel muul töölehel või teises töövihikus. Kasutamise hõlbustamiseks saate kasutada nimega vahemikke, nt „Nädal1“, „Nädal2“ jne ja neile oma valemis viidata:

=SUM(Nädal1,Nädal2)

Excelis saate hõlpsalt teha mitmesuguseid matemaatikatehteid nii eraldiseisvalt kui ka Exceli funktsioonide (nt SUM) abil. Järgmises tabelis on loetletud kasutatavad tehtemärgid ning mõni nendega seotud funktsioon. Tehtemärkide sisestamiseks saate kasutada nii klaviatuuri numbririda kui ka 10-kohalist numbriklahvistikku. Näiteks klahvikombinatsiooni Shift + 8 abil saate korrutamise jaoks sisestada tärni (*).

Tehtemärk

Tehe

Näited

+

Liitmine

=1+1

=A1+B1

=SUM(A1:A10)+10

=SUM(A1:A10)+B1

-

Lahutamine

=1-1

=A1-B1

=SUM(A1:A10)-10

=SUM(A1:A10)-B1

*

Korrutamine

=1*1

=A1*B1

=SUM(A1:A10)*10

=SUM(A1:A10)*B1

=PRODUCT(1;1) – funktsioon PRODUCT

/

Jagamine

=1/1

=A1/B1

=SUM(A1:A10)/10

=SUM(A1:A10)/B1

=QUOTIENT(1;1) – funktsioon QUOTIENT

^

Astendamine

=1^1

=A1^B1

=SUM(A1:A10)^10

=SUM(A1:A10)^B1

=POWER(1;1) – funktsioon POWER

Lisateavet leiate teemast Exceli kasutamine kalkulaatorina.

Teisi näiteid

  1. Oletagem, et soovite rakendada allahindluse protsenti summeeritud lahtrivahemikule.

    Tehtemärkide kasutamine funktsiooniga SUM  Lahtris B16 on valem: =SUM(A2:A14)*-25%  Valem oleks õigesti koostatud, kui -25% asemel oleks lahtriviide: = SUM(A2:A14) * E2
    • =SUM(A2:A14)*-25%

    annaks teile 25% summeeritavast vahemikust, aga sellega püsiprogrammeeritaks 25% valemisse ja seda võib olla raske hiljem leida, kui soovite seda muuta. Palju parem oleks paigutada 25% lahtrisse ja sellele viidata, nii et see oleks hõlpsasti nähtav ja muudetav:

    • =SUM(A2:A14)*E2

    Kui soovite korrutamise asemel jagada, asendage sümbol „*“ lihtsalt sümboliga „/“: = SUM(A2:A14)/E2

  2. Summast liitmine või lahutamine

    i. Sümbolite + või - abil saate hõlpsasti summast liita või lahutada:

    • =SUM(A1:A10)+E2

    • =SUM(A1:A10)-E2

Selles jaotises räägime SUM-funktsiooniga töötamise heast tavast. Suurt osa sellest saab kasutada ka muude funktsioonidega töötamisel.

=1+2 või =A+B meetod – ehkki võite sisestada valemi =1+2+3 või =A1+B1+C2 ja saada täiesti täpsed tulemused, kaasneb nende meetoditega mitmel põhjusel veaoht.

  1. Trükivead – kujutage ette, et proovite sisestada rohkem ja/või suuremaid väärtusi, näiteks:

    • =14598.93+65437.90+78496.23

    Siis proovige kontrollida, kas teie sisestatud andmed on õiged. Palju lihtsam on sisestada need väärtused üksikutesse lahtritesse ja kasutada funktsiooni SUM. Lisaks saate lahtrites olevaid väärtusi vormindada, nii et neid on palju hõlpsam lugeda kui valemis olevaid väärtusi.

    Püsiprogrammeeritud väärtuste asemel funktsiooni SUM kasutamine valemites.  Lahtris D5 on valem: =SUM(D2:D4)
  2. Vead #VALUE!, kui arvude asemel viidatakse tekstile.

    Kui kasutate mõnd sellist valemit:

    • =A1+B1+C1 või =A1+A2+A3

    Ebaõnnestunud valemi moodustamise näide.  Lahtris D2 on valem = A2+B2+C2

    Valem võib katkeda, kui viidatud lahtrites esineb mittearvulisi väärtusi (tekstväärtusi), mille korral tagastatakse viga#VALUE!. SUM ignoreerib tekstväärtusi ja annab teile vaid arvväärtuste summa.

    Õige valemi koostamine.  = A2 + B2 + C2 asemel on lahtri D2 valem =SUM(A2:C2)
  3. Viga #REF! ridade või veergude kustutamise korral

    Vea #REF! on põhjustanud veeru kustutamine.  Valem on muutunud kujule =A2+#REF!+B2

    Kui kustutate rea või veeru, ei värskendata valemit, nii et kustutatud rida arvataks välja. Seetõttu tagastatakse viga #REF!. Funktsiooni SUM värskendatakse automaatselt.

    Funktsiooni SUM kohandatakse ridade ja veergude lisamisel või kustutamisel automaatselt
  4. Ridade ja veergude lisamisel ei värskendata valemites viiteid

    = A+B+C valemeid ridade lisamisel ei värskendata

    Rea või veeru lisamisel ei värskendata valemit, nii et see hõlmaks ka lisatud rida. Funktsiooni SUM värskendatakse automaatselt (kui te pole valemis viidatud vahemikust väljas). See on eriti oluline siis, kui eeldate, et teie valemit värskendatakse, aga seda ei tehta, sest nii võib teil märkamata jääda tulemustes olev viga.

    Näitel on näha, kuidas SUM-valem =SUM(A2:C2) laieneb veeru lisamisel automaatselt kujule =SUM(A2:D2)
  5. Liitmine üksikute lahtriviidetega või vahemikena

    Kui kasutate sellist valemit:

    • =SUM(A1,A2,A3,B1,B2,B3)

    on veaoht samadel põhjustel suur ka viidatud vahemikus ridasid lisades või kustutades. Palju parem on kasutada üksikuid vahemikke, nt:

    • =SUM(A1:A3,B1:B3)

    mida ridu lisades või kustutades värskendatakse.

  1. Saate kasutada funktsiooni SUM koos muude funktsioonidega. Siin on näide kuukeskmise arvutamise kohta:

    Funktsiooni SUM kasutamine koos muude funktsioonidega.  Valem lahtris M2 on: =SUM(A2:L2)/COUNTA(A2:L2) .  Märkus: veerud mai – november on selguse huvides peidetud.
    • =SUM(A2:L2)/COUNTA(A2:L2)

  2. Sellega saadakse vahemiku A2:L2 summa, mis on jagatud vahemiku A2:L2 mittetühjade lahtrite arvuga (maist detsembrini on lahtrid tühjad).

  1. Mõnikord on vaja kokku liita ühe kindla lahtri väärtused mitmel töölehel. Võite ju klõpsata igat lehte ja soovitud lahtrit ja kasutada väärtuste kokkuliitmiseks sümbolit „+“, kuid see on tüütu ja nii on veaohtlik.

    • =Leht1!A1+Leht2!A1+Leht3!A1

    Palju lihtsam on seda teha 3D- või kolmedimensioonilise summa funktsiooni abil:

    3D summa – lahtris D2 on valem =SUM(Sheet1:Sheet3!A2)
    • =SUM(Leht1:Leht3!A1)

    Nii liidetakse kokku lahtri A1 väärtused kõigil lehtedel alates lehest 1 kuni leheni 3.

    See on eriti mugav juhul, kui teil on iga kuu (jaanuar – detsember) jaoks eraldi leht ja te soovite need kokkuvõttelehel kokku liita.

    3d SUM kõigil nimega lehtedel.  Lahtris D2 on valem: =SUM(jaanuar:detsember!A2)
    • =SUM(jaanuar:detsember!A2)

    Nii liidetakse kokku lahtris A2 olevad väärtused kõigil lehtedel jaanuarist detsembrini.

    Märkmed : Kui töölehtede nimedes esineb tühikuid, nt „jaanuari müük“, tuleb valemis töölehenimedele viidates kasutada ülakoma. Pange tähele ülakoma esimese töölehe nime EES ja uuesti viimase töölehe nime JÄREL.

    • =SUM(‘jaanuari müük:detsembri müük’!A2)

    3D-meetod toimib ka teiste funktsioonide puhul, nt AVERAGE, MIN, MAX jne:

    • =AVERAGE(Leht1:Leht3!A1)

    • =MIN(Leht1:Leht3!A1)

    • =MAX(Leht1:Leht3!A1)

Probleem

Mis läks valesti

Funktsioon SUM kuvab tulemi asemel sümbolid #####.

Vaadake üle veerulaiused. ##### tähendab enamasti, et veerg on valemi tulemi kuvamiseks liiga kitsas.

Funktsioon SUM kuvab tekstina esitatud valemi, mitte tulemi.

Kontrollige, ega lahter ole vormindatud tekstina. Valige vastav lahter või vahemik ja vajutage dialoogiboksi Lahtrite vormindamine kuvamiseks klahvikombinatsiooni Ctrl + 1. Seejärel klõpsake vahekaarti Arv ja valige vajalik vorming. Kui lahter oli vormindatud tekstina ja vormingu muutmine ei mõju, vajutage vormingumuutuse jõustamiseks klahve F2 ja sisestusklahv (Enter).

Funktsiooni SUM ei värskendata.

Veenduge, et sätte Arvutus väärtuseks oleks määratud Automaatne. Valige menüüs Valemid käsk Arvutussuvandid. Töölehel arvutamise jõustamiseks saate kasutada ka klahvi F9.

Veenduge, et arvutamine oleks määratud automaatseks.  Valige menüüs Valemid käsk Arvutussuvandid.

Osa väärtusi jääb liitmata.

Liita saab ainult funktsiooniviite või vahemiku arvväärtusi. Tühje lahtreid, loogikaväärtusi (nt TRUE) ja teksti ignoreeritakse.

Eeldatava tulemi asemel kuvatakse veaväärtus #NAME?.

Tavaliselt tähendab see, et valemis on kirjaviga, nt =sume(A1:A10), mitte =SUM(A1:A10).

Funktsiooni SUM kuvab täisarvu, kuid peaks kuvama kümnendkohtadega arvu

Kontrollige lahtrivormingut veendumaks, et kümnendkohtade kuvamine on valitud. Valige vastav lahter või vahemik ja vajutage dialoogiboksi Lahtrite vormindamine kuvamiseks klahvikombinatsiooni Ctrl + 1. Seejärel klõpsake vahekaarti Arv ja valige vajalik vorming ning soovitud arv komakohti.

  1. Soovin arve liita, lahutada, korrutada või jagada. Vaadake videoid teemadel Matemaatika alused Excelis ja Exceli kasutamine kalkulaatorina.

  2. Kuidas kuvada rohkem või vähem kümnendkohti? Saate muuta arvuvormingut. Valige vastav lahter või vahemik ja vajutage dialoogiboksi Lahtrite vormindamine kuvamiseks klahvikombinatsiooni Ctrl + 1. Seejärel klõpsake vahekaarti Arv ja valige vajalik vorming ning soovitud arv komakohti.

  3. Kuidas liita või lahutada kellaajaväärtusi? Kellaaegade liitmiseks ja lahutamiseks on mitu võimalust. Näiteks juhul, kui soovite palgaarvestuse jaoks leida kellaaegade 8:00 ja 24:00 vahe, saate kasutada järgmist valemit =("24:00"-"8:00")*24, lahutades lõppaja algusajast. Pange tähele, et Excel arvutab kellaaega päeva osana, nii et tundide koguarvu saamiseks on vaja korrutada arv 24-ga. Esimeses näites arvutame valemi =((B2-A2)+(D2-C2))*24 abil tundide summa tööaja algusest kuni lõpuni, lahutades sellest lõunapausi aja (kokku 8,5 tundi).

    Kui soovite lihtsalt liita tunnid ja minutid ning kuvada tulemi sel kujul, ei pea te summat 24-ga korrutama. Sel juhul kasutame teises näites valemit =SUM(A6:C6), sest meil on vaja lihtsalt leida määratud ülesannetele kulunud tundide ja minutite koguarv (5:36 ehk 5 tundi 36 minutit).

    Kellaaegade arvutamine

    Lisateavet leiate teemast Kellaajaväärtuste liitmine või lahutamine.

  4. Kuidas arvutada kahe kuupäeva vahele jäävate päevade arvu? Nagu kellaaegu, saate ka kuupäevi liita ja lahutada. Siin on toodud näide tavapärasest kahe kuupäeva vahele jäävate päevade arvu leidmisest. See käib lihtsalt nii: =B2-A2. Kuupäevade ja kellaaegade puhul on peamine pidada meeles, et alustada tuleb lõpukuupäevast või -kellaajast ja lahutada sellest alguskuupäev või -kellaaeg.

    Kahe kuupäeva vahele jäävate päevade arvu leidmine

    Lisavõimalusi kuupäevadega töötamiseks leiate teemast Kahe kuupäeva vahele jäävate päevade arvu arvutamine.

  5. Kuidas leida üksnes nähtavate lahtrite summa? Mõnikord (nt juhul, kui peidate lahtreid käsitsi või kasutate ainult teatud andmete kuvamiseks automaatfiltrit), soovite leida üksnes nähtavate lahtrite summa. Selleks saate kasutada funktsiooni SUBTOTAL. Kui kasutate Exceli tabelis summarida, sisestatakse kõik rippmenüüst Summa valitud funktsioonid automaatselt vahesummana. Lisateavet saate lugeda teemast Exceli tabeli andmete summeerimine.

Kas vajate rohkem abi?

Võite oma küsimuse alati esitada mõnele Exceli tehnikakogukonna eksperdile, otsida abi vastustefoorumist või soovitada mõnd uut funktsiooni või täiustust Exceli User Voice’i lehel.

Vaata ka

Vaadake videot funktsiooni SUM kasutamise kohta

Funktsioon SUMIF liidab ainult ühele kriteeriumile vastavad väärtused

Funktsioon SUMIFS liidab ainult mitmele kriteeriumile vastavad väärtused

Funktsioon COUNTIF loendab ainult ühele kriteeriumile vastavad väärtused

Funktsioon COUNTIFS loendab ainult mitmele kriteeriumile vastavad väärtused

Exceli valemite ülevaade

Katkiste valemite ärahoidmine

Valemites vigade leidmine ja lahendamine

Kiirklahvid rakenduses Excel for Windows

Kiirklahvid rakenduses Excel for Mac

Matemaatika- ja trigonomeetriafunktsioonid

Exceli funktsioonid (tähestikuliselt)

Exceli funktsioonid (kategooriate kaupa)

Täiendage oma oskusi
Tutvuge koolitusmaterjalidega
Kasutage uusi funktsioone enne teisi
Liituge Office Insideri programmiga

Kas sellest teabest oli abi?

Täname tagasiside eest!

Täname tagasiside eest! Tundub, et võiksime teid kokku viia ühega meie Office'i tugiagentidest, kes aitab teil probleemi lahendada.

×