Μάθετε περισσότερα σχετικά με τη συνάρτηση SUM

Εάν θέλετε να βρείτε γρήγορα το άθροισμα μιας περιοχής κελιών, το μόνο που χρειάζεται να κάνετε είναι να επιλέξετε την περιοχή και να κοιτάξετε στην κάτω δεξιά πλευρά του παραθύρου του Excel.

Αυτή είναι η γραμμή κατάστασης και εμφανίζει πληροφορίες σχετικά με ό,τι έχετε επιλέξει, είτε πρόκειται για ένα μεμονωμένο κελί είτε για πολλά κελιά. Εάν κάνετε δεξιό κλικ στη γραμμή κατάστασης, θα εμφανιστεί ένα παράθυρο διαλόγου με όλες τις επιλογές που μπορείτε να ενεργοποιήσετε. Λάβετε υπόψη ότι εμφανίζει επίσης τιμές για την επιλεγμένη περιοχή, εάν έχετε επιλέξει αυτά τα χαρακτηριστικά. 

Ο ευκολότερος τρόπος για να προσθέσετε έναν τύπο SUM στο φύλλο εργασίας σας είναι να χρησιμοποιήσετε τον οδηγό Αυτόματης Άθροισης. Επιλέξτε ένα κενό κελί απευθείας επάνω ή κάτω από την περιοχή που θέλετε να αθροίσετε και στις καρτέλες "Κεντρική" ή "Τύπος" στην κορδέλα, πατήστε Αυτόματη Άθροιση > Άθροισμα. Ο οδηγός Αυτόματης Άθροισης θα ανιχνεύσει αυτόματα την περιοχή που θέλετε να αθροίσετε και θα δημιουργήσει τον τύπο για εσάς. Μπορεί επίσης να λειτουργήσει οριζόντια, εάν επιλέξετε ένα κελί προς τα αριστερά ή προς τα δεξιά της περιοχής που θέλετε να αθροίσετε. Λάβετε υπόψη ότι δεν πρόκειται να λειτουργήσει σε μη συνεχόμενες περιοχές, αλλά αυτό θα το εξετάσουμε στην επόμενη ενότητα.

Το παράθυρο διαλόγου "Αυτόματη Άθροιση" σάς επιτρέπει επίσης να επιλέξετε άλλες κοινές συναρτήσεις, όπως:

• Μέσος όρος

• Καταμέτρηση αριθμών

• Μέγιστο

• Ελάχιστο

• Περισσότερες συναρτήσεις

Αυτόματη Άθροιση κατακόρυφα

Ο οδηγός Αυτόματης Άθροισης εντόπισε αυτόματα τα κελιά B2:B5 ως την περιοχή προς άθροιση. Το μόνο που χρειάζεται να κάνετε είναι να πατήσετε το πλήκτρο Enter για επιβεβαίωση. Εάν χρειάζεται να προσθέσετε ή να εξαιρέσετε περισσότερα κελιά, μπορείτε να κρατήσετε πατημένο το πλήκτρο Shift > πλήκτρο βέλους της επιλογής σας μέχρι η επιλογή σας να συμφωνεί με αυτό που θέλετε και να πατήσετε το πλήκτρο Enter όταν είστε έτοιμοι.

Οδηγός συναρτήσεων Intellisense: the SUM(αριθμός1;[αριθμός2]; ...) Κινητή ετικέτα κάτω από τη συνάρτηση είναι ο οδηγός Intellisense. Εάν κάνετε κλικ στο όνομα της συνάρτησης SUM, θα μετατραπεί σε μπλε υπερ-σύνδεση, η οποία θα σας μεταφέρει στο θέμα της Βοήθειας για τη συγκεκριμένη συνάρτηση. Εάν κάνετε κλικ στα μεμονωμένα στοιχεία της συνάρτησης, τα αντιπροσωπευτικά τμήματά τους στον τύπο θα επισημανθούν. Σε αυτή την περίπτωση, μόνο Η διαδρομή B2:B5 επισημαίνεται, εφόσον υπάρχει μόνο μία αναφορά αριθμού σε αυτόν τον τύπο. Η ετικέτα Intellisense θα εμφανιστεί για οποιαδήποτε συνάρτηση.

Αυτόματη Άθροιση οριζόντια

Ο οδηγός Αυτόματης Άθροισης λειτουργεί σε γενικές γραμμές μόνο για συνεχόμενες περιοχές, επομένως εάν έχετε κενές γραμμές ή στήλες στην περιοχή αθροίσματος, το Excel θα σταματήσει στο πρώτο κενό. Σε αυτή την περίπτωση θα πρέπει να χρησιμοποιήσετε τη συνάρτηση SUM με βάση την επιλογή, όπου θα προσθέσετε τις μεμονωμένες περιοχές μία προς μία. Σε αυτό το παράδειγμα, αν είχατε δεδομένα στο κελί B4, το Excel θα δημιουργούσε τον τύπο =SUM(C2:C6) , καθώς θα αναγνώριζε μια συνεχόμενη περιοχή.

Μπορείτε να επιλέξετε γρήγορα πολλές, μη συνεχόμενες περιοχές με το συνδυασμό Ctrl+αριστερού κλικ. Πρώτα, εισαγάγετε "=SUM(", στη συνέχεια, επιλέξτε τις διαφορετικές περιοχές και το Excel θα προσθέσει αυτόματα το διαχωριστικό ελληνικό ερωτηματικό μεταξύ περιοχών για εσάς. Πατήστε το πλήκτρο Enter, όταν ολοκληρώσετε τη διαδικασία.

ΣΥΜΒΟΥΛΗ: Μπορείτε να χρησιμοποιήσετε το συνδυασμό πλήκτρων ALT+ = για να προσθέσετε γρήγορα τη συνάρτηση SUM σε ένα κελί. Στη συνέχεια, το μόνο που χρειάζεται να κάνετε είναι να επιλέξετε τις περιοχές σας.

Σημείωση: Ενδέχεται να παρατηρήσετε πώς το Excel έχει επισημάνει τις διάφορες περιοχές συναρτήσεων κατά χρώμα και συμφωνούν μέσα στον ίδιο τον τύπο, επομένως η περιοχή C2:C3 είναι ένα χρώμα και η περιοχή C5:C6 είναι ένα άλλο. Το Excel θα το κάνει αυτό για όλες τις συναρτήσεις, εκτός εάν η περιοχή αναφοράς βρίσκεται σε διαφορετικό φύλλο εργασίας ή σε διαφορετικό βιβλίο εργασίας. Για βελτιωμένη προσβασιμότητα με τεχνολογία υποβοήθησης, μπορείτε να χρησιμοποιήσετε καθορισμένες περιοχές, όπως "Εβδομάδα1", "Εβδομάδα2" κ.λπ. και, στη συνέχεια, να τις αναφέρετε στον τύπο σας:

=SUM(Εβδομάδα1;Εβδομάδα2)

1. Μπορείτε να χρησιμοποιήσετε τη συνάρτηση SUM με άλλες συναρτήσεις. Ακολουθεί ένα παράδειγμα που δημιουργεί έναν υπολογισμό μηνιαίου μέσου όρου:

   

   • =SUM(A2:L2)/COUNTA(A2:L2)

2. Το οποίο διαιρεί το άθροισμα των A2:L2 με το πλήθος των μη κενών κελιών στην περιοχή A2:L2 (τα κελιά από τον Μάιο έως τον Δεκέμβριο είναι κενά).

1. Μερικές φορές πρέπει να αθροίσετε ένα συγκεκριμένο κελί σε πολλά φύλλα εργασίας. Μπορεί να μπείτε στον πειρασμό να κάνετε κλικ σε κάθε φύλλο και στο κελί που θέλετε και απλώς να χρησιμοποιήσετε το "+" για να αθροίσετε τις τιμές των κελιών, αλλά αυτή η μέθοδος είναι χρονοβόρα και είναι πιθανό να παρουσιάσει σφάλμα.

   • =Φύλλο1!A1+Φύλλο2!A1+Φύλλο3!A1

   Μπορείτε να επιτύχετε αυτό το αποτέλεσμα πολύ πιο εύκολα με 3D ή τρισδιάστατο SUM:

   

   • =SUM(Φύλλο1:Φύλλο3!A1)

   Το οποίο θα αθροίσει το κελί A1 σε όλα τα φύλλα από το Φύλλο 1 έως το Φύλλο 3.

   Αυτό είναι ιδιαίτερα χρήσιμο στις περιπτώσεις όπου έχετε ένα μεμονωμένο φύλλο για κάθε μήνα (Ιανουάριος-Δεκέμβριος) και πρέπει να τους αθροίσετε σε ένα φύλλο σύνοψης.

   

   • =SUM(Ιανουάριος:Δεκέμβριος!A2)

   Το οποίο θα αθροίσει το κελί A2 σε κάθε φύλλο από τον Ιανουάριο έως το Δεκέμβριο.

   Σημειώσεις: Εάν τα φύλλα εργασίας σας έχουν κενά διαστήματα στα ονόματά τους, όπως "Πωλήσεις Ιανουαρίου", πρέπει να χρησιμοποιήσετε απόστροφο κατά την αναφορά στα ονόματα φύλλων σε έναν τύπο. Παρατηρήστε την απόστροφο ΠΡΙΝ από το πρώτο όνομα φύλλου εργασίας και πάλι ΜΕΤΑ το τελευταίο.

   • =SUM(‘Πωλήσεις Ιανουαρίου:Πωλήσεις Δεκεμβρίου’!A2)

   Η μέθοδος 3D λειτουργεί επίσης και με άλλες συναρτήσεις, όπως οι AVERAGE, MIN, MAX, κ.λπ.:

   • =AVERAGE(Φύλλο1:Φύλλο3!A1)

   • =MIN(Φύλλο1:Φύλλο3!A1)

   • =MAX(Φύλλο1:Φύλλο3!A1)

Μπορείτε να πραγματοποιήσετε εύκολα μαθηματικές πράξεις με το Excel, μεμονωμένα και σε συνδυασμό με συναρτήσεις του Excel, όπως η συνάρτηση SUM. Στον παρακάτω πίνακας παρατίθενται οι τελεστές που μπορείτε να χρησιμοποιήσετε, καθώς και ορισμένες σχετικές συναρτήσεις. Μπορείτε να εισαγάγετε τους τελεστές είτε από τη γραμμή αριθμών στο πληκτρολόγιό σας ή από το αριθμητικό πληκτρολόγιο 10 πλήκτρων, αν διαθέτετε. Για παράδειγμα, ο συνδυασμός πλήκτρων Shift+8 εισάγει τον αστερίσκο (*) για πολλαπλασιασμό.

Τελεστής	Λειτουργία	Παραδείγματα
+	Πρόσθεση	=1+1 =A1+B1 =SUM(A1:A10)+10 =SUM(A1:A10)+B1
-	Αφαίρεση	=1-1 =A1-B1 =SUM(A1:A10)-10 =SUM(A1:A10)-B1
*	Πολλαπλασιασμός	=1*1 =A1*B1 =SUM(A1:A10)*10 =SUM(A1:A10)*B1 =PRODUCT(1,1) - Συνάρτηση PRODUCT
/	Διαίρεση	=1/1 =A1/B1 =SUM(A1:A10)/10 =SUM(A1:A10)/B1 =QUOTIENT(1,1) - Συνάρτηση QUOTIENT
^	Ύψωση σε δύναμη	=1^1 =A1^B1 =SUM(A1:A10)^10 =SUM(A1:A10)^B1 =POWER(1,1) - Συνάρτηση POWER

Για περισσότερες πληροφορίες, ανατρέξτε στο θέμα Χρήση του Excel ως αριθμομηχανής.

Άλλα παραδείγματα

1. Ας υποθέσουμε ότι θέλετε να εφαρμόσετε ένα ποσοστό έκπτωσης σε μια περιοχή κελιών που έχετε αθροίσει.

   

   • =SUM(A2:A14)*-25%

   Θα επέστρεφε το 25% του αθροίσματος της περιοχής, ωστόσο με αυτόν τρόπο το 25% θα ενσωματωνόταν στον κώδικα του τύπου και θα ήταν ίσως δύσκολο να το βρείτε αργότερα, εάν χρειαζόταν να το αλλάξετε. Είναι προτιμότερο να τοποθετήσετε το 25% σε ένα κελί και να αναφερθείτε σε αυτό, όπου είναι εμφανές και είναι εύκολο να αλλάξει, ως εξής:

   • =SUM(A2:A14)*E2

   Για να διαιρέσετε αντί να πολλαπλασιάσετε, απλώς αντικαταστήστε το "*" με "/": =SUM(A2:A14)/E2

2. Πρόσθεση ή αφαίρεση από μια συνάρτηση SUM

   i. Μπορείτε να προσθέσετε ή να αφαιρέσετε εύκολα από ένα άθροισμα χρησιμοποιώντας τα σύμβολα + ή - ως εξής:

   • =SUM(A1:A10)+E2

   • =SUM(A1:A10)-E2