Use VLOOKUP, one of the lookup and reference functions, when you need to find things in a table or a range by row. For example, look up an employee's last name by her employee number, or find her phone number by looking up her last name (just like a telephone book).
This video is part of a training course called VLOOKUP: When and how to use it.
Tip: The secret to VLOOKUP is to organize your data so that the value you look up (employee’s last name) is to the left of the return value you want to find (employee’s phone number).
Syntax
VLOOKUP (lookup_value, table_array, col_index_num, [range_lookup])
For example:

=VLOOKUP(105,A2:C7,2,TRUE)

=VLOOKUP("Fontana",B2:E7,2,FALSE)
Argument name 
Description 
lookup_value (required) 
The value you want to look up. The value you want to look up must be in the first column of the range of cells you specify in tablearray . For example, if tablearray spans cells B2:D7, then your lookup_value must be in column B. See the graphic below. Lookup_value can be a value or a reference to a cell. 
table_array (required) 
The range of cells in which the VLOOKUP will search for the lookup_value and the return value. The first column in the cell range must contain the lookup_value (for example, Last Name in the picture below.) The cell range also needs to include the return value (for example, First Name in the graphic below) you want to find. Learn how to select ranges in a worksheet. 
col_index_num (required) 
The column number (starting with 1 for the leftmost column of tablearray) that contains the return value. 
range_lookup (optional) 
A logical value that specifies whether you want VLOOKUP to find an exact match or an approximate match:

The following picture shows how you'd set up your worksheet with =VLOOKUP("Akers",B2:D5,2,FALSE) to return Kim.
Examples
To use these examples in Excel, copy the data in the table below, and paste it in cell A1 of a new worksheet.
ID 
Last name 
First name 
Title 
Birth date 
101 
Davis 
Sara 
Sales Rep. 
12/8/1968 
102 
Fontana 
Olivier 
V.P. of Sales 
2/19/1952 
103 
Leal 
Karina 
Sales Rep. 
8/30/1963 
104 
Patten 
Michael 
Sales Rep. 
9/19/1958 
105 
Burke 
Brian 
Sales Mgr. 
3/4/1955 
106 
Sousa 
Luis 
Sales Rep. 
7/2/1963 
Now paste the following table below the data. This table contains VLOOKUP formulas in the first column, and a description of how the formula works in the second column.
Formula 
Description 
=VLOOKUP("Fontana",B2:E7,2,FALSE) 
Looks for the value Fontana in the first column (column B) of table_array B2:E7 and returns the value Olivier found in the second column (Column C) of the table_array. The range_lookup FALSE returns an exact match. 
=VLOOKUP(102,A2:C7,2,FALSE) 
Searches for an exact match of the last name for lookup_value102 in column A. Fontana is returned. If lookup_value is 105, Burke is returned. 
=IF(VLOOKUP(103,A1:E7,2,FALSE)="Sousa","Located","Not found") 
Checks to see if the last name of Employee with ID 103 is Sousa. Uses the IF function to return one value if a condition is true and another value if it's false. Because 103 is actually Leal, the result is Not found. If you change "Sousa" to "Leal" in the formula, the result is Located. 
=INT(YEARFRAC(DATE(2014,6,30), VLOOKUP(105,A2:E7,5, FALSE), 1)) 
For the fiscal year 2014, finds the age of the employee with ID 105. Uses the YEARFRAC function to subtract the birth date from the fiscal year end date and displays the result 59 as an integer using the INT function. 
=IF(ISNA(VLOOKUP(105,A2:E7,2,FALSE)) = TRUE, "Employee not found", VLOOKUP(105,A2:E7,2,FALSE)) 
If there is an employee with ID 105, displays the employee's last name, which is Burke. Otherwise, displays the message Employee not found. The ISNA function (see IS functions) returns a TRUE value when the VLOOKUP function returns the #N/A error value. 
Common Problems
Problem 
What went wrong 
Wrong value returned 
If range_lookup is TRUE or left out, the first column needs to be sorted alphabetically or numerically. If the first column isn't sorted, the return value might be something you don't expect. Either sort the first column, or use FALSE for an exact match. 
#N/A in cell 
Learn more about errors in worksheets, like #N/A, #REF, and the rest. 
#REF! in cell 
If col_index_num is greater than the number of columns in tablearray, you'll get the #REF! error value. 
#VALUE! in cell 
If the table_array is less than 1, you'll get the #VALUE! error value. 
#NAME? in cell 
The #NAME? error value usually means that the formula is missing quotes. To look up a person's name, make sure you use quotes around the name in the formula. For example, enter the name as "Fontana" in =VLOOKUP("Fontana",B2:E7,2,FALSE). 
Best practices
Do this 
Why 
Use absolute references for range_lookup 
Using absolute references allows you to filldown a formula so that it always looks at the same exact lookup range. Learn how to use absolute cell references. 
Don't store number or date values as text. 
When searching number or date values, be sure the data in the first column of table_array isn't stored as text values. Otherwise, VLOOKUP might return an incorrect or unexpected value. 
Sort the first column 
Sort the first column of the table_array before using VLOOKUP when range_lookup is TRUE. 
Use wildcard characters 
If range_lookup is FALSE and lookup_value is text, you can use the wildcard characters—the question mark (?) and asterisk (*)—in lookup_value. A question mark matches any single character. An asterisk matches any sequence of characters. If you want to find an actual question mark or asterisk, type a tilde (~) in front of the character. For example, =VLOOKUP("Fontan?",B2:E7,2,FALSE) will search for all instances of Fontana with a last letter that could vary. 
Make sure your data doesn't contain erroneous characters. 
When searching text values in the first column, make sure the data in the first column doesn't have leading spaces, trailing spaces, inconsistent use of straight ( ' or " ) and curly ( ‘ or “) quotation marks, or nonprinting characters. In these cases, VLOOKUP might return an unexpected value. To get accurate results, try using the CLEAN function or the TRIM function to remove trailing spaces after table values in a cell. 
Related

View Quick Reference Card: VLOOKUP refresher for a refresher on best ways to use VLOOKUP to look up data in tables.

Learn how to create or change a cell reference.

Learn how to sort data in a table alphabetically or numerically.

VLOOKUP is a member of the lookup and reference functions, which includes the HLOOKUP function.

Use the CLEAN function or the TRIM function to remove leading spaces in table values.

Use the SUMIF function to sum the values in a range that meet criteria that you specify.