ZÄHLENWENN (Funktion)

Verwenden Sie ZÄHLENWENN, eine der statistischen Funktionen, um die Anzahl der Zellen zu zählen, die ein Kriterium erfüllen; beispielsweise, um zu ermitteln, wie oft eine bestimmte Stadt in einer Kundenliste vorkommt.

Ihr Browser unterstützt kein Video. Installieren Sie Microsoft Silverlight, Adobe Flash Player oder Internet Explorer 9.

Hinweis : Die ZÄHLENWENN-Funktion unterstützt Daten oder Bereiche nicht direkt, die auf der Hintergrund- oder Schriftfarbe von Datenzellen basieren. Excel unterstützt die Definition von benutzerdefinierten Funktionen (User-Defined Functions, UDFs) mithilfe des Microsoft Visual Basic for Applications-Editors, um Excel-Operationen in Zellen und Tabellen zu unterstützen, die Farbe zum Markieren von Daten anwenden. (Drücken Sie ALT+F11, um den Editor zu öffnen.)

Syntax

ZÄHLENWENN(Bereich;Suchkriterium)

Beispiel:

  • =ZÄHLENWENN(A2:A5;"Äpfel")

  • =ZÄHLENWENN(A2:A5;A4)

Argumentname

Beschreibung

Bereich    (erforderlich)

Die Gruppe von Zellen, die Sie zählen möchten. Bereich kann Zahlen, Matrizen, einen benannten Bereich oder Bezüge mit Zahlen enthalten. Leere Werte und Textwerte werden ignoriert.

Informationen zum Markieren von Bereichen auf einem Arbeitsblatt.

Suchkriterium    (erforderlich)

Eine Zahl, ein Ausdruck, ein Zellbezug oder eine Textzeichenfolge, durch die bzw. den definiert wird, welche Zellen gezählt werden.

Als Suchkriterien können Zahlen wie 32, Vergleiche wie ">32", eine Zelle wie B4 oder Wörter wie "Äpfel" angegeben werden.

Für ZÄHLENWENN kann nur ein einzelnes Suchkriterium angegeben werden. Verwenden Sie ZÄHLENWENNS, wenn Sie mehrere Kriterien angeben möchten.

Beispiele

Zum Verwenden dieser Beispiele in Excel kopieren Sie die Daten in der folgenden Tabelle, und fügen Sie sie in Zelle A1 eines neuen Arbeitsblatts ein.

Daten

Daten

Äpfel

32

Orangen

54

Pfirsiche

75

Äpfel

86

Formel

Beschreibung

=ZÄHLENWENN(A2:A5;"Äpfel")

Ermittelt die Anzahl der Zellen mit dem Wert "Äpfel" in den Zellen A2 bis A5. Das Ergebnis lautet "2".

=ZÄHLENWENN(A2:A5;A4)

Ermittelt die Anzahl der Zellen mit dem Wert "Pfirsiche" (unter Verwendung des Kriteriums in Zelle A4) in den Zellen A2 bis A5. Das Ergebnis lautet "1".

=ZÄHLENWENN(A2:A5;A3)+ZÄHLENWENN(A2:A5;A2)

Ermittelt die Anzahl der Zellen mit dem Wert "Orangen" (unter Verwendung des Kriteriums in Zelle A3) und dem Wert "Äpfel" (unter Verwendung des Kriteriums in Zelle A2) in den Zellen A2 bis A5. Das Ergebnis lautet "3". Diese Formel verwendet zwei ZÄHLENWENN-Ausdrücke zur Angabe mehrerer Kriterien (ein Kriterium pro Ausdruck).

=ZÄHLENWENN(B2:B5;">55")

Ermittelt die Anzahl der Zellen mit einem Wert größer als 55 in den Zellen B2 bis B5. Das Ergebnis lautet "2".

=ZÄHLENWENN(B2:B5;"<>"&B4)

Ermittelt die Anzahl der Zellen mit einem Wert ungleich 75 in den Zellen B2 bis B5. Das kaufmännische Und-Zeichen (&) verknüpft den Vergleichsoperator für ungleich (<>) und den Wert in B4 zu: =ZÄHLENWENN(B2:B5;"<>75"). Das Ergebnis lautet "3".

=ZÄHLENWENN(B2:B5;">=32")-ZÄHLENWENN(B2:B5;">85")

Ermittelt die Anzahl der Zellen mit einem Wert größer (>) oder gleich (=) 32 und kleiner (<) oder gleich (=) 85 in den Zellen B2 bis B5. Das Ergebnis lautet "3".

=ZÄHLENWENN(A2:A5;"*")

Ermittelt die Anzahl der Zellen mit beliebigem Text in den Zellen A2 bis A5. Das Sternchen (*) wird als Platzhalterzeichen für eine beliebige Zeichenfolge verwendet. Das Ergebnis lautet "4".

=ZÄHLENWENN(A2:A5;"?????es")

Ermittelt die Anzahl der Zellen mit genau 7 Zeichen und "es" als den letzten beiden Buchstaben in den Zellen A2 bis A5. Das Fragezeichen (?) wird als Platzhalterzeichen für ein einzelnes Zeichen verwendet. Das Ergebnis lautet "2".

=ZÄHLENWENN(Obst;">=32")-ZÄHLENWENN(Obst;">85")

Verwendet einen benannten Bereich (angewendet auf die Zellen A2:A5), um in den Zellen B2 bis B5 die Anzahl der Zellen mit einem Wert größer als 55 zu ermitteln. Das Ergebnis lautet "2".

Häufig auftretende Probleme

Problem

Ursache

Für lange Zeichenfolgen wird ein falscher Wert zurückgegeben.

Die Funktion ZÄHLENWENN gibt falsche Ergebnisse zurück, wenn sie dazu verwendet wird, Zeichenfolgen mit mehr als 255 Zeichen abzugleichen.

Um Zeichenfolgen mit mehr als 255 Zeichen abzugleichen, verwenden Sie die Funktion VERKETTEN oder den Verkettungsoperator &. Beispiel: = ZÄHLENWENN(A2:A5;"lange Zeichenfolge"&"weitere lange Zeichenfolge").

Es wird kein Wert zurückgegeben, obwohl Sie einen Wert erwarten.

Stellen Sie sicher, dass das Kriterien-Argument in Anführungszeichen angegeben ist.

Bei einer ZÄHLENWENN-Formel wird ein #WERT!-Fehler ausgegeben, wenn sie auf ein anderes Arbeitsblatt verweist.

Dieser Fehler tritt auf, wenn die Formel mit der Funktion auf Zellen oder einen Bereich in einer geschlossenen Arbeitsmappe verweist und die Zellen berechnet werden. Damit dieses Feature funktioniert, muss die andere Arbeitsmappe geöffnet sein.

Bewährte Methoden

Aktion

Grund

Beachten Sie, dass ZÄHLENWENN Groß- und Kleinschreibung in Zeichenfolgen ignoriert.

Bei Suchkriterien wird die Groß- und Kleinschreibung nicht beachtet. Das bedeutet, mit den Zeichenfolgen "äpfel" und "ÄPFEL" werden dieselben Zellen einbezogen.

Verwenden Sie Platzhalterzeichen.

Eine als Kriterien angegebene Zeichenfolge darf Platzhalterzeichen – Fragezeichen (?) und Sternchen (*) – enthalten. Ein Fragezeichen ersetzt ein einzelnes Zeichen, ein Sternchen ersetzt eine beliebige Zeichenfolge. Wenn Sie nach einem Fragezeichen oder Sternchen suchen möchten, müssen Sie eine Tilde (~) vor das zu suchende Zeichen setzen.

Beispiel: =ZÄHLENWENN(A2:A5;"apfel?") ermittelt alle Instanzen von "apfel" wobei der letzte Buchstabe variieren kann.

Stellen Sie sicher, dass Ihre Daten keine fehlerhaften Zeichen enthalten.

Beim Zählen von Textwerten müssen Sie sicherstellen, dass die Daten keine führenden oder abschließenden Leerzeichen enthalten, dass gerade und typografische Anführungszeichen nicht inkonsistent verwendet wurden und dass keine nicht druckbaren Zeichen vorhanden sind. In diesen Fällen gibt ZÄHLENWENN möglicherweise einen unerwarteten Wert zurück.

Verwenden Sie die Funktion SÄUBERN oder GLÄTTEN.

Verwenden Sie zur einfacheren Handhabung benannte Bereiche.

ZÄHLENWENN unterstützt benannte Bereiche in einer Formel (z. B. =ZÄHLENWENN (Obst;">=32")-ZÄHLENWENN (Obst;">85"). Der benannte Bereich kann sich im aktuellen Arbeitsblatt, in einem anderen Arbeitsblatt in derselben Arbeitsmappe oder in einer anderen Arbeitsmappe befinden. Wenn aus einer anderen Arbeitsmappe darauf verwiesen werden soll, muss diese zweite Arbeitsmappe ebenfalls geöffnet sein.

Haben Sie eine Frage zu einer bestimmten Funktion?

Eine Frage im Excel-Communityforum stellen

Helfen Sie uns, Excel zu verbessern

Haben Sie Vorschläge, wie wir die kommende Version von Excel verbessern könnten? Wenn ja, lesen Sie die Themen unter Excel User Voice.

Siehe auch

Zählen von nicht leeren Zellen mit der Funktion ANZAHL2

Zählen von Zellen mit mehreren Kriterien mit der Funktion ZÄHLENWENN

Sehen Sie sich ein Video zur Verwendung der Funktion ZÄHLENWENNS an.

Mit der Funktion SUMMEWENN werden nur die Werte addiert, die einem einzelnen Kriterium entsprechen.

Mit der Funktion SUMMEWENNS werden nur die Werte addiert, die mehreren Kriterien entsprechen.

Funktion WENNS (Office 365, Excel 2016 und höher)

Mit der Funktion GLÄTTEN werden führende und nachgestellte Leerzeichen aus Zellen entfernt.

Mit der Funktion SÄUBERN werden nicht druckbare Zeichen aus Zellen entfernt.

Übersicht über Formeln in Excel

Vermeiden defekter Formeln

Ermitteln von Fehlern in Formeln

Statistische Funktionen

Excel-Funktionen (alphabetisch)

Excel-Funktionen (nach Kategorie)

War diese Information hilfreich?

Sehr gut. Noch anderes Feedback?

Was können wir verbessern?

Vielen Dank für Ihr Feedback!

×