Usar SI con las funciones Y, O y NO

La función SI le permite realizar una comparación lógica entre un valor y el resultado que espera probando una condición y devolviendo un resultado si dicha condición es verdadera o falsa.

  • =SI(Algo es Verdadero, hacer algo; de lo contrario hacer algo diferente)

Pero, ¿qué sucede si necesita probar varias condiciones, donde supongamos todas las condiciones tienen que ser Verdadero o Falso (Y), o solo una condición debe ser Verdadero o Falso (O), o si desea comprobar si una condición NO cumple los criterios? Las tres funciones se pueden usar por sí mismas, pero es mucho más común verlas emparejadas con funciones SI.

Use la función SI junto con Y, O y NO para realizar varias evaluaciones si las condiciones son Verdadero o Falso.

Sintaxis

  • SI(Y()): SI(Y(valor_lógico1, [valor_lógico2], ...), valor_si_verdadero, [valor_si_falso]))

  • SI(O()): SI(O(valor_lógico1, [valor_lógico2], ...), valor_si_verdadero, [valor_si_falso]))

  • SI(NO()): SI(NO(valor_lógico1), valor_si_verdadero, [valor_si_falso]))

Nombre del argumento

Descripción

prueba_lógica (obligatorio)

El valor que quiere probar.

valor_si_verdadero (obligatorio)

El valor que desea devuelto si el resultado de prueba_lógica es VERDADERO.

valor_si_falso (opcional)

El valor que desea devuelto si el resultado de prueba_lógica es FALSO.

La siguiente información general muestra cómo estructurar individualmente las funciones Y, O y NO. Cuando se combina cada una de ellas con una instrucción SI, se leen de esta forma:

  • Y: =SI(Y(Algo es verdadero, Algo diferente es verdadero), Valor si es verdadero, Valor si es falso)

  • O: =SI(O(Algo es verdadero, Algo diferente es verdadero), Valor si es verdadero, Valor si es falso)

  • NO: =SI(NO(Algo es verdadero), Valor si es verdadero, Valor si es falso)

Ejemplos

Estos son algunos ejemplos de instrucciones SI(Y()), SI(O()) y SI(NO()) comunes anidadas. Las funciones Y y O pueden admitir un máximo de 255 condiciones individuales, pero no es recomendable usar más de unas cuantas, ya que las fórmulas complejas y anidadas pueden ser muy difíciles de crear, probar y mantener. La función NO solo toma una condición.

Ejemplos de uso de SI con Y, O y NO para evaluar valores numéricos y texto

Estas son las fórmulas desarrolladas según su lógica:

Fórmula

Descripción

=SI(Y(A2>0,B2<100),VERDADERO, FALSO)

SI A2 (25) es mayor que 0, Y B2 (75) es menor que 100, devolver VERDADERO, de lo contrario, devolver FALSO. En este caso, ambas condiciones son verdaderas, por tanto se devuelve VERDADERO.

=SI(Y(A3="Rojo",B3="Verde"),VERDADERO,FALSO)

Si A3 ("Azul") = "Rojo", Y B3 ("Verde") es igual a "Verde"devolver VERDADERO, de lo contrario, devolver FALSO. En este caso, solo la primera condición es verdadera, por lo que se devuelve FALSO.

=SI(O(A4>0,B4<50),VERDADERO, FALSO)

SI A4 (25) es mayor que 0, O B4 (75) es menor que 50, devolver VERDADERO, de lo contrario, devolver FALSO. En este caso, solo la primera condición es VERDADERO, pero como O solo requiere que un argumento sea verdadero, la fórmula devuelve VERDADERO.

=SI(O(A5="Rojo",B5="Verde"),VERDADERO,FALSO)

Si A5 ("Azul") es igual a "Rojo" O B5 ("Verde") es igual a "Verde" devolver VERDADERO, de lo contrario, devolver FALSO. En este caso, el segundo argumento es verdadero, por lo que la fórmula devuelve VERDADERO.

=SI(NO(A6>50),VERDADERO,FALSO)

SI A6 (25) NO es mayor que 50, devolver VERDADERO, de lo contrario, devolver FALSO. En este caso 25 no es mayor que 50, por lo que la fórmula devuelve VERDADERO.

=SI(NO(A7="Rojo"),VERDADERO,FALSO)

IF A7 ("Azul") No es igual a "Rojo", devolver VERDADERO, de lo contrario, devolver FALSO.

Tenga en cuenta que todos los ejemplos tienen un paréntesis de cierre después de escribir sus correspondientes condiciones. El resto de los argumentos Verdadero/Falso se dejan como parte de la instrucción SI externa. También puede sustituir texto o valores numéricos para los valores VERDADERO/FALSO para que se devuelvan en los ejemplos.

Estos son algunos ejemplos de uso de Y, O y NO para evaluar fechas.

Ejemplos de uso de SI con Y, O y NO para evaluar fechas

Estas son las fórmulas desarrolladas según su lógica:

Fórmula

Descripción

=SI(A2>B2,VERDADERO,FALSO)

SI A2 es mayor que B2, devolver VERDADERO, de lo contrario, devolver FALSO. 03/12/14 es mayor que 01/01/14, por lo que la fórmula devuelve VERDADERO.

=SI(Y(A3>B2,A3<C2),VERDADERO,FALSO)

SI A3 es mayor que B2 Y A3 es menor que C2, devolver VERDADERO, de lo contrario, devolver FALSO. En este caso, los dos argumentos son verdaderos, por lo que la fórmula devuelve VERDADERO.

=SI(O(A4>B2,A4<B2+60),VERDADERO,FALSO)

SI A4 es mayor que B2 O A4 es menor que B2 + 60, devolver VERDADERO, de lo contrario, devolver FALSO. En este caso, el primer argumento es verdadero, pero el segundo es falso. Como O solo necesita que uno de los argumentos sea verdadero, la fórmula devuelve VERDADERO. Si usa al Asistente para evaluar fórmulas desde la pestaña Fórmula verá cómo Excel evalúa la fórmula.

=SI(NO(A5>B2),VERDADERO,FALSO)

SI A5 no es mayor que B2, devolver VERDADERO, de lo contrario, devolver FALSO. En este caso, A5 es mayor que B2, por lo que la fórmula devuelve FALSO.

Ejemplo del asistente para evaluar fórmulas.

Ejemplo de uso de Y, O y NO con formato condicional

También puede usar Y, O y NO para establecer criterios de formato condicional con la opción de la fórmula. Al hacer esto puede omitir la función SI y usar Y, O y NO por sí mismas.

En la pestaña Inicio, haga clic en Formato condicional > Nueva regla. Después, seleccione la opción "Usar una fórmula que determine las celdas para aplicar formato", escriba la fórmula y aplique el formato que desee.

Cuadro de diálogo Formato condicional > Editar regla con el método de fórmula

Usando el ejemplo de fechas anterior, este sería el aspecto de las fórmulas.

Ejemplo de uso de Y, O y NO como pruebas de formato condicional


Fórmula

Descripción

=A2>B2

Si A2 es mayor que B2, dar formato a la celda, de lo contrario, no hacer nada.

=Y(A3>B2,A3<C2)

SI A3 es mayor que B2 Y A3 es menor que C2, dar formato a la celda, de lo contrario, no hacer nada.

=O(A4>B2,A4<B2+60)

SI A4 es mayor que B2 O A4 es menor que B2 más 60 (días), dar formato a la celda, de lo contrario, no hacer nada.

=NO(A5>B2)

Si A5 NO es mayor que B2, dar formato a la celda, de lo contrario, no hacer nada. En este caso, A5 es mayor que B2, por lo que la fórmula devuelve FALSO. Si cambiara la fórmula por =NO(B2>A5) devolvería VERDADERO y se daría formato a la celda.

Nota: Un error común es escribir la fórmula en Formato condicional sin el signo igual (=). Si hace esto, verá que el cuadro de diálogo Formato condicional agrega el signo igual y comillas a la fórmula: ="O(A4>B2,A4<B2+60)", por lo que tendrá que quitar las comillas antes de que la fórmula responda correctamente.

Principio de página

¿Necesitas más ayuda?

Siempre puede preguntar a un experto en Excel Tech Community, obtener soporte técnico en la Comunidad de respuestas o sugerir una característica nueva o mejora en el UserVoice de Excel.

Vea también

Ver un vídeo sobre cómo usar la función SI

Obtener información sobre cómo usar funciones anidadas en una fórmula

Función SI

Función Y

Función O

Función NO

Información general de fórmulas en Excel

Cómo evitar las fórmulas rotas

Usar la comprobación de errores para detectar errores en las fórmulas

Métodos abreviados de teclado en Excel para Windows

Métodos abreviados de teclado en Excel para Mac

Funciones lógicas (referencia)

Funciones de Excel (orden alfabético)

Funciones de Excel (por categoría)

Ampliar sus conocimientos
Explorar los cursos
Obtener nuevas características primero
Únase a los participantes de Office Insider

¿Le ha sido útil esta información?

¡Gracias por sus comentarios!

Gracias por sus comentarios. Quizá le interese ponerse en contacto con uno de nuestros agentes de soporte de Office.

×