Berechnen des Unterschieds zwischen zwei Datumsangaben

Berechnen des Unterschieds zwischen zwei Datumsangaben

Verwenden Sie die DATEDIF-Funktion, wenn Sie die Differenz zwischen zwei Datumsangaben berechnen möchten. Geben Sie zuerst ein Anfangsdatum in eine Zelle und ein Enddatum in eine andere Zelle ein. Geben Sie dann eine der folgenden Formeln ein.

Differenz in Tagen

=DATEDIF(D9;E9;"d") mit Ergebnis 856

In diesem Beispiel befindet sich das Anfangsdatum in Zelle D9 und das Enddatum in Zelle E9. Die Formel befindet sich Zelle F9. "d" gibt die Anzahl von ganzen Tagen zwischen den beiden Datumsangaben zurück.

Differenz in Wochen

=(DATEDIF(D13;E13;"d")/7) und Ergebnis: 122,29

In diesem Beispiel befindet sich das Anfangsdatum in Zelle D13 und das Enddatum in Zelle E13. "d" gibt die Anzahl von Tagen zurück. Aber beachten Sie die Angabe /7 am Ende. Dadurch wird die Anzahl von Tagen durch 7 dividiert, weil eine Woche 7 Tage hat. Beachten Sie, dass dieses Ergebnis auch als Zahl formatiert werden muss. Drücken Sie STRG+1. Klicken Sie dann auf Zahl > Dezimalstellen: 2.

Differenz in Monaten

=DATEDIF(D5;E5;"m") und Ergebnis: 28

In diesem Beispiel befindet sich das Anfangsdatum in Zelle D5 und das Enddatum in Zelle E5. In der Formel gibt "m" die Anzahl von ganzen Monaten zwischen den zwei Angaben zurück.

Differenz in Jahren

=DATEDIF(D2;E2;"y") und Ergebnis: 2

In diesem Beispiel befindet sich das Anfangsdatum in Zelle D2 und das Enddatum in Zelle E2. "y" gibt die Anzahl von ganzen Jahren zwischen den beiden Angaben zurück.

Berechnen des Alters in kumulierten Jahren, Monaten und Tagen

Sie können auch das Alter oder Dienstalter (die Zugehörigkeitsdauer) einer Person berechnen. Das Ergebnis kann beispielsweise "2 Jahre, 4 Monate, 5 Tage" lauten.

1. Verwenden Sie DATEDIF, um die Gesamtzahl der Jahre zu ermitteln.

=DATEDIF(D17;E17;"y") und Ergebnis: 2

In diesem Beispiel befindet sich das Anfangsdatum in Zelle D17 und das Enddatum in Zelle E17. In der Formel gibt "y" die Anzahl von ganzen Jahren zwischen den beiden Angaben zurück.

2. Verwenden Sie DATEDIF mit "ym", um die Monate zu ermitteln.

=DATEDIF(D17;E17;"ym") und Ergebnis: 4

Verwenden Sie in einer anderen Zelle die DATEDIF-Formel mit dem Parameter "ym". "ym" gibt die Anzahl der restlichen Monate nach dem letzten vollen Jahr zurück.

3. Verwenden Sie eine andere Formel, um Tage zu finden.

=DATEDIF(D17;E17;"md") und Ergebnis: 5

Nun müssen wir die Anzahl der verbleibenden Tage finden. Hierfür schreiben wir eine andere Art von Formel, wie oben gezeigt. Mit dieser Formel wird der erste Tag des letzten Monats (5/1/2016) vom ursprünglichen Enddatum in Zelle E17 (5/6/2016) abgezogen. Und so funktioniert es: Zuerst wird mit dem Funktion DATUM das Datum 5/1/2016 erstellt. Es wird erstellt, indem das Jahr in der Zelle E17 vom Monat in Zelle E17 verwendet wird. Die 1 repräsentiert den ersten Tag dieses Monats. Das Ergebnis der Funktion DATUM ist 5/1/2016. Anschließend wird dieser Wert vom ursprünglichen Enddatum in Zelle E17 subtrahiert (5/6/2016), 5/6/2016 minus 5/1/2016 sind 5 Tage.

Hinweis : Es wird empfohlen, das Argument "md" von DATEDIF nicht zu verwenden, da dies zu ungenauen Ergebnissen führen kann.

4. Optional: Kombinieren Sie drei Formeln in einem.

=DATEDIF(D17;E17;"y")&" Jahre, "&DATEDIF(D17;E17;"ym")&" Monate, "&DATEDIF(D17;E17;"md")&" Tage" und Ergebnis: 2 Jahre, 4 Monate, 5 Tage

Sie können alle drei Berechnungen in eine Zelle einfügen, wie in diesem Beispiel. Verwenden Sie kaufmännische Und-Zeichen, Anführungszeichen und Text. Sie müssen zwar eine längere Formel eingeben, aber dafür haben Sie alles in einem. Tipp: Drücken Sie ALT+EINGABETASTE, um Zeilenumbrüche in die Formel einzufügen. Dadurch ist sie leichter lesbar. Und drücken Sie STRG+UMSCHALT+U, wenn Sie nicht die gesamte Formel sehen können.

Herunterladen unserer Beispiele

Sie können eine Beispielarbeitsmappe mit allen Beispielen in diesem Artikel herunterladen. Sie können die Beispiele nachvollziehen oder eigene Formeln erstellen.

Beispiele für Datumsberechnungen herunterladen

Andere Datums- und Zeitberechnungen

Wie oben gezeigt wird, berechnet die DATEDIF-Funktion die Differenz zwischen einem Anfangsdatum und einem Enddatum. Statt jedoch bestimmte Datumsangaben einzugeben, können Sie in der Formel auch die Funktion HEUTE() verwenden. Wenn Sie mit der Funktion HEUTE() arbeiten, verwendet Excel als Datum das aktuelle Datum des Computers. Beachten Sie, dass sich dieses Datum ändert, wenn die Datei an einem zukünftigen Tag erneut geöffnet wird.

=DATEDIF(HEUTE();D28;"y") und Ergebnis: 984

Der Zeitpunkt der Erstellung dieses Dokuments war der 6. Oktober 2016.

Verwenden Sie die Funktion NETTOARBEITSTAGE.INTL, wenn Sie die Anzahl von Arbeitstagen zwischen zwei Datumsangaben berechnen möchten. Sie können dabei auch Wochenenden und (arbeits)freie Tage ausschließen.

Vorbemerkung: Bestimmen Sie, ob (arbeits)freie Tage ausgeschlossen werden sollen. Geben Sie in dem Fall eine Liste mit Datumsangaben der freien Tage in einem separaten Bereich oder auf einem separaten Blatt ein. Verwenden Sie für jeden freien Tag eine eigene Zelle. Markieren Sie dann diese Zellen, und wählen Sie Formeln > Namen definieren aus. Weisen Sie dem Bereich den Namen MyHolidays zu, und klicken Sie auf OK. Erstellen Sie dann die Formel, indem Sie die folgenden Schritte ausführen.

1. Geben Sie ein Anfangsdatum und ein Enddatum ein.

Startdatum in Zelle D53 ist der 1/1/2016, Enddatum in Zelle E53 ist der 12/31/2016

In diesem Beispiel befindet sich das Anfangsdatum in Zelle D53 und das Enddatum in Zelle E53.

2. Geben Sie in eine andere Zelle eine Formel wie die folgende ein:

=NETTOARBEITSTAGE.INTL(D53;E53;1) und Ergebnis: 261

Geben Sie eine Formel wie im obigen Beispiel ein. Durch den Wert "1" in der Formel werden Samstage und Sonntage als Wochenendtage festgelegt und aus der Summe ausgeschlossen.

Hinweis: In Excel 2007 gibt es die Funktion NETTOARBEITSTAGE.INTL nicht. NETTOARBEITSTAGE ist jedoch verfügbar. In Excel 2007 sähe das obige Beispiel wie folgt aus: =NETTOARBEITSTAGE(D53;E53). Den Wert "1" geben Sie nicht an, weil NETTOARBEITSTAGE Samstag und Sonntag als Wochenende zählt.

3. Ändern Sie gegebenenfalls den Wert "1".

Intellisense-Liste mit 2 – Sonntag, Montag; 3 – Montag, Dienstag usw.

Wenn Samstag und Sonntag nicht Ihre Wochenendtage sind, ändern Sie "1" in eine andere Zahl aus der IntelliSense-Liste. Mit "2" werden beispielsweise Sonntage und Montage als Wochenendtage festgelegt.

Wenn Sie Excel 2007 verwenden, überspringen Sie diesen Schritt. In Excel 2007 zählt die Funktion NETTOARBEITSTAGE immer Samstag und Sonntag als Wochenende.

4. Geben Sie den Bereichsnamen der freien Tage ein.

=NETTOARBEITSTAGE.INTL(D53;E53;1;MyHolidays) und Ergebnis: 252

Wenn Sie oben im Abschnitt "Vorbemerkung" einen entsprechenden Bereich erstellt haben, geben Sie den Bereichsnamen wie in diesem Beispiel gezeigt am Ende ein. Wenn keine freien Tage berücksichtigt werden sollen, können Sie das Semikolon und "MyHolidays" weglassen. Bei Verwendung von Excel 2007 sähe das obige Beispiel stattdessen wie folgt aus: =NETTOARBEITSTAGE(D53;E53;MyHolidays).

Tipp: Wenn Sie keinen Bereichsnamen der freien Tage angeben möchten, können Sie stattdessen auch einen Bereich wie z. B. D35:E:39 eingeben. Alternativ könnten Sie auch jeden freien Tag in die Formel eingeben. Wenn Ihre freien Tage beispielsweise der 1. und 2. Januar 2016 waren, geben Sie diese wie folgt ein: =NETTOARBEITSTAGE.INTL(D53;E53;1;{"2016/1/1";"2016/1/2"}). In Excel 2007 sähe das wie folgt aus: =NETTOARBEITSTAGE(D53;E53;{"2016/1/1";"2016/1/2"}) .

Sie können die verstrichene Zeit berechnen, indem Sie eine Zeitangabe von einer anderen subtrahieren. Geben Sie zuerst eine Anfangszeit in eine Zelle und eine Endzeit in eine andere Zelle ein. Geben Sie die Zeit unbedingt vollständig (einschließlich der Stunde und Minuten) ein, und setzen Sie ein Leerzeichen vor AM oder PM. Gehen Sie wie folgt vor:

1. Geben Sie eine Anfangszeit und eine Endzeit ein.

Startdatum/-uhrzeit /7:15 AM, Enddatum-/uhrzeit 4:30 PM

In diesem Beispiel befindet sich die Anfangszeit in Zelle D80 und die Endzeit in Zelle E80. Geben Sie die Stunde, Minuten und ein Leerzeichen vor AM oder PM ein.

2. Legen Sie das Format auf "h:mm AM/PM" fest.

Dialogfeld "Zellen formatieren", Befehl "Benutzerdefiniert", Typ h:mm AM/PM

Wählen Sie beide Datumsangaben aus, und drücken Sie STRG+1 (bzw. Abbildung des Symbols der MAC-Schaltfläche BEFEHL +1 auf einem Mac). Vergewissern Sie sich, dass Benutzerdefiniert > h:mm AM/PM ausgewählt ist.

3. Subtrahieren Sie die beiden Zeitangaben.

=E80-D80 und Ergebnis: 9:15 AM

Subtrahieren Sie in einer anderen Zelle die Zelle mit der Anfangszeit von der Zelle mit der Endzeit.

4. Legen Sie das Format auf "h:mm" fest.

Dialogfeld "Zellen formatieren", Befehl "Benutzerdefiniert", Typ h:mm

Drücken Sie STRG+1 (bzw. Abbildung des Symbols der MAC-Schaltfläche BEFEHL +1 auf einem Mac). Wählen Sie Benutzerdefiniert > h:mm aus, damit AM und PM aus dem Ergebnis ausgeschlossen werden.

Wenn Sie die Zeit zwischen zwei Datums- und Uhrzeitangaben berechnen möchten, können Sie einfach die eine Angabe von der anderen subtrahieren. Sie müssen jedoch jede Zelle entsprechend formatieren, um sicherzustellen, dass Excel das gewünschte Ergebnis zurückgibt.

1. Geben Sie die beiden vollständigen Datums- und Uhrzeitangaben ein.

Startdatum 1/1/16 1:00 PM, Enddatum 1/2/16 2:00 PM

Geben Sie in eine Zelle eine vollständige Angabe aus Anfangsdatum und Anfangszeit ein. Und geben Sie in eine andere Zelle eine vollständige Angabe aus Enddatum und Endzeit ein. In jeder Zelle müssen Monat, Tag, Jahr, Stunde und Minute angegeben und ein Leerzeichen vor AM oder PM vorhanden sein.

2. Legen Sie das Format "3/14/12 1:30 PM" fest.

Dialogfeld "Zellen formatieren", Befehl "Datum", Typ 3/14/12 1:30 PM

Markieren Sie beide Zellen, und drücken Sie dann STRG+1 (bzw. Abbildung des Symbols der MAC-Schaltfläche BEFEHL +1 auf einem Mac). Wählen Sie dann Datum > 3/14/12 1:30 PM aus. Das ist nicht das von Ihnen festgelegte Datum, sondern nur ein Beispiel dafür, wie das Format aussieht. In Versionen vor Excel 2016 kann für dieses Format ein anderes Beispieldatum vorhanden sein, z. B. 3/14/01 1:30 PM.

3. Subtrahieren Sie die beiden Angaben.

=E84-D84 und Ergebnis 1,041666667

Subtrahieren Sie in einer anderen Zelle den Anfangsdatums-/Anfangszeitwert von dem Enddatums-/Endzeitwert. Das Ergebnis sieht wahrscheinlich aus wie eine Zahl mit Dezimalzahlstellen. Das korrigieren Sie im nächsten Schritt.

4. Legen Sie das Format auf "[h]:mm" fest.

Dialogfeld "Zellen formatieren", Befehl "Benutzerdefiniert", Typ [h]:mm

Drücken Sie STRG+1 (bzw. Abbildung des Symbols der MAC-Schaltfläche BEFEHL +1 auf einem Mac). Wählen Sie Benutzerdefiniert aus. Geben Sie im Feld Typ die Zeichenfolge [h]:mm ein.

Siehe auch

DATEDIF-Funktion

NETTOARBEITSTAGE.INTL (Funktion)

NETTOARBEITSTAGE (Funktion)

Weitere Datums- und Uhrzeitfunktionen

Berechnen des Unterschieds zwischen zwei Zeitangaben

Ihre Fähigkeiten erweitern
Schulung erkunden
Neue Funktionen als Erster erhalten
An Office Insider teilnehmen

War diese Information hilfreich?

Vielen Dank für Ihr Feedback!

Vielen Dank für Ihr Feedback. Es klingt, als ob es hilfreich sein könnte, Sie mit einem unserer Office-Supportmitarbeiter zu verbinden.

×