PrtDevMode-Eigenschaft

Betrifft

Form-Objekt

Report-Objekt

Sie können die PrtDevMode-Eigenschaft zum Festlegen oder Zurückgeben von Informationen bezüglich des Druckermodus verwenden, die im Dialogfeld Drucken für ein Formular oder einen Bericht angegeben wurden. Wert vom Typ Variant mit Lese-/Schreibzugriff.

Ausdruck.PrtDevMode

Ausdruck Erforderlich. Ein Ausdruck, der eines der Objekte aus der Liste Betrifft zurückgibt.

Hinweise

Wir empfehlen dringend, für eine vollständige Dokumentation zu den Eigenschaften PrtDevMode, PrtDevNames und PrtMip das Win32-Softwareentwicklungskit zurate zu ziehen.

Bei der Einstellung der PrtDevMode-Eigenschaft handelt es sich um eine 94-Byte-Struktur, die die im Win32-Softwareentwicklungskit definierte DEVMODE-Struktur spiegelt. Vollständige Informationen zu den Elementen der PrtDevMode-Eigenschaft finden Sie im Win32-Softwareentwicklungskit.

Die PrtDevMode-Eigenschaft besteht aus den folgenden Elementen.

Element

Beschreibung

DeviceName

Eine Zeichenfolge mit maximal 32 Byte, die den Namen des vom Treiber unterstützten Geräts angibt – beispielsweise HP LaserJet IIISi, wenn Hewlett-Packard LaserJet IIISi der angegebene Drucker ist. Jeder Druckertreiber verfügt über eine eindeutige Zeichenfolge.

SpecVersion

Ein Integer-Datentyp, der die Versionsnummer der DEVMODE-Struktur im Win32-Softwareentwicklungskit angibt.

DriverVersion

Ein Integer, der die vom Druckertreiberentwickler zugewiesene Versionsnummer des Druckertreibers angibt.

Size

Ein Integer, der die Größe der DEVMODE-Struktur in Byte angibt. (Dieser Wert enthält nicht das optionale DmDriverData-Element für gerätespezifische Daten, die der Struktur folgen können). Wenn eine Anwendung nur den treiberunabhängigen Teil der Daten verarbeitet, können Sie dieses Element verwenden, um die Länge dieser Struktur zu ermitteln, ohne dass Sie verschiedene Versionen berücksichtigen müssen.

DriverExtra

Ein Integer, der die Größe des optionalen dmDriverData-Elements für gerätespezifische Daten, die dieser Struktur folgen können, in Byte angibt. Wenn eine Anwendung keine gerätespezifischen Daten verwendet, können Sie dieses Element auf 0 festlegen.

Fields

Ein Long-Datentyp-Wert, der angibt, welche der in der DEVMODE-Struktur verbleibenden Elemente initialisiert wurden.

Orientation

Ein Integer, der die Papierausrichtung angibt. Möglich ist entweder 1 (Hochformat) oder 2 (Querformat).

PaperSize

Ein Integer, der das Papierformat des zu bedruckenden Papiers angibt. Wenn Sie dieses Element auf 0 oder 256 festlegen, werden Länge und Breite des Papiers über die Elemente PaperLength und PaperWidth festgelegt. Andernfalls können Sie das PaperSize-Element auf einen vordefinierten Wert festlegen.

PaperLength

Ein Integer, der die Papierlänge in 1/10-Millimeterschritten angibt. Dieses Element überschreibt die im PaperSize-Element festgelegte Papierlänge für benutzerdefinierte Papierformate oder für Geräte wie Punktmatrixdrucker, die auf verschiedene Papiergrößen drucken können.

PaperWidth

Ein Integer, der die Papierbreite in 1/10-Millimeterschritten angibt. Dieses Element überschreibt die im PaperSize-Element angegebene Papierbreite.

Scale

Ein Integer, der den Skalierungsfaktor der gedruckten Ausgabe angibt. Die sichtbare Seitengröße wird von der Seitengröße der gedruckten Seite mittels eines Faktors von Maßsstab/100 skaliert. So kann beispielsweise eine Seite im Format 8,5 Zoll x 11 Zoll (Letter-Format), die mit einem Skalierungswert von 50 versehen wird, so viele Daten enthalten wie eine Seite im Format 17 Zoll x 22 Zoll, da Breite und Höhe des Ausgabetexts und der Grafiken auf die Hälfte reduziert werden.

Copies

Ein Integer, der die Anzahl gedruckter Kopien angibt, wenn der Drucker mehrseitige Kopien unterstützt.

DefaultSource

Ein Integer, der den Standardpapierschacht angibt.

PrintQuality

Ein Integer, der die Druckerauflösung angibt. Mögliche Werte: –4 (Hoch), –3 (Mittel), –2 (Niedrig) und –1 (Entwurf).

Color

Ein Integer. Gibt für einen Farbdrucker an, ob die Ausgabe in Farbe gedruckt wird. Mögliche Werte: 1 (Farbe) und 2 (Schwarzweiß).

Duplex

Ein Integer. Gibt für Duplexdruck-fähige Drucker an, ob die Ausgabe auf beiden Seiten des Papiers gedruckt wird. Mögliche Werte: 1 (Simplex), 2 (Horizontal) und 3 (Vertikal).

YResolution

Ein Integer, der die Y-Auflösung des Druckers in Punkten pro Zoll (dpi) angibt. Wenn der Drucker dieses Element initialisiert, gibt das PrintQuality-Element die X-Auflösung des Druckers in dpi an.

TTOption

Ein Integer, der angibt, wie TrueType-Schriftarten gedruckt werden.

Collate

Ein Integer, der angibt, ob beim Drucken mehrerer Kopien eine Sortierung erfolgen soll. Die Verwendung unsortierter Kopien bietet eine schnellere, effizientere Ausgabe, da die Daten nur einmal an den Drucker übermittelt werden.

FormName

Eine Zeichenfolge mit maximal 16 Zeichen, die das zu verwendende Papierformat angibt, beispielsweise Letter oder Legal.

Pad

Ein Long-Wert, der zum Auffüllen von Leerzeichen, Zeichen oder Werten für zukünftige Versionen verwendet wird.

Bits

Ein Long-Wert, der die Farbauflösung des Anzeigegeräts in Bit pro Pixel angibt.

PW

Ein Long-Wert, der die Breite der sichtbaren Geräteoberfläche (Bildschirm oder Drucker) in Pixeln angibt.

PH

Ein Long-Wert, der die Höhe der sichtbaren Geräteoberfläche (Bildschirm oder Drucker) in Pixeln angibt.

DFI

Ein Long-Wert, der den Anzeigemodus des Geräts angibt.

DFR

Ein Long-Wert, der die Frequenz eines bestimmten Modus des Anzeigegeräts in Hertz (Zyklen pro Sekunde) angibt.


Hinweis : Sie können die PrtDevMode-Eigenschaft mittels Visual Basic for Applications (VBA)-Code festlegen.

In der Entwurfs- und Layoutansicht verfügt diese Eigenschafteneinstellung über Lese-/Schreibzugriff; in allen anderen Ansichten ist sie schreibgeschützt.

Druckertreiber können gerätespezifische Daten hinzufügen, die unmittelbar auf die 94 Byte der DEVMODE-Struktur folgen. Aus diesem Grund ist es wichtig, dass die DEVMODE-Daten, die oben beschrieben werden, 94 Byte nicht überschreiten.

Die DEVMODE-Struktur wird nur von Druckertreibern verwendet, die die ExtDeviceMode-Funktion exportieren.

Eine Anwendung kann die von einem Drucker unterstützten Papiergrößen und -namen mittels der Werte DC_PAPERS, DC_PAPERSIZE und DC_PAPERNAMES abrufen, um die DeviceCapabilities-Funktion aufzurufen.

Bevor Sie die Werte des TTOption-Elements festlegen, sollten Anwendungen ermitteln, wie ein Druckertreiber TrueType-Schriftarten mittels des DC_TRUETYPE-Werts verwenden kann, um die DeviceCapabilities-Funktion aufzurufen.

Beispiel

Im folgenden Beispiel wird die PrtDevMode-Eigenschaft verwendet, um die benutzerdefinierte Seitengröße für einen Bericht zu prüfen:

Private Type str_DEVMODE
RGB As String * 94
End Type
Private Type type_DEVMODE
strDeviceName As String * 32
intSpecVersion As Integer
intDriverVersion As Integer
intSize As Integer
intDriverExtra As Integer
lngFields As Long
intOrientation As Integer
intPaperSize As Integer
intPaperLength As Integer
intPaperWidth As Integer
intScale As Integer
intCopies As Integer
intDefaultSource As Integer
intPrintQuality As Integer
intColor As Integer
intDuplex As Integer
intResolution As Integer
intTTOption As Integer
intCollate As Integer
strFormName As String * 32
lngPad As Long
lngBits As Long
lngPW As Long
lngPH As Long
lngDFI As Long
lngDFr As Long
End Type
Public Sub CheckCustomPage(ByVal rptName As String)
Dim DevString As str_DEVMODE
Dim DM As type_DEVMODE
Dim strDevModeExtra As String
Dim rpt As Report
Dim intResponse As Integer
' Opens report in Design view.
DoCmd.OpenReport rptName, acDesign
Set rpt = Reports(rptName)
If Not IsNull(rpt.PrtDevMode) Then
strDevModeExtra = rpt.PrtDevMode
' Gets current DEVMODE structure.
DevString.RGB = strDevModeExtra
LSet DM = DevString
If DM.intPaperSize = 256 Then
' Display user-defined size.
intResponse = MsgBox("The current custom page size is " & _
DM.intPaperWidth / 254 & " inches wide by " & _
DM.intPaperLength / 254 & " inches long. Do you want " & _
"to change the settings?", vbYesNo + vbQuestion)
Else
' Currently not user-defined.
intResponse = MsgBox("The report does not have a custom page size. " & _
"Do you want to define one?", vbYesNo + vbQuestion)
End If
If intResponse = vbYes Then
' User wants to change settings. Initialize fields.
DM.lngFields = DM.lngFields Or DM.intPaperSize Or _
DM.intPaperLength Or DM.intPaperWidth
' Set custom page.
DM.intPaperSize = 256
' Prompt for length and width.
DM.intPaperLength = InputBox("Please enter page length in inches.") * 254
DM.intPaperWidth = InputBox("Please enter page width in inches.") * 254
' Update property.
LSet DevString = DM
Mid(strDevModeExtra, 1, 94) = DevString.RGB
rpt.PrtDevMode = strDevModeExtra
End If
End If
Set rpt = Nothing
End Sub

Das folgende Beispiel zeigt, wie die Ausrichtung des Berichts geändert werden kann. In diesem Beispiel wird die Ausrichtung – abhängig von der aktuellen Ausrichtung – von Hoch- auf Querformat bzw. von Quer- auf Hochformat umgestellt.

Public Sub SwitchOrient(ByVal strName As String)
Const DM_PORTRAIT = 1
Const DM_LANDSCAPE = 2
Dim DevString As str_DEVMODE
Dim DM As type_DEVMODE
Dim strDevModeExtra As String
Dim rpt As Report
' Opens report in Design view.
DoCmd.OpenReport strName, acDesign
Set rpt = Reports(strName)
If Not IsNull(rpt.PrtDevMode) Then
strDevModeExtra = rpt.PrtDevMode
DevString.RGB = strDevModeExtra
LSet DM = DevString
DM.lngFields = DM.lngFields Or DM.intOrientation
' Initialize fields.
If DM.intOrientation = DM_PORTRAIT Then
DM.intOrientation = DM_LANDSCAPE
Else
DM.intOrientation = DM_PORTRAIT
End If
' Update property.
LSet DevString = DM
Mid(strDevModeExtra, 1, 94) = DevString.RGB
rpt.PrtDevMode = strDevModeExtra
End If
Set rpt = Nothing
End Sub
Teilen Facebook Facebook Twitter Twitter E-Mail E-Mail

War diese Information hilfreich?

Sehr gut. Noch anderes Feedback?

Was können wir verbessern?

Vielen Dank für Ihr Feedback!

×