Format-Funktion

Beispiele

Verwenden der Format-Funktion in einem Ausdruck    Sie können Format überall verwenden, wo Ausdrücke zulässig sind. Beispielsweise können Sie sie in einer Abfrage als Teil eines Feldalias oder in der Control Source-Eigenschaft eines Textfelds in einem Formular oder einem Bericht verwenden. Das folgende Beispiel zeigt einen Ausdruck, den Sie in einer Filter-Eigenschaft eines Berichts verwenden können, um die Ausgabe auf Datensätze der vorherigen Woche zu beschränken.

Format([Datum],"ww")=Format(Now(),"ww")-1

In diesem Beispiel verfügt die Datensatzquelle des Berichts über ein Feld namens "Datum", das das Datum enthält, an dem jeder einzelne Datensatz, der im Bericht verwendet wird, geändert wurde. Beim Ausführen des Berichts werden die Ergebnisse so gefiltert, dass nur die Datensätze angezeigt werden, bei denen der Wert im Feld "Datum" (Format([Datum],"ww")) der vorherigen Woche entspricht (Format(Now(),"ww")-1).

Verwenden der Format-Funktion in VBA-Code    

In diesem Beispiel werden unterschiedliche Verwendungsmöglichkeiten der Format-Funktion gezeigt, um Werte mithilfe von benannten und benutzerdefinierten Formaten zu formatieren. Für das Datumstrennzeichen (/), das Zeittrennzeichen (:) und das AM/PM-Literal hängt die tatsächliche formatierte, von Ihrem System angezeigte Ausgabe von den Gebietsschemaeinstellungen des Computers ab, auf dem der Code ausgeführt wird. Wenn Uhrzeit und Datum in der Entwicklungsumgebung angezeigt werden, wird das kurze Uhrzeit-/Datumsformat des Code-Gebietsschemas verwendet. Bei der Anzeige durch Ausführen des Codes wird das kurze Uhrzeit-/Datumsformat des System-Gebietsschemas verwendet, welches vom Code-Gebietsschema abweichen kann. Für dieses Beispiel verwenden wir Englisch (USA).

MyTime und MyDate werden in der Entwicklungsumgebung mit der kurzen Uhrzeit-/Datumseinstellung des Systems angezeigt.

Dim MyTime, MyDate, MyStr
MyTime = #17:04:23#
MyDate = #January 27, 1993#
' Returns current system time in the system-defined long time format.
MyStr = Format(Time, "Long Time")
' Returns current system date in the system-defined long date format.
MyStr = Format(Date, "Long Date")
MyStr = Format(MyTime, "h:m:s")    ' Returns "17:4:23".
MyStr = Format(MyTime, "hh:mm:ss AMPM")    ' Returns "05:04:23 PM".
MyStr = Format(MyDate, "dddd, mmm d yyyy")    ' Returns "Wednesday,
    ' Jan 27 1993".
' If format is not supplied, a string is returned.
MyStr = Format(23)    ' Returns "23".
' User-defined formats.
MyStr = Format(5459.4, "##,##0.00")    ' Returns "5,459.40".
MyStr = Format(334.9, "###0.00")    ' Returns "334.90".
MyStr = Format(5, "0.00%")    ' Returns "500.00%".
MyStr = Format("HELLO", "<")    ' Returns "hello".
MyStr = Format("This is it", ">")    ' Returns "THIS IS IT".

Verwenden von Format mit leeren Zeichenfolgen

In Microsoft Access 2.0 und früher konnten Sie die Format-Funktion verwenden, um für eine Leere Zeichenfolge einen Wert und für einen Wert einen anderen Wert zurückzugeben. Sie konnten z. B. einen Formatausdruck wie etwa den folgenden mit der Format-Funktion verwenden, um den entsprechenden Zeichenfolgenwert aus Code zurückzugeben:

Dim varX As Variant
Dim varStrX As Variant
' Assign some value to varStrX and pass to Format function.
varX = Format(varStrX, "@;ZLS;Null")

In Microsoft Access 97 und höher müssen Sie separat auf den Nullwert testen, und den entsprechenden Wert basierend auf dem Ergebnis zurückgeben. Sie könnten beispielsweise die IIf-Funktion in einem Ausdruck mit der Format-Funktion verwenden, wie im Folgenden dargestellt:

varX = IIf(IsNull(varStrX),"Null", Format(varStrX, "@;ZLS"))

Diese Änderung gilt nur dann, wenn Sie die Format-Funktion verwenden, um eine Zeichenfolge abhängig davon zu formatieren, ob es sich um eine leere Zeichenfolge oder einen NULL-Wert handelt. Andere mit der Format-Funktion verwendete Formatausdrücke funktionieren weiterhin wie in früheren Versionen.

Wenn Sie eine Datenbank von Microsoft Access 2.0 oder früher in Microsoft Access 2002 oder höher konvertieren, müssen Sie Code ändern, um separat auf NULL-Werte zu testen.