Gibt einen Double-Wert zurück, der die Zinszahlung für einen bestimmten Zeitraum einer Annuität basierend auf regelmäßigen, festen Zahlungen und einem festen Zinssatz angibt.
Syntax
IPmt ( rate, per, nper , pv [, fv ] [, type ] )
Die Syntax der Funktion IPmt weist die folgenden Argumente auf:
|
Argument |
Beschreibung |
|
rate |
Erforderlich. Double-Wert, der den Zinssatz pro Zeitraum angibt. Wenn Sie beispielsweise einen Autokredit mit einem Jahreszins von 10 Prozent aufnehmen und monatliche Zahlungen leisten, beträgt der Zinssatz pro Zeitraum 0,1/12 oder 0,0083. |
|
per |
Erforderlich. Double , der den Zahlungszeitraum im Bereich von 1 bis nper angibt. |
|
nper |
Erforderlich. Double-Wert, der die Gesamtanzahl von Zahlungszeiträumen für die Annuität angibt. Wenn Sie beispielsweise monatliche Zahlungen für einen Autokredit mit vierjähriger Laufzeit leisten, umfasst Ihr Kredit insgesamt 4 * 12 (also 48) Zahlungszeiträume. |
|
BW |
Erforderlich. Double-Wert, der den Barwert, also den heutigen Wert, einer Reihe zukünftiger Zahlungen oder Geldeingänge angibt. Wenn Sie beispielsweise einen Kredit für ein Auto aufnehmen, ist die Summe dieses Kredits für den Kreditgeber gleich dem Barwert der monatlichen Zahlungen, die Sie für das Auto leisten. |
|
ZW |
Optional. Variant-Wert, der den Endwert (future value) oder Kontostand angibt, der nach der letzten Zahlung erreicht sein soll. Der Endwert eines Kredits ist z. B. 0 Euro, da dies sein Wert nach der letzten Zahlung ist. Wenn Sie jedoch für die Ausbildung Ihrer Kinder 50.000 Euro in 18 Jahren ansparen möchten, entspricht der Endwert 50.000 Euro. Fehlt dieses Argument, wird 0 angenommen. |
|
type |
Optional. Variant-Wert, der angibt, wann Zahlungen fällig sind. Verwenden Sie 0, wenn die Zahlungen am Ende des Zahlungszeitraums fällig sind, oder verwenden Sie 1, wenn die Zahlungen am Anfang des Zeitraums fällig sind. Fehlt dieses Argument, wird 0 angenommen. |
Hinweise
Eine Annuität ist eine Reihe von konstanten Barzahlungen, die in einem Zeitraum geleistet werden. Eine Annuität kann ein Kredit (z. B. eine Eigenheimhypothek) oder eine Investition (z. B. eine monatliche Spareinlage) sein.
Die Argumente rate und nper müssen mit Zahlungszeiträumen berechnet werden, die in derselben Einheit angegeben sind. Wir rate beispielsweise mit Monaten berechnet, muss auch nper mit Monaten berechnet werden.
Für alle Argumente gilt, dass Geldbeträge, die ausgezahlt werden (etwa Spareinlagen), durch negative Zahlen und Geldbeträge, die eingenommen werden (etwa Dividenden), durch positive Zahlen dargestellt werden.
Abfragebeispiel
|
Ausdruck |
Ergebnisse |
|
SELECT FinancialSample.*, IPMT([AnnualRate]/12,10,[TermInYears]*12,-[LoanAmount],0,0) AS INTPaid FROM FinancialSample; |
Gibt alle Felder aus der Tabelle "FinancialSample" zurück, berechnet die im "per"(10 in diesem Beispiel) des "LoanAmount" gezahlten Zinsen basierend auf "AnnualRate" und "TermInYears" und zeigt die Ergebnisse in der Spalte INTPaid an. |
VBA-Beispiel
Hinweis: Die folgenden Beispiele zeigen die Verwendung dieser Funktion in einem VBA-Modul (Visual Basic for Applications). Wenn Sie weitere Informationen zum Arbeiten mit VBA wünschen, wählen Sie Entwicklerreferenz in der Dropdownliste neben Suchen aus, und geben Sie einen oder mehrere Begriffe in das Suchfeld ein.
In diesem Beispiel wird die IPmt-Funktion verwendet, um zu berechnen, wie viel von einer Zahlung Zinsen sind, wenn alle Zahlungen gleich sind. Angegeben sind der zinsprozentige Zinssatz pro Zeitraum (APR / 12), der Zahlungszeitraum, für den der Zinsanteil gewünscht wird (Period), die Gesamtzahl der Zahlungen (TotPmts), der Barwert oder der Kapitalbetrag des Darlehens (PVal), der zukünftige Wert des Darlehens (FVal) und eine Zahl, die angibt, ob die Zahlung am Anfang oder Ende des Zahlungszeitraums fällig ist (PayType).
Dim FVal, Fmt, PVal, APR, TotPmts, PayType
Dim Period, IntPmt, TotInt, Msg
Const ENDPERIOD = 0, BEGINPERIOD = 1
FVal = 0 ' Usually 0 for a loan.
Fmt = "###,###,##0.00" ' Define money format.
PVal = InputBox("How much do you want to borrow?")
APR = InputBox("What is the annual percentage rate " & _
"of your loan?")
If APR > 1 Then APR = APR / 100 ' Ensure proper form.
TotPmts = InputBox("How many monthly payments?")
PayType = MsgBox("Do you make payments at " & _
"the end of the month?", vbYesNo)
If PayType = vbNo Then
PayType = BEGINPERIOD
Else PayType = ENDPERIOD
End If
For Period = 1 To TotPmts ' Total all interest.
IntPmt = IPmt(APR / 12, Period, TotPmts, _
-PVal, FVal, PayType)
TotInt = TotInt + IntPmt
Next Period
Msg = "You'll pay a total of " & Format(TotInt, Fmt)
Msg = Msg & " in interest for this loan."
MsgBox Msg ' Display results.
