ZÄHLENWENN (Funktion)

In diesem Artikel werden die Formelsyntax und die Verwendung der Funktion ZÄHLENWENN in Microsoft Excel beschrieben.

Beschreibung

Mit der Funktion ZÄHLENWENN wird die Anzahl der Zellen in einem Bereich ermittelt, die einem einzelnen angegebenen Kriterium entsprechen. Sie können beispielsweise alle Zellen zählen, die mit einem bestimmten Buchstaben beginnen, oder alle Zellen, die eine Zahl enthalten, die größer oder kleiner als eine angegebene Zahl ist. Wenn Sie z. B. über ein Arbeitsblatt mit einer Reihe von Aufgaben in Spalte A und dem Vornamen der Person, der diese Aufgabe zugeordnet ist, in Spalte B verfügen, können Sie mit der Funktion ZÄHLENWENN ermitteln, wie oft der Name einer Person in Spalte B vorkommt, und auf diese Weise feststellen, wie viele Aufgaben dieser Person zugeordnet sind. Beispiel:

=ZÄHLENWENN(B2:B25;"Andrea")

Hinweis   Informationen, wie Zellen anhand mehrerer Kriterien gezählt werden können, finden Sie unter ZÄHLENWENNS (Funktion).

Syntax

ZÄHLENWENN(Bereich;Suchkriterien)

Die Syntax der Funktion ZÄHLENWENN weist die folgenden Argument auf:

  • Bereich    Erforderlich. Eine oder mehrere zu zählende Zellen, einschließlich Zahlen oder Namen, Arrays oder Bezügen mit Zahlen. Leere Zellen und Textwerte werden ignoriert.

  • Suchkriterien    Erforderlich. Eine Zahl, ein Ausdruck, ein Zellbezug oder eine Textzeichenfolge, durch die bzw. den definiert wird, welche Zellen gezählt werden. Suchkriterien können z. B. als 32, ">32", B4, "Äpfel" oder "32" formuliert werden.

    Hinweis   

    • Eine als Suchkriterien angegebene Zeichenfolge darf die Platzhalterzeichen Fragezeichen (?) und Sternchen (*) enthalten. Ein Fragezeichen ersetzt ein Zeichen; ein Sternchen ersetzt eine beliebige Zeichenfolge. Wenn Sie nach einem Fragezeichen oder Sternchen suchen möchten, müssen Sie eine Tilde (~) vor das zu suchende Zeichen setzen.

    • Bei Suchkriterien wird die Groß- und Kleinschreibung nicht beachtet. Mit den Zeichenfolgen "äpfel" und "ÄPFEL" werden dieselben Zellen einbezogen.

Hinweise

  • Die Funktion ZÄHLENWENN gibt falsche Ergebnisse zurück, wenn sie dazu verwendet wird, Zeichenfolgen mit mehr als 255 Zeichen mit der Zeichenfolge "#WERT!" abzugleichen.

Beispiele

Die folgende Arbeitsmappe enthält Beispiele dieser Funktion. Sie können diese prüfen, vorhandene Formeln ändern oder eigene Formeln eingeben, um die Funktionsweise der Funktion kennenzulernen.

Kopieren Sie die Beispieldaten in der folgenden Tabelle, und fügen Sie sie in Zelle A1 eines neuen Excel-Arbeitsblatts ein. Um die Ergebnisse der Formeln anzuzeigen, markieren Sie sie, drücken Sie F2 und dann die EINGABETASTE. Im Bedarfsfall können Sie die Breite der Spalten anpassen, damit alle Daten angezeigt werden.

Daten

Daten

Äpfel

32

Orangen

54

Pfirsiche

75

Äpfel

86

Formel

Beschreibung

Ergebnis

=ZÄHLENWENN(A2:A5;"Äpfel")

Anzahl der Zellen mit "Äpfel" in den Zellen A2 bis A5

2

=ZÄHLENWENN(A2:A5;A4)

Anzahl der Zellen mit "Pfirsiche" in den Zellen A2 bis A5

1

=ZÄHLENWENN(A2:A5;A3)+ZÄHLENWENN(A2:A5;A2)

Anzahl der Zellen mit "Orangen" und "Äpfel" in den Zellen A2 bis A5

3

=ZÄHLENWENN(B2:B5;">55")

Anzahl der Zellen mit einem Wert größer als 55 in den Zellen B2 bis B5

2

=ZÄHLENWENN(B2:B5;"<>"&B4)

Anzahl der Zellen mit einem Wert ungleich 75 in den Zellen B2 bis B5

3

=ZÄHLENWENN(B2:B5;">=32")-ZÄHLENWENN(B2:B5;">85")

Anzahl der Zellen mit einem Wert größer oder gleich 32 und kleiner oder gleich 85 in den Zellen B2 bis B5

3

Wenn Sie umfassender mit den Beispieldaten in Excel arbeiten möchten, laden Sie die eingebettete Arbeitsmappe auf Ihren Computer herunter, und öffnen Sie sie dann in Excel.

Beispiel 2

Daten

Äpfel

Ja

Orangen

NEIN

Birnen

Nein

Äpfel

ja

Formel

Beschreibung

Ergebnis

=ZÄHLENWENN(A2:A7;"*en")

Anzahl der Zellen, die mit den Buchstaben "en" enden, in den Zellen A2 bis A7

4

=ZÄHLENWENN(A2:A7;"???el")

Anzahl der Zellen, die mit den Buchstaben "el" enden und genau fünf Buchstaben aufweisen, in den Zellen A2 bis A7

2

=ZÄHLENWENN(A2:A7;"*")

Anzahl der Zellen mit beliebigem Text in den Zellen A2 bis A7

4

=ZÄHLENWENN(A2:A7;"<>"&"*")

Anzahl der Zellen ohne Text in den Zellen A2 bis A7

2

=ZÄHLENWENN(B2:B7;"Nein") / ZEILEN(B2:B7)

Durchschnittliche Anzahl der Zellen mit "Nein" (einschließlich leerer Zellen) in den Zellen B2 bis B7

0,33333333

=ZÄHLENWENN(B2:B7;"Ja") / (ZEILEN(B2:B7) -ZÄHLENWENN(B2:B7; "<>"&"*"))

Durchschnittliche Anzahl der Zellen mit "Ja" (ohne leere Zellen) in den Zellen B2 bis B7

0,5

Gilt für: Excel 2013, Excel Online



War diese Information hilfreich?

Ja Nein

Wie können wir es verbessern?

255 Zeichen verfügbar

Um Ihre Privatsphäre zu schützen, geben Sie bitte keine Kontaktinformationen in Ihrem Feedback an. Lesen Sie unsere Datenschutzbestimmung.

Vielen Dank für Ihr Feedback!

Supportressourcen

Sprache ändern