Zu Hauptinhalt springen
WENN-Funktion – Geschachtelte Formeln und das Vermeiden von Fallgruben

WENN-Funktion – Geschachtelte Formeln und das Vermeiden von Fallgruben

Die WENN-Funktion ermöglicht einen logischen Vergleich zwischen einem aktuellen Wert und einem erwarteten Wert. Dazu wird auf eine Bedingung geprüft und ein Ergebnis zurückgegeben, wenn der Wert wahr oder falsch ist.

  • WENN(ein Wert wahr ist, tue dieses, andernfalls tue etwas anderes)

Daher kann eine WENN-Anweisung zwei Ergebnisse haben. Das erste Ergebnis wird ausgegeben, wenn der Vergleich wahr ist, das zweite, wenn der Vergleich falsch ist.

WENN-Anweisungen sind unglaublich robust und bilden die Basis vieler Kalkulationstabellenmodelle, sind aber auch die Ursache vieler Probleme mit Kalkulationstabellen. Im Idealfall sollte eine WENN-Anweisung für minimale Bedingungen gelten (z. B. Männlich/Weiblich, Ja/Nein/Vielleicht, um nur einige zu nennen), doch müssen manchmal komplexere Szenarien ausgewertet werden, die das Schachteln* von mehr als 3 WENN-Funktionen erfordern.

* Als "Schachteln" wird das Zusammenführen mehrerer Funktionen in einer Formel bezeichnet.

Verwenden Sie die Funktion WENN, eine der logischen Funktionen, um einen Wert zurückzugeben, wenn eine Bedingung erfüllt ist, und ein anderen Wert, wenn die Bedingung nicht erfüllt ist.

Syntax

WENN(Prüfung;Dann_Wert;[Sonst_Wert])

Beispiel:

  • =WENN(A2>B2;"Budget überschritten";"OK")

  • =WENN(A2=B2;B4-A4;"")

Argumentname

Beschreibung

Prüfung   

(erforderlich)

Die zu prüfende Bedingung.

Dann_Wert   

(erforderlich)

Der Wert, der zurückgegeben werden soll, wenn das Ergebnis der Prüfung WAHR ist.

Sonst_Wert   

(optional)

Der Wert, der zurückgegeben werden soll, wenn das Ergebnis der Prüfung FALSCH ist.

Hinweise

Excel erlaubt zwar das Schachteln von bis zu 64 unterschiedlichen WENN-Funktionen, dennoch ist das nicht ratsam. Warum?

  • Mehrere WENN-Anweisungen erfordern ein hohes Maß an Konzentration, um korrekt erstellt zu werden und um sicherzustellen, dass deren Logik über jede Bedingung bis zum Schluss ordnungsgemäß berechnet wird. Wird die Formel nicht zu 100 % korrekt geschachtelt, funktioniert sie möglicherweise nur zu 75 % und gibt in 25 % der Fälle unerwartete Ergebnisse zurück. Unglücklicherweise ist es fast unmöglich, diese problematischen 25 % abzufangen.

  • Mehrere WENN-Anweisungen sind ggf. unglaublich schwierig zu verwalten, besonders, wenn Sie später noch einmal darauf zurückkommen und versuchen herauszufinden, was Sie oder – noch schlimmer – eine andere Person hiermit erreichen wollten.

Wenn Sie eine WENN-Anweisung haben, die einfach immer weiter anzuwachsen scheint und bei der kein Ende in Sicht ist, sollten Sie die Maus aus der Hand legen und Ihre Strategie überdenken.

Sehen wir uns einmal an, wie eine komplexe geschachtelte WENN-Anweisung mit mehreren WENN-Funktionen ordnungsgemäß erstellt wird, und wann abzusehen ist, dass ein anderes Tool aus dem Excel-Arsenal zu verwenden ist.

Beispiele

Es folgt ein Beispiel für eine recht übliche geschachtelte WENN-Anweisung, mit der Testergebnisse von Schülern in die mit Buchstaben bezeichneten Einstufungen konvertiert werden.

Komplexe geschachtelte WENN-Anweisung – Die Formel in E2 lautet =WENN(B2>97;"A+":WENN(B2>93;"A";WENN(B2>89;"A-";WENN(B2>87;"B+";IF(B2>83;"B";WENN(B2>79;"B-";WENN(B2>77;"C+";WENN(B2>73;"C";WENN(B2>69;"C-";WENN(B2>57;"D+";WENN(B2>53;"D";WENN(B2>49;"D-";"F"))))))))))))
  • =WENN(D2>89;"A";WENN(D2>79;"B";WENN(D2>69;"C";WENN(D2>59;"D";"F"))))

    Diese komplexe geschachtelte WENN-Anweisung folgt einer einfachen Logik:

  1. Wenn das Testergebnis (in Zelle D2) höher als 89 ist, erhält der Schüler ein A.

  2. Wenn das Testergebnis höher als 79 ist, erhält der Schüler ein B.

  3. Wenn das Testergebnis höher als 69 ist, erhält der Schüler ein C.

  4. Wenn das Testergebnis höher als 59 ist, erhält der Schüler ein D.

  5. Andernfalls erhält der Schüler ein F.

Dieses besondere Beispiel ist relativ sicher, da es nicht wahrscheinlich ist, dass sich die Korrelation zwischen den Testergebnissen und den Buchstaben ändert, sodass Sie nicht viel gewartet werden muss. Aber hier ist ein Gedanke – Was ist, wenn Sie die Noten zwischen a +, a und a-(usw.) segmentieren müssen? Nun müssen Sie Ihre vier Bedingung für die Bedingung, wenn die Anweisung neu geschrieben werden muss, um 12 Bedingungen zu haben! So würde Ihre Formel jetzt aussehen:

  • =WENN(B2>97;"A+";WENN(B2>93;"A";WENN(B2>89;"A-";WENN(B2>87;"B+";WENN(B2>83;"B";WENN(B2>79;"B-";WENN(B2>77;"C+";WENN(B2>73;"C";WENN(B2>69;"C-";WENN(B2>57;"D+";WENN(B2>53;"D";WENN(B2>49;"D-";"F"))))))))))))

Die Formel funktioniert immer noch korrekt und erwartungsgemäß, doch nimmt das Schreiben und Testen zur Sicherstellung der ordnungsgemäßen Ausführung mehr Zeit in Anspruch. Ein weiteres offensichtliches Problem ist, dass Sie die Punktzahlen und die entsprechenden Einstufungen von Hand eingeben müssten. Wie wahrscheinlich ist es, dass Sie versehentlich einen Tippfehler machen? Stellen Sie sich nun vor, Sie würden das bei noch komplexeren Bedingungen 64-mal machen! Natürlich ist das möglich, doch möchten Sie wirklich solchen Aufwand treiben und Fehler riskieren, die nur sehr schwer zu erkennen sind?

Tipp: Jede Funktion in Excel erfordert eine öffnende und eine schließende Klammer (). Excel unterstützt Sie beim Zusammenstellen der Formel, indem verschiedene Teile während der Bearbeitung farblich gekennzeichnet werden. Wenn Sie beispielsweise die oben angegebene Formel bearbeiten, wird beim Bewegen des Cursors hinter die einzelnen schließenden Klammern ")" die jeweils entsprechende öffnende Klammer in der gleichen Farbe angezeigt. Dies kann bei komplexen geschachtelten Formeln besonders hilfreich sein, wenn Sie herauszufinden versuchen, ob Sie über genügend Klammerpaare verfügen.

Weitere Beispiele

Es folgt ein typisches Beispiel der Berechnung einer Vertriebsprovision basierend auf der Umsatzhöhe.

Die Formel in Zelle D9 lautet WENN(C9>15000;20%;WENN(C9>12500;17,5%;WENN(C9>10000;15%;WENN(C9>7500;12,5%;WENN(C9>5000;10%;0)))))
  • =WENN(C9>15000;20%;WENN(C9>12500;17,5%;WENN(C9>10000;15%;WENN(C9>7500;12,5%;WENN(C9>5000;10%;0)))))

Diese Formel besagt Folgendes: WENN(C9 größer ist als 15.000, wird 20% zurückgegeben; WENN(C9 größer ist als 12.500, wird 17,5% zurückgegeben usw.

Diese Formel ist zwar erstaunlich ähnlich wie im Beispiel für frühere Klassen, doch ist diese Formel ein hervorragendes Beispiel dafür, wie schwierig es sein kann, große if-Anweisungen zu verwalten – Was müssten Sie tun, wenn Ihre Organisation beschloss, neue Vergütungsstufen hinzuzufügen und möglicherweise sogar die vorhandenen Dollar-oder Prozentwerte zu ändern? Sie hätten viel Arbeit an Ihren Händen!

Tipp: Sie können in der Bearbeitungsleiste Zeilenumbrüche einfügen, damit lange Formeln leichter zu lesen sind. Drücken Sie einfach ALT+EINGABE vor dem Text, den Sie in eine neue Zeile umbrechen möchten.

Es folgt ein Beispiel für das Provisionsszenario mit fehlerhafter Logik:

Die Formel in D9 ist fehlerhaft und lautet =WENN(C9>5000;10%;WENN(C9>7500;12,5%;WENN(C9>10000;15%;WENN(C9>12500;17,5%;WENN(C9>15000;20%;0)))))

Können Sie sehen, wo der Fehler liegt? Vergleichen Sie die Reihenfolge der Umsätze mit dem vorherigen Beispiel. Welche Reihenfolge liegt hier vor? Wie Sie sehen, verläuft die Reihenfolge vom niedrigsten zum höchsten Wert (von 5.000 € bis 15.000 €) und nicht umgekehrt. Aber warum ist das so eine große Sache? Der Grund ist, dass die Formel die erste Auswertung nicht für einen Wert über 5.000 € durchführen kann. Wenn Sie beispielsweise einen Umsatz von 12.500 € haben, gibt die WENN-Anweisung 10 % zurück, da der Wert größer als 5.000 € ist, und stoppt dann. Dies kann besonders problematisch sein, da diese Art von Fehlern in vielen Situationen so lange unbemerkt bleibt, bis sie eine negative Auswirkung hat. Sie wissen also, dass bei komplexen geschachtelten WENN-Anweisungen schwerwiegende Probleme auftreten können, doch was können Sie tun? In den meisten Fällen können Sie die Funktion SVERWEIS verwenden, statt eine komplexe Formel mit der WENN-Funktion zu erstellen. Für die Funktion SVERWEIS müssen Sie zuerst eine Bezugstabelle erstellen:

Die Formel in Zelle D2 lautet =SVERWEIS(C2;C5:D17;2;WAHR)
  • =SVERWEIS(C2;C5:D17;2;WAHR)

Diese Formel besagt, dass nach dem Wert in C2 im Bereich C5:C17 gesucht werden soll. Wird der Wert gefunden, wird der entsprechende Wert aus der gleichen Zeile in Spalte D zurückgegeben.

Die Formel in Zelle C9 lautet =SVERWEIS(B9;B2:C6;2;WAHR)
  • =SVERWEIS(B9;B2:C6;2;WAHR)

Bei dieser Formel wird nach dem Wert in Zelle B9 im Bereich B2:B22 gesucht. Wird der Wert gefunden, wird der entsprechende Wert aus der gleichen Zeile in Spalte C zurückgegeben.

Hinweis: Beide VLOOKUPs verwenden das Argument true am Ende der Formeln, was bedeutet, dass Sie nach einer approxiate Übereinstimmung suchen möchten. Mit anderen Worten: Es entspricht den genauen Werten in der Nachschlagetabelle sowie allen Werten, die zwischen Ihnen liegen. In diesem Fall müssen die Nachschlagetabellen in aufsteigender Reihenfolge von der kleinsten zur größten sortiert werden.

SVERWEIS wird hierviel detaillierter behandelt, doch dies ist sicherlich viel einfacher als eine komplexe geschachtelte if-Anweisung mit 12 Ebenen! Es gibt auch noch andere, weniger offensichtliche Vorteile:

  • SVERWEIS-Bezugstabellen stehen offen bereit und sind leicht zu sehen.

  • Tabellenwerte können problemlos aktualisiert werden, und Sie müssen die Formel nicht bearbeiten, wenn sich die Bedingungen ändern.

  • Wenn Sie nicht möchten, dass andere Personen die Bezugstabelle sehen oder ändern können, speichern Sie sie einfach in einem anderen Arbeitsblatt.

Wussten Sie schon?

Es gibt jetzt eine WENNS-Funktion, die mehrere geschachtelte WENN-Anweisung durch eine einzelne Funktion ersetzen kann. Das anfängliche Beispiel mit den Einstufungen, bei dem vier geschachtelte WENN-Funktionen verwendet werden:

  • =WENN(D2>89;"A";WENN(D2>79;"B";WENN(D2>69;"C";WENN(D2>59;"D";"F"))))

kann durch eine einzelne WENNS-Funktion wesentlich vereinfacht werden:

  • =WENNS(D2>89;"A";D2>79;"B";D2>69;"C";D2>59;"D";WAHR;"F")

Der Vorteil der WENNS-Funktion besteht darin, dass Sie sich keine Gedanken über alle diese WENN-Anweisungen und Klammern machen müssen.

Hinweis: Dieses Feature ist nur verfügbar, wenn Sie über ein Microsoft 365-Abonnement verfügen. Wenn Sie Microsoft 365-Abonnent sind,vergewissern Sie sich, dass Sie über die neueste Office-Version verfügen.

Benötigen Sie weitere Hilfe?

Sie können jederzeit einen Experten in der Excel Tech Community fragen, Unterstützung in der Answers Community erhalten oder aber ein neues Feature oder eine Verbesserung auf Excel User Voice vorschlagen.

Verwandte Themen

Video: Erweiterte wenn-Funktionen
IFS-Funktion (Microsoft 365, Excel 2016 und höher)
die ZÄHLENWENN-Funktion zählt Werte basierend auf einem einzelnen Kriterium
, beidem die ZÄHLENWENNS-Funktion Werte basierend auf mehreren Kriterien
zählt.die SUMMEWENN-Funktion addiert Werte basierend auf einem einzelnen Kriterium
,das die SUMMEWENNS-Funktion aufführt. Addieren von Werten auf der Grundlage mehrerer Kriterien
und
Funktionoder Funktion
SVERWEIS-Funktion
Übersicht über Formeln in Excel
So vermeiden Sie fehlerhafte Formeln
Erkennen von Fehlern in Formeln
logische Funktionen
Excel-Funktionen (alphabetisch) Excel-
Funktionen (nach Kategorie)

Hinweis:  Diese Seite wurde automatisiert übersetzt und kann Grammatikfehler oder Ungenauigkeiten enthalten. Unser Ziel ist es, Ihnen hilfreiche Inhalte bereitzustellen. Lassen Sie uns bitte wissen, ob diese Informationen hilfreich für Sie waren. Hier finden Sie den englischen Artikel als Referenz.

Ihre Office-Fähigkeiten erweitern
Schulungen erkunden
Neue Funktionen als Erster erhalten
Office Insider werden

War diese Information hilfreich?

Vielen Dank für Ihr Feedback!

Vielen Dank für Ihr Feedback. Es klingt, als ob es hilfreich sein könnte, Sie mit einem unserer Office-Supportmitarbeiter zu verbinden.

×