Η συνάρτηση TEXT σάς επιτρέπει να αλλάξετε τον τρόπο εμφάνισης ενός αριθμού μέσω της εφαρμογής μορφοποίησης με κωδικούς μορφής. Είναι χρήσιμη σε περιπτώσεις όπου θέλετε να εμφανίσετε αριθμούς σε πιο ευανάγνωστη μορφή ή θέλετε να συνδυάσετε αριθμούς με κείμενο ή σύμβολα.
Σημείωση: Η συνάρτηση TEXT μετατρέπει τους αριθμούς σε κείμενο, γεγονός που μπορεί να δυσχεράνει την αναφορά σε μεταγενέστερους υπολογισμούς. Είναι καλύτερα να διατηρήσετε την αρχική τιμή σε ένα κελί και, στη συνέχεια, να χρησιμοποιήσετε τη συνάρτηση TEXT σε άλλο κελί. Στη συνέχεια, εάν θέλετε να δημιουργήσετε άλλους τύπους, πάντα να αναφέρετε την αρχική τιμή και όχι το αποτέλεσμα της συνάρτησης TEXT.
Σύνταξη
TEXT(τιμή; μορφοποίηση_κειμένου)
Η σύνταξη της συνάρτησης TEXT περιλαμβάνει τα παρακάτω ορίσματα:
|
Όνομα ορίσματος |
Περιγραφή |
|
τιμή |
Μια αριθμητική τιμή που θέλετε να μετατραπεί σε κείμενο. |
|
μορφή_κειμένου |
Μια συμβολοσειρά κειμένου που καθορίζει τη μορφοποίηση που θέλετε να εφαρμοστεί στην τιμή που παρέχεται. |
Επισκόπηση
Στην απλούστερη μορφή της, η συνάρτηση TEXT έχει ως εξής:
-
=TEXT(Τιμή που θέλετε να μορφοποιήσετε; "Κωδικός μορφής που θέλετε να εφαρμόσετε")
Εδώ θα βρείτε ορισμένα δημοφιλή παραδείγματα, τα οποία μπορείτε να αντιγράψετε απευθείας στο Excel για να πειραματιστείτε μόνοι σας. Σημειώστε ότι οι κωδικοί μορφής περικλείονται σε εισαγωγικά.
|
Τύπος |
Περιγραφή |
|---|---|
|
=TEXT(1234,567;"#.##0,00 €") |
Νομισματική μονάδα με διαχωριστικό χιλιάδων και 2 δεκαδικά ψηφία, όπως 1.234,57 €. Σημειώστε ότι το Excel στρογγυλοποιεί την τιμή στα 2 δεκαδικά ψηφία. |
|
=TEXT(TODAY();"ΗΗ/ΜΜ/ΕΕ") |
Η τρέχουσα ημερομηνία σε μορφή ΗΗ/ΜΜ/ΕΕ, όπως 14/03/12 |
|
=TEXT(TODAY();"ΗΗΗΗ") |
Η σημερινή ημέρα της εβδομάδας, όπως Δευτέρα |
|
=TEXT(NOW();"Ω:ΛΛ ΠΜ/ΜΜ") |
Η τρέχουσα ώρα, όπως 1:29 ΜΜ |
|
=TEXT(0,285;"0,0%") |
Ποσοστό, όπως 28,5% |
|
=TEXT(4,34 ;"# ?/?") |
Κλάσμα, όπως 4 1/3 |
|
=TRIM(TEXT(0,34;"# ?/?")) |
Κλάσμα, όπως 1/3. Λάβετε υπόψη ότι αυτός ο τύπος χρησιμοποιεί τη συνάρτηση TRIM για να καταργήσει το αρχικό κενό διάστημα με μια δεκαδική τιμή. |
|
=TEXT(12200000;"0,00E+00") |
Επιστημονική σημειογραφία, όπως 1,22E+07 |
|
=TEXT(1234567898;"[<=9999999]###-####,(###) ###-####") |
Ειδικού τύπου (Αριθμός τηλεφώνου), όπως (123) 456-7898 |
|
=TEXT(1234;"0000000") |
Προσθήκη αρχικών μηδενικών (0), όπως 0001234 |
|
=TEXT(123456;"##0° 00' 00''") |
Προσαρμοσμένο - Γεωγραφικό πλάτος/μήκος |
Σημείωση: Παρόλο που μπορείτε να χρησιμοποιήσετε τη συνάρτηση TEXT για να αλλάξετε τη μορφή, αυτός δεν είναι ο μόνος τρόπος. Μπορείτε να αλλάξετε τη μορφή χωρίς τύπο, πατώντας το συνδυασμό πλήκτρων CTRL+1 (ή 
Λήψη των παραδειγμάτων μας
Μπορείτε να πραγματοποιήσετε λήψη ενός παραδείγματος βιβλίου εργασίας με όλα τα παραδείγματα της συνάρτησης TEXT που θα βρείτε σε αυτό το άρθρο, συν ορισμένα επιπλέον. Μπορείτε να τα ακολουθήσετε ή να δημιουργήσετε τους δικούς σας κωδικούς μορφής της συνάρτησης TEXT.
Λήψη παραδειγμάτων συνάρτησης TEXT στο Excel
Άλλοι διαθέσιμοι κωδικοί μορφής
Μπορείτε να χρησιμοποιήσετε το παράθυρο διαλόγου Μορφοποίηση κελιών για να βρείτε τους άλλους διαθέσιμους κωδικούς μορφής:
-
Πατήστε το συνδυασμό πλήκτρων Ctrl+1 (
-
Επιλέξτε τη μορφή που θέλετε από την καρτέλα Αριθμός .
-
Επιλέξτε Προσαρμογή .
-
Ο κωδικός μορφής που θέλετε εμφανίζεται τώρα στο πλαίσιο Τύπος. Σε αυτή την περίπτωση, επιλέξτε τα πάντα, από το πλαίσιο Τύπος, εκτός από το κόμμα (,) και το σύμβολο @. Στο παρακάτω παράδειγμα, επιλέξαμε και αντιγράψαμε μόνο το τμήμα ηη/μμ/εε.
-
Πατήστε το συνδυασμό πλήκτρων Ctrl+C για να αντιγράψετε τον κωδικό μορφής και, στη συνέχεια, πατήστε το πλήκτρο Άκυρο για να κλείσετε το παράθυρο διαλόγου Μορφοποίηση κελιών .
-
Τώρα, το μόνο που πρέπει να κάνετε είναι να πατήσετε Ctrl+V για να επικολλήσετε τον κωδικό μορφής στο τύπο TEXT, όπως: =TEXT(B2;"ηη/μμ/εε"). Βεβαιωθείτε ότι έχετε επικολλήσει τον κωδικό μορφής μέσα σε εισαγωγικά ("κωδικός μορφής"), διαφορετικά το Excel θα εμφανίσει ένα μήνυμα σφάλματος.
Κωδικοί μορφής ανά κατηγορία
Ακολουθούν ορισμένα παραδείγματα για το πώς μπορείτε να εφαρμόσετε διαφορετικές μορφές αριθμών στις τιμές σας χρησιμοποιώντας το παράθυρο διαλόγου Μορφοποίηση κελιών και, στη συνέχεια, να χρησιμοποιήσετε την επιλογή Προσαρμογή για να αντιγράψετε αυτούς τους κωδικούς μορφής στη συνάρτηση TEXT .
Γιατί το Excel διαγράφει τα αρχικά μηδενικά (0);
Το Excel είναι εκπαιδευμένο να πραγματοποιεί αναζήτηση για αριθμούς που έχουν καταχωρηθεί σε κελιά και όχι για αριθμούς που μοιάζουν με κείμενο, όπως τμήματα αριθμών ή SKU. Για να διατηρήσετε τα μηδενικά στην αρχή, μορφοποιήστε την περιοχή εισαγωγής ως "Κείμενο" πριν επικολλήσετε ή εισαγάγετε τις τιμές. Επιλέξτε τη στήλη ή την περιοχή όπου πρόκειται να τοποθετηθούν οι τιμές, στη συνέχεια, πατήστε CTRL+1 για να εμφανιστεί το παράθυρο διαλόγου Μορφοποίηση > Κελιά και, στην καρτέλα "Αριθμός" επιλέξτε Κείμενο. Τώρα το Excel θα διατηρεί τα αρχικά μηδενικά (0).
Εάν έχετε εισαγάγει ήδη δεδομένα και το Excel έχει καταργήσει τα μηδενικά (0) στην αρχή, μπορείτε να χρησιμοποιήσετε τη συνάρτηση TEXT για να τα προσθέσετε ξανά. Μπορείτε να κάνετε αναφορά στο επάνω κελί με τις τιμές, να χρησιμοποιήσετε τον τύπο =TEXT(τιμή;"00000"), όπου ο αριθμός των (0) στον τύπο αντιπροσωπεύει τον συνολικό αριθμό χαρακτήρων που θέλετε και, στη συνέχεια, να κάνετε αντιγραφή και επικόλληση στην υπόλοιπη περιοχή σας.
Εάν για κάποιο λόγο πρέπει να μετατρέψετε ξανά τις τιμές κειμένου σε αριθμούς, μπορείτε να τις πολλαπλασιάσετε επί 1, όπως =D4*1 ή να χρησιμοποιήσετε τον διπλό μοναδιαίο τελεστή (--), όπως =--D4.
Το Excel διαχωρίζει τις χιλιάδες με τελείες εάν η μορφή περιέχει μια τελεία (.) που περικλείεται από σύμβολα αριθμού (#) ή από μηδενικά. Για παράδειγμα, εάν η συμβολοσειρά μορφοποίησης είναι "#,###", το Excel εμφανίζει τον αριθμό 12200000 ως 12.200.000.
Μια τελεία που ακολουθεί ένα σύμβολο κράτησης θέσης ψηφίου εμφανίζει τον αριθμό σε χιλιάδες (1.000). Για παράδειγμα, εάν η συμβολοσειρά μορφοποίησης είναι "#.###,0." το Excel εμφανίζει τον αριθμό 12200000 ως 12.200,0.
Σημειώσεις:
-
Το διαχωριστικό χιλιάδων εξαρτάται από τις τοπικές ρυθμίσεις. Στην Ελλάδα είναι μια τελεία, αλλά σε άλλες τοπικές ρυθμίσεις μπορεί να είναι ένα κόμμα (,).
-
Το διαχωριστικό χιλιάδων είναι διαθέσιμο για τις μορφές "Αριθμός", "Νομισματική" και "Λογιστική".
Ακολουθούν παραδείγματα για τις μορφές τυπικού αριθμού (μόνο διαχωριστικό χιλιάδων και δεκαδικών ψηφίων), νομισματικής μονάδας και λογιστικής. Η νομισματική μορφή σας επιτρέπει να εισαγάγετε το σύμβολο νομισματικής μονάδας της επιλογής σας και το στοιχίζει δίπλα την τιμή, ενώ η λογιστική μορφή θα στοιχίσει το σύμβολο νομισματικής μονάδας στα αριστερά του κελιού και την τιμή στα δεξιά. Παρατηρήστε τη διαφορά μεταξύ των κωδικών μορφής νομισματικής μονάδας και λογιστικής παρακάτω, όπου η λογιστική χρησιμοποιεί έναν αστερίσκο (*) για να δημιουργήσει διαχωριστικό ανάμεσα στο σύμβολο και την τιμή.
Για να βρείτε τον κωδικό μορφής για ένα σύμβολο νομισματικής μονάδας, πατήστε πρώτα Ctrl+1 (ή
Στη συνέχεια, κάντε κλικ στην επιλογή Προσαρμογή που βρίσκεται στην ενότητα Κατηγορία στα αριστερά και αντιγράψτε τον κώδικα μορφής, συμπεριλαμβάνοντας το σύμβολο νομισματικής μονάδας.
Σημείωση: Η συνάρτηση TEXT δεν υποστηρίζει μορφοποίηση χρώματος, επομένως, αν αντιγράψετε έναν κωδικό μορφής από το παράθυρο διαλόγου "Μορφοποίηση κελιών" που περιλαμβάνει ένα χρώμα, ως εξής: #.##0,00_€),[Κόκκινο](#.##0,00 €), η συνάρτηση TEXT θα αποδεχτεί αυτό τον κωδικό μορφής, αλλά δεν θα μπορεί να εμφανίσει το χρώμα.
Μπορείτε να αλλάξετε τον τρόπο εμφάνισης μιας ημερομηνίας, χρησιμοποιώντας ένα συνδυασμό των γραμμάτων "Η" για την ημέρα, "Μ" για τον μήνα και "Ε" για το έτος.
Οι κωδικοί μορφής στη συνάρτηση TEXT δεν κάνουν διάκριση πεζών-κεφαλαίων, επομένως, μπορείτε να χρησιμοποιήσετε τα γράμματα "Η" ή "η", "Μ" ή "μ" και "Ε" ή "ε".
|
|
Η Mynda συνιστά... Εάν κάνετε κοινή χρήση αρχείων και αναφορών του Excel με χρήστες από διαφορετικές χώρες/περιοχές, τότε, μπορεί να θέλετε να τους δώσετε μια αναφορά στη δική τους γλώσσα. Η MVP του Excel, Mynda Treacy έχει μια εξαιρετική λύση για αυτή την περίπτωση στο άρθρο Ημερομηνίες του Excel που εμφανίζονται σε διαφορετικές γλώσσες. Περιλαμβάνει επίσης ένα δείγμα βιβλίου εργασίας, του οποίου μπορείτε να κάνετε λήψη. |
Μπορείτε να αλλάξετε τον τρόπο εμφάνισης της ώρας, χρησιμοποιώντας ένα συνδυασμό από τα γράμματα "Ω" για τις ώρες, "Λ" για τα λεπτά ή "Δ" για τα δευτερόλεπτα και "ΠΜ/ΜΜ" για την 12-ωρη μορφή ώρας.
Εάν παραλείψετε την ένδειξη "ΠΜ/ΜΜ" ή "Π/Μ", τότε, η ώρα θα εμφανίζεται στην 24-ωρη μορφή.
Οι κωδικοί μορφής στη συνάρτηση TEXT δεν κάνουν διάκριση πεζών-κεφαλαίων, επομένως, μπορείτε να χρησιμοποιήσετε τα γράμματα "Ω" ή "ω", "Λ" ή "λ", "Δ" ή "δ" και "ΠΜ/ΜΜ" ή "πμ/μμ".
Μπορείτε να αλλάξετε τον τρόπο εμφάνισης των δεκαδικών τιμών με μορφές ποσοστού (%).
Μπορείτε να αλλάξετε τον τρόπο εμφάνισης των δεκαδικών τιμών με μορφές κλασμάτων (?/?).
Η Επιστημονική σημειογραφία είναι ένας τρόπος για την εμφάνιση των αριθμών με τη μορφή δεκαδικών μεταξύ 1 και 10, πολλαπλασιασμένους επί δύναμη του 10. Χρησιμοποιείται συχνά για τη συντόμευση του τρόπου εμφάνισης μεγάλων αριθμών.
Το Excel παρέχει 4 ειδικές μορφές:
-
Ταχυδρομικός κώδικας - "00000"
-
Ταχυδρομικός κώδικας + 4 - "00000-0000"
-
Αριθμός τηλεφώνου - "[<=9999999]###-####,(###) ###-####"
-
Αριθμός κοινωνικής ασφάλισης - "000-00-0000"
Οι ειδικές μορφές θα διαφέρουν ανάλογα με τις τοπικές ρυθμίσεις σας, αλλά εάν δεν υπάρχουν τυχόν ειδικές μορφές για τις τοπικές ρυθμίσεις σας ή εάν αυτές δεν καλύπτουν τις ανάγκες σας, τότε, μπορείτε να δημιουργήσετε δικές σας, από το παράθυρο διαλόγου Μορφοποίηση κελιών > Προσαρμογή.
Συνηθισμένο σενάριο
Η συνάρτηση TEXT σπάνια χρησιμοποιείται αυτόνομα, επειδή συνήθως χρησιμοποιείται σε συνδυασμό με κάτι άλλο. Ας υποθέσουμε ότι θέλετε να συνδυάσετε κείμενο και μια αριθμητική τιμή, όπως "Εκτύπωση αναφοράς στις: 14/03/12" ή "Εβδομαδιαία έσοδα: €66.348,72". Θα μπορούσατε να το πληκτρολογήσετε στο Excel χειροκίνητα, αλλά γιατί να το κάνετε αφού το Excel μπορεί να το κάνει για εσάς; Δυστυχώς, όταν συνδυάζετε κείμενο και μορφοποιημένους αριθμούς, όπως ημερομηνίες, ώρες, νομισματικές μονάδες, κ.λπ., το Excel δεν γνωρίζει πώς θέλετε να τους εμφανίσετε, επομένως, απορρίπτει τη μορφοποίηση αριθμών. Εδώ θα σας φανεί πολύ χρήσιμη η συνάρτηση TEXT, επειδή σας επιτρέπει να επιβάλετε στο Excel να μορφοποιήσει τις τιμές με όποιον τρόπο εσείς θέλετε, χρησιμοποιώντας έναν κωδικό μορφής, όπως το "ΗΗ/ΜΜ/ΕΕ" για τη μορφή ημερομηνίας.
Στο παρακάτω παράδειγμα, θα δείτε τι θα συμβεί εάν προσπαθήσετε να συνδέσετε κείμενο και αριθμό χωρίς να χρησιμοποιήσετε τη συνάρτηση TEXT. Σε αυτή την περίπτωση, χρησιμοποιούμε τον τελεστή εμπορικό "και" (&) για να συνενώσουμε μια συμβολοσειρά κειμένου, ένα κενό διάστημα (" ") και μια τιμή με τον τύπο =A2&" "&B2.
Όπως μπορείτε να δείτε, το Excel κατάργησε τη μορφοποίηση από την ημερομηνία στο κελί B2. Στο επόμενο παράδειγμα, θα δείτε πώς η συνάρτηση TEXT σάς επιτρέπει να εφαρμόσετε τη μορφοποίηση που θέλετε.
Ο ενημερωμένος τύπος είναι:
-
Κελί C2:=A2&" "&TEXT(B2;"ηη/μμ/εε") - Μορφή ημερομηνίας
Συνήθεις ερωτήσεις
Δυστυχώς, δεν μπορείτε να το κάνετε αυτό με τη συνάρτηση TEXT. πρέπει να χρησιμοποιήσετε κώδικα Visual Basic for Applications (VBA). Η παρακάτω σύνδεση διαθέτει μια μέθοδο: Πώς μπορείτε να μετατρέψετε μια αριθμητική τιμή σε αγγλικές λέξεις στο Excel.
Ναι, αλλά χρειάζονται μερικά βήματα. Πρώτα, επιλέξτε το κελί ή τα κελιά όπου θέλετε να συμβεί αυτό και χρησιμοποιήστε το συνδυασμό πλήκτρων Ctrl+1 για να εμφανίσετε το παράθυρο διαλόγου Μορφοποίηση > Κελιά και, στη συνέχεια, την επιλογή Στοίχιση > στοιχείο ελέγχου κειμένου > επιλέξτε Αναδίπλωση κειμένου . Στη συνέχεια, προσαρμόστε την ολοκληρωμένη συνάρτηση TEXT για να συμπεριλάβετε τη συνάρτηση ASCII CHAR(10) εκεί όπου θέλετε να γίνει η αλλαγή γραμμής. Ίσως χρειαστεί να προσαρμόσετε το πλάτος των στηλών ανάλογα με τον τρόπο που στοιχίζεται το τελικό αποτέλεσμα.
Σε αυτή την περίπτωση, χρησιμοποιήσαμε τον εξής τύπο: ="Σήμερα είναι: "&CHAR(10)&TEXT(TODAY();"ηη/μμ/εε")
Αυτό ονομάζεται Επιστημονική σημειογραφία και το Excel μετατρέπει αυτόματα αριθμούς που είναι μεγαλύτεροι από 12 ψηφία εάν τα κελιά είναι μορφοποιημένα ως Γενικά και 15 ψηφία εάν τα κελιά είναι μορφοποιημένα ως αριθμός. Εάν θέλετε να εισαγάγετε μεγάλες αριθμητικές συμβολοσειρές, αλλά δεν θέλετε να μετατραπούν, μορφοποιήστε τα εν λόγω κελιά ως Κείμενο πριν εισαγάγετε ή επικολλήσετε τις τιμές σας στο Excel.
|
|
Η Mynda συνιστά... Εάν κάνετε κοινή χρήση αρχείων και αναφορών του Excel με χρήστες από διαφορετικές χώρες/περιοχές, τότε, μπορεί να θέλετε να τους δώσετε μια αναφορά στη δική τους γλώσσα. Η MVP του Excel, Mynda Treacy έχει μια εξαιρετική λύση για αυτή την περίπτωση στο άρθρο Ημερομηνίες του Excel που εμφανίζονται σε διαφορετικές γλώσσες. Περιλαμβάνει επίσης ένα δείγμα βιβλίου εργασίας, του οποίου μπορείτε να κάνετε λήψη. |
Δείτε επίσης
Δημιουργία ή διαγραφή προσαρμοσμένης μορφής αριθμού
Μετατροπή αριθμών που είναι αποθηκευμένοι ως κείμενο σε αριθμούς
