Temas relacionados
×
Fórmulas y funciones
Iniciar sesión con Microsoft
Iniciar sesión o crear una cuenta
Hola:
Seleccione una cuenta diferente.
Tiene varias cuentas
Elija la cuenta con la que desea iniciar sesión.
Fórmulas y funciones

Función CONTAR.SI

Use CONTAR.SI, una de las funciones estadísticas, para contar el número de celdas que cumplen un criterio; por ejemplo, para contar el número de veces que una ciudad determinada aparece en una lista de clientes.

En su forma más sencilla, CONTAR.SI indica lo siguiente:

  • =CONTAR.SI(¿Dónde quiere realizar la búsqueda y qué quiere buscar?)

Por ejemplo:

  • =CONTAR.SI(A2:A5;"Londres")

  • =CONTAR.SI(A2:A5;A4)

Su explorador no admite vídeo. Instale Microsoft Silverlight, Adobe Flash Player o Internet Explorer 9.

CONTAR.SI(rango;criterios)

Nombre del argumento

Descripción

Rango    (obligatorio)

El grupo de celdas que desea contar. Rango puede contener números, matrices, un rango con nombre o referencias que contengan números. Los valores en blanco y de texto se ignoran.

Obtenga información sobre cómo seleccionar rangos en una hoja.

Criterios    (obligatorio)

Número, expresión, referencia de celda o cadena de texto que determina las celdas que se van a contar.

Por ejemplo, puede usar un número como 32, una comparación como ">32", una celda como B4 o una palabra como "manzanas".

CONTAR.SI usa solo un criterio. Use CONTAR.SI.CONJUNTO si desea usar varios criterios.

Ejemplos

Para usar estos ejemplos de Excel, copie los datos de la tabla de abajo y péguelos en la celda A1 de una nueva hoja de cálculo.

Datos

Datos

manzanas

32

naranjas

54

melocotones

75

manzanas

86

Fórmula

Descripción

=CONTAR.SI(A2:A5;"manzanas")

Cuenta el número de celdas con manzanas entre las celdas A2 y A5. El resultado es 2.

=CONTAR.SI(A2:A5;A4)

Cuenta el número de celdas con melocotones, el valor de A4, entre las celdas A2 y A5. El resultado es 1.

=CONTAR.SI(A2:A5;A2)+CONTAR.SI(A2:A5;A3)

Cuenta el número de manzanas, el valor de A2, y de naranjas, el valor de A3, entre las celdas A2 y A5. El resultado es 3. Esta fórmula usa CONTAR.SI dos veces para especificar varios criterios, un criterio por expresión. También puede utilizar la función CONTAR.SI.CONJUNTO.

=CONTAR.SI(B2:B5;">55")

Cuenta el número de celdas con un valor superior a 55 entre las celdas B2 y B5. El resultado es 2.

=CONTAR.SI(B2:B5;"<>"&B4)

Cuenta el número de celdas con un valor distinto de 75 entre las celdas B2 y B5. El símbolo de la "y" (&) combina el operador de comparación "<>" (no es igual a) y el valor de B4 para leer =CONTAR.SI(B2:B5;"<>75"). El resultado es 3.

=CONTAR.SI(B2:B5;">=32")-CONTAR.SI(B2:B5;"<=85")

Cuenta el número de celdas con un valor superior o igual a 32 e inferior o igual a 85 entre las celdas B2 y A5. El resultado es 1.

=CONTAR.SI(A2:A5;"*")

Cuenta el número de celdas que contienen texto entre las celdas A2 y A5. El carácter comodín * se usa para reemplazar cualquier carácter. El resultado es 4.

=CONTAR.SI(A2:A5;"?????nas")

Cuenta el número de celdas que tienen exactamente 8 caracteres y que terminan con las letras "nas" entre las celdas A2 y A5. El signo de interrogación (?) se usa como carácter comodín para coincidir con caracteres individuales. El resultado es 2.

Problemas comunes

Problema

Qué ha fallado

Se devolvió un valor incorrecto para cadenas largas.

La función CONTAR.SI devuelve resultados incorrectos cuando se usa para comparar cadenas de más de 255 caracteres.

Para comparar cadenas de más de 255 caracteres, use la función CONCATENAR o el operador concatenar &. Por ejemplo, =CONTAR.SI(A2:A5;"cadena larga"&"otra cadena larga").

No se devolvió ningún valor cuando se esperaba uno.

Asegúrese de encerrar el argumento de criterios entre comillas.

Una formula CONTAR.SI recibe un error #¡VALOR! al hacer referencia a otra hoja de cálculo.

Este error se produce cuando la fórmula que contiene la función hace referencia a celdas o a un rango de un libro cerrado y se calculan las celdas. Para que esta característica funcione, el otro libro debe estar abierto.

Prácticas recomendadas

Realice este procedimiento

¿Por qué?

Tenga en cuenta que CONTAR.SI pasa por alto mayúsculas y minúsculas en las cadenas de texto.

Los criterios no distinguen entre mayúsculas y minúsculas. En otras palabras, la cadena "manzanas" y la cadena "MANZANAS" darán como resultado la misma cantidad de celdas.

Use caracteres comodín.

Los caracteres comodín, como el signo de interrogación (?) y asterisco (*), pueden usarse en criterios. El signo de interrogación reemplaza cualquier carácter individual. El asterisco reemplaza cualquier secuencia de caracteres. Si lo que desea buscar es un signo de interrogación o un asterisco, escriba una tilde (~) antes del carácter.

Por ejemplo, =CONTAR.SI(A2:A5;"manzana?") contará todas las instancias de "manzana" con una última letra que podrá variar.

Asegúrese de que los datos no contienen caracteres incorrectos.

Al contar valores de texto, asegúrese de que los datos no contienen espacios al principio ni al final, de que no haya un uso incoherente de las comillas rectas (' o ") ni tipográficas (‘ o “) y de que no haya caracteres no imprimibles. En estos casos, CONTAR.SI puede devolver un valor inesperado o incorrecto.

Intente usar la función LIMPIAR o la función ESPACIOS.

Para mayor comodidad, use rangos con nombre.

CONTAR.SI admite el uso de rangos con nombre en una fórmula (por ejemplo, =CONTAR.SI(fruta;">=32")-CONTAR.SI(fruta;">85"). El rango con nombre puede estar en la hoja de cálculo actual, en otra hoja de cálculo del mismo libro o en una hoja de cálculo de otro libro. Para hacer referencia a otro libro, ese libro también debe estar abierto.

Nota: La función CONTAR.SI no contará celdas según el color de la fuente o el fondo de la celda. Pero Excel es compatible con funciones definidas por el usuario (UDF) con las operaciones de Microsoft Visual Basic para Aplicaciones (VBA) en celdas basadas en el color de la fuente o el fondo. Este es un ejemplo de cómo puede contar el número de celdas con un color de celda específico con VBA.

¿Necesitas más ayuda?

Siempre puede preguntar a un experto en Excel Tech Community u obtener soporte técnico en Comunidades.

Vea también

Función CONTAR.SI.CONJUNTO

Función SI

Función CONTARA

Información general sobre fórmulas en Excel

Función SI.CONJUNTO

SUMAR.SI (función SUMAR.SI)

¿Necesita más ayuda?

¿Quiere más opciones?

Explore las ventajas de las suscripciones, examine los cursos de aprendizaje, aprenda a proteger su dispositivo y mucho más.

Las comunidades le ayudan a formular y responder preguntas, enviar comentarios y leer a expertos con conocimientos extensos.

¿Le ha sido útil esta información?

¿Cuál es tu grado de satisfacción con la calidad del lenguaje?
¿Qué ha afectado a su experiencia?
Si presiona Enviar, sus comentarios se usarán para mejorar los productos y servicios de Microsoft. El administrador de TI podrá recopilar estos datos. Declaración de privacidad.

¡Gracias por sus comentarios!

×