Dividir texto entre columnas mediante funciones

Las funciones de texto sirven para manipular cadenas de datos como, por ejemplo, distribuir, el nombre, el segundo nombre y el apellido en tres columnas distintas.

En este artículo se explica cómo usar combinaciones de las siguientes funciones de texto para extraer y copiar componentes del nombre en celdas distintas.

Función

Sintaxis

IZQUIERDA

IZQUIERDA(texto;núm_de_caracteres)

EXTRAE

EXTRAE(texto;posición_inicial;núm_de_caracteres)

DERECHA

DERECHA(texto;núm_de_caracteres)

BUSCAR

BUSCAR(texto_buscado;dentro_del_texto;núm_inicial)

LARGO

LARGO(texto)

Extraer componentes del nombre

La clave para distribuir componentes del nombre con funciones de texto es la posición de cada carácter dentro de una cadena de texto. Las posiciones de los espacios dentro de la cadena de texto son importantes porque indican el principio y el fin de los componentes del nombre en una cadena.

Por ejemplo, en una celda que contiene sólo un nombre y un apellido, el apellido comienza detrás de la primera instancia de un espacio. Algunos nombres de la lista pueden contener un segundo nombre, en cuyo caso el apellido comienza detrás de la segunda instancia de un espacio.

En este artículo se explica cómo extraer los distintos componentes de una gran variedad de formatos de nombre. Haga clic en un nombre de ejemplo de la siguiente tabla para ver las fórmulas de extracción de los componentes de ese nombre.

Las fórmulas pueden resultar más fáciles de entender si las copia en una hoja de cálculo en blanco.

Cómo copiar un ejemplo

  1. Cree una hoja de cálculo o un libro en blanco.

  2. Seleccione el texto de ejemplo y las fórmulas en la tabla.

    Nota: No seleccione los encabezados de fila ni de columna.

    Seleccionar un ejemplo de la Ayuda

  3. Presione CTRL+C.

  4. En la hoja de cálculo, seleccione la celda A1 y presione CTRL+V.

  5. Para cambiar entre ver los resultados y las fórmulas que devuelven los resultados, presione Alt+º (ordinal masculino) o bien, en el grupo Auditoría de fórmulas de la ficha Fórmulas, haga clic en el botón Mostrar fórmulas.

Nombre de ejemplo

Descripción

Nombre

Segundo nombre

Apellidos

Sufijo

1

Juan Casanova

Sin segundo nombre

Juan

Casanova

2

Yago I. Castañeda

Una inicial en medio

Yago

I.

Castañeda

3

Eulalia B. G. Terán

Dos iniciales en medio

Eulalia

B. G.

Terán

4

Chávez, Edurne Candela

Primero el apellido con una coma

Edurne

Candela

Chávez

5

María Julia D. Linares

Nombre con dos partes

María Julia

D.

Linares

6

Nuria Acevedo de Galván

Apellido con tres partes

Nuria

Acevedo de Galván

7

Pedro de Armijo

Apellido con dos partes

Pedro

de Armijo

8

Tórrez F., Juan A.

Primero el apellido y el sufijo con una coma

Juan

A.

Tórrez

F.

9

Íker Arteaga III

Con sufijo

Íker

Arteaga

III

10

Sr. Ángel Valádez

Con prefijo

Ángel

Valádez

11

Leticia Terrazas-Núñez

Apellido con un guión

Leticia

Terrazas-Núñez


Ejemplo 1: Juan Casanova

En este ejemplo, sólo hay dos componentes: el nombre y el apellido. Los dos componentes están separados por un único espacio.

1

2

A

B

C

Nombre completo

Nombre

Apellidos

Juan Casanova

=IZQUIERDA(A2, HALLAR(" ",A2,1))

=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,1))

En los gráficos siguientes, la parte resaltada del nombre completo indica el carácter del que la fórmula BUSCAR busca coincidencias.

Nombre

El nombre comienza en el primer carácter de la cadena (J) y termina en el quinto carácter (el espacio). La fórmula devuelve cinco caracteres en A2, empezando desde la izquierda.

Fórmula para extraer un nombre

Utiliza la función BUSCAR para buscar el valor de núm_caracteres:

Busca la posición numérica del espacio en A2, empezando desde la izquierda. (5)

Apellido

El apellido comienza en el espacio, ocupa ocho caracteres desde la derecha y termina en el último carácter de la derecha (a). La fórmula extrae ocho caracteres en A2, empezando desde la derecha.

Fórmula para extraer un apellido

Utiliza las funciones BUSCAR y LARGO para buscar el valor de núm_caracteres:

Busca la posición numérica del espacio en A2, empezando desde la izquierda. (5)

Cuenta la longitud total de la cadena de texto y después resta el número de caracteres desde la izquierda al primer espacio hallado en el paso 1. (13 - 5 = 8)

Principio de página

Ejemplo 2: Yago I. Castañeda

En este ejemplo, el nombre completo tiene tres componentes: el nombre, la inicial y el apellido. Cada componente del nombre está separado por un espacio.

1

2

A

B

C

D

Nombre

Nombre (Yago)

Segundo nombre (I.)

Apellido ( Castañeda )

Yago I. Castañeda

=IZQUIERDA(A2, HALLAR(" ",A2,1))

=EXTRAE(A2,HALLAR(" ",A2,1)+1,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)-HALLAR(" ",A2,1))

=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,HALLAR(" ",A2,1)+1))

En los gráficos siguientes, la parte resaltada del nombre completo indica el carácter del que la fórmula BUSCAR busca coincidencias.

Nombre

El nombre comienza en el primer carácter de la izquierda (J) y termina en el quinto carácter (el primer espacio). La fórmula extrae los cinco primeros caracteres en A2, empezando desde la izquierda.

Fórmula para separar un nombre y un apellido más una inicial del segundo nombre

Utiliza la función BUSCAR para buscar el valor de núm_caracteres:

Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (5)

Segundo nombre

El segundo nombre comienza en el sexto carácter (I) y termina en la octava posición (el segundo espacio). Esta fórmula incluye funciones BUSCAR anidadas para buscar la segunda instancia de un espacio.

La fórmula extrae tres caracteres, empezando desde la sexta posición.

Detalles de una fórmula para separar nombre, segundo nombre y apellidos

Utiliza la función BUSCAR para buscar el valor de núm_inicial:

Busca la posición numérica del primer espacio en A2, empezando desde el primer carácter de la izquierda. (5)

Agrega 1 para obtener la posición del carácter situado detrás del primer espacio (I). Esta posición numérica es la posición inicial del segundo nombre. (5 + 1 = 6)

Utiliza funciones BUSCAR anidadas para buscar el valor de núm_caracteres:

Busca la posición numérica del primer espacio en A2, empezando desde el primer carácter de la izquierda. (5)

Agrega 1 para obtener la posición del carácter situado detrás del primer espacio (I). El resultado es el número de carácter en el que desea iniciar la búsqueda de la segunda instancia del espacio. (5 + 1 = 6)

Busca la segunda instancia del espacio en A2, empezando desde la sexta posición (I) hallada en el paso 4. Este número de carácter es la posición final del segundo nombre. (8)

Busca la posición numérica del espacio en A2, empezando desde el primer carácter de la izquierda. (5)

Toma el número de carácter del segundo espacio hallado en el paso 5 y lo resta del primer espacio hallado en el paso 6. El resultado es el número de caracteres que la función EXTRAE extrae del texto empezando en la sexta posición hallada en el paso 2. (8 – 5 = 3)

Apellido

El apellido comienza en el quinto carácter desde la derecha (C) y termina en el primer carácter de la derecha (a). Esta fórmula incluye funciones BUSCAR anidadas para buscar la segunda y tercera instancia del espacio (que se encuentra en las posiciones quinta y octava desde la izquierda).

La fórmula extrae cinco caracteres en A2, empezando desde la derecha.

La segunda función de búsqueda en una fórmula para separar nombre, segundo nombre y apellidos

Utiliza las funciones LARGO y BUSCAR para buscar el valor de núm_caracteres:

Busca la posición numérica del espacio en A2, empezando desde el primer carácter de la izquierda. (5)

Agrega 1 para obtener la posición del carácter situado detrás del primer espacio (I). El resultado es el número de carácter en el que desea iniciar la búsqueda de la segunda instancia del espacio. (5 + 1 = 6)

Busca la segunda instancia del espacio en A2, empezando desde la sexta posición (I) hallada en el paso 2. Este número de carácter es la posición final del segundo nombre. (8)

Cuenta la longitud total de la cadena de texto en A2 y después resta el número de caracteres desde la izquierda hasta la segunda instancia del espacio hallada en el paso 3. El resultado es el número de caracteres que se van a extraer desde la derecha del nombre completo. (13 – 8 = 5)

Principio de página

Ejemplo 3: Eulalia B. G. Terán

En este ejemplo hay dos iniciales intermedias. Los componentes del nombre se separan con el segundo y el tercer espacio.

1

2

A

B

C

D

Nombre

Nombre ( Eulalia )

Segundo nombre (B. G.)

Apellido ( Terán )

Eulalia B. G. Terán

=IZQUIERDA(A2, HALLAR(" ",A2,1))

=EXTRAE(A2,HALLAR(" ",A2,1)+1,HALLAR(" ",A2,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1)-HALLAR(" ",A2,1))

=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1))

En los gráficos siguientes, la parte resaltada del nombre completo indica el carácter del que la fórmula BUSCAR busca coincidencias.

Nombre

El nombre comienza en el primer carácter de la izquierda (E) y termina en el octavo carácter (el primer espacio). La fórmula extrae los ocho primeros caracteres en A2, empezando desde la izquierda.

Fórmula para separar nombre, apellido y dos iniciales del segundo nombre

Utiliza la función BUSCAR para buscar el valor de núm_caracteres:

Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (8)

Segundo nombre

El segundo nombre comienza en la novena posición (B) y termina en la decimocuarta posición (el tercer espacio). Esta fórmula incluye funciones HALLAR anidadas para buscar la primera, segunda y tercera instancia del espacio en la octava, novena y decimocuarta posición.

La fórmula extrae cinco caracteres, empezando desde la novena posición.

Fórmula para separar nombre, apellido y dos iniciales del segundo nombre

Utiliza la función BUSCAR para buscar el valor de núm_inicial:

Busca la posición numérica del primer espacio en A2, empezando desde el primer carácter de la izquierda. (8)

Agrega 1 para obtener la posición del carácter situado detrás del primer espacio (B). Esta posición numérica es la posición inicial del segundo nombre. (8 + 1 = 9)

Utiliza funciones BUSCAR anidadas para buscar el valor de núm_caracteres:

Busca la posición numérica del primer espacio en A2, empezando desde el primer carácter de la izquierda. (8)

Agrega 1 para obtener la posición del carácter situado detrás del primer espacio (B). El resultado es el número de carácter en el que desea iniciar la búsqueda de la segunda instancia del espacio. (8 + 1 = 9)

Busca el segundo espacio en A2, empezando desde la novena posición (B) hallada en el paso 4. (11)

Agrega 1 para obtener la posición del carácter situado detrás del segundo espacio (G). Este número de carácter es la posición inicial en la que desea iniciar la búsqueda del tercer espacio. (11 + 1 = 12)

Busca el tercer espacio en A2, empezando desde la duodécima posición hallada en el paso 6. (14)

Busca la posición numérica del primer espacio en A2. (8)

Toma el número de carácter del tercer espacio hallado en el paso 7 y lo resta del primer espacio hallado en el paso 6. El resultado es el número de caracteres que la función EXTRAE extrae de la cadena de texto empezando en la novena posición hallada en el paso 2.

Apellido

El apellido comienza en el quinto carácter desde la derecha (T) y termina en el primer carácter de la derecha (n). Esta fórmula incluye funciones BUSCAR anidadas para buscar la primera, segunda y tercera instancia del espacio.

La fórmula extrae ocho caracteres en A2, empezando desde la derecha del nombre completo.

Fórmula para separar nombre, apellido y dos iniciales del segundo nombre

Utiliza funciones BUSCAR anidadas y la función y LARGO para buscar el valor de núm_caracteres:

Busca la posición numérica del primer espacio en A2, empezando desde el primer carácter de la izquierda. (8)

Agrega 1 para obtener la posición del carácter situado detrás del primer espacio (B). El resultado es el número de carácter en el que desea iniciar la búsqueda de la segunda instancia del espacio. (8 + 1 = 9)

Busca el segundo espacio en A2, empezando desde la novena posición (B) hallada en el paso 2. (11)

Suma 1 para obtener la posición del carácter situado detrás del segundo espacio (G). Este número de carácter es la posición inicial en la que desea iniciar la búsqueda del tercer espacio. (11 + 1 = 12)

Busca el tercer espacio en A2, empezando en la duodécima posición (G) hallada en el paso 6. (14)

Cuenta la longitud total de la cadena de texto en A2 y después resta el número de caracteres desde la izquierda hasta el tercer espacio hallado en el paso 5. El resultado es el número de caracteres que se van a extraer desde la derecha del nombre completo. (19 -14 = 5)

Principio de página

Ejemplo 4: Chávez, Edurne Candela

En este ejemplo, el apellido precede al nombre y el segundo nombre aparece al final. La coma indica el final del apellido y un espacio separa cada componente del nombre.

1

2

A

B

C

D

Nombre

Nombre (Edurne)

Segundo nombre (Candela)

Apellido (Chávez)

Chávez, Edurne Candela

=EXTRAE(A2,HALLAR(" ",A2,1)+1,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)-HALLAR(" ",A2,1))

=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,HALLAR(" ",A2,1)+1))

=IZQUIERDA(A2, HALLAR(" ",A2,1)-2)

En los gráficos siguientes, la parte resaltada del nombre completo indica el carácter del que la fórmula BUSCAR busca coincidencias.

Nombre

El nombre comienza en el noveno carácter de la izquierda (E) y termina en el decimocuarto carácter (el segundo espacio). Como el nombre aparece en medio del nombre completo, necesita utilizar la función EXTRAE para extraerlo.

La fórmula extrae ocho caracteres, empezando desde la novena posición.

Fórmula para separar un apellido seguido de un nombre y un segundo nombre

Utiliza la función BUSCAR para buscar el valor de núm_inicial:

Busca la posición numérica del primer espacio en A2, empezando desde el primer carácter de la izquierda. (8)

Agrega 1 para obtener la posición del carácter situado detrás del primer espacio (E). Esta posición numérica es la posición inicial del nombre. (8 + 1 = 9)

Utiliza funciones BUSCAR anidadas para buscar el valor de núm_caracteres:

Busca la posición numérica del primer espacio en A2, empezando desde el primer carácter de la izquierda. (8)

Suma 1 para obtener la posición del carácter situado detrás del primer espacio (E). El resultado es número de carácter en el que desea iniciar la búsqueda del segundo espacio. (8 + 1 = 9)

Busca el segundo espacio en A2, empezando desde la novena posición (E) hallada en el paso 4. (14)

Busca la posición numérica del primer espacio en A2, empezando desde el primer carácter de la izquierda. (8)

Toma el número de carácter del segundo espacio hallado en el paso 5 y lo resta del primer espacio hallado en el paso 6. El resultado es el número de caracteres que la función EXTRAE extrae de la cadena de texto empezando en la novena posición hallada en el paso 2. (14 - 8 = 6)

Segundo nombre

El segundo nombre comienza en el octavo carácter de la derecha (C) y termina en el primer carácter de la derecha (a). Esta fórmula incluye funciones HALLAR anidadas para buscar la primera y segunda instancia del espacio en las posiciones octava y decimocuarta desde la izquierda.

La fórmula extrae ocho caracteres, empezando desde la derecha.

Fórmula para separar un apellido seguido de un nombre y un segundo nombre

Utiliza las funciones BUSCAR y LARGO anidadas para buscar el valor de núm_caracteres:

Busca la posición numérica del primer espacio en A2, empezando desde el primer carácter de la izquierda. (8)

Suma 1 para obtener la posición del carácter situado detrás del primer espacio (E). El resultado es número de carácter en el que desea iniciar la búsqueda del segundo espacio. (8 + 1 = 9)

Busca la segunda instancia del espacio en A2, empezando desde la novena posición (E) hallada en el paso 2. (14)

Cuenta la longitud total de la cadena de texto en A2 y después resta el número de caracteres desde la izquierda hasta el segundo espacio hallado en el paso 3. El resultado es el número de caracteres que se van a extraer desde la derecha del nombre completo. (16 -12 = 4)

Apellido

El apellido comienza en el primer carácter de la izquierda (C) y termina en el sexto carácter (z). La fórmula extrae seis caracteres, empezando desde la izquierda.

Fórmula para separar un apellido seguido de un nombre y un segundo nombre

Utiliza la función BUSCAR para buscar el valor de núm_caracteres:

Busca la posición numérica del primer espacio en A2, empezando desde el primer carácter de la izquierda. (8)

Resta 2 para obtener la posición numérica del carácter final del apellido (z). El resultado es el número de caracteres que la función IZQUIERDA debe extraer. (8 - 2 = 6)

Principio de página

Ejemplo 5: María Julia D. Linares

En este ejemplo el nombre tiene dos partes: María Julia. El segundo y el tercer espacio separan cada componente del nombre.

1

2

A

B

C

D

Nombre

Nombre (María Julia)

Segundo nombre (D.)

Apellido (Linares)

María Julia D. Linares

=IZQUIERDA(A2, HALLAR(" ",A2,HALLAR(" ",A2,1)+1))

=EXTRAE(A2,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1,HALLAR(" ",A2,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1)-(HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1))

=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1))

En los gráficos siguientes, la parte resaltada del nombre completo indica el carácter del que la fórmula BUSCAR busca coincidencias.

Nombre

El nombre comienza en el primer carácter de la izquierda y termina en el duodécimo carácter (el segundo espacio). Esta fórmula incluye funciones HALLAR anidadas para buscar la segunda instancia del espacio desde la izquierda.

La fórmula extrae doce caracteres, empezando desde la izquierda.

Fórmula para separar nombre, segundo nombre, inicial del segundo nombre y apellido

Utiliza funciones BUSCAR anidadas para buscar el valor de núm_caracteres:

Busca la posición numérica del primer espacio en A2, empezando desde el primer carácter de la izquierda. (6)

Agrega 1 para obtener la posición del carácter situado detrás del primer espacio (J). El resultado es el número de carácter en el que desea iniciar la búsqueda de la segunda instancia del espacio. (6 + 1 = 7)

Busca la segunda instancia del espacio en A2, empezando desde la séptima posición (J) hallada en el paso 2. El resultado es el número de caracteres que la función IZQUIERDA extrae de la cadena de texto. (12)

Segundo nombre

El segundo nombre comienza en la decimotercera posición (D) y termina en la decimoquinta posición (el tercer espacio). Esta fórmula incluye funciones HALLAR anidadas para buscar la primera, segunda y tercera instancia del espacio.

La fórmula extrae dos caracteres del medio, empezando desde la décima posición.

Fórmula para separar nombre, segundo nombre, inicial del segundo nombre y apellido

Utiliza funciones BUSCAR anidadas para buscar el valor de núm_inicial:

Busca la posición numérica del primer espacio en A2, empezando desde el primer carácter de la izquierda. (6)

Agrega 1 para obtener el carácter situado detrás del primer espacio (J). El resultado es el número de carácter en el que desea iniciar la búsqueda del segundo espacio. (6 + 1 = 7)

Busca la posición de la segunda instancia del espacio en A2, empezando desde la séptima posición (J) hallada en el paso 2. El resultado es el número de caracteres que la función IZQUIERDA extrae desde la izquierda. (9)

Agrega 1 para obtener el carácter situado detrás del segundo espacio (D). El resultado es la posición inicial del segundo nombre. (9 + 1 = 10)

Utiliza funciones BUSCAR anidadas para buscar el valor de núm_caracteres:

Busca la posición numérica del carácter situado detrás del segundo espacio (D). El resultado es el número de carácter en el que desea iniciar la búsqueda del tercer espacio. (10)

Busca la posición numérica del tercer espacio en A2, empezando desde la izquierda. El resultado es la posición final del segundo nombre. (12)

Busca la posición numérica del carácter situado detrás del segundo espacio (D). El resultado es la posición inicial del segundo nombre. (10)

Toma el número de carácter del tercer espacio hallado en el paso 6 y resta el número de carácter de “D” hallado en el paso 7. El resultado es el número de caracteres que la función EXTRAE extrae de la cadena de texto empezando en la décima posición hallada en el paso 4. (12 - 10 = 2)

Apellido

El apellido empieza en el octavo carácter de la derecha. Esta fórmula incluye funciones HALLAR anidadas para buscar la primera, segunda y tercera instancia del espacio en la quinta, novena y duodécima posición.

La fórmula extrae ocho caracteres desde la derecha.

Fórmula para separar nombre, segundo nombre, inicial del segundo nombre y apellido

Utiliza funciones BUSCAR anidadas y las funciones LARGO para buscar el valor de núm_caracteres:

Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (5)

Agrega 1 para obtener el carácter situado detrás del primer espacio (J). El resultado es el número de carácter en el que desea iniciar la búsqueda del espacio. (6 + 1 = 7)

Busca el segundo espacio en A2, empezando desde la séptima posición (J) hallada en el paso 2. (10)

Agrega 1 para obtener la posición del carácter situado detrás del segundo espacio (D). El resultado es la posición inicial del segundo nombre. (9 + 1 = 10)

Busca la posición numérica del tercer espacio en A2, empezando desde la izquierda. El resultado es la posición final del segundo nombre. (12)

Cuenta la longitud total de la cadena de texto en A2 y después resta el número de caracteres desde la izquierda hasta el tercer espacio hallado en el paso 5. El resultado es el número de caracteres que se van a extraer desde la derecha del nombre completo. (22 -15 = 7)

Principio de página

Ejemplo 6: Nuria Acevedo de Galván

En este ejemplo, el apellido consta de tres partes: Acevedo de Galván. El primer espacio indica el final del nombre y el inicio del apellido.

1

2

A

B

D

Nombre

Nombre (Nuria)

Apellido ( Acevedo de Galván )

Nuria Acevedo de Galván

=IZQUIERDA(A2, HALLAR(" ",A2,1))

=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,1))

En los gráficos siguientes, la parte resaltada del nombre completo indica el carácter del que la fórmula BUSCAR busca coincidencias.

Nombre

El nombre comienza en el primer carácter de la izquierda (N) y termina en el sexto carácter (el primer espacio). La fórmula extrae seis caracteres desde la izquierda.

Fórmula para separar un nombre y un apellido de tres palabras

Utiliza la función BUSCAR para buscar el valor de núm_caracteres:

Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (6)

Apellido

El apellido comienza en el séptimo carácter desde la derecha (A) y termina en el primer carácter de la derecha (o). La fórmula extrae diecisiete caracteres desde la derecha.

Fórmula para separar un nombre y un apellido de tres palabras

Utiliza las funciones LARGO y BUSCAR para buscar el valor de núm_caracteres:

Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (6)

Cuenta la longitud total de la cadena de texto en A2 y después resta el número de caracteres desde la izquierda hasta el primer espacio hallado en el paso 1. El resultado es el número de caracteres que se van a extraer desde la derecha del nombre completo. (23 - 6 = 17)

Principio de página

Ejemplo 7: Pedro de Armijo

En este ejemplo, el apellido consta de dos partes: de Armijo. El primer espacio indica el final del nombre y el inicio del apellido.

1

2

A

B

D

Nombre

Nombre (Pedro)

Apellido (de Armijo)

Pedro de Armijo

=IZQUIERDA(A2, HALLAR(" ",A2,1))

=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,1))

En los gráficos siguientes, la parte resaltada del nombre completo indica el carácter del que la fórmula BUSCAR busca coincidencias.

Nombre

El nombre comienza en el primer carácter de la izquierda (P) y termina en el octavo carácter (el primer espacio). La fórmula extrae seis caracteres desde la izquierda.

Fórmula para separar un nombre y un apellido de dos palabras

Utiliza la función BUSCAR para buscar el valor de núm_caracteres:

Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (6)

Apellido

El apellido comienza en el noveno carácter desde la derecha (d) y termina en el primer carácter de la derecha (o). La fórmula extrae nueve caracteres desde la derecha del nombre completo.

Fórmula para separar un nombre y un apellido de dos palabras

Utiliza las funciones LARGO y BUSCAR para buscar el valor de núm_caracteres:

Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (6)

Cuenta la longitud total de la cadena de texto en A2 y después resta el número de caracteres desde la izquierda hasta el primer espacio hallado en el paso 1. El resultado es el número de caracteres que se van a extraer desde la derecha del nombre completo. (15 - 6 = 9)

Principio de página

Ejemplo 8: Tórrez F., Juan A.

En este ejemplo, el apellido ocupa el primer lugar, seguido del sufijo. La coma separa el apellido y el sufijo del nombre y de la inicial.

1

2

A

B

C

C

E

Nombre

Nombre (Juan)

Segundo nombre (A.)

Apellido (Tórrez)

Sufijo (F.)

Tórrez F., Juan A.

=EXTRAE(A2,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1,HALLAR(" ",A2,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1)-HALLAR(" ",A2,HALLAR(" ",A2,1)+1))

=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)+1))

=IZQUIERDA(A2, HALLAR(" ",A2,1))

=EXTRAE(A2,HALLAR(" ", A2,1)+1,(HALLAR(" ",A2,HALLAR(" ",A2,1)+1)-2)-HALLAR(" ",A2,1))

En los gráficos siguientes, la parte resaltada del nombre completo indica el carácter del que la fórmula BUSCAR busca coincidencias.

Nombre

El nombre comienza en el duodécimo carácter (J) y termina en el decimoquinto carácter (el tercer espacio). La fórmula extrae tres caracteres, empezando desde la decimoquinta posición.

Fórmula para extraer el nombre del ejemplo 8: Iñárritu, Juan L.

Utiliza funciones BUSCAR anidadas para buscar el valor de núm_inicial:

Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (6)

Agrega 1 para obtener el carácter situado detrás del primer espacio (F). El resultado es el número de carácter en el que desea iniciar la búsqueda del segundo espacio. (7 + 1 = 8)

Busca el segundo espacio en A2, empezando desde la octava posición (F) hallada en el paso 2. (12)

Agrega 1 para obtener el carácter situado detrás del segundo espacio (J). El resultado es la posición inicial del nombre. (12 + 1 = 13)

Utiliza funciones BUSCAR anidadas para buscar el valor de núm_caracteres:

Busca la posición numérica del carácter situado detrás del segundo espacio (J). El resultado es el número de carácter en el que desea iniciar la búsqueda del tercer espacio. (13)

Busca la posición numérica del tercer espacio en A2, empezando desde la izquierda. El resultado es la posición final del nombre. (16)

Busca la posición numérica del carácter situado detrás del segundo espacio (J). El resultado es la posición inicial del nombre. (13)

Toma el número de carácter del tercer espacio hallado en el paso 6 y resta el número de carácter de “J” hallado en el paso 7. El resultado es el número de caracteres que la función EXTRAE extrae de la cadena de texto empezando en la duodécima posición hallada en el paso 4. (16 -13 = 3)

Segundo nombre

El segundo nombre empieza en el segundo carácter de la derecha (A). La fórmula extrae dos caracteres desde la derecha.

Fórmula para extraer el segundo nombre del ejemplo 8: Iñárritu, Juan L.

Utiliza funciones BUSCAR anidadas para buscar el valor de núm_caracteres:

Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (6)

Agrega 1 para obtener el carácter situado detrás del primer espacio (F). El resultado es el número de carácter en el que desea iniciar la búsqueda del segundo espacio. (7 + 1 = 8)

Busca el segundo espacio en A2, empezando desde la octava posición (F) hallada en el paso 2. (12)

Agrega 1 para obtener el carácter situado detrás del segundo espacio (J). El resultado es la posición inicial del nombre. (12 + 1 = 13)

Busca la posición numérica del tercer espacio en A2, empezando desde la izquierda. El resultado es la posición final del segundo nombre. (16)

Cuenta la longitud total de la cadena de texto en A2 y después resta el número de caracteres desde la izquierda hasta el tercer espacio hallado en el paso 5. El resultado es el número de caracteres que se van a extraer desde la derecha del nombre completo. (17 - 15 = 2)

Apellido

El apellido comienza en el primer carácter de la izquierda (T) y termina en el séptimo carácter (el primer espacio). Por tanto, la fórmula extrae siete caracteres desde la izquierda.

Fórmula para extraer el apellido del ejemplo 8: Iñárritu, Juan L.

Utiliza la función BUSCAR para buscar el valor de núm_caracteres:

Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (7)

Sufijo

El sufijo empieza en el octavo carácter de la izquierda (F) y termina en el noveno carácter de la izquierda (.). La fórmula extrae tres caracteres, empezando desde el octavo carácter.

Fórmula para extraer el sufijo del ejemplo 8: Iñárritu, Juan L.

Utiliza la función BUSCAR para buscar el valor de núm_inicial:

Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (7)

Agrega 1 para obtener el carácter situado detrás del primer espacio (F). El resultado es la posición inicial del sufijo. (7 + 1 = 8)

Utiliza funciones BUSCAR anidadas para buscar el valor de núm_caracteres:

Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (7)

Agrega 1 para obtener la posición numérica del carácter situado detrás del primer espacio (F). El resultado es número de carácter en el que desea iniciar la búsqueda del segundo espacio. (8)

Busca la posición numérica del segundo espacio en A2, empezando desde el octavo carácter hallado en el paso 4. (12)

Resta 1 del número de carácter del segundo espacio hallado en el paso 4 para obtener el número de carácter de “,”. El resultado es la posición final del sufijo. (12 - 1 = 11)

Busca la posición numérica del carácter situado detrás del primer espacio (F), hallada también en los pasos 3 y 4. (8)

Busca la posición numérica del carácter situado detrás del primer espacio (F), hallada también en los pasos 3 y 4. (8)

Toma el número de carácter de “,” hallado en el paso 6 y resta el número de carácter de “F” hallado en los pasos 3 y 4. El resultado es el número de caracteres que la función EXTRAE extrae de la cadena de texto empezando en la séptima posición hallada en el paso 2. (11 - 8 = 3)

Principio de página

Ejemplo 9: Íker Arteaga III

En este ejemplo, el nombre está al principio de la cadena y el sufijo está al final del nombre. La fórmula que se utiliza para los componentes del nombre es similar a la del Ejemplo 2, en el que el nombre se extrae mediante la función IZQUIERDA, el apellido se extrae mediante la función EXTRAE y el sufijo se extrae mediante la función DERECHA.

1

2

A

B

C

D

Nombre

Nombre (Gary)

Apellido (Arteaga)

Sufijo (III)

Íker Arteaga III

=IZQUIERDA(A2, HALLAR(" ",A2,1))

=EXTRAE(A2,HALLAR(" ",A2,1)+1,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)-(HALLAR(" ",A2,1)+1))

=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,HALLAR(" ",A2,1)+1))

En los gráficos siguientes, la parte resaltada del nombre completo indica el carácter del que la fórmula BUSCAR busca coincidencias.

Nombre

El nombre comienza en el primer carácter de la izquierda (I) y termina en el quinto carácter (el primer espacio). Por tanto, la fórmula extrae cinco caracteres desde la izquierda del nombre completo.

Fórmula para separar nombre, apellido y tratamiento

Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (5)

Apellido

El apellido comienza en el sexto carácter de la izquierda (A) y termina en el undécimo carácter (el segundo espacio). Esta fórmula incluye funciones HALLAR anidadas para buscar las posiciones de los espacios.

La fórmula extrae seis caracteres del medio, empezando desde el sexto carácter.

Fórmula para separar nombre, apellido y tratamiento

Utiliza la función BUSCAR para buscar el valor de núm_inicial:

Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (5)

Agrega 1 para obtener la posición del carácter situado detrás del primer espacio (A). El resultado es la posición inicial del apellido. (5 + 1 = 6)

Utiliza funciones BUSCAR anidadas para buscar el valor de núm_caracteres:

Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (5)

Agrega 1 para obtener la posición del carácter situado detrás del primer espacio (A). El resultado es el número de carácter en el que desea iniciar la búsqueda del segundo espacio. (5 + 1 = 6)

Busca la posición numérica del segundo espacio en A2, empezando desde el sexto carácter hallado en el paso 4. Este número de carácter es la posición final del apellido. (13)

Busca la posición numérica del carácter situado detrás del primer espacio (A), hallada también en los pasos 3 y 4. (6)

Busca la posición numérica del carácter situado detrás del primer espacio (A), hallada también en los pasos 3 y 4. (6)

Toma el número de carácter del segundo espacio hallado en el paso 5 y, a continuación, resta el número de carácter de “A” hallado en los pasos 6 y 7. El resultado es el número de caracteres que la función EXTRAE extrae de la cadena de texto empezando en la sexta posición hallada en el paso 2. (13 - 7 = 6)

Sufijo

El sufijo comienza en el tercer carácter de la derecha. Esta fórmula incluye funciones HALLAR anidadas para buscar las posiciones de los espacios.

Fórmula para separar nombre, apellido y tratamiento

Utiliza funciones BUSCAR anidadas y las funciones LARGO para buscar el valor de núm_caracteres:

Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (5)

Agrega 1 para obtener el carácter situado detrás del primer espacio (A). El resultado es el número de carácter en el que desea iniciar la búsqueda del segundo espacio. (5 + 1 = 6)

Busca el segundo espacio en A2, empezando desde la sexta posición (A) hallada en el paso 2. (12)

Cuenta la longitud total de la cadena de texto en A2 y después resta el número de caracteres desde la izquierda hasta el segundo espacio hallado en el paso 3. El resultado es el número de caracteres que se van a extraer desde la derecha del nombre completo. (15 -12 = 3)

Principio de página

Ejemplo 10: Sr. Ángel Valádez

En este ejemplo, el nombre completo está precedido por un prefijo. Las fórmulas que se utilizan para los componentes del nombre son similares a las del ejemplo 2, en las que el nombre se extrae mediante la función EXTRAE y el apellido se extrae mediante la función DERECHA.

1

2

A

B

C

Nombre

Nombre (Ángel)

Apellido ( Valádez )

Sr. Ángel Valádez

=EXTRAE(A2,HALLAR(" ",A2,1)+1,HALLAR(" ",A2,HALLAR(" ",A2,1)+1)-(HALLAR(" ",A2,1)+1))

=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,HALLAR(" ",A2,1)+1))

En los gráficos siguientes, la parte resaltada del nombre completo indica el carácter del que la fórmula BUSCAR busca coincidencias.

Nombre

El nombre comienza en el quinto carácter de la izquierda (T) y termina en el décimo carácter (el segundo espacio). Esta fórmula incluye funciones HALLAR anidadas para buscar las posiciones de los espacios.

La fórmula extrae cuatro caracteres, empezando desde la quinta posición.

Fórmula para extraer el nombre del ejemplo 10: Sr. Tomás Navarro

Utiliza la función BUSCAR para buscar el valor de núm_inicial:

Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (4)

Agrega 1 para obtener la posición del carácter situado detrás del primer espacio (T). El resultado es la posición inicial del nombre. (4 + 1 = 5)

Utiliza funciones BUSCAR anidadas para buscar el valor de núm_caracteres:

Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (4)

Agrega 1 para obtener la posición del carácter situado detrás del primer espacio (T). El resultado es el número de carácter en el que desea iniciar la búsqueda del segundo espacio. (4 + 1 = 5)

Busca la posición numérica del segundo espacio en A2, empezando desde el quinto carácter hallado en los pasos 3 y 4. Este número de carácter es la posición final del nombre. (10)

Busca la posición numérica del carácter situado detrás del primer espacio (T), hallada también en los pasos 3 y 4. (5)

Busca la posición numérica del carácter situado detrás del primer espacio (T), hallada también en los pasos 3 y 4. (5)

Toma el número de carácter del segundo espacio hallado en el paso 5 y, a continuación, resta el número de carácter de “T” hallado en los pasos 6 y 7. El resultado es el número de caracteres que la función EXTRAE extrae de la cadena de texto empezando en la quinta posición hallada en el paso 2. (10 - 5 = 5)

Apellido

El apellido comienza en el séptimo carácter de la derecha. Esta fórmula incluye funciones HALLAR anidadas para buscar las posiciones de los espacios.

Fórmula para extraer el apellido del ejemplo 10: Sr. Tomás Navarro

Utiliza funciones BUSCAR anidadas y las funciones LARGO para buscar el valor de núm_caracteres:

Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (4)

Agrega 1 para obtener la posición del carácter situado detrás del primer espacio (T). El resultado es el número de carácter en el que desea iniciar la búsqueda del segundo espacio. (4 + 1 = 5)

Busca el segundo espacio en A2, empezando desde la quinta posición (T) hallada en el paso 2. (10)

Cuenta la longitud total de la cadena de texto en A2 y después resta el número de caracteres desde la izquierda hasta el segundo espacio hallado en el paso 3. El resultado es el número de caracteres que se van a extraer desde la derecha del nombre completo. (14 -9 = 5)

Principio de página

Ejemplo 11: Leticia Terrazas-Núñez

En este ejemplo, el apellido contiene un guión. Cada componente del nombre está separado por un espacio.

1

2

A

B

C

Nombre

Nombre (Leticia)

Apellido (Terrazas-Núñez)

Leticia Terrazas-Núñez

=IZQUIERDA(A2, HALLAR(" ",A2,1))

=DERECHA(A2,LARGO(A2)-HALLAR(" ",A2,1))

En los gráficos siguientes, la parte resaltada del nombre completo indica el carácter del que la fórmula BUSCAR busca coincidencias.

Nombre

El nombre comienza en el primer carácter de la izquierda y termina en la décima posición (el primer espacio). La fórmula extrae diez caracteres desde la izquierda.

Fórmula para extraer el nombre del ejemplo 11: Francisco Pérez-Olaeta

Utiliza la función BUSCAR para buscar el valor de núm_caracteres:

Busca la posición numérica del primer espacio en A2, empezando desde la izquierda. (7)

Apellido

El apellido completo comienza en el duodécimo carácter desde la derecha (T) y termina en el primer carácter de la derecha (z).

Fórmula para extraer el apellido del ejemplo 11: Francisco Pérez-Olaeta

Utiliza las funciones LARGO y BUSCAR para buscar el valor de núm_caracteres:

Busca la posición numérica del espacio en A2, empezando desde el primer carácter de la izquierda. (10)

Cuenta la longitud total de la cadena de texto que se va a extraer y después resta el número de caracteres desde la izquierda al primer espacio, según el resultado del paso 1. (22 - 10 = 12)

Principio de página

¿Le ha sido útil esta información?

De acuerdo. ¿Algún comentario más?

¿Cómo podemos mejorarlo?

¡Gracias por sus comentarios!

×