Iniciar sesión con Microsoft
Iniciar sesión o crear una cuenta
Hola:
Seleccione una cuenta diferente.
Tiene varias cuentas
Elija la cuenta con la que desea iniciar sesión.
Dividir texto en columnas diferentes con funciones

Puede usar las funciones de texto IZQUIERDA, EXTRAE, DERECHA, HALLAR y LARGO para manipular cadenas de texto en los datos. Por ejemplo, puede distribuir el nombre, el segundo nombre y los apellidos de una sola celda en tres columnas independientes.

La clave para distribuir componentes de nombre con funciones de texto es la posición de cada carácter dentro de una cadena de texto. Las posiciones de los espacios dentro de la cadena de texto también son importantes porque indican el principio o el final de los componentes del nombre en una cadena.

Por ejemplo, en una celda que contiene solo un nombre y un apellido, el apellido comienza detrás de la primera instancia de un espacio. Algunos nombres de la lista pueden contener un segundo nombre, en cuyo caso el apellido comienza detrás de la segunda instancia de un espacio.

En este artículo se muestra cómo extraer varios componentes de una variedad de formatos de nombre con estas útiles funciones. También puede dividir texto en columnas diferentes con el Asistente para convertir texto en columnas

Nombre de ejemplo

Descripción

Nombre

Segundo nombre

Apellidos

Sufijo

1

Juan Saavedra

Sin segundo nombre

Jeff

Saavedra

2

José I. Peiro

Una inicial en medio

José

S.

Peiro

3

Janaina B. G. Bueno

Dos iniciales en medio

Janaina

B. G.

Bueno

4

Jaime, Humberto Patino

Primero el apellido con una coma

Jaime

Humberto

Patino

5

Mary Kay D. Andersen

Nombre con dos partes

Mary Kay

D.

Andersen

6

Paula Barreto de Mattos

Apellido con tres partes

Paula

Barreto de Mattos

7

James van Eaton

Apellido con dos partes

James

van Eaton

8

Bacon Jr., Dan K.

Primero el apellido y el sufijo con una coma

Dan

K.

Bacon

Jr.

9

Gary Altman III

Con sufijo

Gary

Altman

III

10

Sr. Tomás Navarro

Con prefijo

Tomás

Navarro

11

Francisco Pérez-Olaeta

Apellido con un guión

Francisco

Pérez-Olaeta

Nota: En los gráficos de los ejemplos siguientes, el resaltado en el nombre completo muestra el carácter que busca la fórmula HALLAR coincidente.

En este ejemplo se separan dos componentes: nombre y apellido. Un solo espacio separa los dos nombres.

Copie las celdas de la tabla y péguelas en una hoja de cálculo de Excel en la celda A1. La fórmula que ve a la izquierda se mostrará como referencia, mientras que Excel convertirá automáticamente la fórmula a la derecha en el resultado adecuado.

Sugerencia    Antes de pegar los datos en la hoja de cálculo, establezca los anchos de columna de las columnas A y B en 250.

Nombre de ejemplo

Descripción

Juan Saavedra

Sin segundo nombre

Fórmula

Resultado (nombre)

'=IZQUIERDA(A2, HALLAR(" ",A2,1))

=IZQUIERDA(A2, HALLAR(" ",A2,1))

Fórmula

Resultado (apellido)

'=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,1))

=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,1))

  1. Nombre

    El nombre empieza en el primer carácter de la cadena (J) y termina en el quinto carácter (el espacio). La fórmula devuelve cinco caracteres en la celda A2, empezando desde la izquierda.

    Fórmula para extraer un nombre

    Use la función HALLAR para buscar el valor de núm_caracteres:

    Busque la posición numérica del espacio en A2, empezando desde la izquierda.

  2. Apellido

    El apellido comienza en el espacio, ocupa ocho caracteres desde la derecha y termina en el último carácter de la derecha (a). La fórmula extrae ocho caracteres en A2, empezando desde la derecha.

    Fórmula para extraer un apellido

    Use las funciones HALLAR y LARGO para buscar el valor de núm_caracteres:

    Busque la posición numérica del espacio en A2, empezando desde la izquierda. (5)

  3. Cuente la longitud total de la cadena de texto y, después, reste el número de caracteres hasta la izquierda del primer espacio hallado en el paso 1.

En este ejemplo se usa un nombre, una inicial del segundo nombre y un apellido. Los componentes del nombre completo se separan con espacios.

Copie las celdas de la tabla y péguelas en una hoja de cálculo de Excel en la celda A1. La fórmula que ve a la izquierda se mostrará como referencia, mientras que Excel convertirá automáticamente la fórmula a la derecha en el resultado adecuado.

Sugerencia    Antes de pegar los datos en la hoja de cálculo, establezca los anchos de columna de las columnas A y B en 250.

Nombre de ejemplo

Descripción

José I. Peiro

Una inicial en medio

Fórmula

Resultado (nombre)

'=IZQUIERDA(A2, HALLAR(" ",A2,1))

=IZQUIERDA(A2, HALLAR(" ",A2,1))

Fórmula

Resultado (inicial del medio)

'=EXTRAE(A2,HALLAR(" ",A2,1)+1,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)-HALLAR(" ",A2,1))

=EXTRAE(A2,HALLAR(" ",A2,1)+1,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)-HALLAR(" ",A2,1))

Fórmula

Resultado activo (apellido)

'=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,HALLAR(" ",A2,1)+1))

=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,HALLAR(" ",A2,1)+1))

  1. Nombre

    El nombre comienza en el primer carácter de la izquierda (J) y termina en el quinto carácter (el primer espacio). La fórmula extrae los cinco primeros caracteres en A2, empezando desde la izquierda.

    Fórmula para separar un nombre y apellido, más la inicial del segundo nombre

    Use la función HALLAR para buscar el valor de núm_caracteres:

    Busque la posición numérica del espacio en A2, empezando desde la izquierda. (5)

  2. Segundo nombre

    El segundo nombre comienza en el sexto carácter (I) y termina en la octava posición (el segundo espacio). Esta fórmula incluye funciones HALLAR anidadas para buscar la segunda instancia de un espacio.

    La fórmula extrae tres caracteres, empezando desde la sexta posición.

    Detalles de una fórmula para separar nombre, segundo nombre y apellidos

    Use la función HALLAR para buscar el valor de núm_inicial:

    Busque la posición numérica del primer espacio en A2, empezando desde el primer carácter de la izquierda. (5).

  3. Sume 1 para obtener la posición del carácter situado detrás del primer espacio (S). Esta posición numérica es la posición inicial del segundo nombre. (5 + 1 = 6)

    Use funciones HALLAR anidadas para buscar el valor de núm_caracteres:

    Busque la posición numérica del primer espacio en A2, empezando desde el primer carácter de la izquierda. (5)

  4. Sume 1 para obtener la posición del carácter situado detrás del primer espacio (S). El resultado es el número de carácter en el que desea iniciar la búsqueda de la segunda instancia del espacio. (5 + 1 = 6)

  5. Busque la segunda instancia del espacio en A2, empezando desde la sexta posición (S) hallada en el paso 4. Este número de carácter es la posición final del segundo nombre. (8)

  6. Busque la posición numérica del espacio en A2, empezando desde el primer carácter de la izquierda. (5)

  7. Tome el número de carácter del segundo espacio hallado en el paso 5 y reste el número de carácter del primer espacio hallado en el paso 6. El resultado es el número de caracteres que la función EXTRAE extrae de la cadena de texto empezando en la sexta posición hallada en el paso 2. (8 – 5 = 3)

  8. Apellido

    El apellido comienza en el quinto carácter desde la derecha (P) y termina en el primer carácter de la derecha (o). Esta fórmula incluye funciones HALLAR anidadas para buscar la segunda y tercera instancia del espacio (que se encuentra en las posiciones quinta y octava desde la izquierda).

    La fórmula extrae cinco caracteres en A2, empezando desde la derecha.

    La segunda función HALLAR en una fórmula para separar nombre, segundo nombre y apellidos
  9. Use las funciones LARGO y HALLAR para buscar el valor de núm_caracteres:

    Busque la posición numérica del espacio en A2, empezando desde el primer carácter de la izquierda. (5)

  10. Sume 1 para obtener la posición del carácter situado detrás del primer espacio (S). El resultado es el número de carácter en el que desea iniciar la búsqueda de la segunda instancia del espacio. (5 + 1 = 6)

  11. Busque la segunda instancia del espacio en A2, empezando desde la sexta posición (S) hallada en el paso 2. Este número de carácter es la posición final del segundo nombre. (8)

  12. Cuenta la longitud total de la cadena de texto en A2 y, después, resta el número de caracteres desde la izquierda hasta la segunda instancia del espacio que se encontró en el paso 3. El resultado es el número de caracteres que se extraerán desde la derecha del nombre completo. (14 – 8 = 6).

Este es un ejemplo de cómo extraer dos iniciales del medio. Los componentes del nombre se separan con el primer y el tercer espacio.

Copie las celdas de la tabla y péguelas en una hoja de cálculo de Excel en la celda A1. La fórmula que ve a la izquierda se mostrará como referencia, mientras que Excel convertirá automáticamente la fórmula a la derecha en el resultado adecuado.

Sugerencia    Antes de pegar los datos en la hoja de cálculo, establezca los anchos de columna de las columnas A y B en 250.

Nombre de ejemplo

Descripción

Janaina B. G. Bueno

Dos iniciales en medio

Fórmula

Resultado (nombre)

'=IZQUIERDA(A2, HALLAR(" ",A2,1))

=IZQUIERDA(A2, HALLAR(" ",A2,1))

Fórmula

Resultado (iniciales del medio)

'=EXTRAE(A2,HALLAR(" ",A2,1)+1,HALLAR(" ",A2,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1)-HALLAR(" ",A2,1))

=EXTRAE(A2,HALLAR(" ",A2,1)+1,HALLAR(" ",A2,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1)-HALLAR(" ",A2,1))

Fórmula

Resultado activo (apellido)

'=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1))

=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1))

  1. Nombre

    El nombre comienza en el primer carácter de la izquierda (J) y termina en el octavo carácter (el primer espacio). La fórmula extrae los ocho primeros caracteres en A2, empezando desde la izquierda.

    Fórmula para separar nombre, apellido y dos iniciales del segundo nombre

    Use la función HALLAR para buscar el valor de núm_caracteres:

    Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (8)

  2. Segundo nombre

    El segundo nombre comienza en la novena posición (B) y termina en la decimocuarta posición (el tercer espacio). Esta fórmula incluye funciones HALLAR anidadas para buscar la primera, segunda y tercera instancia del espacio en la octava, novena y decimocuarta posición.

    La fórmula extrae cinco caracteres, empezando desde la novena posición.

    Fórmula para separar nombre, apellido y dos iniciales del segundo nombre

    Use la función HALLAR para buscar el valor de núm_inicial:

    Busque la posición numérica del primer espacio en A2, empezando desde el primer carácter de la izquierda. (8)

  3. Sume 1 para obtener la posición del carácter situado detrás del primer espacio (B). Esta posición numérica es la posición inicial del segundo nombre. (8 + 1 = 9)

    Use funciones HALLAR anidadas para buscar el valor de núm_caracteres:

    Busque la posición numérica del primer espacio en A2, empezando desde el primer carácter de la izquierda. (8)

  4. Sume 1 para obtener la posición del carácter situado detrás del primer espacio (B). El resultado es el número de carácter en el que desea iniciar la búsqueda de la segunda instancia del espacio. (8 + 1 = 9)

  5. Busca el segundo espacio en A2, empezando desde la novena posición (B) que se encontró en el paso 4. (11).

  6. Sume 1 para obtener la posición del carácter situado detrás del segundo espacio (G). Este número de carácter es la posición inicial en la que desea iniciar la búsqueda del tercer espacio. (11 + 1 = 12)

  7. Busque el tercer espacio en A2, empezando desde la decimosegunda posición hallada en el paso 6. (14)

  8. Busque la posición numérica del primer espacio en A2. (8)

  9. Tome el número de carácter del tercer espacio hallado en el paso 7 y réstelo del primer espacio hallado en el paso 6. El resultado es el número de caracteres que la función EXTRAE extrae del texto empezando en la novena posición hallada en el paso 2.

  10. Apellido

    El apellido comienza en el quinto carácter desde la derecha (B) y termina en el primer carácter de la derecha (o). Esta fórmula incluye funciones HALLAR anidadas para buscar la primera, segunda y tercera instancia del espacio.

    La fórmula extrae ocho caracteres en A2, empezando desde la derecha del nombre completo.

    Fórmula para separar nombre, apellido y dos iniciales del segundo nombre

    Use las funciones anidadas HALLAR y LARGO para buscar el valor de núm_caracteres:

    Busque la posición numérica del primer espacio en A2, empezando desde el primer carácter de la izquierda. (8)

  11. Sume 1 para obtener la posición del carácter situado detrás del primer espacio (B). El resultado es el número de carácter en el que desea iniciar la búsqueda de la segunda instancia del espacio. (8 + 1 = 9)

  12. Busca el segundo espacio en A2, empezando desde la novena posición (B) hallada en el paso 2. (11)

  13. Sume 1 para obtener la posición del carácter situado detrás del segundo espacio (G). Este número de carácter es la posición inicial en la que desea iniciar la búsqueda de la tercera instancia del espacio. (11 + 1 = 12)

  14. Busca el tercer espacio en A2, empezando desde la decimosegunda posición (G) hallada en el paso 6. (14)

  15. Cuente la longitud total de la cadena de texto en A2 y, después, reste el número de caracteres desde la izquierda hasta el tercer espacio hallado en el paso 5. El resultado es el número de caracteres que se extraerán desde la derecha del nombre completo. (19 - 14 = 5)

En este ejemplo, el apellido precede al nombre y el segundo nombre aparece al final. La coma indica el final del apellido y un espacio separa cada componente del nombre.

Copie las celdas de la tabla y péguelas en una hoja de cálculo de Excel en la celda A1. La fórmula que ve a la izquierda se mostrará como referencia, mientras que Excel convertirá automáticamente la fórmula a la derecha en el resultado adecuado.

Sugerencia    Antes de pegar los datos en la hoja de cálculo, establezca los anchos de columna de las columnas A y B en 250.

Nombre de ejemplo

Descripción

Jaime, Humberto Patino

Primero el apellido con una coma

Fórmula

Resultado (nombre)

'=EXTRAE(A2,HALLAR(" ",A2,1)+1,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)-HALLAR(" ",A2,1))

=EXTRAE(A2,HALLAR(" ",A2,1)+1,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)-HALLAR(" ",A2,1))

Fórmula

Resultado (segundo nombre)

'=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,HALLAR(" ",A2,1)+1))

=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,HALLAR(" ",A2,1)+1))

Fórmula

Resultado activo (apellido)

'=IZQUIERDA(A2, HALLAR(" ",A2,1)-2)

=IZQUIERDA(A2, HALLAR(" ",A2,1)-2)

  1. Nombre

    El nombre comienza en el noveno carácter de la izquierda (J) y termina en el decimocuarto carácter (el segundo espacio). Como el nombre aparece en medio del nombre completo, necesita usar la función EXTRAE para extraerlo.

    La fórmula extrae ocho caracteres, empezando desde la novena posición.

    Fórmula para separar un apellido seguido de un nombre y un segundo nombre

    Use la función HALLAR para buscar el valor de núm_inicial:

    Busque la posición numérica del primer espacio en A2, empezando desde el primer carácter de la izquierda. (6)

  2. Sume 1 para obtener la posición del carácter situado detrás del primer espacio (J). Esta posición numérica es la posición inicial del nombre. (6 + 1 = 7)

    Use funciones HALLAR anidadas para buscar el valor de núm_caracteres:

    Busque la posición numérica del primer espacio en A2, empezando desde el primer carácter de la izquierda. (6)

  3. Sume 1 para obtener la posición del carácter situado detrás del primer espacio (J). El resultado es el número de carácter en el que desea iniciar la búsqueda del segundo espacio. (6 + 1 = 7)

    Busque el segundo espacio en A2, empezando desde la séptima posición (W) hallada en el paso 4. (12)

  4. Busque la posición numérica del primer espacio en A2, empezando desde el primer carácter de la izquierda. (6)

  5. Tome el número de carácter del segundo espacio hallado en el paso 5 y reste el número de carácter del primer espacio hallado en el paso 6. El resultado es el número de caracteres que la función EXTRAE extrae de la cadena de texto empezando en la séptima posición hallada en el paso 2. (12 - 6 = 6)

  6. Segundo nombre

    El segundo nombre comienza en el octavo carácter de la derecha (H) y termina en el primer carácter de la derecha (o). Esta fórmula incluye funciones HALLAR anidadas para buscar la primera y segunda instancia del espacio en las posiciones octava y decimocuarta desde la izquierda.

    La fórmula extrae ocho caracteres, empezando desde la derecha.

    Fórmula para separar un apellido seguido de un nombre y un segundo nombre

    Use las funciones HALLAR y LARGO anidadas para buscar el valor de núm_caracteres:

    Busque la posición numérica del primer espacio en A2, empezando desde el primer carácter de la izquierda. (6)

  7. Sume 1 para obtener la posición del carácter situado detrás del primer espacio (J). El resultado es el número de carácter en el que desea iniciar la búsqueda del segundo espacio. (6 + 1 = 7)

  8. Busque la segunda instancia del espacio en A2 empezando desde la séptima posición (W) hallada en el paso 2. (12)

  9. Cuente la longitud total de la cadena de texto en A2 y, después, reste el número de caracteres desde la izquierda hasta el segundo espacio hallado en el paso 3. El resultado es el número de caracteres que se extraerán desde la derecha del nombre completo. (16 - 12 = 4)

  10. Apellido

    El apellido comienza en el primer carácter de la izquierda (P) y termina en el sexto carácter (o). La fórmula extrae seis caracteres, empezando desde la izquierda.

    Fórmula para separar un apellido seguido de un nombre y un segundo nombre

    Use la función HALLAR para buscar el valor de núm_caracteres:

    Busque la posición numérica del primer espacio en A2, empezando desde el primer carácter de la izquierda. (6)

  11. Resta 2 para obtener la posición numérica del carácter final del apellido (o). El resultado es el número de caracteres que quiere extraer con la función IZQUIERDA. (8 - 2 = 6)

En este ejemplo se usa un nombre de dos partes, Mary Kay. El segundo y el tercer espacio separan los componentes del nombre.

Copie las celdas de la tabla y péguelas en una hoja de cálculo de Excel en la celda A1. La fórmula que ve a la izquierda se mostrará como referencia, mientras que Excel convertirá automáticamente la fórmula a la derecha en el resultado adecuado.

Sugerencia    Antes de pegar los datos en la hoja de cálculo, establezca los anchos de columna de las columnas A y B en 250.

Nombre de ejemplo

Descripción

Mary Kay D. Andersen

Nombre con dos partes

Fórmula

Resultado (nombre)

IZQUIERDA(A2, HALLAR(" ",A2,HALLAR(" ",A2,1)+1))

=IZQUIERDA(A2, HALLAR(" ",A2,HALLAR(" ",A2,1)+1))

Fórmula

Resultado (inicial del medio)

'=EXTRAE(A2,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1,HALLAR(" ",A2,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1)-(HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1))

=EXTRAE(A2,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1,HALLAR(" ",A2,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1)-(HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1))

Fórmula

Resultado activo (apellido)

'=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1))

=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1))

  1. Nombre

    El nombre comienza en el primer carácter de la izquierda y termina en el noveno carácter (el segundo espacio). Esta fórmula incluye funciones HALLAR anidadas para buscar la segunda instancia del espacio desde la izquierda.

    La fórmula extrae nueve caracteres, empezando desde la izquierda.

    Fórmula para separar nombre, segundo nombre, inicial del segundo nombre y apellido

    Use funciones HALLAR anidadas para buscar el valor de núm_caracteres:

    Busque la posición numérica del primer espacio en A2, empezando desde el primer carácter de la izquierda. (5)

  2. Sume 1 para obtener la posición del carácter situado detrás del primer espacio (K). El resultado es el número de carácter en el que desea iniciar la búsqueda de la segunda instancia del espacio. (5 + 1 = 6)

  3. Busque la segunda instancia del espacio en A2, empezando desde la sexta posición (K) hallada en el paso 2. El resultado es el número de caracteres que izquierda extrae de la cadena de texto. (9)

  4. Segundo nombre

    El segundo nombre comienza en la décima posición (D) y termina en la decimosegunda posición (el tercer espacio). Esta fórmula incluye funciones HALLAR anidadas para buscar la primera, segunda y tercera instancia del espacio.

    La fórmula extrae dos caracteres del medio, empezando desde la décima posición.

    Fórmula para separar nombre, segundo nombre, inicial del segundo nombre y apellido

    Use funciones HALLAR anidadas para buscar el valor de núm_inicial:

    Busque la posición numérica del primer espacio en A2, empezando desde el primer carácter de la izquierda. (5)

  5. Sume 1 para obtener el carácter situado detrás del primer espacio (K). El resultado es el número de carácter en el que desea iniciar la búsqueda del segundo espacio. (5 + 1 = 6)

  6. Busque la posición de la segunda instancia del espacio en A2, empezando desde la sexta posición (K) hallada en el paso 2. El resultado es el número de caracteres que la función IZQUIERDA extrae desde la izquierda. (9)

  7. Sume 1 para obtener el carácter situado detrás del segundo espacio (D). El resultado es la posición inicial del segundo nombre. (9 + 1 = 10)

    Use funciones HALLAR anidadas para buscar el valor de núm_caracteres:

    Busca la posición numérica del carácter situado detrás del segundo espacio (D). El resultado es el número de carácter en el que desea iniciar la búsqueda del tercer espacio. (10)

  8. Busca la posición numérica del tercer espacio en A2, empezando desde la izquierda. El resultado es la posición final del segundo nombre. (12)

  9. Busca la posición numérica del carácter situado detrás del segundo espacio (D). El resultado es la posición inicial del segundo nombre. (10)

  10. Tome el número de carácter del tercer espacio hallado en el paso 6 y reste el número de carácter de "D" hallado en el paso 7. El resultado es el número de caracteres que la función EXTRAE extrae de la cadena de texto empezando en la décima posición hallada en el paso 4. (12 - 10 = 2)

  11. Apellido

    El apellido empieza en el octavo carácter de la derecha. Esta fórmula incluye funciones HALLAR anidadas para buscar la primera, segunda y tercera instancia del espacio en la quinta, novena y decimosegunda posición.

    La fórmula extrae ocho caracteres desde la derecha.

    Fórmula para separar nombre, segundo nombre, inicial del segundo nombre y apellido

    Use las funciones HALLAR y LARGO anidadas para buscar el valor de núm_caracteres:

    Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (5)

  12. Sume 1 para obtener el carácter situado detrás del primer espacio (K). El resultado es el número de carácter en el que desea iniciar la búsqueda del espacio. (5 + 1 = 6)

  13. Busque el segundo espacio en A2, empezando desde la sexta posición (K) hallada en el paso 2. (9)

  14. Sume 1 para obtener la posición del carácter situado detrás del segundo espacio (D). El resultado es la posición inicial del segundo nombre. (9 + 1 = 10)

  15. Busca la posición numérica del tercer espacio en A2, empezando desde la izquierda. El resultado es la posición final del segundo nombre. (12)

  16. Cuente la longitud total de la cadena de texto en A2 y, después, reste el número de caracteres desde la izquierda hasta el tercer espacio hallado en el paso 5. El resultado es el número de caracteres que se extraerán desde la derecha del nombre completo. (20 - 12 = 8)

En este ejemplo se usa un apellido de tres partes: Barreto de Mattos. El primer espacio indica el final del nombre y el principio del apellido.

Copie las celdas de la tabla y péguelas en una hoja de cálculo de Excel en la celda A1. La fórmula que ve a la izquierda se mostrará como referencia, mientras que Excel convertirá automáticamente la fórmula a la derecha en el resultado adecuado.

Sugerencia    Antes de pegar los datos en la hoja de cálculo, establezca los anchos de columna de las columnas A y B en 250.

Nombre de ejemplo

Descripción

Paula Barreto de Mattos

Apellido con tres partes

Fórmula

Resultado (nombre)

'=IZQUIERDA(A2, HALLAR(" ",A2,1))

=IZQUIERDA(A2, HALLAR(" ",A2,1))

Fórmula

Resultado (apellido)

DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,1))

=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,1))

  1. Nombre

    El nombre comienza en el primer carácter de la izquierda (P) y termina en el sexto carácter (el primer espacio). La fórmula extrae seis caracteres desde la izquierda.

    Fórmula para separar un nombre y un apellido de tres partes

    Use la función HALLAR para buscar el valor de núm_caracteres:

    Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (6)

  2. Apellido

    El apellido comienza en el séptimo carácter desde la derecha (B) y termina en el primer carácter de la derecha (s). La fórmula extrae diecisiete caracteres desde la derecha.

    Fórmula para separar un nombre y un apellido de tres partes

    Use las funciones LARGO y HALLAR para buscar el valor de núm_caracteres:

    Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (6)

  3. Cuente la longitud total de la cadena de texto en A2 y, después, reste el número de caracteres desde la izquierda hasta el primer espacio hallado en el paso 1. El resultado es el número de caracteres que se extraerán desde la derecha del nombre completo. (23 - 6 = 17)

En este ejemplo se usa un apellido de dos partes: van Eaton. El primer espacio indica el final del nombre y el principio del apellido.

Copie las celdas de la tabla y péguelas en una hoja de cálculo de Excel en la celda A1. La fórmula que ve a la izquierda se mostrará como referencia, mientras que Excel convertirá automáticamente la fórmula a la derecha en el resultado adecuado.

Sugerencia    Antes de pegar los datos en la hoja de cálculo, establezca los anchos de columna de las columnas A y B en 250.

Nombre de ejemplo

Descripción

James van Eaton

Apellido con dos partes

Fórmula

Resultado (nombre)

'=IZQUIERDA(A2, HALLAR(" ",A2,1))

=IZQUIERDA(A2, HALLAR(" ",A2,1))

Fórmula

Resultado (apellido)

'=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,1))

=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,1))

  1. Nombre

    El nombre comienza en el primer carácter de la izquierda (J) y termina en el octavo carácter (el primer espacio). La fórmula extrae seis caracteres desde la izquierda.

    Fórmula para separar un nombre y un apellido de dos palabras

    Use la función HALLAR para buscar el valor de núm_caracteres:

    Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (6)

  2. Apellido

    El apellido comienza en el noveno carácter desde la derecha (v) y termina en el primer carácter de la derecha (n). La fórmula extrae nueve caracteres desde la derecha del nombre completo.

    Fórmula para separar un nombre y un apellido de dos palabras

    Use las funciones LARGO y HALLAR para buscar el valor de núm_caracteres:

    Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (6)

  3. Cuente la longitud total de la cadena de texto en A2 y, después, reste el número de caracteres desde la izquierda hasta el primer espacio hallado en el paso 1. El resultado es el número de caracteres que se extraerán desde la derecha del nombre completo. (15 - 6 = 9)

En este ejemplo, el apellido ocupa el primer lugar, seguido del sufijo. La coma separa el apellido y el sufijo del nombre y de la inicial.

Copie las celdas de la tabla y péguelas en una hoja de cálculo de Excel en la celda A1. La fórmula que ve a la izquierda se mostrará como referencia, mientras que Excel convertirá automáticamente la fórmula a la derecha en el resultado adecuado.

Sugerencia    Antes de pegar los datos en la hoja de cálculo, establezca los anchos de columna de las columnas A y B en 250.

Nombre de ejemplo

Descripción

Bacon Jr., Dan K.

Primero el apellido y el sufijo con una coma

Fórmula

Resultado (nombre)

'=EXTRAE(A2,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1,HALLAR(" ",A2,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1)-HALLAR(" ",A2,HALLAR(" ",A2,1)+1))

=EXTRAE(A2,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1,HALLAR(" ",A2,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1)-HALLAR(" ",A2,HALLAR(" ",A2,1)+1))

Fórmula

Resultado (inicial del medio)

'=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1))

=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1))

Fórmula

Resultado (apellido)

'=IZQUIERDA(A2, HALLAR(" ",A2,1))

=IZQUIERDA(A2, HALLAR(" ",A2,1))

Fórmula

Resultado (sufijo)

'=EXTRAE(A2,HALLAR(" ", A2,1)+1,(HALLAR(" ",A2,HALLAR(" ",A2,1)+1)-2)-HALLAR(" ",A2,1))

=EXTRAE(A2,HALLAR(" ", A2,1)+1,(HALLAR(" ",A2,HALLAR(" ",A2,1)+1)-2)-HALLAR(" ",A2,1))

  1. Nombre

    El nombre comienza en el decimosegundo carácter (D) y termina en el decimoquinto carácter (el tercer espacio). La fórmula extrae tres caracteres, empezando desde la decimoquinta posición.

    Fórmula para separar primero un apellido y un sufijo, con coma

    Use funciones HALLAR anidadas para buscar el valor de núm_inicial:

    Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (6)

  2. Sume 1 para obtener el carácter situado detrás del primer espacio (J). El resultado es el número de carácter en el que desea iniciar la búsqueda del segundo espacio. (6 + 1 = 7)

  3. Busque el segundo espacio en A2, empezando desde la séptima posición (J), hallada en el paso 2. (11)

  4. Sume 1 para obtener el carácter situado detrás del segundo espacio (D). El resultado es la posición inicial del nombre. (11 + 1 = 12)

    Use funciones HALLAR anidadas para buscar el valor de núm_caracteres:

    Busca la posición numérica del carácter situado detrás del segundo espacio (D). El resultado es el número de carácter en el que desea iniciar la búsqueda del tercer espacio. (12)

  5. Busca la posición numérica del tercer espacio en A2, empezando desde la izquierda. El resultado es la posición final del nombre. (15)

  6. Busca la posición numérica del carácter situado detrás del segundo espacio (D). El resultado es la posición inicial del nombre. (12)

  7. Tome el número de carácter del tercer espacio hallado en el paso 6 y reste el número de carácter de "D" hallado en el paso 7. El resultado es el número de caracteres que la función EXTRAE extrae de la cadena de texto empezando en la decimocuarta posición hallada en el paso 4. (15 - 12 = 3)

  8. Segundo nombre

    El segundo nombre empieza en el segundo carácter de la derecha (K). La fórmula extrae dos caracteres desde la derecha.

    Fórmula para separar primero un apellido y un sufijo, con coma

    Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (6)

  9. Sume 1 para obtener el carácter situado detrás del primer espacio (J). El resultado es el número de carácter en el que desea iniciar la búsqueda del segundo espacio. (6 + 1 = 7)

  10. Busque el segundo espacio en A2, empezando desde la séptima posición (J), hallada en el paso 2. (11)

  11. Sume 1 para obtener el carácter situado detrás del segundo espacio (D). El resultado es la posición inicial del nombre. (11 + 1 = 12)

  12. Busca la posición numérica del tercer espacio en A2, empezando desde la izquierda. El resultado es la posición final del segundo nombre. (15)

  13. Cuente la longitud total de la cadena de texto en A2 y, después, reste el número de caracteres desde la izquierda hasta el tercer espacio hallado en el paso 5. El resultado es el número de caracteres que se extraerán desde la derecha del nombre completo. (17 - 15 = 2)

  14. Apellido

    El apellido comienza en el primer carácter de la izquierda (B) y termina en el sexto carácter (el primer espacio). Por tanto, la fórmula extrae seis caracteres desde la izquierda.

    Fórmula para separar primero un apellido y un sufijo, con coma

    Use la función HALLAR para buscar el valor de núm_caracteres:

    Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (6)

  15. Sufijo

    El sufijo empieza en el séptimo carácter de la izquierda (J) y termina en el noveno carácter de la izquierda (.). La fórmula extrae tres caracteres, empezando desde el séptimo carácter.

    Fórmula para separar primero un apellido y un sufijo, con coma

    Use la función HALLAR para buscar el valor de núm_inicial:

    Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (6)

  16. Sume 1 para obtener el carácter situado detrás del primer espacio (J). El resultado es la posición inicial del sufijo. (6 + 1 = 7)

    Use funciones HALLAR anidadas para buscar el valor de núm_caracteres:

    Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (6)

  17. Sume 1 para obtener la posición numérica del carácter situado detrás del primer espacio (J). El resultado es el número de carácter en el que desea iniciar la búsqueda del segundo espacio. (7)

  18. Busque la posición numérica del segundo espacio en A2, empezando desde el séptimo carácter hallado en el paso 4. (11)

  19. Reste 1 del número de carácter del segundo espacio hallado en el paso 4 para obtener el número de carácter de ",". El resultado es la posición final del sufijo. (11 - 1 = 10)

  20. Busque la posición numérica del primer espacio. (6)

  21. Después de encontrar el primer espacio, agregue 1 para buscar el carácter siguiente (J), que también se encontró en los pasos 3 y 4. (7)

  22. Tome el número de carácter de "", hallado en el paso 6, y reste el número de carácter de "J" hallado en los pasos 3 y 4. El resultado es el número de caracteres que la función EXTRAE extrae de la cadena de texto empezando en la séptima posición hallada en el paso 2. (10 - 7 = 3)

En este ejemplo, el nombre está al principio de la cadena y el sufijo está al final, por lo que puede usar fórmulas similares al ejemplo 2: Use la función IZQUIERDA para extraer el nombre, la función EXTRAE para extraer el apellido y la función DERECHA para extraer el sufijo.

Copie las celdas de la tabla y péguelas en una hoja de cálculo de Excel en la celda A1. La fórmula que ve a la izquierda se mostrará como referencia, mientras que Excel convertirá automáticamente la fórmula a la derecha en el resultado adecuado.

Sugerencia    Antes de pegar los datos en la hoja de cálculo, establezca los anchos de columna de las columnas A y B en 250.

Nombre de ejemplo

Descripción

Gary Altman III

Nombre y apellido con sufijo

Fórmula

Resultado (nombre)

'=IZQUIERDA(A2, HALLAR(" ",A2,1))

=IZQUIERDA(A2, HALLAR(" ",A2,1))

Fórmula

Resultado (apellido)

'=EXTRAE(A2,HALLAR(" ",A2,1)+1,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)-(HALLAR(" ",A2,1)+1))

=EXTRAE(A2,HALLAR(" ",A2,1)+1,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)-(HALLAR(" ",A2,1)+1))

Fórmula

Resultado (sufijo)

'=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,HALLAR(" ",A2,1)+1))

=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,HALLAR(" ",A2,1)+1))

  1. Nombre

    El nombre comienza en el primer carácter de la izquierda (G) y termina en el quinto carácter (el primer espacio). Por tanto, la fórmula extrae cinco caracteres desde la izquierda del nombre completo.

    Fórmula para separar un nombre y un apellido seguidos de un sufijo

    Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (5)

  2. Apellido

    El apellido comienza en el sexto carácter de la izquierda (A) y termina en el undécimo carácter (el segundo espacio). Esta fórmula incluye funciones HALLAR anidadas para buscar las posiciones de los espacios.

    La fórmula extrae seis caracteres del medio, empezando desde el sexto carácter.

    Fórmula para separar un nombre y un apellido seguidos de un sufijo

    Use la función HALLAR para buscar el valor de núm_inicial:

    Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (5)

  3. Sume 1 para obtener la posición del carácter situado detrás del primer espacio (A). El resultado es la posición inicial del apellido. (5 + 1 = 6)

    Use funciones HALLAR anidadas para buscar el valor de núm_caracteres:

    Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (5)

  4. Sume 1 para obtener la posición del carácter situado detrás del primer espacio (A). El resultado es el número de carácter en el que desea iniciar la búsqueda del segundo espacio. (5 + 1 = 6)

  5. Busque la posición numérica del segundo espacio en A2, empezando desde el sexto carácter hallado en el paso 4. Este número de carácter es la posición final del apellido. (12)

  6. Busque la posición numérica del primer espacio. (5)

  7. Sumar 1 para buscar la posición numérica del carácter situado detrás del primer espacio (A), que también se encontró en los pasos 3 y 4. (6)

  8. Tome el número de carácter del segundo espacio hallado en el paso 5 y, después, reste el número de carácter de "A" hallado en los pasos 6 y 7. El resultado es el número de caracteres que la función EXTRAE extrae de la cadena de texto, empezando en la sexta posición hallada en el paso 2. (12 - 6 = 6)

  9. Sufijo

    El sufijo comienza en el tercer carácter de la derecha. Esta fórmula incluye funciones HALLAR anidadas para buscar las posiciones de los espacios.

    Fórmula para separar un nombre y un apellido seguidos de un sufijo

    Use las funciones HALLAR y LARGO anidadas para buscar el valor de núm_caracteres:

    Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (5)

  10. Sume 1 para obtener el carácter situado detrás del primer espacio (A). El resultado es el número de carácter en el que desea iniciar la búsqueda del segundo espacio. (5 + 1 = 6)

  11. Busque el segundo espacio en A2, empezando desde la sexta posición (A), hallada en el paso 2. (12)

  12. Cuente la longitud total de la cadena de texto en A2 y, después, reste el número de caracteres desde la izquierda hasta el segundo espacio hallado en el paso 3. El resultado es el número de caracteres que se extraerán desde la derecha del nombre completo. (15 - 12 = 3)

En este ejemplo, el nombre completo va precedido por un prefijo y se usan fórmulas similares al ejemplo 2: la función EXTRAE para extraer el nombre, la función DERECHA para extraer el apellido.

Copie las celdas de la tabla y péguelas en una hoja de cálculo de Excel en la celda A1. La fórmula que ve a la izquierda se mostrará como referencia, mientras que Excel convertirá automáticamente la fórmula a la derecha en el resultado adecuado.

Sugerencia    Antes de pegar los datos en la hoja de cálculo, establezca los anchos de columna de las columnas A y B en 250.

Nombre de ejemplo

Descripción

Sr. Tomás Navarro

Con prefijo

Fórmula

Resultado (nombre)

'=EXTRAE(A2,HALLAR(" ",A2,1)+1,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)-(HALLAR(" ",A2,1)+1))

=EXTRAE(A2,HALLAR(" ",A2,1)+1,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)-(HALLAR(" ",A2,1)+1))

Fórmula

Resultado (apellido)

'=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,HALLAR(" ",A2,1)+1))

=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,HALLAR(" ",A2,1)+1))

  1. Nombre

    El nombre empieza en el quinto carácter desde la izquierda (T) y termina en el décimo carácter (el segundo espacio). La fórmula anida HALLAR para buscar las posiciones de los espacios. Extrae cuatro caracteres, empezando desde la quinta posición.

    Fórmula para separar un nombre precedido por un prefijo

    Use la función HALLAR para buscar el valor de núm_inicial:

    Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (4)

  2. Sume 1 para obtener la posición del carácter situado detrás del primer espacio (R). El resultado es la posición inicial del nombre. (4 + 1 = 5)

    Use funciones HALLAR anidadas para buscar el valor de núm_caracteres:

    Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (4)

  3. Sume 1 para obtener la posición del carácter situado detrás del primer espacio (R). El resultado es el número de carácter en el que desea iniciar la búsqueda del segundo espacio. (4 + 1 = 5)

  4. Busque la posición numérica del segundo espacio en A2, empezando desde el quinto carácter hallado en los pasos 3 y 4. Este número de carácter es la posición final del nombre. (9)

  5. Busca el primer espacio. (4)

  6. Sumar 1 para buscar la posición numérica del carácter situado detrás del primer espacio (R), que también se encontró en los pasos 3 y 4. (5)

  7. Tome el número de carácter del segundo espacio hallado en el paso 5 y, después, reste el número de carácter de "R" hallado en los pasos 6 y 7. El resultado es el número de caracteres que la función EXTRAE extrae de la cadena de texto, empezando en la quinta posición hallada en el paso 2. (9 - 5 = 4)

  8. Apellido

    El apellido comienza en el séptimo carácter de la derecha. Esta fórmula incluye funciones HALLAR anidadas para buscar las posiciones de los espacios.

    Fórmula para separar un nombre precedido por un prefijo

    Use las funciones HALLAR y LARGO anidadas para buscar el valor de núm_caracteres:

    Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (4)

  9. Sume 1 para obtener la posición del carácter situado detrás del primer espacio (R). El resultado es el número de carácter en el que desea iniciar la búsqueda del segundo espacio. (4 + 1 = 5)

  10. Busque el segundo espacio en A2, empezando desde la quinta posición (R), hallada en el paso 2. (9)

  11. Cuente la longitud total de la cadena de texto en A2 y, después, reste el número de caracteres desde la izquierda hasta el segundo espacio hallado en el paso 3. El resultado es el número de caracteres que se extraerán desde la derecha del nombre completo. (14 - 9 = 5)

En este ejemplo se usa un apellido con guiones. Los componentes del nombre completo se separan con espacios.

Copie las celdas de la tabla y péguelas en una hoja de cálculo de Excel en la celda A1. La fórmula que ve a la izquierda se mostrará como referencia, mientras que Excel convertirá automáticamente la fórmula a la derecha en el resultado adecuado.

Sugerencia    Antes de pegar los datos en la hoja de cálculo, establezca los anchos de columna de las columnas A y B en 250.

Nombre de ejemplo

Descripción

Francisco Pérez-Olaeta

Apellido con un guión

Fórmula

Resultado (nombre)

'=IZQUIERDA(A2, HALLAR(" ",A2,1))

=IZQUIERDA(A2, HALLAR(" ",A2,1))

Fórmula

Resultado (apellido)

'=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,1))

=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,1))

  1. Nombre

    El nombre comienza en el primer carácter de la izquierda (F) y termina en la décima posición (el primer espacio). La fórmula extrae diez caracteres desde la izquierda.

    Fórmula para separar un nombre y un apellido con guiones

    Use la función HALLAR para buscar el valor de núm_caracteres:

    Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (6)

  2. Apellido

    El apellido completo comienza en el decimosegundo carácter desde la derecha (P) y termina en el primer carácter de la derecha (a).

    Fórmula para separar un nombre y un apellido con guiones

    Use las funciones LARGO y HALLAR para buscar el valor de núm_caracteres:

    Busque la posición numérica del espacio en A2, empezando desde el primer carácter de la izquierda. (6)

  3. Cuente la longitud total de la cadena de texto que se va a extraer y, después, reste el número de caracteres desde la izquierda hasta el primer espacio hallado en el paso 1. (16 - 6 = 10)

Dividir texto en diferentes columnas con el Asistente para convertir texto en columnas

¿Necesita más ayuda?

¿Quiere más opciones?

Explore las ventajas de las suscripciones, examine los cursos de aprendizaje, aprenda a proteger su dispositivo y mucho más.

Las comunidades le ayudan a formular y responder preguntas, enviar comentarios y leer a expertos con conocimientos extensos.

¿Le ha sido útil esta información?

¿Cuál es tu grado de satisfacción con la calidad del lenguaje?
¿Qué ha afectado a su experiencia?
Si presiona Enviar, sus comentarios se usarán para mejorar los productos y servicios de Microsoft. El administrador de TI podrá recopilar estos datos. Declaración de privacidad.

¡Gracias por sus comentarios!

×