Μετατροπή αριθμών σε λέξεις

Σημείωση: Θέλουμε να σας παρέχουμε το πιο πρόσφατο περιεχόμενο βοήθειας στη γλώσσα σας όσο πιο σύντομα γίνεται. Αυτή η σελίδα έχω μεταφραστεί μέσω αυτοματοποιημένης διαδικασίας και ενδεχομένως να περιέχει γραμματικά λάθη και ανακρίβειες. Ο σκοπός μας είναι αυτό το περιεχόμενο να σας φανεί χρήσιμο. Μπορείτε να μας ενημερώσετε στο κάτω μέρος αυτής της σελίδας εάν οι πληροφορίες σάς φάνηκαν χρήσιμες; Εδώ θα βρείτε το άρθρο στα Αγγλικά, για να το συμβουλεύεστε εύκολα.

Excel δεν διαθέτει μια προεπιλεγμένη συνάρτηση που εμφανίζει τους αριθμούς ως λέξεων στα Αγγλικά σε ένα φύλλο εργασίας, αλλά μπορείτε να προσθέσετε αυτήν τη δυνατότητα επικολλώντας τον παρακάτω κώδικα συνάρτησης SpellNumber σε μια λειτουργική μονάδα VBA (Visual Basic for Applications). Αυτή η συνάρτηση σάς επιτρέπει να μετατρέψει δολάρια και εκατό ποσά σε λέξεις με έναν τύπο, έτσι ώστε να διαβάσετε 22.50 ως είκοσι δύο ευρώ και πενήντα λεπτών. Αυτό μπορεί να είναι πολύ χρήσιμο εάν χρησιμοποιείτε το Excel ως πρότυπο για να εκτυπώσετε ελέγχων.

Εάν θέλετε να μετατρέψετε αριθμητικές τιμές σε μορφή κειμένου χωρίς εμφάνισή τους ως λέξεις, χρησιμοποιήστε τη συνάρτηση TEXT .

Σημείωση: Η Microsoft παρέχει παραδείγματα προγραμματισμού μόνο για επεξήγηση, χωρίς καμία εγγύηση ρητή ή έμμεση. Αυτό περιλαμβάνει, αλλά δεν είναι ενδεικτικά, οι σιωπηρή εγγυήσεις εμπορευσιμότητας ή καταλληλότητας για συγκεκριμένο σκοπό. Σε αυτό το άρθρο προϋποθέτει ότι είστε εξοικειωμένοι με τη γλώσσα προγραμματισμού VBA, καθώς και με τα εργαλεία που χρησιμοποιούνται για τη δημιουργία και τον εντοπισμό σφαλμάτων διαδικασίες. Οι μηχανικοί υποστήριξης της Microsoft να επεξηγούν τη λειτουργικότητα μιας συγκεκριμένης διαδικασίας. Ωστόσο, δεν θα τροποποιήσουν αυτά τα παραδείγματα για να παρέχουν πρόσθετες λειτουργίες, ούτε θα δημιουργήσουν διαδικασίες για να πληρούν τις συγκεκριμένες απαιτήσεις σας.

Δημιουργία συνάρτησης SpellNumber για τη μετατροπή αριθμών σε λέξεις

  1. Χρησιμοποιήστε τη συντόμευση πληκτρολογίου, Alt + F11 για να ανοίξετε το πρόγραμμα επεξεργασίας Visual Basic (VBE).

    Σημείωση: Μπορείτε επίσης να αποκτήσετε πρόσβαση στην Επεξεργασία της Visual Basic, εμφανίζοντας την καρτέλα "Προγραμματιστής" στην κορδέλα.

  2. Κάντε κλικ στην καρτέλα Insert και, στη συνέχεια, επιλέξτε Module.

    Στο μενού "Εισαγωγή", κάντε κλικ στην επιλογή "Λειτουργική μονάδα".
  3. Αντιγράψτε τις παρακάτω γραμμές κώδικα.

    Σημείωση: Γνωστό ως μια Συνάρτηση που ορίζονται από το χρήστη (UDF), αυτός ο κώδικας εκτελεί αυτόματα την εργασία από τη μετατροπή αριθμών σε κείμενο σε όλο το φύλλο εργασίας σας.

    Option Explicit
    
    'Main Function
    
    Function SpellNumber(ByVal MyNumber)
    
    Dim Dollars, Cents, Temp
    
    Dim DecimalPlace, Count
    
    ReDim Place(9) As String
    
    Place(2) = " Thousand "
    
    Place(3) = " Million "
    
    Place(4) = " Billion "
    
    Place(5) = " Trillion "
    
    ' String representation of amount.
    
    MyNumber = Trim(Str(MyNumber))
    
    ' Position of decimal place 0 if none.
    
    DecimalPlace = InStr(MyNumber, ".")
    
    ' Convert cents and set MyNumber to dollar amount.
    
    If DecimalPlace > 0 Then
    
    Cents = GetTens(Left(Mid(MyNumber, DecimalPlace + 1) & _ "00", 2))
    
    MyNumber = Trim(Left(MyNumber, DecimalPlace - 1))
    
    End If
    
    Count = 1
    
    Do While MyNumber <> ""
    
    Temp = GetHundreds(Right(MyNumber, 3))
    
    If Temp <> "" Then Dollars = Temp & Place(Count) & Dollars
    
    If Len(MyNumber) > 3 Then
    
    MyNumber = Left(MyNumber, Len(MyNumber) - 3)
    
    Else
    
    MyNumber = ""
    
    End If
    
    Count = Count + 1
    
    Loop
    
    Select Case Dollars
    
    Case ""
    
    Dollars = "No Dollars"
    
    Case "One"
    
    Dollars = "One Dollar"
    
    Case Else
    
    Dollars = Dollars & " Dollars"
    
    End Select
    
    Select Case Cents
    
    Case ""
    
    Cents = " and No Cents"
    
    Case "One"
    
    Cents = " and One Cent"
    
    Case Else
    
    Cents = " and " & Cents & " Cents"
    
    End Select
    
    SpellNumber = Dollars & Cents
    
    End Function
    
    
    ' Converts a number from 100-999 into text
    
    Function GetHundreds(ByVal MyNumber)
    
    Dim Result As String
    
    If Val(MyNumber) = 0 Then Exit Function
    
    MyNumber = Right("000" & MyNumber, 3)
    
    ' Convert the hundreds place.
    
    If Mid(MyNumber, 1, 1) <> "0" Then
    
    Result = GetDigit(Mid(MyNumber, 1, 1)) & " Hundred "
    
    End If
    
    ' Convert the tens and ones place.
    
    If Mid(MyNumber, 2, 1) <> "0" Then
    
    Result = Result & GetTens(Mid(MyNumber, 2))
    
    Else
    
    Result = Result & GetDigit(Mid(MyNumber, 3))
    
    End If
    
    GetHundreds = Result
    
    End Function
    
    
    ' Converts a number from 10 to 99 into text.
    
    
    Function GetTens(TensText)
    
    Dim Result As String
    
    Result = "" ' Null out the temporary function value.
    
    If Val(Left(TensText, 1)) = 1 Then ' If value between 10-19...
    
    Select Case Val(TensText)
    
    Case 10: Result = "Ten"
    
    Case 11: Result = "Eleven"
    
    Case 12: Result = "Twelve"
    
    Case 13: Result = "Thirteen"
    
    Case 14: Result = "Fourteen"
    
    Case 15: Result = "Fifteen"
    
    Case 16: Result = "Sixteen"
    
    Case 17: Result = "Seventeen"
    
    Case 18: Result = "Eighteen"
    
    Case 19: Result = "Nineteen"
    
    Case Else
    
    End Select
    
    Else ' If value between 20-99...
    
    Select Case Val(Left(TensText, 1))
    
    Case 2: Result = "Twenty "
    
    Case 3: Result = "Thirty "
    
    Case 4: Result = "Forty "
    
    Case 5: Result = "Fifty "
    
    Case 6: Result = "Sixty "
    
    Case 7: Result = "Seventy "
    
    Case 8: Result = "Eighty "
    
    Case 9: Result = "Ninety "
    
    Case Else
    
    End Select
    
    Result = Result & GetDigit _
    
    (Right(TensText, 1)) ' Retrieve ones place.
    
    End If
    
    GetTens = Result
    
    End Function
    
    
    ' Converts a number from 1 to 9 into text.
    
    Function GetDigit(Digit)
    
    Select Case Val(Digit)
    
    Case 1: GetDigit = "One"
    
    Case 2: GetDigit = "Two"
    
    Case 3: GetDigit = "Three"
    
    Case 4: GetDigit = "Four"
    
    Case 5: GetDigit = "Five"
    
    Case 6: GetDigit = "Six"
    
    Case 7: GetDigit = "Seven"
    
    Case 8: GetDigit = "Eight"
    
    Case 9: GetDigit = "Nine"
    
    Case Else: GetDigit = ""
    
    End Select
    
    End Function
  4. Επικολλήστε τις γραμμές του κώδικα στο πλαίσιο Module1 (Code).

    Κώδικας που έχει επικολληθεί στο πλαίσιο Λειτουργική μονάδα1 (Κώδικας).
  5. Πατήστε το συνδυασμό πλήκτρων Alt + Q για να επιστρέψετε στο Excel. Η συνάρτηση SpellNumber είναι τώρα έτοιμο για χρήση.

    Σημείωση: Αυτή η συνάρτηση λειτουργεί μόνο για το τρέχον βιβλίο εργασίας. Για να χρησιμοποιήσετε αυτήν τη συνάρτηση σε άλλο βιβλίο εργασίας, πρέπει να επαναλάβετε τα βήματα για να αντιγράψετε και να επικολλήσετε τον κώδικα σε αυτό το βιβλίο εργασίας.

Αρχή της σελίδας

Χρήση της συνάρτησης SpellNumber σε μεμονωμένα κελιά

  1. Πληκτρολογήστε τον τύπο = SpellNumber (A1) στο κελί όπου θέλετε να εμφανίσετε έναν αριθμό χειρόγραφων, όπου A1 είναι το κελί που περιέχει τον αριθμό που θέλετε να μετατρέψετε. Μπορείτε να πληκτρολογήσετε επίσης με μη αυτόματο τρόπο την τιμή όπως = SpellNumber(22.50).

  2. Πατήστε το πλήκτρο Enter για να επιβεβαιώσετε τον τύπο.

Αρχή της σελίδας

Αποθήκευση του βιβλίου εργασίας της συνάρτησης SpellNumber

Είναι δυνατή η αποθήκευση ενός βιβλίου εργασίας με συναρτήσεις μακροεντολών στη μορφή τυπική βιβλίου εργασίας με δυνατότητα μακροεντολών (.xlsx). Εάν κάνετε κλικ στην επιλογή αρχείο > Αποθήκευση. Ανοίγει ένα παράθυρο διαλόγου έργου VB. Κάντε κλικ στην επιλογή όχι.

Στο παράθυρο διαλόγου του έργου VB, κάντε κλικ στην επιλογή "Όχι".

Μπορείτε να αποθηκεύσετε το αρχείο σας ως ένα Βιβλίο εργασίας του Excel με δυνατότητα μακροεντολών (.xlsm) για να διατηρήσετε το αρχείο σας στην τρέχουσα μορφή.

  1. Κάντε κλικ στα στοιχεία Αρχείο > Αποθήκευση ως.

  2. Κάντε κλικ στο αναπτυσσόμενο μενού Αποθήκευση ως τύπου και επιλέξτε Βιβλίο εργασίας του Excel με δυνατότητα μακροεντολών.

  3. Κάντε κλικ στο κουμπί Αποθήκευση.

Αρχή της σελίδας

Δείτε επίσης

Συνάρτηση TEXT

Αναπτύξτε τις δεξιότητές σας στο Office
Εξερευνήστε το περιεχόμενο της εκπαίδευσης
Αποκτήστε πρώτοι τις νέες δυνατότητες
Γίνετε μέλος του Office Insider

Σας βοήθησαν αυτές οι πληροφορίες;

Σας ευχαριστούμε για τα σχόλιά σας!

Σας ευχαριστούμε για τα σχόλιά σας! Φαίνεται ότι μπορεί να είναι χρήσιμο να συνδεθείτε με έναν από τους συνεργάτες υποστήριξης του Office.

×