Festlegen benutzerdefinierter Datenbeschriftungen in einem Diagramm

Mit der folgenden VBA-Prozedur (Visual Basic for Applications) können Sie Zellenwerte als Datenbeschriftungen in Ihren Diagrammen in Excel für Mac verwenden. Gehen Sie wie folgt vor, um das Verfahren zu verwenden:

1. Klicken Sie in Excel auf Extras > Makros > Neues Makro aufzeichnen.

2. Wählen Sie im Dropdownfeld Makro speichern in: die Option Persönliche Makroarbeitsmappe aus.

   Hinweis: Indem Sie die VBA-Prozedur in der Persönlichen Makroarbeitsmappe speichern, können Sie sie dann in jeder instance von Excel verwenden. Dies bedeutet, dass es nicht nur auf die Verwendung in einer einzelnen Arbeitsmappe beschränkt ist.

3. Klicken Sie auf OK.

4. Wechseln Sie zu Extras > Makros > Aufzeichnung beenden.

5. Wechseln Sie zu Extras > Makros > Visual Basic-Editor.

6. Der Visual Basic-Editor (VBE) wird über Excel geöffnet. Erweitern Sie im Navigationsbereich auf der linken Seite vbaProject (PERSONAL. XLSB)-Ordner, um Module1 anzuzeigen.

7. Doppelklicken Sie auf Modul1 , um den Codebereich anzuzeigen, der auf der rechten Seite des VBE-Fensters geöffnet wird.

8. Der VBA-Code, der beim Aufzeichnen eines neuen Makros erstellt wurde, ist nicht erforderlich. Wählen Sie also alles aus, und drücken Sie dann ENTF. 

9. Wählen Sie als Nächstes den VBA-Code im Textfeld unten aus, drücken Sie CMD+C, um ihn zu kopieren, und fügen Sie ihn dann mit CMD+V wieder in den Codebereich ein. Sie können nun den Visual Basic-Editor beenden und zu Excel zurückkehren.

10. Testen Sie das Makro, indem Sie ein Diagramm mit Datenbeschriftungen erstellen. Wählen Sie als Nächstes eine beliebige Datenbeschriftung im Diagramm aus, und führen Sie das Makro aus, indem Sie auf Extras > Makros > Makros klicken. Wählen Sie SetCustomDataLabels aus, und drücken Sie dann Ausführen. Sie werden automatisch aufgefordert, Ihren Datenbezeichnungsbereich auszuwählen. Klicken Sie dazu auf OK.  

    Hinweis: VBA-Prozeduren können nicht rückgängig werden. Stellen Sie daher sicher, dass Sie dies für eine Kopie einer Arbeitsmappe ausprobieren. Wenn Sie den Code ausführen und die Ergebnisse nicht beibehalten möchten, müssen Sie die Arbeitsmappe schließen, ohne sie zu speichern.

11. Wenn Sie Excel beenden, stellen Sie sicher, dass Sie die Änderungen in PERSONAL speichern möchten. XLSB, sodass das Makro in Zukunft verfügbar sein wird.

12. Wenn Sie einem Diagramm Datenbeschriftungen hinzufügen oder daraus entfernen möchten, wählen Sie die Datenbeschriftungen aus, und führen Sie das Makro aus.

13. Sie können Excel > Einstellungen > Menüband & Symbolleiste verwenden, um eine Schaltfläche zum Ausführen des Makros über das Menüband oder die Symbolleiste hinzuzufügen.

Option Explicit

Sub SetCustomDataLabels()
' make sure a series is selected
    If TypeOf Selection Is DataLabels Or TypeOf Selection Is Point Then
        Selection.Parent.Select
    ElseIf TypeOf Selection Is DataLabel Then
        Selection.Parent.Parent.Select
    End If

    If TypeOf Selection Is Series Then
        Else
        MsgBox "Select a chart series and try again."
        Exit Sub
    End If

    If Selection.HasDataLabels Then
        'If the data labels from cells are already showing, stop showing them and exit.
        'If labels include other info (e.g., values or categories) this will still appear
        If Selection.DataLabels.ShowRange Then
            Selection.DataLabels.ShowRange = False
            Exit Sub
        End If
    End If
 
'Use the InputBox dialog to set the range for the data labels
    On Error Resume Next
        Dim rng As Range
        Set rng = Application.InputBox(Prompt:="Select data label range.", Title:="Data Label Range", Type:=8)
    On Error GoTo 0

    If rng Is Nothing Then Exit Sub ' clicked cancel
        If Selection.HasDataLabels Then
            'This will include the new text from cells into existing data labels
        Else
        'Otherwise add data labels (empty labels)
            Selection.HasDataLabels = True
            Selection.DataLabels.ShowValue = False
        End If
    
    'Create a string that includes the sheet name and range reference.
    Dim rngAddress As String
        rngAddress = "='" & rng.Worksheet.Name & "'!" & rng.Address(RowAbsolute:=True, ColumnAbsolute:=True, External:=False)
        Selection.DataLabels.Format.TextFrame2.TextRange.InsertChartField msoChartFieldRange, rngAddress, 0
        Selection.DataLabels.ShowRange = True

End Sub