Función SI

La función SI es una de las funciones más populares de Excel y le permite realizar comparaciones lógicas entre un valor y un resultado que espera. En su forma más sencilla, la función SI dice:

  • SI(Algo es Verdadero, hacer algo; de lo contrario hacer algo diferente)

Por esto, una instrucción SI puede tener dos resultados. El primer resultado es si la comparación es Verdadera y el segundo si la comparación es Falsa.

Si quiere avanzar para trabajar con varias instrucciones SI, vea: Funciones SI avanzadas: Trabajar con fórmulas anidadas para evitar errores.

Use la función SI, una de las funciones lógicas, para devolver un valor si una condición es verdadera y otro si es falsa.

Sintaxis

SI(prueba_lógica; valor_si_verdadero; [valor_si_falso])

Por ejemplo:

  • =SI(A2>B2,"Presupuesto excedido";"Correcto")

  • =SI(A2=B2,B4-A4,"")

Nombre del argumento

Descripción

prueba_lógica    (requerido)

El valor que quiere probar.

valor_si_verdadero    (requerido)

El valor que desea devuelto si el resultado de prueba_lógica es VERDADERO.

valor_si_falso    (opcional)

El valor que desea devuelto si el resultado de prueba_lógica es FALSO.

Ejemplos sencillos de SI

La celda D2 contiene la fórmula =SI(C2="SÍ";1;2)
  • =SI(C2="Sí",1,2)

En el ejemplo anterior, la celda D2 dice: SI(C2 = Sí, entonces devolver un 1, en caso contrario devolver un 2)

La celda D2 contiene la fórmula =SI(C2=1,"SÍ","NO")
  • =SI(C2=1,"Sí","No")

En este ejemplo, la fórmula de la celda D2 dice: SI(C2 = 1, entonces devolver Sí, en caso contrario devolver No)

Como puede ver, la función SI se puede usar para evaluar texto y valores. También se puede usar para evaluar errores. No está limitado exclusivamente a comprobar si un elemento es igual a otro y devolver un único resultado, también puede usar operadores matemáticos y realizar cálculos adicionales según sus criterios. También se pueden anidar varias funciones SI para realizar varias comparaciones.

Nota: Si va a usar texto en fórmulas, tendrá que escribir el texto entre comillas (por ejemplo, “Texto”). La única excepción es el uso de VERDADERO o FALSO, que Excel entiende de forma automática.

Primeros pasos

La mejor forma de empezar a escribir una instrucción SI es pensar en lo que quiere conseguir. ¿Qué comparación está intentando realizar? En muchos casos, escribir una instrucción SI puede ser tan sencillo como analizar mentalmente la lógica: “qué ocurre si se cumple esta condición y que ocurre si no se cumple”. Asegúrese siempre de que los pasos siguen una progresión lógica, ya que, en caso contrario, la fórmula no hará lo que piensa que tendría que hacer. Esto es especialmente importante al crear instrucciones SI complejas (anidadas).

Más ejemplos de SI

La fórmula de la celda D2 es =SI(C2 > B2,"Presupuesto excedido","Dentro de presupuesto")
  • =SI(C2>B2,"Presupuesto excedido","Dentro de presupuesto")

En el ejemplo anterior, la función en D2 dice SI(C2 es mayor que B2, devolver "Presupuesto excedido"; de lo contrario, devolver "Dentro de presupuesto")

La fórmula de la celda E2 es =SI(C2>B2;C2-B2;"")
  • =SI(C2>B2;C2-B2;0)

En la ilustración anterior, en lugar de devolver un resultado de texto, vamos a devolver un cálculo matemático. La fórmula en E2 dice lo siguiente: SI(la cantidad real es mayor que la presupuestada, resta la cantidad presupuestada de la cantidad real; en caso contrario, no se devuelve nada).

La fórmula de la celda F7 es SI(E7="Sí";F5*0,0825,0)
  • =SI(E7="Sí";F5*0,0825;0)

En este ejemplo, la fórmula en F7 dice lo siguiente: SI(E7 = "Sí", calcula la cantidad total con F5 * 8,25 %; en caso contrario, no hay ningún impuesto sobre las ventas, por lo que se devuelve 0)

Procedimientos recomendados: Constantes

En el último ejemplo, vimos que tanto "Sí" como el índice de impuestos (0,0825) se escribían directamente en la fórmula. En general, no se recomienda usar constantes literales (valores que pueden cambiar ocasionalmente) directamente en las fórmulas, ya que puede ser difícil encontrarlas y cambiarlas en el futuro. Es mucho mejor colocar las constantes en sus propias celdas, donde se pueden encontrar y cambiar fácilmente. En este caso es correcto, ya que solo hay una función SI y rara vez se cambiará el índice de impuestos. Incluso si esto ocurre, se puede cambiar fácilmente en la fórmula.

Usar SI para comprobar si una celda está en blanco

A veces es necesario comprobar si una celda está en blanco (normalmente, para que una fórmula no muestre un resultado sin datos de entrada).

Comprobar si una celda está en blanco: la fórmula de la celda E2 es =SI(ESBLANCO(D2);"En blanco";"No está en blanco")

En este caso, usaremos SI con la función ESBLANCO:

  • =SI(ESBLANCO(D2);"En blanco";"No está en blanco")

Lo que equivale a SI(D2 está en blanco, devuelve "En blanco"; en caso contrario, devuelve "No está en blanco"). También podría usar fácilmente su propia fórmula para la condición "No está en blanco". En el ejemplo siguiente usaremos "" en lugar de ESBLANCO. Básicamente, las dos comillas dobles ("") equivalen a "nada".

Usar "" para comprobar si una celda está en blanco: la fórmula de la celda E3 es =SI(D3="";"En blanco";"No está en blanco")
  • =SI(D3="";"En blanco";"No está en blanco")

Esta fórmula dice lo siguiente: SI(D3 no tiene nada, devuelve "En blanco"; en caso contrario, devuelve "No está en blanco"). Este es un ejemplo de un método muy común del uso de "" para evitar que una fórmula realice un cálculo si una celda dependiente está en blanco:

  • =SI(D3="";"";SuFórmula())

    SI(D3 equivale a nada, no se devuelve nada; en caso contrario, calcula la fórmula).

Ejemplo de función SI anidada

La fórmula de la celda E2 es =SI(D2=1,"Sí",IF(D2=2,"No","Es posible"))

Mientras que una función SI sencilla solo contiene dos resultados (verdadero o falso), las funciones SI anidadas pueden tener de 3 a 64 resultados.

  • =SI(D2=1,"Sí",SI(D2=2,"No","Es posible"))

En la ilustración anterior, la fórmula de E2 dice lo siguiente: SI(D2 es igual a 1, devuelve "Sí"; en caso contrario, SI(D2 es igual a 2, devuelve "No"; en caso contrario, devuelve "Es posible")).

Advertencia

Aunque Excel permite anidar hasta 64 funciones SI diferentes, no se recomienda hacerlo. ¿Por qué?

  • El uso de varias instrucciones SI requiere una cuidada planificación para crearlas correctamente y asegurarse de que su lógica puede calcular sin errores cada una de las condiciones hasta llegar al final. Si no anida sus instrucciones SI con una precisión absoluta, una fórmula podría funcionar en el 75% de los casos pero devolver resultados inesperados en el 25% restante. Desafortunadamente, las probabilidades de detectar ese 25 % de casos son muy escasas.

  • Mantener varias instrucciones SI puede resultar muy difícil, especialmente si, pasado un tiempo, intenta averiguar lo que usted (o, peor todavía, otra persona) estaba intentando hacer.

Problemas comunes

Problema

Qué ha fallado

0 (cero) en la celda

No había argumento para valor_si_verdadero ni para valor_si_falso. Para que se devuelva un valor correcto, agregue texto de argumento a los dos argumentos, o agregue VERDADERO o FALSO al argumento.

#¿NOMBRE? en la celda

Normalmente, esto significa que la fórmula se ha escrito mal.

¿Tiene alguna pregunta sobre una función específica?

Publique una pregunta en el foro de la comunidad de Excel

Ayudarnos a mejorar Excel

¿Tiene alguna sugerencia sobre cómo podemos mejorar la siguiente versión de Excel? Si es así, consulte los temas en Excel User Voice.

Vea también

Vea un vídeo sobre cómo usar la función SI

Función SI.CONJUNTO (Office 365, Excel 2016 y posterior)

Funciones SI avanzadas: Trabajar con fórmulas anidadas y evitar errores

Vídeos de aprendizaje: Funciones SI avanzadas

La función CONTAR.SI contará los valores según un solo criterio

La función CONTAR.SI.CONJUNTO contará los valores según varios criterios

La función SUMAR.SI sumará los valores según un solo criterio

La función SUMAR.SI.CONJUNTO sumará los valores según varios criterios

Función Y

Función O

Función BUSCARV

Información general sobre las fórmulas de Excel

Evitar fórmulas erróneas

Usar la comprobación de errores para detectar errores en las fórmulas

Funciones lógicas

Funciones de Excel (por orden alfabético)

Funciones de Excel (por categoría)

¿Le ha sido útil esta información?

¿Cómo podemos mejorarlo?

¿Cómo podemos mejorarlo?

Para proteger su privacidad, no incluya información de contacto en sus comentarios. Revisar política de privacidad.

¡Gracias por sus comentarios!