Información general sobre fórmulas en Excel

Información general sobre fórmulas en Excel

Si no ha usado Excel antes, pronto descubrirá que no es solo una cuadrícula en la que introducir números en columnas y filas. Por supuesto, puede usar Excel para calcular los totales de una columna o una fila de números, pero también puede calcular el pago de una hipoteca, resolver problemas matemáticos o de ingeniería, o dar con la hipótesis más optimista en función de las variables que introduzca.

Excel realiza estas operaciones usando fórmulas en las celdas. Una fórmula realiza cálculos u otras acciones con los datos de su hoja de cálculo. Una fórmula siempre empieza con un signo igual (=), que puede ir seguido de números, operadores matemáticos (como los signos + o - para sumar o restar) y funciones integradas de Excel, que pueden ampliar el poder de una fórmula.

Por ejemplo, la siguiente fórmula multiplica 2 por 3 y, después, suma 5 al resultado para dar con la respuesta, 11.

=2*3+5

A continuación, se ofrece una muestra de los tipos de fórmulas que se pueden escribir en una hoja de cálculo.

  • =A1+A2+A3    Suma los valores de las celdas A1, A2 y A3.

  • =SUM(A1:A10)   . Usa la función SUMA para devolver la suma de los valores de A1 a A10.

  • =HOY()   . Devuelve la fecha actual.

  • =MAYUSC("hola")    Convierte el texto "hola" en "HOLA" mediante la función MAYUSC.

  • =SI(A1>0)   . Usa la función SI para probar la celda A1 y determinar si contiene un valor mayor que 0.

Una fórmula también puede contener algunos o todos los elementos siguientes: funciones, referencias, operadores y constantes.

Partes de una fórmula   

Partes de una fórmula

1. Funciones: la función PI() devuelve el valor de Pi: 3,142...

2. Referencias: A2 devuelve el valor de la calda A2.

3. Constantes: números o valores de texto escritos directamente en una fórmula como, por ejemplo, 2.

4. Operadores: el operador ^ (acento circunflejo) eleva un número a una potencia y el operador * (asterisco) multiplica números.

Una constante es un valor que no se calcula, sino que siempre permanece igual. Por ejemplo, la fecha 9-10-2008, el número 210 y el texto "Ganancias trimestrales" son constantes. Una expresión o un valor obtenido como resultado de una expresión, no son constantes. Si usa constantes en la fórmula en vez de referencias a celdas (por ejemplo, =30+70+110), el resultado solo cambia si modifica la fórmula. En general, es mejor insertar constantes en celdas individuales donde se puedan cambiar fácilmente si fuera necesario y luego hacer referencia a esas celdas en las fórmulas.

Los operadores especifican el tipo de cálculo que se quiere ejecutar en los elementos de una fórmula. Excel sigue las reglas matemáticas generales para los cálculos, que son Paréntesis, Exponentes, Multiplicación y división y Suma y resta, o el acrónimo PEMDAS (en inglés: Discúlpeme, mi querida tía Sally). El uso de paréntesis permite modificar el orden del cálculo.

Tipos de operadores. Existen cuatro tipos de operadores de cálculo: aritmético, comparación, concatenación de texto y referencia.

  • Operadores aritméticos

    Para ejecutar las operaciones matemáticas básicas como suma, resta, multiplicación o división, combinar números y generar resultados numéricos, use los siguientes operadores aritméticos.

    Operador aritmético

    Significado

    Ejemplo

    + (signo más)

    Suma

    =3+3

    – (signo menos)

    Resta
    Negación

    =3–3
    =-3

    * (asterisco)

    Multiplicación

    =3*3

    / (barra oblicua)

    División

    =3/3

    % (signo de porcentaje)

    Porcentaje

    30 %

    ^ (acento circunflejo)

    Exponenciación

    =3^3

  • Operadores de comparación

    Se pueden comparar dos valores con los siguientes operadores. Cuando se comparan dos valores con estos operadores, el resultado es un valor lógico: VERDADERO o FALSO.

    Operador de comparación

    Significado

    Ejemplo

    = (signo igual)

    Igual a

    =A1=B1

    > (signo mayor que)

    Mayor que

    =A1>B1

    < (signo menor que)

    Menor que

    =A1<B1

    >= (signo mayor o igual que)

    Mayor o igual que

    =A1>=B1

    <= (signo menor o igual que)

    Menor o igual que

    =A1<=B1

    <> (signo distinto de)

    Distinto de

    =A1<>B1

  • Operador de concatenación de texto

    Use la y comercial (&) para concatenar (unir) una o varias cadenas de texto con el fin de generar un solo elemento de texto.

    Operador de texto

    Significado

    Ejemplo

    & ("y" comercial)

    Conecta o concatena dos valores para generar un valor de texto continuo

    ="Nord"&"este" se traduce en "Nordeste".
    Cuando A1 contiene "Apellido" y B1 contiene "Nombre", =A1&", "&B1 se traduce en "Apellido, Nombre".

  • Operadores de referencia

    Combine rangos de celdas para los cálculos con los siguientes operadores.

    Operador de referencia

    Significado

    Ejemplo

    : (dos puntos)

    Operador de rango, que genera una referencia a todas las celdas entre dos referencias, estas incluidas

    B5:B15

    , (coma)

    Operador de unión, que combina varias referencias en una sola

    =SUMA(B5:B15,D5:D15)

    (espacio)

    Operador de intersección, que genera una referencia a las celdas comunes a dos referencias

    B7:D7 C6:C8

Volver al principio

En algunos casos, el orden en el que se ejecuta el cálculo puede afectar al valor devuelto de la fórmula. Por tanto, es importante comprender cómo se determina el orden y cómo puede cambiar el orden para obtener los resultados deseados.

  • Orden de cálculo

    Las fórmulas calculan los valores en un orden específico. Las fórmulas de Excel siempre comienzan por un signo igual (=). Excel interpreta los caracteres detrás del signo igual como una fórmula. Tras el signo igual están los elementos que se van a calcular (los operandos); por ejemplo, constantes o referencias a celdas. Estos se encuentran separados por operadores de cálculo. Excel calcula la fórmula de izquierda a derecha, según el orden específico de cada operador de la fórmula.

  • Prioridad de operadores en las fórmulas de Excel

    Si se combinan varios operadores en una única fórmula, Excel ejecutará las operaciones en el orden que se indica en la siguiente tabla. Si una fórmula contiene operadores con la misma prioridad (por ejemplo, si una fórmula contiene un operador de multiplicación y otro de división), Excel evaluará los operadores de izquierda a derecha.

    Operador

    Descripción

    : (dos puntos)

    (un solo espacio)

    , (coma)

    Operadores de referencia

    Negación (como en –1)

    %

    Porcentaje

    ^

    Exponenciación

    * y /

    Multiplicación y división

    + y -

    Suma y resta

    &

    Conecta dos cadenas de texto (concatenación)

    =
    < >
    <=
    >=
    <>

    Comparación

  • Uso de paréntesis en las fórmulas de Excel

    Para cambiar el orden de evaluación, escriba entre paréntesis la parte de la fórmula que se calculará en primer lugar. Por ejemplo, la siguiente fórmula da un resultado de 11 porque Excel efectúa la multiplicación antes que la suma. La fórmula multiplica 2 por 3 y después suma 5 al resultado.

    =5+2*3

    Por el contrario, si se usan paréntesis para cambiar la sintaxis, Excel sumará 5 y 2 y después multiplicará el resultado por 3, con lo que se obtiene 21.

    =(5+2)*3

    En el siguiente ejemplo, los paréntesis que rodean la primera parte de la fórmula indican a Excel que calcule B4+25 primero y después divida el resultado por la suma de los valores de las celdas D5, E5 y F5.

    =(B4+25)/SUMA(D5:F5)

    Volver al principio

Las funciones son fórmulas predefinidas que ejecutan cálculos con valores específicos, denominados argumentos, en un determinado orden o estructura. Las funciones pueden usarse para ejecutar cálculos simples o complejos. Encontrará todas las funciones de Excel en la pestaña Fórmulas de la cinta:

La pestaña Fórmulas de Excel en la cinta
  • Sintaxis de función de Excel

    El siguiente ejemplo de la función REDONDEAR, que redondea un número de la celda A10, ilustra la sintaxis de una función.

    Estructura de una función

    1. Estructura. La estructura de una función comienza por el signo igual (=), seguido por el nombre de la función, un paréntesis de apertura, los argumentos de la función separados por punto y coma y un paréntesis de cierre.

    2. Nombre de función. Para obtener una lista de las funciones disponibles, haga clic en una celda y presione MAYÚ+F3, lo que abrirá el cuadro de diálogo Insertar función.

    Fórmulas de Excel - cuadro de diálogo Insertar función

    3. Argumentos. Los argumentos pueden ser números, texto, valores lógicos como VERDADERO o FALSO, matrices, valores de error como #N/A o referencias de celda. El argumento que se designe deberá generar un valor válido para el mismo. Los argumentos también pueden ser constantes, fórmulas u otras funciones.

    4. Información sobre herramientas de argumentos. Cuando se escribe la función, aparece la información sobre herramientas con su sintaxis y sus argumentos. Por ejemplo, escriba =REDONDEAR( y aparecerá la información sobre herramientas. Esta información solo aparece para las funciones integradas.

    Nota: No hay que escribir las funciones en mayúsculas, como =REDONDEAR, ya que Excel pondrá automáticamente en mayúsculas el nombre de la función después de presionar Entrar. Si se equivoca al escribir un nombre de función, como =SUME(A1:A10) en lugar de =SUMA(A1:A10), ¿devolverá Excel un error #¿NOMBRE?.

  • Escribir funciones de Excel

    Cuando cree una fórmula que contenga una función, puede usar el cuadro de diálogo Insertar función como ayuda para especificar las funciones de la hoja de cálculo. Al seleccionar una función en el cuadro de diálogo Insertar función, Excel iniciará un asistente para funciones, que muestra el nombre de la función, cada uno de sus argumentos, una descripción de la función y de cada argumento, el resultado actual de la función y el resultado actual de toda la fórmula.

    Asistente de funciones de Excel

    Para facilitar la creación y edición de fórmulas, y minimizar los errores de escritura y sintaxis, use Autocompletar fórmula. Después de escribir un = (signo igual) y las letras iniciales de una función, Excel muestra una lista desplegable dinámica de funciones, argumentos y nombres válidos que coinciden con las letras. Puede seleccionar un elemento de la lista desplegable y Excel lo insertará automáticamente.

    Fórmula de Excel Autocompletar

  • Anidar funciones de Excel

    En algunos casos, puede que deba usar una función como uno de los argumentos de otra función. Por ejemplo, la siguiente fórmula usa una función anidada PROMEDIO y compara el resultado con el valor 50.

    Funciones anidadas

    1. La función PROMEDIO y la función SUMA están anidadas dentro de la función SI.

    Resultados válidos    Cuando se usa una función anidada como argumento, deberá devolver el mismo tipo de valor que el que use el argumento. Por ejemplo, si el argumento devuelve un valor VERDADERO o FALSO, la función anidada deberá devolver VERDADERO o FALSO. Si este no es el caso, Excel mostrará el valor de error #¡VALOR!.

    Límites del nivel de anidamiento    Una fórmula puede contener hasta siete niveles de funciones anidadas. Si una función (a la que llamaremos Función B) se usa como argumento de otra función (a la que llamaremos Función A), la Función B actúa como función de segundo nivel. Por ejemplo, la función PROMEDIO y la función SUMA son ambas funciones de segundo nivel si se usan como argumentos de la función SI. Una función anidada dentro de la función anidada PROMEDIO será entonces una función de tercer nivel, y así sucesivamente.

    Volver al principio

Una referencia identifica una celda o un rango de celdas en una hoja de cálculo e indica a Excel dónde debe buscar los valores o los datos que desea usar en una fórmula. Las referencias permiten usar datos de distintas partes de una hoja de cálculo en una fórmula, o bien usar el valor de una celda en varias fórmulas. También puede hacerse referencia a las celdas de otras hojas en el mismo libro y de otros libros. Las referencias a celdas de otros libros se denominan vínculos o referencias externas.

  • Estilo de referencia A1

    De forma predeterminada, Excel usa el estilo de referencia A1, que se refiere a las columnas con letras (de A a XFD, para un total de 16 384 columnas) y a las filas con números (del 1 al 1 048 576). Estas letras y números se denominan encabezados de fila y de columna. Para hacer referencia a una celda, escriba la letra de la columna seguida del número de fila. Por ejemplo, B2 hace referencia a la celda en la intersección de la columna B y la fila 2.

    Para hacer referencia a

    Usar

    La celda de la columna A y la fila 10

    A10

    El rango de celdas de la columna A y de las filas 10 a 20

    A10:A20

    El rango de celdas de la fila 15 y de las columnas B a E

    B15:E15

    Todas las celdas de la fila 5

    5:5

    Todas las celdas de las filas 5 a 10

    5:10

    Todas las celdas de la columna H

    H:H

    Todas las celdas desde la columna H hasta la J

    H:J

    El rango de celdas de las columnas A a E y de las filas 10 a 20

    A10:E20

  • Hacer referencia a una celda o un rango de celdas de otra hoja de cálculo del mismo libro

    En el siguiente ejemplo, la función PROMEDIO calcula el valor promedio del rango B1:B10 de la hoja de cálculo denominada Marketing del mismo libro.

    Ejemplo de referencia de hoja

    1. Se refiere a la hoja de cálculo Marketing

    2. se refiere al rango de celdas de B1 a B10

    3. El signo de exclamación separa la referencia de hoja de cálculo de la referencia del rango de celdas

    Nota: Si la hoja de cálculo a la que se hace referencia incluye espacios o números, hay que agregar apóstrofos (') antes y después del nombre de la hoja de cálculo, como, por ejemplo, ='123'!A1 o ='Ingresos enero'!A1.

  • Diferencia entre referencias absolutas, relativas y mixtas

    1. Referencias relativas    Una referencia relativa en una fórmula, como A1, se basa en la posición relativa de la celda que contiene la fórmula y de la celda a la que hace referencia. Si cambia la posición de la celda que contiene la fórmula, cambia la referencia. Si se copia o se rellena la fórmula en filas o columnas, la referencia se ajusta automáticamente. De forma predeterminada, las nuevas fórmulas usan referencias relativas. Por ejemplo, si copia o rellena una referencia relativa de la celda B2 en la celda B3, se ajusta automáticamente de =A1 a =A2.

      Fórmula copiada con referencia relativa   

      Fórmula copiada con referencia relativa

    2. Referencias absolutas    Una referencia de celda absoluta en una fórmula, como $A$1, siempre hace referencia a una celda en una ubicación específica. Si cambia la posición de la celda que contiene la fórmula, la referencia absoluta permanece invariable. Si se copia la fórmula en filas o columnas, la referencia absoluta no se ajusta. De forma predeterminada, las nuevas fórmulas usan referencias relativas, de modo que puede resultar necesario cambiarlas a referencias absolutas. Por ejemplo, si copia una referencia absoluta de la celda B2 en la celda B3, permanece invariable en ambas celdas: =$A$1.

      Fórmula copiada con referencia absoluta   

      Fórmula copiada con referencia absoluta
    3. Referencias mixtas    Una referencia mixta tiene una columna absoluta y una fila relativa, o una fila absoluta y una columna relativa. Una referencia de columna absoluta adopta la forma $A1, $B1, etc. Una referencia de fila absoluta adopta la forma A$1, B$1, etc. Si cambia la posición de la celda que contiene la fórmula, se cambia la referencia relativa y la referencia absoluta permanece invariable. Si se copia o rellena la fórmula en filas o columnas, la referencia relativa se ajusta automáticamente y la referencia absoluta no se ajusta. Por ejemplo, si se copia o rellena una referencia mixta de la celda A2 en B3, se ajusta de =A$1 a =B$1.

      Fórmula copiada con referencia mixta   

      Fórmula copiada con referencia mixta

  • Estilo de referencia 3D

    Hacer referencia de manera conveniente a varias hojas de cálculo    Si desea analizar los datos de la misma celda o del mismo rango de celdas en varias hojas de cálculo dentro del libro, use una referencia 3D. Una referencia 3D incluye la referencia de celda o de rango, precedida de un rango de nombres de hoja de cálculo. Excel usará las hojas de cálculo almacenadas entre los nombres inicial y final de la referencia. Por ejemplo, =SUMA(Hoja2:Hoja13!B5) agrega todos los valores contenidos en la celda B5 en todas las hojas de cálculo comprendidas entre la Hoja 2 y la Hoja 13, ambas incluidas.

    • Pueden usarse referencias 3D a las celdas de otras hojas para definir nombres y crear fórmulas mediante las siguientes funciones: SUMA, PROMEDIO, PROMEDIOA, CONTAR, CONTARA, MAX, MAXA, MIN, MINA, PRODUCTO, DESVEST.P, DESVEST.M, DESVESTA, DESVESTPA, VAR.P, VAR.S, VARA y VARPA.

    • No pueden usarse referencias 3D en fórmulas de matriz.

    • No pueden usarse referencias 3D con el operador de intersección (un solo espacio) o en fórmulas que usen una intersección implícita.

    Qué ocurre cuando se mueven, copian, insertan o eliminan hojas de cálculo    Los siguientes ejemplos explican lo que ocurre cuando mueve, copia, inserta o elimina hojas de cálculo incluidas en una referencia 3D. En los ejemplos se usa la fórmula =SUMA(Hoja2:Hoja6!A2:A5) para sumar las celdas A2 a A5 desde la hoja 2 hasta la hoja 6.

    • Insertar o copiar    Si se insertan o se copian hojas entre la Hoja2 y la Hoja6 del libro (las extremas en este ejemplo), Excel incluirá en los cálculos todos los valores en las celdas de la A2 a la A5 de las hojas que se hayan agregado.

    • Eliminar    Si se eliminan hojas entre la Hoja2 y la Hoja6, Excel eliminará de los cálculos los valores de las mismas.

    • Mover    Si se mueven hojas situadas entre la Hoja2 y la Hoja6 a una ubicación situada fuera del rango de hojas al que se hace referencia, Excel eliminará de los cálculos los valores de dichas hojas.

    • Mover un punto final    Si se mueve la Hoja2 o la Hoja6 a otra ubicación en el mismo libro, Excel ajustará los cálculos para que integren el nuevo rango de hojas que exista entre ellas.

    • Eliminar un punto final    Si se elimina la Hoja2 o la Hoja6, Excel ajustará los cálculos para que integren el nuevo rango de hojas que exista entre ellas.

  • Estilo de referencia F1C1

    También puede usarse un estilo de referencia en el que se numeren tanto las filas como las columnas de la hoja de cálculo. El estilo de referencia F1C1 es útil para calcular las posiciones de fila y columna en macros. En el estilo F1C1, Excel indica la ubicación de una celda con una "F" seguida de un número de fila y una "C" seguida de un número de columna.

    Referencia

    Significado

    F[-2]C

    referencia relativa a la celda situada dos filas por encima, en la misma columna.

    F[2]C[2]

    Referencia relativa a la celda situada dos filas hacia abajo y dos columnas hacia la derecha.

    F2C2

    Referencia absoluta a la celda de la segunda fila y la segunda columna.

    F[-1]

    Referencia relativa a toda la fila situada sobre la celda activa

    F

    Referencia absoluta a la fila actual

    Al grabar una macro, Excel registra algunos comandos usando el estilo de referencia F1C1. Por ejemplo, si se registra un comando como hacer clic en el botón Autosuma para insertar una fórmula que suma un rango de celdas, Excel registra la fórmula usando referencias del estilo F1C1 y no del estilo A1.

    Puede activar o desactivar el estilo de referencia F1C1 si activa o desactiva la casilla Estilo de referencia F1C1 en la sección Trabajo con fórmulas, que se encuentra en la categoría Fórmulas del cuadro de diálogo Opciones. Para abrir este cuadro de diálogo, haga clic en la pestaña Archivo.

    Volver al principio

Puede crear nombres definidos para representar celdas, rangos de celdas, fórmulas, valores constantes o tablas de Excel. Un nombre es una forma abreviada de referirse a una referencia de celda, una constante, una fórmula o una tabla cuyo propósito, a primera vista, podría resultar difícil de comprender. A continuación se muestran algunos ejemplos de nombres y el modo en que pueden mejorar la claridad y facilitar la comprensión de las fórmulas.

Ejemplo 1

Tipo de ejemplo

Ejemplo, usando intervalos en lugar de nombres

Ejemplo, usando nombres

Referencia

=SUMA(A16:A20)

=SUMA(Ventas)

Constante

=PRODUCTO(A12,9,5%)

=PRODUCTO(Precio,Tasa-impuestos)

Fórmula

=TEXTO(BUSCARV(MAX(A16,A20),A16:B20,2,FALSO),"m/dd/aaaa")

=TEXTO(BUSCARV(MAX(Ventas),InfoVentas,2,FALSO),"m/dd/aaaa")

Tabla

A22:B25

=PRODUCTO(Precio,Tabla1[@Tipo de interés])

Ejemplo 2

Copie los datos del ejemplo en la siguiente tabla y péguelos en la celda A1 de una nueva hoja de cálculo de Excel. Para las fórmulas que muestren resultados, selecciónelas, presione F2 y, a continuación, presione Entrar. Si lo necesita, puede ajustar los anchos de la columna para ver todos los datos.

Nota:  En las fórmulas de las columnas C y D, el nombre definido "Ventas" se sustituye por la referencia al rango A9:A13 y el nombre "InfoVentas" se sustituye por el rango A9: B13. Si no crea estos nombres en el libro de prueba, ¿devolverán las fórmulas de D2:D3 el error #¿NOMBRE?.

Tipo de ejemplo

Ejemplo, sin usar un nombre

Ejemplo, usando un nombre

Fórmula y resultado, usando un nombre

Referencia

'=SUMA(A9:A13)

'=SUMA(Ventas)

=SUMA(Ventas)

Fórmula

'=TEXTO(BUSCARV(MAX(A9:13),A9:B13,2,FALSO),"m/dd/yyyy")

'=TEXTO(BUSCARV(MAX(Ventas),InfoVentas,2,FALSO),"m/dd/yyyy")

=TEXTO(BUSCARV(MAX(Ventas),InfoVentas,2,FALSO),"m/dd/aaaa")

Precio

995 €

Ventas

Fecha de venta

249 €

17/3/2011

399 €

2/4/2011

643 €

23/4/2011

275 €

30/4/2011

447 €

4/5/2011

  • Tipos de nombres

    Existen varios tipos de nombres que se pueden crear y usar.

    • Nombre definido    Es un nombre que representa una celda, un rango de celdas, una fórmula o un valor constante. Puede crear sus propios nombres definidos, aunque Excel en ocasiones los crea por usted, como por ejemplo, cuando se establece un área de impresión.

    • Nombre de tabla    Es un nombre para una tabla de Excel, que es un conjunto de datos relacionados que se guardan en registros (filas) y campos (columnas). Excel crea nombres de tabla predeterminados, como "Tabla1", "Tabla2", etc., cada vez que se inserta una tabla de Excel, pero usted puede cambiar estos nombres por otros más significativos.

      Para más información sobre las tablas de Excel, vea el tema sobre cómo usar referencias estructuradas con tablas de Excel.

  • Crear y especificar nombres

    Puede crear un nombre con cualquiera de estos métodos:

    • Cuadro Nombre de la barra de fórmulas    Es la forma más adecuada de crear un nombre en el nivel de libro para un rango seleccionado.

    • Crear un nombre a partir de una selección    Puede crear nombres cómodamente partiendo de los rótulos de fila y de columna existentes usando una selección de celdas de la hoja de cálculo.

    • El cuadro de diálogo Nombre nuevo    Es lo mejor que se puede usar cuando se desea más flexibilidad a la hora de crear nombres, por ejemplo para especificar un ámbito de nivel de hoja de cálculo local o para crear un comentario del nombre.

    Nota: De forma predeterminada, en los nombres se usan referencias absolutas de celda.

    Puede especificar un nombre con cualquiera de estos métodos:

    • Escribiendo    Escribiendo el nombre; por ejemplo, como argumento de una fórmula.

    • Usar Fórmula Autocompletar    Use la lista desplegable Fórmula Autocompletar, en la que se muestran automáticamente los nombres válidos.

    • Realizando una selección en el comando Utilizar en la fórmula    Seleccione un nombre definido de la lista que muestra el comando Utilizar en la fórmula del grupo Nombres definidos de la pestaña Fórmulas.

Para más información, vea Definir y usar nombres en fórmulas.

Volver al principio

Una fórmula de matriz puede ejecutar varias operaciones y devolver un único resultado o varios resultados. Las fórmulas de matriz actúan en dos o más conjuntos de valores denominados argumentos matriciales. Cada argumento matricial debe tener el mismo número de filas y de columnas. Estas fórmulas se crean del mismo modo que las demás fórmulas, excepto que se debe presionar la combinación de teclas Ctrl+Mayús+Entrar. Algunas de las funciones integradas son fórmulas de matriz y se deben escribir como matrices para obtener los resultados correctos.

Las constantes matriciales se pueden usar en lugar de las referencias cuando no se desea especificar el valor de cada constante en una celda independiente de la hoja de cálculo.

Usar una fórmula de matriz para calcular resultados únicos y múltiples

Nota: Cuando se escribe un fórmula de matriz, Excel inserta automáticamente la fórmula entre {} (llaves). Si intenta escribir las llaves de forma manual, Excel mostrará la fórmula como texto.

  • Fórmula de matriz que genera un único resultado    Este tipo de fórmula de matriz permite simplificar un modelo de hoja de cálculo reemplazando varias fórmulas distintas por una sola fórmula de matriz.

    Por ejemplo, la siguiente calcula el valor total de una matriz de cotizaciones y números de acciones sin usar una fila de celdas para calcular y mostrar los valores individuales de cada acción.

    Fórmula de matriz que genera un único resultado

    Cuando se escribe la fórmula ={SUMA(B2:D2*B3:D3)} como fórmula de matriz, multiplica el número de acciones y el precio correspondiente a cada acción, y luego suma los resultados de dichos cálculos.

  • Fórmula de matriz que genera varios resultados    Algunas funciones de la hoja de cálculo devuelven matrices de valores o requieren una matriz de valores como argumento. Para calcular varios resultados con una fórmula de matriz, se deberá especificar la matriz en un rango de celdas que tenga el mismo número de filas y columnas que los argumentos de la matriz.

    Por ejemplo, dada una serie de tres cifras de ventas (en la columna B) para una serie de tres meses (en la columna A), la función TENDENCIA determinará los valores de la línea recta para las cifras de ventas. Para mostrar todos los resultados de la fórmula, se escribe en tres celdas en la columna C (C1:C3).

    Fórmula de matriz que genera varios resultados

    Al especificar la fórmula =TENDENCIA(B1:B3;A1:A3) como fórmula de matriz, generará tres resultados separados (22196, 17079 y 11962) basados en las tres cifras de ventas y en los tres meses.

Usar constantes de matriz

En una fórmula normal se puede escribir una referencia a una celda que contenga un valor o el valor propiamente dicho, también denominado constante. Igualmente, en una fórmula de matriz se puede escribir una referencia a una matriz o la propia matriz de valores contenidos en las celdas, lo que también se denomina constante matricial. Las fórmulas de matriz aceptan constantes del mismo modo que las fórmulas que no son de matriz, pero las constantes matriciales se deben especificar con un formato determinado.

Las constantes matriciales pueden contener números, texto, valores lógicos como VERDADERO o FALSO o valores de error como #N/A. En la misma constante matricial puede haber distintos tipos de valores, por ejemplo, {1;3;4\VERDADERO;FALSO;VERDADERO}. Los números de las constantes matriciales pueden tener formato entero, decimal o científico. El texto debe incluirse entre comillas, por ejemplo, "martes".

Las constantes matriciales no pueden contener referencias a celdas, columnas ni filas de longitud desigual, fórmulas ni los caracteres especiales $ (símbolo de dólar), paréntesis o % (símbolo de porcentaje).

Cuando dé formato a constantes matriciales, asegúrese de:

  • Incluirlas entre llaves ( { } ).

  • Separar los valores situados en columnas diferentes mediante punto y coma (;). Por ejemplo, para representar los valores 10, 20, 30 y 40, escriba {10;20;30;40}. Esta constante matricial se denomina matriz de 1 por 4, y equivale a una referencia a 1 fila por 4 columnas.

  • Separar los valores situados en filas diferentes mediante barras inversas (\). Por ejemplo, para representar los valores 10, 20, 30 y 40 de una fila y los valores 50, 60, 70 y 80 de la inmediatamente inferior, se escribiría una constante matricial de 2 por 4: {10;20;30;40\50;60;70;80}.

Volver al principio

Al eliminar una fórmula, se eliminan también los valores resultantes de la fórmula. Aunque se puede eliminar solo la fórmula y dejar que el valor resultante de la fórmula aparezca en la celda.

  • Para eliminar fórmulas con los valores resultantes, haga lo siguiente:

    1. Seleccione la celda o el rango de celdas que contiene la fórmula.

    2. Pulse SUPRIMIR.

  • Para eliminar fórmulas sin quitar los valores resultantes, haga lo siguiente:

    1. Seleccione la celda o el rango de celdas que contiene la fórmula.

      Si la fórmula es una fórmula de matriz, seleccione el rango de celdas que la contiene.

      Cómo seleccionar un rango de celdas que contiene la fórmula de matriz

      1. Haga clic en una celda de la fórmula de matriz.

      2. En la pestaña Inicio, en el grupo Modificar, haga clic en Buscar y seleccionar y, a continuación, haga clic en Ir a.

      3. Haga clic en Especial.

      4. Haga clic en Matriz actual.

    2. En el grupo Portapapeles de la pestaña Inicio, haga clic en Copiar Imagen del botón .
      Imagen de la cinta de Excel

      Método abreviado de teclado    también puede presionar CTRL+C.

    3. En el grupo Portapapeles de la pestaña Inicio, haga clic en la flecha situada bajo Pegar Imagen del botón y, después, en Pegar valores.

Principio de página

En la tabla siguiente se resumen los errores más comunes que puede realizar un usuario al escribir una fórmula y se explica cómo evitarlos.

Asegúrese de...

Más información

Emparejar todos los paréntesis de apertura y de cierre de la fórmula   

En las fórmulas, todos los paréntesis forman parte de una pareja. Cuando se crea una fórmula, Excel muestra paréntesis en color a medida que se escriben.

Usar dos puntos para indicar un rango que escribe en la fórmula   

Los dos puntos (:) se usan para separar la referencia a la primera y la última celda del rango. Por ejemplo, A1:A5.

Escribir todos los argumentos necesarios   

Las funciones pueden tener argumentos necesarios y opcionales (que se indican mediante corchetes en la sintaxis). Todos los argumentos necesarios deben especificarse. Además, asegúrese de que no ha especificado demasiados argumentos.

No anidar más de 64 funciones en una fórmula   

El anidamiento de funciones dentro de una fórmula está limitado a 64 niveles.

Escribir los nombres de libro o de hoja entre comillas simples    

Al hacer referencia a valores o celdas de otras hojas de cálculo o libros que incluyen caracteres no alfabéticos en sus nombres, los nombres deben escribirse entre comillas simples (').

Incluir la ruta de acceso a libros externos   

Las referencias externas deben incluir el nombre del libro y su ruta de acceso.

Escribir los números sin formato   

No debe aplicar formato con separadores decimales o signos de dólar ($) a los números que especifique en una fórmula porque las comas ya se usan como separadores de argumentos en las fórmulas y los signos de dólar se usan para marcar referencias absolutas. Por ejemplo, en lugar de escribir 1000 $, escriba 1000 en la fórmula.

Principio de página

Importante: Los resultados calculados de las fórmulas y algunas funciones de hoja de cálculo de Excel pueden diferir entre un PC de Windows con arquitectura x86 o x86-64 y un PC de Windows RT con arquitectura ARM. Más información sobre las diferencias.

¿Tiene alguna pregunta sobre una función específica?

Publique una pregunta en el foro de la comunidad de Excel

Ayudarnos a mejorar Excel

¿Tiene alguna sugerencia acerca de cómo podemos mejorar la siguiente versión de Excel? Si es así, consulte los temas del sitio de UserVoice de Excel.

Vea también

Información general sobre fórmulas en Excel

Cómo evitar la ruptura de las fórmulas

Buscar y corregir errores en fórmulas

Métodos abreviados de teclado y teclas de función en Excel

Funciones de Excel (por orden alfabético)

Funciones de Excel (por categoría)

Ampliar sus conocimientos
Explorar los cursos
Obtener nuevas características primero
Únase a los participantes de Office Insider

¿Le ha sido útil esta información?

¡Gracias por sus comentarios!

Gracias por sus comentarios. Quizá le interese ponerse en contacto con uno de nuestros agentes de soporte de Office.

×