Διαίρεση κειμένου σε διαφορετικές στήλες με συναρτήσεις

Διαίρεση κειμένου σε διαφορετικές στήλες με συναρτήσεις

Σημείωση:  Θέλουμε να σας παρέχουμε το πιο πρόσφατο περιεχόμενο βοήθειας στη γλώσσα σας όσο πιο σύντομα γίνεται. Αυτή η σελίδα έχω μεταφραστεί μέσω αυτοματοποιημένης διαδικασίας και ενδεχομένως να περιέχει γραμματικά λάθη και ανακρίβειες. Ο σκοπός μας είναι αυτό το περιεχόμενο να σας φανεί χρήσιμο. Μπορείτε να μας ενημερώσετε στο κάτω μέρος αυτής της σελίδας εάν οι πληροφορίες σάς φάνηκαν χρήσιμες; Εδώ θα βρείτε το άρθρο στα Αγγλικά , για να το συμβουλεύεστε εύκολα.

Μπορείτε να χρησιμοποιήσετε τις συναρτήσεις LEFT, MID, RIGHT, SEARCH και LEN για να χειρίζεστε συμβολοσειρές κειμένου στα δεδομένα σας. Για παράδειγμα, μπορείτε να κατανείμετε το όνομα, το πατρώνυμο και το επώνυμο από ένα κελί σε τρεις χωριστές στήλες.

Το βασικό στοιχείο στην κατανομή των στοιχείων ονόματος με τη χρήση συναρτήσεων κειμένου είναι η θέση κάθε χαρακτήρα σε μια συμβολοσειρά κειμένου. Οι θέσεις των διαστημάτων στη συμβολοσειρά κειμένου είναι επίσης σημαντικές, καθώς υποδεικνύουν την αρχή ή το τέλος των στοιχείων του ονόματος σε μια συμβολοσειρά.

Για παράδειγμα, σε ένα κελί που περιέχει μόνο ένα όνομα και ένα επώνυμο, το επίθετο ξεκινά μετά την πρώτη εμφάνιση ενός διαστήματος. Κάποια ονόματα στη λίστα σας ενδέχεται να περιέχουν πατρώνυμο, όπου το επώνυμο ξεκινά με τη δεύτερη εμφάνιση ενός διαστήματος.

Σε αυτό το άρθρο σας δείχνει τον τρόπο εξαγωγής των διαφόρων στοιχείων από μια ποικιλία μορφών όνομα χρησιμοποιώντας αυτές τις συναρτήσεις εύχρηστο. Μπορείτε επίσης να διαιρέσετε το κείμενο σε διαφορετικές στήλες με τη Μετατροπή κειμένου σε στήλες οδηγού

Όνομα παραδείγματος

Περιγραφή

Όνομα

Πατρώνυμο

Επώνυμο

Επίθεμα

1

Jeff Smith

Χωρίς πατρώνυμο

Jeff

Παπαδόπουλος

2

Τον Kurjan S.

Ένα αρχικό πατρώνυμου

Eric

Σ.

Kurjan

3%

Janaina Bueno ζ. B.

Δύο αρχικά πατρώνυμου

Janaina

B. G.

Bueno

-4

Kahn, Wendy Beth

Επώνυμο πρώτο, με κόμμα

Wendy

Beth

Kahn

5

Ηλιοπούλου Mary Kay D.

Όνομα με δύο μέρη

Mary Kay

D.

Andersen

6

Paula Barreto de Mattos

Επώνυμο με τρία μέρη

Paula

Barreto de Mattos

7

James van Eaton

Επώνυμο με δύο μέρη

James

van Eaton

8

Bacon Jr., Dan K.

Επώνυμο και επίθεμα πρώτα, με κόμμα

Dan

K.

Bacon

Jr.

9

Ο Gary Altman III

Με επίθεμα

Gary

Altman

III

10

Ryan Ihrig κ.

Με πρόθεμα

Ryan

Ihrig

11

Julie Taft-Rider

Επώνυμο με συλλαβισμό

Julie

Taft-Rider

Σημείωση: Στα γραφικά στα παρακάτω παραδείγματα, η επισήμανση στο ονοματεπώνυμο επισημαίνει το χαρακτήρα που αναζητά ο αντίστοιχος τύπος SEARCH.

Αυτό το παράδειγμα διαχωρίζει δύο στοιχεία: όνομα και επώνυμο. Ένα μονό διάστημα διαχωρίζει τα ονόματα των δύο.

Αντιγράψτε τα κελιά του πίνακα και επικολλήστε στο φύλλο εργασίας του Excel από το κελί A1. Ο τύπος που βλέπετε στην αριστερή πλευρά θα εμφανίζονται για αναφορά, ενώ το Excel θα μετατραπεί αυτόματα τον τύπο στη δεξιά πλευρά σε το κατάλληλο αποτέλεσμα.

Υπόδειξη    Πριν επικολλήσετε τα δεδομένα στο φύλλο εργασίας, ορίστε τα πλάτη των στηλών για τις στήλες A και B σε 250.

Όνομα παραδείγματος

Περιγραφή

Jeff Smith

Δεν υπάρχει πατρώνυμο

Τύπος

Αποτέλεσμα (όνομα)

'=LEFT(A2; SEARCH(" ";A2;1))

=LEFT(A2; SEARCH(" ";A2;1))

Τύπος

Αποτέλεσμα (επώνυμο)

'=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;1))

=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;1))

  1. Όνομα  

    Το όνομα ξεκινά με τον πρώτο χαρακτήρα στη συμβολοσειρά (J) και τελειώνει στον πέμπτο χαρακτήρα (στο διάστημα). Ο τύπος επιστρέφει πέντε χαρακτήρες στο κελί A2, ξεκινώντας από τα αριστερά.

    Τύπος εξαγωγής ονόματος

    Χρήση της συνάρτησης SEARCH για την εύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά.

  2. Επώνυμο  

    Το επώνυμο ξεκινάει από το διάστημα, πέντε χαρακτήρες από τα δεξιά, και τελειώνει στον τελευταίο χαρακτήρα στα δεξιά (h). Ο τύπος εξαγάγει πέντε χαρακτήρες στο A2, ξεκινώντας από τα δεξιά.

    Τύπος εξαγωγής επώνυμου

    Χρήση των συναρτήσεων SEARCH και LEN για την εύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. (5)

  3. Μέτρηση του συνολικού μήκους της συμβολοσειράς κειμένου και στη συνέχεια αφαίρεση του αριθμού των χαρακτήρων στα αριστερά του πρώτου διαστήματος που προέκυψε στο βήμα 1.

Αυτό το παράδειγμα χρησιμοποιεί όνομα, πατρώνυμο και επώνυμο. Κάθε στοιχείο του ονόματος διαχωρίζεται με ένα διάστημα.

Αντιγράψτε τα κελιά του πίνακα και επικολλήστε στο φύλλο εργασίας του Excel από το κελί A1. Ο τύπος που βλέπετε στην αριστερή πλευρά θα εμφανίζονται για αναφορά, ενώ το Excel θα μετατραπεί αυτόματα τον τύπο στη δεξιά πλευρά σε το κατάλληλο αποτέλεσμα.

Υπόδειξη    Πριν επικολλήσετε τα δεδομένα στο φύλλο εργασίας, ορίστε τα πλάτη των στηλών για τις στήλες A και B σε 250.

Όνομα παραδείγματος

Περιγραφή

Eric S. Kurjan

Ένα αρχικό πατρώνυμου

Τύπος

Αποτέλεσμα (όνομα)

'=LEFT(A2; SEARCH(" ";A2;1))

=LEFT(A2; SEARCH(" ";A2;1))

Τύπος

Αποτέλεσμα (αρχικό πατρώνυμου)

'=MID(A2;SEARCH(" ";A2;1)+1;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)-SEARCH(" ";A2;1))

=MID(A2;SEARCH(" ";A2;1)+1;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)-SEARCH(" ";A2;1))

Τύπος

Αποτέλεσμα σε πραγματικό χρόνο (επώνυμο)

'=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;1)+1))

=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;1)+1))

  1. Όνομα  

    Το όνομα ξεκινάει με τον πρώτο χαρακτήρα από τα αριστερά (E) και τελειώνει στον πέμπτο χαρακτήρα (στο πρώτο διάστημα). Ο τύπος εξαγάγει τους πρώτους πέντε χαρακτήρες στο A2, ξεκινώντας από τα αριστερά.

    Τύπος για το διαχωρισμό ενός ονόματος και επωνύμου, συν το πατρώνυμο

    Χρήση της συνάρτησης SEARCH για εντοπισμό της τιμής για num_chars:

    Αναζήτηση της αριθμητικής θέσης του διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. (5)

  2. Πατρώνυμο

    Το πατρώνυμο ξεκινά από τη θέση του έκτου χαρακτήρα (S) και τελειώνει στην όγδοη θέση (στο δεύτερο διάστημα). Αυτός ο τύπος περιλαμβάνει την ένθεση συναρτήσεων SEARCH για τον εντοπισμό της δεύτερης εμφάνισης ενός διαστήματος.

    Ο τύπος εξαγάγει τρεις χαρακτήρες, ξεκινώντας από την έκτη θέση.

    Λεπτομέρειες τύπου για το διαχωρισμό ονόματος, πατρώνυμου και επώνυμου

    Χρήση της συνάρτησης SEARCH για την ανεύρεση της τιμής του ορίσματος αριθμός_έναρξης:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τον πρώτο χαρακτήρα στα αριστερά. (5).

  3. Πρόσθεση του 1 για τη λήψη της θέσης του χαρακτήρα μετά το πρώτο διάστημα (S). Αυτή η αριθμητική θέση είναι η θέση έναρξης του πατρώνυμου. (5 + 1 = 6)

    Χρήση ένθετων συναρτήσεων SEARCH για την ανεύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τον πρώτο χαρακτήρα στα αριστερά. (5)

  4. Πρόσθεση του 1 για τη λήψη της θέσης του χαρακτήρα μετά το πρώτο διάστημα (S). Το αποτέλεσμα είναι ο αριθμός χαρακτήρα από τον οποίο θα ξεκινήσει η αναζήτηση για τη δεύτερη εμφάνιση διαστήματος. (5 + 1 = 6)

  5. Αναζήτηση της δεύτερης εμφάνισης του διαστήματος στο κελί A2, ξεκινώντας από την έκτη θέση (S) που προέκυψε στο βήμα 4. Αυτός ο αριθμός χαρακτήρα είναι η τερματική θέση του πατρώνυμου. (8)

  6. Αναζήτηση της αριθμητικής θέσης του διαστήματος στο κελί A2, ξεκινώντας από τον πρώτο χαρακτήρα στα αριστερά. (5)

  7. Λήψη του αριθμού χαρακτήρα του δεύτερου διαστήματος που προέκυψε στο βήμα 5 και αφαίρεση του αριθμού χαρακτήρα του πρώτου διαστήματος που προέκυψε στο βήμα 6. Το αποτέλεσμα είναι ο αριθμός των χαρακτήρων που εξάγει η συνάρτηση MID από τη συμβολοσειρά κειμένου, ξεκινώντας από την έκτη θέση που προέκυψε στο βήμα 2. (8 – 5 = 3)

  8. Επώνυμο  

    Το επώνυμο ξεκινάει έξι χαρακτήρες από τα δεξιά (K) και τελειώνει στον πρώτο χαρακτήρα από τα δεξιά (n). Αυτός ο τύπος περιλαμβάνει ένθετες συναρτήσεις SEARCH για τον εντοπισμό της δεύτερης και τρίτης εμφάνισης ενός διαστήματος (οι οποίες είναι στην πέμπτη και έκτη θέση από τα αριστερά).

    Ο τύπος εξαγάγει έξι χαρακτήρες στο A2, ξεκινώντας από τα δεξιά.

    Η δεύτερη συνάρτηση SEARCH σε έναν τύπο για το διαχωρισμό ονόματος, πατρώνυμου, και επώνυμου
  9. Χρήση των συναρτήσεων LEN και SEARCH για την ανεύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του διαστήματος στο κελί A2, ξεκινώντας από τον πρώτο χαρακτήρα στα αριστερά. (5)

  10. Πρόσθεση του 1 για τη λήψη της θέσης του χαρακτήρα μετά το πρώτο διάστημα (S). Το αποτέλεσμα είναι ο αριθμός χαρακτήρα από τον οποίο θα ξεκινήσει η αναζήτηση για τη δεύτερη εμφάνιση διαστήματος. (5 + 1 = 6)

  11. Αναζήτηση της δεύτερης εμφάνισης του διαστήματος στο κελί A2, ξεκινώντας από την έκτη θέση (S) που προέκυψε στο βήμα 2. Αυτός ο αριθμός χαρακτήρα είναι η τερματική θέση του πατρώνυμου. (8)

  12. Μέτρηση του συνολικού μήκους της συμβολοσειράς κειμένου στο κελί A2 και, στη συνέχεια, αφαίρεση του αριθμού των χαρακτήρων από τα αριστερά μέχρι τη δεύτερη εμφάνιση του διαστήματος που βρίσκεται στο βήμα 3. Το αποτέλεσμα είναι το πλήθος των χαρακτήρων που θα εξαχθούν από τα δεξιά του ονοματεπώνυμου. (14 – 8 = 6).

Ακολουθεί ένα παράδειγμα του τρόπου εξαγωγής δύο αρχικών στο μέσο του ονοματεπώνυμου. Η πρώτη και η τρίτη εμφάνιση του διαστήματος διαχωρίζουν τα στοιχεία ονόματος.

Αντιγράψτε τα κελιά του πίνακα και επικολλήστε στο φύλλο εργασίας του Excel από το κελί A1. Ο τύπος που βλέπετε στην αριστερή πλευρά θα εμφανίζονται για αναφορά, ενώ το Excel θα μετατραπεί αυτόματα τον τύπο στη δεξιά πλευρά σε το κατάλληλο αποτέλεσμα.

Υπόδειξη    Πριν επικολλήσετε τα δεδομένα στο φύλλο εργασίας, ορίστε τα πλάτη των στηλών για τις στήλες A και B σε 250.

Όνομα παραδείγματος

Περιγραφή

Janaina B. G. Bueno

Δύο αρχικά πατρώνυμου

Τύπος

Αποτέλεσμα (όνομα)

'=LEFT(A2; SEARCH(" ";A2;1))

=LEFT(A2; SEARCH(" ";A2;1))

Τύπος

Αποτέλεσμα (αρχικά πατρώνυμου)

'=MID(A2;SEARCH(" ";A2;1)+1;SEARCH(" ";A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1)-SEARCH(" ";A2;1))

=MID(A2;SEARCH(" ";A2;1)+1;SEARCH(" ";A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1)-SEARCH(" ";A2;1))

Τύπος

Αποτέλεσμα σε πραγματικό χρόνο (επώνυμο)

'=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1))

=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1))

  1. Όνομα  

    Το όνομα ξεκινάει με τον πρώτο χαρακτήρα από τα αριστερά (J) και τελειώνει στον όγδοο χαρακτήρα (στο πρώτο διάστημα). Ο τύπος εξαγάγει τους πρώτους οκτώ χαρακτήρες στο A2, ξεκινώντας από τα αριστερά.

    Τύπος για το διαχωρισμό ονόματος, επώνυμου και δύο αρχικών πατρώνυμου

    Χρήση της συνάρτησης SEARCH για την εύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. (8)

  2. Πατρώνυμο

    Το πατρώνυμο ξεκινάει στην ένατη θέση (B) και τελειώνει στην δέκατη τέταρτη θέση (στο τρίτο διάστημα). Αυτός ο τύπος περιλαμβάνει την ένθεση της συνάρτησης SEARCH για τον εντοπισμό της πρώτης, δεύτερης και τρίτης εμφάνισης του διαστήματος στην όγδοη, ενδέκατη και δέκατη τέταρτη θέση.

    Ο τύπος εξαγάγει πέντε χαρακτήρες, ξεκινώντας από την ένατη θέση.

    Τύπος για το διαχωρισμό ονόματος, επώνυμου και δύο αρχικών πατρώνυμου

    Χρήση της συνάρτησης SEARCH για την ανεύρεση της τιμής του ορίσματος αριθμός_έναρξης:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τον πρώτο χαρακτήρα στα αριστερά. (8)

  3. Πρόσθεση του 1 για τη λήψη της θέσης του χαρακτήρα μετά το πρώτο διάστημα (B). Αυτή η αριθμητική θέση είναι η θέση έναρξης του πατρώνυμου. (8 + 1 = 9)

    Χρήση ένθετων συναρτήσεων SEARCH για την ανεύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τον πρώτο χαρακτήρα στα αριστερά. (8)

  4. Πρόσθεση του 1 για τη λήψη της θέσης του χαρακτήρα μετά το πρώτο διάστημα (B). Το αποτέλεσμα είναι ο αριθμός χαρακτήρα από τον οποίο θα ξεκινήσει η αναζήτηση για τη δεύτερη εμφάνιση διαστήματος. (8 + 1 = 9)

  5. Αναζήτηση για το δεύτερο διάστημα στο κελί A2, ξεκινώντας από την ένατο θέση (B) που βρίσκεται στο βήμα 4. (11).

  6. Πρόσθεση του 1 για τη λήψη της θέσης του χαρακτήρα μετά το δεύτερο διάστημα (G). Αυτός ο αριθμός χαρακτήρα είναι η θέση έναρξης από την οποία θα ξεκινήσετε την αναζήτηση για το τρίτο διάστημα. (11 + 1 = 12)

  7. Αναζήτηση του τρίτου διαστήματος στο κελί A2, ξεκινώντας από τη δωδέκατη θέση που βρίσκεται στο βήμα 6. (14)

  8. Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2. (8)

  9. Λήψη του αριθμού χαρακτήρα του τρίτου διαστήματος που προέκυψε στο βήμα 7 και αφαίρεση του αριθμού χαρακτήρα του πρώτου διαστήματος που προέκυψε στο βήμα 6. Το αποτέλεσμα είναι ο αριθμός των χαρακτήρων που εξάγει η συνάρτηση MID από τη συμβολοσειρά κειμένου, ξεκινώντας από την ένατη θέση που προέκυψε στο βήμα 2.

  10. Επώνυμο  

    Το επώνυμο ξεκινάει πέντε χαρακτήρες από τα δεξιά (B) και τελειώνει στον πρώτο χαρακτήρα από τα δεξιά (o). Αυτός ο τύπος περιλαμβάνει την ένθεση της συνάρτησης SEARCH για τον εντοπισμό της πρώτης, της δεύτερης και της τρίτης εμφάνισης του διαστήματος.

    Ο τύπος εξαγάγει πέντε χαρακτήρες στο A2, ξεκινώντας από τα δεξιά του ονοματεπωνύμου.

    Τύπος για το διαχωρισμό ονόματος, επώνυμου και δύο αρχικών πατρώνυμου

    Χρήση ένθετων συναρτήσεων SEARCH και της συνάρτησης LEN για την ανεύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τον πρώτο χαρακτήρα στα αριστερά. (8)

  11. Πρόσθεση του 1 για τη λήψη της θέσης του χαρακτήρα μετά το πρώτο διάστημα (B). Το αποτέλεσμα είναι ο αριθμός χαρακτήρα από τον οποίο θα ξεκινήσει η αναζήτηση για τη δεύτερη εμφάνιση διαστήματος. (8 + 1 = 9)

  12. Αναζήτηση του δεύτερου διαστήματος στο κελί A2, ξεκινώντας από την ένατη θέση (B) που προέκυψε στο βήμα 2. (11)

  13. Πρόσθεση του 1 για τη λήψη της θέσης του χαρακτήρα μετά το δεύτερο διάστημα (G). Αυτός ο αριθμός χαρακτήρα είναι η θέση έναρξης από την οποία θα ξεκινήσετε την αναζήτηση για την τρίτη εμφάνιση διαστήματος. (11 + 1 = 12)

  14. Αναζήτηση του τρίτου διαστήματος στο κελί A2, ξεκινώντας από τη δωδέκατη θέση (G) που βρίσκεται στο βήμα 6. (14)

  15. Μέτρηση του συνολικού μήκους της συμβολοσειράς κειμένου στο κελί A2 και μετά αφαίρεση του αριθμού των χαρακτήρων από τα αριστερά μέχρι το τρίτο διάστημα που προέκυψε στο βήμα 5. Το αποτέλεσμα είναι ο αριθμός των χαρακτήρων που θα εξαχθούν από τα δεξιά του ονοματεπωνύμου. (19 - 14 = 5)

Σε αυτό το παράδειγμα, το επώνυμο προηγείται του ονόματος και το πατρώνυμο εμφανίζεται στο τέλος. Το κόμμα επισημαίνει το τέλος του επωνύμου και διαστήματα διαχωρίζουν κάθε στοιχείο του ονόματος.

Αντιγράψτε τα κελιά του πίνακα και επικολλήστε στο φύλλο εργασίας του Excel από το κελί A1. Ο τύπος που βλέπετε στην αριστερή πλευρά θα εμφανίζονται για αναφορά, ενώ το Excel θα μετατραπεί αυτόματα τον τύπο στη δεξιά πλευρά σε το κατάλληλο αποτέλεσμα.

Υπόδειξη    Πριν επικολλήσετε τα δεδομένα στο φύλλο εργασίας, ορίστε τα πλάτη των στηλών για τις στήλες A και B σε 250.

Όνομα παραδείγματος

Περιγραφή

Kahn, Wendy Beth

Πρώτα το επώνυμο, με κόμμα

Τύπος

Αποτέλεσμα (όνομα)

'=MID(A2;SEARCH(" ";A2;1)+1;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)-SEARCH(" ";A2;1))

=MID(A2;SEARCH(" ";A2;1)+1;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)-SEARCH(" ";A2;1))

Τύπος

Αποτέλεσμα (πατρώνυμο)

'=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;1)+1))

=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;1)+1))

Τύπος

Αποτέλεσμα σε πραγματικό χρόνο (επώνυμο)

'=LEFT(A2; SEARCH(" ";A2;1)-2)

=LEFT(A2; SEARCH(" ";A2;1)-2)

  1. Όνομα  

    Το όνομα ξεκινά με τον έβδομο χαρακτήρα από τα αριστερά (W) και τελειώνει στον δωδέκατο χαρακτήρα (στο δεύτερο διάστημα). Επειδή το όνομα είναι στην μέση του ονοματεπωνύμου, πρέπει να χρησιμοποιήσετε τη συνάρτηση MID για να εξαγάγετε το όνομα.

    Ο τύπος εξαγάγει έξι χαρακτήρες, ξεκινώντας από την έβδομη θέση.

    Τύπος για το διαχωρισμό επώνυμου που ακολουθείται από όνομα και πατρώνυμο

    Χρήση της συνάρτησης SEARCH για την ανεύρεση της τιμής του ορίσματος αριθμός_έναρξης:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τον πρώτο χαρακτήρα στα αριστερά. (6)

  2. Πρόσθεση του 1 για τη λήψη της θέσης του χαρακτήρα μετά το πρώτο διάστημα (W). Αυτή η αριθμητική θέση είναι η θέση έναρξης του ονόματος. (6 + 1 = 7)

    Χρήση ένθετων συναρτήσεων SEARCH για την ανεύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τον πρώτο χαρακτήρα στα αριστερά. (6)

  3. Πρόσθεση του 1 για τη λήψη της θέσης του χαρακτήρα μετά το πρώτο διάστημα (W). Το αποτέλεσμα είναι ο αριθμός χαρακτήρα από τον οποίο θα ξεκινήσει η αναζήτηση για το δεύτερο διάστημα. (6 + 1 = 7)

    Αναζήτηση του δεύτερου διαστήματος στο κελί A2, ξεκινώντας από την έβδομη θέση (W) που προέκυψε στο βήμα 4. (12)

  4. Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τον πρώτο χαρακτήρα στα αριστερά. (6)

  5. Λήψη του αριθμού χαρακτήρα του δεύτερου διαστήματος που προέκυψε στο βήμα 5 και αφαίρεση του αριθμού χαρακτήρα του πρώτου διαστήματος που προέκυψε στο βήμα 6. Το αποτέλεσμα είναι ο αριθμός των χαρακτήρων που εξάγει η συνάρτηση MID από τη συμβολοσειρά κειμένου, ξεκινώντας από την έβδομη θέση που προέκυψε στο βήμα 2. (12 - 6 = 6)

  6. Πατρώνυμο

    Το πατρώνυμο ξεκινάει τέσσερις χαρακτήρες από τα δεξιά (B) και τελειώνει στον πρώτο χαρακτήρα από τα δεξιά (h). Αυτός ο τύπος περιλαμβάνει την ένθεση της συνάρτησης SEARCH για τον εντοπισμό της πρώτης και δεύτερης εμφάνισης διαστήματος στην έκτη και δωδέκατη θέση από τα αριστερά.

    Ο τύπος εξαγάγει τέσσερις χαρακτήρες, ξεκινώντας από τα δεξιά.

    Τύπος για το διαχωρισμό επώνυμου που ακολουθείται από όνομα και πατρώνυμο

    Χρήση ένθετων συναρτήσεων SEARCH και της συνάρτησης LEN για την ανεύρεση της τιμής του ορίσματος αριθμός_έναρξης:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τον πρώτο χαρακτήρα στα αριστερά. (6)

  7. Πρόσθεση του 1 για τη λήψη της θέσης του χαρακτήρα μετά το πρώτο διάστημα (W). Το αποτέλεσμα είναι ο αριθμός χαρακτήρα από τον οποίο θα ξεκινήσει η αναζήτηση για το δεύτερο διάστημα. (6 + 1 = 7)

  8. Αναζήτηση της δεύτερης εμφάνισης διαστήματος στο κελί A2, ξεκινώντας από την έβδομη θέση (W) που προέκυψε στο βήμα 2. (12)

  9. Μέτρηση του συνολικού μήκους της συμβολοσειράς κειμένου στο κελί A2 και μετά αφαίρεση του αριθμού των χαρακτήρων από τα αριστερά μέχρι το δεύτερο διάστημα που προέκυψε στο βήμα 3. Το αποτέλεσμα είναι ο αριθμός των χαρακτήρων που θα εξαχθούν από τα δεξιά του ονοματεπωνύμου. (16 - 12 = 4)

  10. Επώνυμο  

    Το επώνυμο ξεκινάει με τον πρώτο χαρακτήρα από τα αριστερά (K) και τελειώνει στον τέταρτο χαρακτήρα (n). Ο τύπος εξαγάγει τέσσερις χαρακτήρες, ξεκινώντας από τα αριστερά.

    Τύπος για το διαχωρισμό επώνυμου που ακολουθείται από όνομα και πατρώνυμο

    Χρήση της συνάρτησης SEARCH για την εύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τον πρώτο χαρακτήρα στα αριστερά. (6)

  11. Αφαιρέστε 2 για τη λήψη της αριθμητικής θέσης του τελικού χαρακτήρα του επωνύμου (n). Το αποτέλεσμα είναι το πλήθος των χαρακτήρων που θέλετε να εξαγάγετε. (6 - 2 = 4)

Αυτό το παράδειγμα χρησιμοποιεί δύο μικρά ονόματα, Mary Kay. Το δεύτερο και το τρίτο διάστημα διαχωρίζουν κάθε στοιχείο του ονόματος.

Αντιγράψτε τα κελιά του πίνακα και επικολλήστε στο φύλλο εργασίας του Excel από το κελί A1. Ο τύπος που βλέπετε στην αριστερή πλευρά θα εμφανίζονται για αναφορά, ενώ το Excel θα μετατραπεί αυτόματα τον τύπο στη δεξιά πλευρά σε το κατάλληλο αποτέλεσμα.

Υπόδειξη    Πριν επικολλήσετε τα δεδομένα στο φύλλο εργασίας, ορίστε τα πλάτη των στηλών για τις στήλες A και B σε 250.

Όνομα παραδείγματος

Περιγραφή

Mary Kay D. Andersen

Όνομα δύο τμημάτων

Τύπος

Αποτέλεσμα (όνομα)

LEFT(A2; SEARCH(" ";A2;SEARCH(" ";A2;1)+1))

=LEFT(A2; SEARCH(" ";A2;SEARCH(" ";A2;1)+1))

Τύπος

Αποτέλεσμα (αρχικό πατρώνυμου)

'=MID(A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1;SEARCH(" ";A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1)-(SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1))

=MID(A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1;SEARCH(" ";A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1)-(SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1))

Τύπος

Αποτέλεσμα σε πραγματικό χρόνο (επώνυμο)

'=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1))

=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1))

  1. Όνομα  

    Το όνομα ξεκινά με τον πρώτο χαρακτήρα από τα αριστερά και τελειώνει στον ένατο χαρακτήρα (στο δεύτερο διάστημα). Αυτός ο τύπος περιλαμβάνει την ένθεση της συνάρτησης SEARCH για τον εντοπισμό της δεύτερης εμφάνισης διαστήματος από τα αριστερά.

    Ο τύπος εξαγάγει εννέα χαρακτήρες, ξεκινώντας από τα αριστερά.

    Τύπος για το διαχωρισμό ονόματος, πατρώνυμου, αρχικού πατρώνυμου και επώνυμου

    Χρήση ένθετων συναρτήσεων SEARCH για την ανεύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τον πρώτο χαρακτήρα στα αριστερά. (5)

  2. Πρόσθεση του 1 για τη λήψη της θέσης του χαρακτήρα μετά το πρώτο διάστημα (K). Το αποτέλεσμα είναι ο αριθμός χαρακτήρα από τον οποίο θα ξεκινήσει η αναζήτηση για τη δεύτερη εμφάνιση διαστήματος. (5 + 1 = 6)

  3. Αναζήτηση της δεύτερης εμφάνισης του διαστήματος στο κελί A2, ξεκινώντας από την έκτη θέση (K) που προέκυψε στο βήμα 2. Το αποτέλεσμα είναι ο αριθμός χαρακτήρων που εξάγει η συνάρτηση LEFT από τη συμβολοσειρά κειμένου. (9)

  4. Πατρώνυμο

    Το πατρώνυμο ξεκινάει στη δέκατη θέση (D) και τελειώνει στην δωδέκατη θέση (στο τρίτο διάστημα). Αυτός ο τύπος περιλαμβάνει την ένθεση της συνάρτησης SEARCH για τον εντοπισμό της πρώτης, δεύτερης και τρίτης εμφάνισης διαστήματος.

    Ο τύπος εξαγάγει δύο χαρακτήρες από το πατρώνυμο, ξεκινώντας από τη δέκατη θέση.

    Τύπος για το διαχωρισμό ονόματος, πατρώνυμου, αρχικού πατρώνυμου και επώνυμου

    Χρήση ένθετων συναρτήσεων SEARCH για την ανεύρεση της τιμής του ορίσματος αριθμός_έναρξης:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τον πρώτο χαρακτήρα στα αριστερά. (5)

  5. Πρόσθεση του 1 για τη λήψη του χαρακτήρα μετά το πρώτο διάστημα (K). Το αποτέλεσμα είναι ο αριθμός χαρακτήρα από τον οποίο θα ξεκινήσει η αναζήτηση για το δεύτερο διάστημα. (5 + 1 = 6)

  6. Αναζήτηση της θέσης της δεύτερης εμφάνισης διαστήματος στο κελί A2, ξεκινώντας από την έκτη θέση (K) που προέκυψε στο βήμα 2. Το αποτέλεσμα είναι ο αριθμός χαρακτήρων που εξάγει η συνάρτηση LEFT από τα αριστερά. (9)

  7. Πρόσθεση του 1 για τη λήψη του χαρακτήρα μετά το δεύτερο διάστημα (D). Το αποτέλεσμα είναι η θέση έναρξης του πατρώνυμου. (9 + 1 = 10)

    Χρήση ένθετων συναρτήσεων SEARCH για την ανεύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του χαρακτήρα μετά το δεύτερο διάστημα (D). Το αποτέλεσμα είναι ο αριθμός χαρακτήρα από τον οποίο θα ξεκινήσει η αναζήτηση για το τρίτο διάστημα. (10)

  8. Αναζήτηση της αριθμητικής θέσης του τρίτου διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. Το αποτέλεσμα είναι η θέση τερματισμού του πατρώνυμου. (12)

  9. Αναζήτηση της αριθμητικής θέσης του χαρακτήρα μετά το δεύτερο διάστημα (D). Το αποτέλεσμα είναι η θέση έναρξης του πατρώνυμου. (10)

  10. Λήψη του αριθμού χαρακτήρα του τρίτου διαστήματος που προέκυψε στο βήμα 6 και αφαίρεση του αριθμού χαρακτήρα του “D” που προέκυψε στο βήμα 7. Το αποτέλεσμα είναι ο αριθμός των χαρακτήρων που εξάγει η συνάρτηση MID από τη συμβολοσειρά κειμένου, ξεκινώντας από τη δέκατη θέση που προέκυψε στο βήμα 4. (12 - 10 = 2)

  11. Επώνυμο  

    Το επώνυμο ξεκινάει οκτώ χαρακτήρες από τα δεξιά. Αυτός ο τύπος περιλαμβάνει την ένθεση της συνάρτησης SEARCH για τον εντοπισμό της πρώτης, δεύτερης και τρίτης εμφάνισης διαστήματος στην πέμπτη, ένατη και δωδέκατη θέση.

    Ο τύπος εξαγάγει οκτώ χαρακτήρες, ξεκινώντας από τα δεξιά.

    Τύπος για το διαχωρισμό ονόματος, πατρώνυμου, αρχικού πατρώνυμου και επώνυμου

    Χρήση ένθετων συναρτήσεων SEARCH και της συνάρτησης LEN για την ανεύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. (5)

  12. Πρόσθεση του 1 για τη λήψη του χαρακτήρα μετά το πρώτο διάστημα (K). Το αποτέλεσμα είναι ο αριθμός χαρακτήρα από τον οποίο θα ξεκινήσει η αναζήτηση για το διάστημα. (5 + 1 = 6)

  13. Αναζήτηση του δεύτερου διαστήματος στο κελί A2, ξεκινώντας από την έκτη θέση (K) που προέκυψε στο βήμα 2. (9)

  14. Προσθήκη του 1 για τη λήψη της θέσης του χαρακτήρα μετά το δεύτερο διάστημα (D). Το αποτέλεσμα είναι η θέση έναρξης του πατρώνυμου. (9 + 1 = 10)

  15. Αναζήτηση της αριθμητικής θέσης του τρίτου διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. Το αποτέλεσμα είναι η θέση τερματισμού του πατρώνυμου. (12)

  16. Μέτρηση του συνολικού μήκους της συμβολοσειράς κειμένου στο κελί A2 και μετά αφαίρεση του αριθμού των χαρακτήρων από τα αριστερά μέχρι το τρίτο διάστημα που προέκυψε στο βήμα 5. Το αποτέλεσμα είναι ο αριθμός των χαρακτήρων που θα εξαχθούν από τα δεξιά του ονοματεπωνύμου. (20 - 12 = 8)

Αυτό το παράδειγμα χρησιμοποιεί ένα επώνυμο τριών τμημάτων: Barreto de Mattos. Το πρώτο διάστημα σημειώνει το τέλος του ονόματος και την αρχή του επωνύμου.

Αντιγράψτε τα κελιά του πίνακα και επικολλήστε στο φύλλο εργασίας του Excel από το κελί A1. Ο τύπος που βλέπετε στην αριστερή πλευρά θα εμφανίζονται για αναφορά, ενώ το Excel θα μετατραπεί αυτόματα τον τύπο στη δεξιά πλευρά σε το κατάλληλο αποτέλεσμα.

Υπόδειξη    Πριν επικολλήσετε τα δεδομένα στο φύλλο εργασίας, ορίστε τα πλάτη των στηλών για τις στήλες A και B σε 250.

Όνομα παραδείγματος

Περιγραφή

Paula Barreto de Mattos

Επώνυμο τριών τμημάτων

Τύπος

Αποτέλεσμα (όνομα)

'=LEFT(A2; SEARCH(" ";A2;1))

=LEFT(A2; SEARCH(" ";A2;1))

Τύπος

Αποτέλεσμα (επώνυμο)

=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;1))

=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;1))

  1. Όνομα  

    Το όνομα ξεκινά με τον πρώτο χαρακτήρα από τα αριστερά (P) και τελειώνει στον έκτο χαρακτήρα (στο πρώτο διάστημα). Ο τύπος εξαγάγει τους πρώτους έξι χαρακτήρες, ξεκινώντας από τα αριστερά.

    Τύπος για το διαχωρισμό ονόματος και ένα επώνυμο τριών τμημάτων

    Χρήση της συνάρτησης SEARCH για την ανεύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. (6)

  2. Επώνυμο  

    Το επώνυμο ξεκινάει δεκαεπτά χαρακτήρες από τα δεξιά (B) και τελειώνει στον πρώτο χαρακτήρα από τα δεξιά (s). Ο τύπος εξαγάγει δεκαεπτά χαρακτήρες από τα δεξιά.

    Τύπος για το διαχωρισμό ονόματος και ένα επώνυμο τριών τμημάτων

    Χρήση των συναρτήσεων LEN και SEARCH για την ανεύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. (6)

  3. Μέτρηση του συνολικού μήκους της συμβολοσειράς κειμένου στο κελί A2 και μετά αφαίρεση του αριθμού των χαρακτήρων από τα αριστερά μέχρι το πρώτο διάστημα που προέκυψε στο βήμα 1. Το αποτέλεσμα είναι ο αριθμός των χαρακτήρων που θα εξαχθούν από τα δεξιά του ονοματεπωνύμου. (23 - 6 = 17)

Αυτό το παράδειγμα χρησιμοποιεί ένα επώνυμο δύο τμημάτων: van Eaton. Το πρώτο διάστημα σημειώνει το τέλος του ονόματος και την αρχή του επωνύμου.

Αντιγράψτε τα κελιά του πίνακα και επικολλήστε στο φύλλο εργασίας του Excel από το κελί A1. Ο τύπος που βλέπετε στην αριστερή πλευρά θα εμφανίζονται για αναφορά, ενώ το Excel θα μετατραπεί αυτόματα τον τύπο στη δεξιά πλευρά σε το κατάλληλο αποτέλεσμα.

Υπόδειξη    Πριν επικολλήσετε τα δεδομένα στο φύλλο εργασίας, ορίστε τα πλάτη των στηλών για τις στήλες A και B σε 250.

Όνομα παραδείγματος

Περιγραφή

James van Eaton

Επώνυμο δύο τμημάτων

Τύπος

Αποτέλεσμα (όνομα)

'=LEFT(A2; SEARCH(" ";A2;1))

=LEFT(A2; SEARCH(" ";A2;1))

Τύπος

Αποτέλεσμα (επώνυμο)

'=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;1))

=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;1))

  1. Όνομα  

    Το όνομα ξεκινάει με τον πρώτο χαρακτήρα από τα αριστερά (J) και τελειώνει στον όγδοο χαρακτήρα (στο πρώτο διάστημα). Ο τύπος εξαγάγει έξι χαρακτήρες, ξεκινώντας από τα αριστερά.

    Τύπος για το διαχωρισμό ονόματος και επώνυμου με δύο μέρη

    Χρήση της συνάρτησης SEARCH για την ανεύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. (6)

  2. Επώνυμο  

    Το επώνυμο ξεκινάει με τον ένατο χαρακτήρα από τα δεξιά (v) και τελειώνει στον πρώτο χαρακτήρα από τα δεξιά (n). Ο τύπος εξαγάγει εννέα χαρακτήρες από τα δεξιά του ονοματεπωνύμου.

    Τύπος για το διαχωρισμό ονόματος και επώνυμου με δύο μέρη

    Χρήση των συναρτήσεων LEN και SEARCH για την ανεύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. (6)

  3. Μέτρηση του συνολικού μήκους της συμβολοσειράς κειμένου στο κελί A2 και μετά αφαίρεση του αριθμού των χαρακτήρων από τα αριστερά μέχρι το πρώτο διάστημα που προέκυψε στο βήμα 1. Το αποτέλεσμα είναι ο αριθμός των χαρακτήρων που θα εξαχθούν από τα δεξιά του ονοματεπωνύμου. (15 - 6 = 9)

Αε αυτό το παράδειγμα, το επώνυμο προηγείται και ακολουθεί το επίθεμα. Το κόμμα διαχωρίζει το επώνυμο και το επίθεμα από το όνομα και το αρχικό του πατρώνυμου.

Αντιγράψτε τα κελιά του πίνακα και επικολλήστε στο φύλλο εργασίας του Excel από το κελί A1. Ο τύπος που βλέπετε στην αριστερή πλευρά θα εμφανίζονται για αναφορά, ενώ το Excel θα μετατραπεί αυτόματα τον τύπο στη δεξιά πλευρά σε το κατάλληλο αποτέλεσμα.

Υπόδειξη    Πριν επικολλήσετε τα δεδομένα στο φύλλο εργασίας, ορίστε τα πλάτη των στηλών για τις στήλες A και B σε 250.

Όνομα παραδείγματος

Περιγραφή

Bacon Jr., Dan K.

Πρώτα το επώνυμο και το επίθημα, με κόμμα

Τύπος

Αποτέλεσμα (όνομα)

'=MID(A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1;SEARCH(" ";A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1)-SEARCH(" ";A2;SEARCH(" ";A2;1)+1))

=MID(A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1;SEARCH(" ";A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1)-SEARCH(" ";A2;SEARCH(" ";A2;1)+1))

Τύπος

Αποτέλεσμα (αρχικό πατρώνυμου)

'=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1))

=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)+1))

Τύπος

Αποτέλεσμα (επώνυμο)

'=LEFT(A2; SEARCH(" ";A2;1))

=LEFT(A2; SEARCH(" ";A2;1))

Τύπος

Αποτέλεσμα (επίθημα)

'=MID(A2;SEARCH(" ";A2;1)+1;(SEARCH(" ";A2;SEARCH(" ";A2;1)+1)-2)-SEARCH(" ";A2;1))

=MID(A2;SEARCH(" ";A2;1)+1;(SEARCH(" ";A2;SEARCH(" ";A2;1)+1)-2)-SEARCH(" ";A2;1))

  1. Όνομα  

    Το όνομα ξεκινάει με τον δωδέκατο χαρακτήρα (D) και τελειώνει στον δέκατο πέμπτο χαρακτήρα (στο τρίτο διάστημα). Ο τύπος εξαγάγει τρεις χαρακτήρες, ξεκινώντας από τη δωδέκατη θέση.

    Τύπου για το διαχωρισμό ένα επώνυμο όνομα πρώτα και το επίθημα, με κόμμα

    Χρήση ένθετων συναρτήσεων SEARCH για την ανεύρεση της τιμής του ορίσματος αριθμός_έναρξης:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. (6)

  2. Πρόσθεση του 1 για τη λήψη του χαρακτήρα μετά το πρώτο διάστημα (J). Το αποτέλεσμα είναι ο αριθμός χαρακτήρα από τον οποίο θα ξεκινήσει η αναζήτηση για το δεύτερο διάστημα. (6 + 1 = 7)

  3. Αναζήτηση του δεύτερου διαστήματος στο κελί A2, ξεκινώντας από την έβδομη θέση (J) που προέκυψε στο βήμα 2. (11)

  4. Πρόσθεση του 1 για τη λήψη του χαρακτήρα μετά το δεύτερο διάστημα (D). Το αποτέλεσμα είναι η θέση έναρξης του ονόματος. (11 + 1 = 12)

    Χρήση ένθετων συναρτήσεων SEARCH για την ανεύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του χαρακτήρα μετά το δεύτερο διάστημα (D). Το αποτέλεσμα είναι ο αριθμός χαρακτήρα από τον οποίο θα ξεκινήσει η αναζήτηση για το τρίτο διάστημα. (12)

  5. Αναζήτηση της αριθμητικής θέσης του τρίτου διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. Το αποτέλεσμα είναι η τελική θέση του ονόματος. (15)

  6. Αναζήτηση της αριθμητικής θέσης του χαρακτήρα μετά το δεύτερο διάστημα (D). Το αποτέλεσμα είναι η θέση έναρξης του ονόματος. (12)

  7. Λήψη του αριθμού χαρακτήρα του τρίτου διαστήματος που προέκυψε στο βήμα 6 και αφαίρεση του αριθμού χαρακτήρα του “D” που προέκυψε στο βήμα 7. Το αποτέλεσμα είναι ο αριθμός των χαρακτήρων που εξάγει η συνάρτηση MID από τη συμβολοσειρά κειμένου, ξεκινώντας από τη δωδέκατη θέση που προέκυψε στο βήμα 4. (15 - 12 = 3)

  8. Πατρώνυμο

    Το πατρώνυμο ξεκινάει με τον δεύτερο χαρακτήρα από τα δεξιά (K). Ο τύπος εξαγάγει δύο χαρακτήρες από τα δεξιά.

    Τύπου για το διαχωρισμό ένα επώνυμο όνομα πρώτα και το επίθημα, με κόμμα

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. (6)

  9. Πρόσθεση του 1 για τη λήψη του χαρακτήρα μετά το πρώτο διάστημα (J). Το αποτέλεσμα είναι ο αριθμός χαρακτήρα από τον οποίο θα ξεκινήσει η αναζήτηση για το δεύτερο διάστημα. (6 + 1 = 7)

  10. Αναζήτηση του δεύτερου διαστήματος στο κελί A2, ξεκινώντας από την έβδομη θέση (J) που προέκυψε στο βήμα 2. (11)

  11. Πρόσθεση του 1 για τη λήψη του χαρακτήρα μετά το δεύτερο διάστημα (D). Το αποτέλεσμα είναι η θέση έναρξης του ονόματος. (11 + 1 = 12)

  12. Αναζήτηση της αριθμητικής θέσης του τρίτου διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. Το αποτέλεσμα είναι η τελική θέση του πατρώνυμου. (15)

  13. Μέτρηση του συνολικού μήκους της συμβολοσειράς κειμένου στο κελί A2 και μετά αφαίρεση του αριθμού των χαρακτήρων από τα αριστερά μέχρι το τρίτο διάστημα που προέκυψε στο βήμα 5. Το αποτέλεσμα είναι ο αριθμός των χαρακτήρων που θα εξαχθούν από τα δεξιά του ονοματεπωνύμου. (17 - 15 = 2)

  14. Επώνυμο  

    Το επώνυμο ξεκινάει με τον πρώτο χαρακτήρα από τα αριστερά (B) και τελειώνει στον έκτο χαρακτήρα (στο πρώτο διάστημα). Γι' αυτό, ο τύπος εξαγάγει έξι χαρακτήρες από τα αριστερά.

    Τύπου για το διαχωρισμό ένα επώνυμο όνομα πρώτα και το επίθημα, με κόμμα

    Χρήση της συνάρτησης SEARCH για την εύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. (6)

  15. Επίθεμα

    Το επίθεμα ξεκινάει από τον έβδομο χαρακτήρα από τα αριστερά (J) και τελειώνει στον ένατο χαρακτήρα από τα αριστερά (.). Ο τύπος εξαγάγει τρεις χαρακτήρες, ξεκινώντας από τον έβδομο χαρακτήρα.

    Τύπου για το διαχωρισμό ένα επώνυμο όνομα πρώτα και το επίθημα, με κόμμα

    Χρήση της συνάρτησης SEARCH για την ανεύρεση της τιμής του ορίσματος αριθμός_έναρξης:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. (6)

  16. Πρόσθεση του 1 για τη λήψη του χαρακτήρα μετά το πρώτο διάστημα (J). Το αποτέλεσμα είναι η θέση έναρξης του επιθήματος. (6 + 1 = 7)

    Χρήση ένθετων συναρτήσεων SEARCH για την ανεύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. (6)

  17. Πρόσθεση του 1 για τη λήψη της θέσης του χαρακτήρα μετά το πρώτο διάστημα (J). Το αποτέλεσμα είναι ο αριθμός χαρακτήρα από τον οποίο θα ξεκινήσει η αναζήτηση για το δεύτερο διάστημα. (7)

  18. Αναζήτηση του δεύτερου διαστήματος στο κελί A2, ξεκινώντας από την έβδομη θέση που προέκυψε στο βήμα 4. (11)

  19. Αφαίρεση του 1 από τον αριθμό χαρακτήρα του δεύτερου διαστήματος που προέκυψε στο βήμα 4 για τη λήψη του αριθμού χαρακτήρα του ",". Το αποτέλεσμα είναι η τερματική θέση του επιθήματος. (11 - 1 = 10)

  20. Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος. (6)

  21. Αφού βρεθεί το πρώτο διάστημα, προστίθεται το 1 για τη λήψη του επόμενου χαρακτήρα (J), που προέκυψε επίσης στα βήματα 3 και 4. (7)

  22. Λήψη του αριθμού χαρακτήρα του “,” που προέκυψε στο βήμα 6 και αφαίρεση του αριθμού χαρακτήρα του “J” που προέκυψε στα βήματα 3 και 4. Το αποτέλεσμα είναι ο αριθμός των χαρακτήρων που εξάγει η συνάρτηση MID από τη συμβολοσειρά κειμένου, ξεκινώντας από την έβδομη θέση που προέκυψε στο βήμα 2. (10 - 7 = 3)

Σε αυτό το παράδειγμα, το όνομα είναι στην αρχή της συμβολοσειράς και το επίθημα βρίσκεται στο τέλος, συνεπώς μπορείτε να χρησιμοποιήσετε τύπους παρόμοιους με εκείνους του Παραδείγματος 2: Χρησιμοποιήστε τη συνάρτηση LEFT για να εξαγάγετε το όνομα, τη συνάρτηση MID για να εξαγάγετε το επώνυμο και τη συνάρτηση RIGHT για να εξαγάγετε το επίθημα.

Αντιγράψτε τα κελιά του πίνακα και επικολλήστε στο φύλλο εργασίας του Excel από το κελί A1. Ο τύπος που βλέπετε στην αριστερή πλευρά θα εμφανίζονται για αναφορά, ενώ το Excel θα μετατραπεί αυτόματα τον τύπο στη δεξιά πλευρά σε το κατάλληλο αποτέλεσμα.

Υπόδειξη    Πριν επικολλήσετε τα δεδομένα στο φύλλο εργασίας, ορίστε τα πλάτη των στηλών για τις στήλες A και B σε 250.

Όνομα παραδείγματος

Περιγραφή

Gary Altman III

Όνομα και επώνυμο με επίθεμα

Τύπος

Αποτέλεσμα (όνομα)

'=LEFT(A2; SEARCH(" ";A2;1))

=LEFT(A2; SEARCH(" ";A2;1))

Τύπος

Αποτέλεσμα (επώνυμο)

'=MID(A2;SEARCH(" ";A2;1)+1;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)-(SEARCH(" ";A2;1)+1))

=MID(A2;SEARCH(" ";A2;1)+1;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)-(SEARCH(" ";A2;1)+1))

Τύπος

Αποτέλεσμα (επίθημα)

'=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;1)+1))

=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;1)+1))

  1. Όνομα  

    Το όνομα ξεκινάει με τον πρώτο χαρακτήρα από τα αριστερά (G) και τελειώνει στον πέμπτο χαρακτήρα (στο πρώτο διάστημα). Γι' αυτό, ο τύπος εξαγάγει πέντε χαρακτήρες από τα αριστερά του ονοματεπωνύμου.

    Τύπος για το διαχωρισμό μια πρώτη και επώνυμου που ακολουθείται από μια επίθημα

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. (5)

  2. Επώνυμο  

    Το επώνυμο ξεκινάει με τον έκτο χαρακτήρα από τα αριστερά (A) και τελειώνει στον ενδέκατο χαρακτήρα (στο δεύτερο διάστημα). Αυτός ο τύπος περιλαμβάνει ένθεση της συνάρτησης SEARCH για τον εντοπισμό των θέσεων των διαστημάτων.

    Ο τύπος εξαγάγει έξι χαρακτήρες από το πατρώνυμο, ξεκινώντας από τον έκτο χαρακτήρα.

    Τύπος για το διαχωρισμό μια πρώτη και επώνυμου που ακολουθείται από μια επίθημα

    Χρήση της συνάρτησης SEARCH για την ανεύρεση της τιμής του ορίσματος αριθμός_έναρξης:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. (5)

  3. Πρόσθεση του 1 για τη λήψη της θέσης του χαρακτήρα μετά το πρώτο διάστημα (A). Το αποτέλεσμα είναι η θέση έναρξης του επωνύμου. (5 + 1 = 6)

    Χρήση ένθετων συναρτήσεων SEARCH για την ανεύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. (5)

  4. Πρόσθεση του 1 για τη λήψη της θέσης του χαρακτήρα μετά το πρώτο διάστημα (A). Το αποτέλεσμα είναι ο αριθμός χαρακτήρα από τον οποίο θα ξεκινήσει η αναζήτηση για το δεύτερο διάστημα. (5 + 1 = 6)

  5. Αναζήτηση της αριθμητικής θέσης του δεύτερου διαστήματος στο κελί A2, ξεκινώντας από τον έκτο χαρακτήρα που προέκυψε στο βήμα 4. Αυτός ο αριθμός χαρακτήρα είναι η τερματική θέση του επωνύμου. (12)

  6. Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος. (5)

  7. Πρόσθεση του 1 για τη λήψη της αριθμητικής θέσης του χαρακτήρα μετά το πρώτο διάστημα (A) που προέκυψε επίσης στα βήματα 3 και 4. (6)

  8. Λήψη του αριθμού χαρακτήρα του δεύτερου διαστήματος που προέκυψε στο βήμα 5 και αφαίρεση του αριθμού χαρακτήρα του “A” που προέκυψε στα βήματα 6 και 7. Το αποτέλεσμα είναι ο αριθμός των χαρακτήρων που εξάγει η συνάρτηση MID από τη συμβολοσειρά κειμένου, ξεκινώντας από την έκτη θέση που προέκυψε στο βήμα 2. (12 - 6 = 6)

  9. Επίθεμα

    Το επίθεμα ξεκινάει τρεις χαρακτήρες από τα δεξιά. Αυτός ο τύπος περιλαμβάνει ένθεση της συνάρτησης SEARCH για τον εντοπισμό των θέσεων των διαστημάτων.

    Τύπος για το διαχωρισμό μια πρώτη και επώνυμου που ακολουθείται από μια επίθημα

    Χρήση ένθετων συναρτήσεων SEARCH και της συνάρτησης LEN για την ανεύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. (5)

  10. Πρόσθεση του 1 για τη λήψη του χαρακτήρα μετά το πρώτο διάστημα (A). Το αποτέλεσμα είναι ο αριθμός χαρακτήρα από τον οποίο θα ξεκινήσει η αναζήτηση για το δεύτερο διάστημα. (5 + 1 = 6)

  11. Αναζήτηση του δεύτερου διαστήματος στο κελί A2, ξεκινώντας από την έκτη θέση (A) που προέκυψε στο βήμα 2. (12)

  12. Μέτρηση του συνολικού μήκους της συμβολοσειράς κειμένου στο κελί A2 και μετά αφαίρεση του αριθμού των χαρακτήρων από τα αριστερά μέχρι το δεύτερο διάστημα που προέκυψε στο βήμα 3. Το αποτέλεσμα είναι ο αριθμός των χαρακτήρων που θα εξαχθούν από τα δεξιά του ονοματεπωνύμου. (15 - 12 = 3)

Σε αυτό το παράδειγμα προηγείται ένα πρόθεμα του ονοματεπώνυμου. Οι τύποι που χρησιμοποιούνται για τα στοιχεία του ονόματος μοιάζουν με το Παράδειγμα 2, όπου το όνομα εξάγεται με τη χρήση της συνάρτησης MID και το επώνυμο εξάγεται με τη χρήση της συνάρτησης RIGHT.

Αντιγράψτε τα κελιά του πίνακα και επικολλήστε στο φύλλο εργασίας του Excel από το κελί A1. Ο τύπος που βλέπετε στην αριστερή πλευρά θα εμφανίζονται για αναφορά, ενώ το Excel θα μετατραπεί αυτόματα τον τύπο στη δεξιά πλευρά σε το κατάλληλο αποτέλεσμα.

Υπόδειξη    Πριν επικολλήσετε τα δεδομένα στο φύλλο εργασίας, ορίστε τα πλάτη των στηλών για τις στήλες A και B σε 250.

Όνομα παραδείγματος

Περιγραφή

Mr. Ryan Ihrig

Με πρόθεμα

Τύπος

Αποτέλεσμα (όνομα)

'=MID(A2;SEARCH(" ";A2;1)+1;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)-(SEARCH(" ";A2;1)+1))

=MID(A2;SEARCH(" ";A2;1)+1;SEARCH(" ";A2;SEARCH(" ";A2;1)+1)-(SEARCH(" ";A2;1)+1))

Τύπος

Αποτέλεσμα (επώνυμο)

'=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;1)+1))

=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;SEARCH(" ";A2;1)+1))

  1. Όνομα  

    Το όνομα ξεκινά με τον πέμπτο χαρακτήρα από αριστερά (R) και τελειώνει στον ένατο χαρακτήρα (στο δεύτερο διάστημα). Αυτός ο τύπος χρησιμοποιεί ένθεση της συνάρτησης SEARCH για τον εντοπισμό των θέσεων των διαστημάτων. Ο τύπος εξάγει τέσσερις χαρακτήρες, ξεκινώντας από την πέμπτη θέση.

    Τύπος για το διαχωρισμό ονόματος προηγείται ένα πρόθεμα

    Χρήση της συνάρτησης SEARCH για την ανεύρεση της τιμής του ορίσματος αριθμός_έναρξης:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. (4)

  2. Πρόσθεση του 1 για τη λήψη της θέσης του χαρακτήρα μετά το πρώτο διάστημα (R). Το αποτέλεσμα είναι η θέση έναρξης του ονόματος. (4 + 1 = 5)

    Χρήση ένθεσης της συνάρτησης SEARCH για την ανεύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. (4)

  3. Πρόσθεση του 1 για τη λήψη της θέσης του χαρακτήρα μετά το πρώτο διάστημα (R). Το αποτέλεσμα είναι ο αριθμός χαρακτήρα από τον οποίο θα ξεκινήσει η αναζήτηση για το δεύτερο διάστημα. (4 + 1 = 5)

  4. Αναζήτηση της αριθμητικής θέσης του δεύτερου διαστήματος στο κελί A2, ξεκινώντας από τον πέμπτο χαρακτήρα που προέκυψε στα βήματα 3 και 4. Αυτός ο αριθμός χαρακτήρα είναι η τερματική θέση του ονόματος. (9)

  5. Αναζήτηση του πρώτου διαστήματος. (4)

  6. Πρόσθεση του 1 για τη λήψη της αριθμητικής θέσης του χαρακτήρα μετά το πρώτο διάστημα (R) που προέκυψε επίσης στα βήματα 3 και 4. (5)

  7. Λήψη του αριθμού χαρακτήρα του δεύτερου διαστήματος που προέκυψε στο βήμα 5 και αφαίρεση του αριθμού χαρακτήρα του "R" που προέκυψε στα βήματα 6 και 7. Το αποτέλεσμα είναι ο αριθμός των χαρακτήρων που εξάγει η συνάρτηση MID από τη συμβολοσειρά κειμένου, ξεκινώντας από την πέμπτη θέση που προέκυψε στο βήμα 2. (9 - 5 = 4)

  8. Επώνυμο  

    Το επώνυμο ξεκινάει πέντε χαρακτήρες από τα δεξιά. Αυτός ο τύπος περιλαμβάνει ένθεση της συνάρτησης SEARCH για τον εντοπισμό των θέσεων των διαστημάτων.

    Τύπος για το διαχωρισμό ονόματος προηγείται ένα πρόθεμα

    Χρήση ένθετων συναρτήσεων SEARCH και της συνάρτησης LEN για την ανεύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. (4)

  9. Πρόσθεση του 1 για τη λήψη της θέσης του χαρακτήρα μετά το πρώτο διάστημα (R). Το αποτέλεσμα είναι ο αριθμός χαρακτήρα από τον οποίο θα ξεκινήσει η αναζήτηση για το δεύτερο διάστημα. (4 + 1 = 5)

  10. Αναζήτηση του δεύτερου διαστήματος στο κελί A2, ξεκινώντας από την πέμπτη θέση (R) που προέκυψε στο βήμα 2. (9)

  11. Μέτρηση του συνολικού μήκους της συμβολοσειράς κειμένου στο κελί A2 και μετά αφαίρεση του αριθμού των χαρακτήρων από τα αριστερά μέχρι το δεύτερο διάστημα που προέκυψε στο βήμα 3. Το αποτέλεσμα είναι ο αριθμός των χαρακτήρων που θα εξαχθούν από τα δεξιά του ονοματεπωνύμου. (14 - 9 = 5)

Το παράδειγμα αυτό χρησιμοποιεί επώνυμο με ενωτικό. Κάθε στοιχείο του ονόματος διαχωρίζεται με ένα διάστημα.

Αντιγράψτε τα κελιά του πίνακα και επικολλήστε στο φύλλο εργασίας του Excel από το κελί A1. Ο τύπος που βλέπετε στην αριστερή πλευρά θα εμφανίζονται για αναφορά, ενώ το Excel θα μετατραπεί αυτόματα τον τύπο στη δεξιά πλευρά σε το κατάλληλο αποτέλεσμα.

Υπόδειξη    Πριν επικολλήσετε τα δεδομένα στο φύλλο εργασίας, ορίστε τα πλάτη των στηλών για τις στήλες A και B σε 250.

Όνομα παραδείγματος

Περιγραφή

Julie Taft-Rider

Επώνυμο με ενωτικό

Τύπος

Αποτέλεσμα (όνομα)

'=LEFT(A2; SEARCH(" ";A2;1))

=LEFT(A2; SEARCH(" ";A2;1))

Τύπος

Αποτέλεσμα (επώνυμο)

'=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;1))

=RIGHT(A2;LEN(A2)-SEARCH(" ";A2;1))

  1. Όνομα  

    Το όνομα ξεκινάει με τον πρώτο χαρακτήρα από τα αριστερά (P) και τελειώνει στην έκτη θέση (στο πρώτο διάστημα). Ο τύπος εξαγάγει έξι χαρακτήρες από τα αριστερά.

    Τύπος για το διαχωρισμό μια πρώτη και ένα επώνυμο με ενωτικό

    Χρήση της συνάρτησης SEARCH για την ανεύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του πρώτου διαστήματος στο κελί A2, ξεκινώντας από τα αριστερά. (6)

  2. Επώνυμο  

    Ολόκληρο το επώνυμο ξεκινάει δέκα χαρακτήρες από τα δεξιά (T) και τελειώνει στον πρώτο χαρακτήρα από τα δεξιά (r).

    Τύπος για το διαχωρισμό μια πρώτη και ένα επώνυμο με ενωτικό

    Χρήση των συναρτήσεων LEN και SEARCH για την ανεύρεση της τιμής του ορίσματος αριθμός_χαρακτήρων:

    Αναζήτηση της αριθμητικής θέσης του διαστήματος στο κελί A2, ξεκινώντας από τον πρώτο χαρακτήρα στα αριστερά. (6)

  3. Μέτρηση του συνολικού μήκους της συμβολοσειράς κειμένου και μετά αφαίρεση του αριθμού των χαρακτήρων από τα αριστερά μέχρι το πρώτο διάστημα που προέκυψε στο βήμα 1. (16 - 6 = 10)

Δείτε επίσης

Διαίρεση κειμένου σε διαφορετικές στήλες με του Οδηγού μετατροπής κειμένου σε στήλες

Αναπτύξτε τις δεξιότητές σας στο Office
Εξερευνήστε το περιεχόμενο της εκπαίδευσης
Αποκτήστε πρώτοι τις νέες δυνατότητες
Γίνετε μέλος του Office Insider

Σας βοήθησαν αυτές οι πληροφορίες;

Σας ευχαριστούμε για τα σχόλιά σας!

Σας ευχαριστούμε για τα σχόλιά σας! Φαίνεται ότι μπορεί να είναι χρήσιμο να συνδεθείτε με έναν από τους συνεργάτες υποστήριξης του Office.

×