Med funktionen TEKST kan du ændre den måde, tal vises på, ved at anvende formatering med formatkoder. Det er nyttigt i situationer, hvor du vil have vist tal i et mere læsbart format, eller du vil kombinere tal med tekst eller symboler.
Bemærk!: Funktionen TEKST konverterer tal til tekst, hvilket kan gøre det svært at henvise til i senere beregninger. Det er bedst at bevare den oprindelige værdi i én celle og derefter bruge funktionen TEKST i en anden celle. Hvis du derefter skal oprette andre formler, skal du altid referere til den oprindelige værdi og ikke resultatet fra funktionen TEKST.
Syntaks
TEKST(værdi, format_tekst)
Syntaksen for funktionen TEKST har følgende argumenter:
|
Argumentnavn |
Beskrivelse |
|
værdi |
En numerisk værdi, der skal konverteres til tekst. |
|
format_tekst |
En tekststreng, der definerer den formatering, der skal anvendes på den angivne værdi. |
Oversigt
I din simpleste form lyder funktionen TEKST:
-
=TEKST (Værdi, du vil formatere, "Formatkode, du vil anvende")
Her er nogle almindelige eksempler, som du kan kopiere direkte i Excel for selv at eksperimentere. Bemærk formatkoderne omgivet af anførselstegn.
|
Formel |
Beskrivelse |
|---|---|
|
=TEKST(1234,567,"$#,##0.00") |
Valuta med en tusindtalsseparator og 2 decimaler, såsom DKK 1.234,57. Bemærk, at Excel afrunder værdien til 2 decimaler. |
|
= TEKST(IDAG(),"DD-MM-ÅÅ") |
Dags dato i DD-MM-ÅÅ-format, f.eks. 14-03-12 |
|
= TEKST(IDAG(),"DDDD") |
Dags dag i ugen, f.eks. mandag |
|
= TEKST(NU(),"T:MM AM/PM") |
Aktuelt klokkeslæt, f.eks. 13.29 |
|
= TEKST(0,285,"0,0%") |
Procent, f.eks. 28,5 % |
|
=TEKST(4;34;"# ?/?") |
Brøk, f.eks. 4 1/3 |
|
=FJERN.OVERFLØDIGE.BLANKE(TEKST(0,34,"# ?/?")) |
Brøk, f.eks. 1/3. Bemærk, at dette bruger funktionen FJERN.OVERFLØDIGE.BLANKE til at fjerne det foranstillede mellemrum ved et decimaltal. |
|
= TEKST(12200000,"0,00E+00") |
Videnskabelig notation, f.eks. 1,22E+07 |
|
=TEKST(1234567898,"[<=9999999]###-####;(###) ###-####") |
Speciel (telefonnummer), f.eks. 9875432 |
|
=TEKST(1234,"0000000") |
Tilføj foranstillede nuller (0), f.eks. 0001234 |
|
=TEKST(123456,"##0° 00' 00''") |
Brugerdefineret - længde-/breddegrader |
Bemærk!: Selvom du kan bruge funktionen TEKST til at ændre formateringen, er det ikke den eneste måde. Du kan ændre formatet uden en formel ved at trykke på Ctrl+1 (eller 
Hent vores eksempler
Du kan hente en eksempelprojektmappe med alle de eksempler på funktionen TEKST, som findes i denne artikel, plus nogle ekstra. Du kan følge med, eller du kan oprette dine egne formatkoder med funktionen TEKST.
Hent Excel-eksempler på funktionen TEKST
Andre tilgængelige formatkoder
Du kan bruge dialogboksen Formatér celler til at finde de andre tilgængelige formatkoder:
-
Tryk på Ctrl+1 (
-
Vælg det ønskede format fra fanen Tal .
-
Vælg indstillingen Brugerdefineret .
-
Den ønskede formatkode vises nu i feltet Type. I dette tilfælde kan du markere alt fra feltet Type med undtagelse af semikolon (;) og @-symbolet. I eksemplet herunder har vi blot markeret og kopieret dd-mm-åå.
-
Tryk på Ctrl+C for at kopiere formatkoden, og tryk derefter på Annuller for at lukke dialogboksen Formatér celler .
-
Du skal nu blot trykke på Ctrl+V for at indsætte formatkoden i TEKST-formlen, f.eks.: =TEKST(B2,"(B2,"dd/mm/åå"). Sørg for at indsætte formatkoden i anførselstegn ("formatkode"), ellers får du en fejlmeddelelse i Excel.
Formatkoder efter kategori
Her er nogle eksempler på, hvordan du kan anvende forskellige talformater på dine værdier ved hjælp af dialogboksen Formatér celler og derefter bruge indstillingen Brugerdefineret til at kopiere disse formatkoder til funktionen TEKST .
Hvorfor sletter Excel mine foranstillede 0'er?
Excel er trænet til at søge efter tal, der indtastes i celler, ikke tal, der ligner tekst, f.eks. deltal eller varenumre. Hvis du vil bevare foranstillede nuller, skal du formatere inputområdet som tekst, inden du indsætter eller indtaster værdier. Markér den kolonne eller række, hvor du vil indsætte værdierne, og brug derefter CTRL+1 for at få vist dialogboksen Formatér > Celler, og markér Tekst på fanen Tal. Nu bevarer Excel dine foranstillede nuller.
Hvis du allerede har indtastet data, og Excel har fjernet foranstillede nuller, kan du bruge funktionen TEKST til at tilføje dem igen. Du kan referere til den øverste celle med værdierne og bruge =TEKST(værdi,"00000"), hvor antallet af 0’er i formlen repræsenterer det samlede antal ønskede tegn, og derefter kopiere og indsætte i resten af dit område.
Hvis du af eller anden grund har brug for at konvertere tekstværdier tilbage til tal, kan du multiplicere med 1, f.eks. = D4*1, eller bruge en dobbelt unær operator (--), f.eks. =--D4.
Excel adskiller tusinder med et punktum, hvis formatet indeholder et punktum (.), der er omsluttet af nummertegn (#) eller af nuller. Hvis formatstrengen er "#,###", viser Excel tallet 12200000 som 12.200,000.
Et punktum, der efterfølger en pladsholder for et ciffer, skalerer tallet med 1.000. Hvis formatstrengen er "#.###,0;", viser Excel tallet 12200000 som 12.200,0.
Bemærkninger!:
-
Tusindtalsseparator er afhængig af de internationale indstillinger. I Danmark er det et punktum, men det kan være et komma (,) i andre landestandarder.
-
Tusindtalsseparatoren er tilgængelig for tal, valuta og revisionsformater.
Følgende er eksempler på almindelige tal (kun tusindtalsseparator og decimaler), valuta og revisionsformater. Valutaformat gør det muligt at indsætte det ønskede valutasymbol og justere det ud for værdien, mens revisionsformatet justerer valutasymbolet til venstre for cellen og værdien til højre. Vær opmærksom på forskellen mellem formatkoder for valuta og revision nedenfor, hvor revision bruger en stjerne (*) til at oprette en separering mellem symbolet og værdien.
Hvis du vil finde formatkoden for et valutasymbol, skal du først trykke på Ctrl+1 (eller
Klik derefter på Brugerdefineret i venstre side fra sektionen Kategori, og kopiér formatkoden, inklusive valutasymbolet.
Bemærk!: Funktionen TEKST understøtter ikke farveformatering, så hvis du kopierer en talformatkode fra dialogboksen Formatér celler, der indeholder en farve, som denne: $#,##0.00_);[Rød]($#,##0.00), accepterer funktionen TEKST formatkoden, men viser ikke farven.
Du kan ændre den måde, en dato vises på, ved hjælp af en blanding af "M" for måned, "D" for dage, og "Å" for år.
Formatkoder i funktionen TEKST skelner ikke mellem store og små bogstaver, så du kan bruge enten "M" eller "m", "D" eller "d", "Å" eller "å".
|
|
Mynda anbefaler ... Hvis du vil dele Excel-filer og rapporter med brugere fra forskellige lande/områder, kan det være en fordel at give dem en rapport på deres eget sprog. MVP for Excel, Mynda Treacy har en god løsning på dette i artiklen Excel Dates Displayed in Different Languages om at vise datoer i Excel på forskellige sprog. Den indeholder også en eksempelprojektmappe, du kan downloade. |
Du kan ændre den måde, et klokkeslæt vises på, ved hjælp af en blanding af "T" for timer, "M" for minutter eller "S" for sekunder og "AM/PM" for et 12-timers ur.
Hvis du udelader "AM/PM", vises tiden som et 24-timers format.
Formatkoder i funktionen TEKST skelner ikke mellem store og små bogstaver, så du kan bruge enten "T" eller "t", "M" eller "m", "S" eller "s" og "AM/PM" eller "am/pm".
Du kan ændre den måde, som decimalværdier vises på med procentformater (%).
Du kan ændre den måde, som decimalværdier vises på, med brøkformater (?/?).
Videnskabelig notation er en metode til at vise tal i form af et decimaltal mellem 1 og 10, ganget med en potens af 10. Det bruges ofte til at afkorte den måde, som store tal vises på.
Excel indeholder 4 specielle formater:
-
Postnummer - "00000"
-
Postnummer + 4 "00000-0000"
-
Telefonnummer - "[<=9999999]###-####;(###) ###-####"
-
CPR-nummer - "000-00-0000"
Særlige formater vil være forskellige afhængigt af landestandard, men hvis der ikke er nogen særlige formater for din landestandard, eller hvis disse ikke opfylder dine behov, kan du oprette dine egne gennem dialogboksen Formater celler > Brugerdefineret.
Almindeligt scenarie
Funktionen TEKST bruges sjældent for sig selv og bruges oftest sammen med noget andet. Lad os antage, at du vil kombinere tekst og en talværdi, f.eks. "Rapport udskrevet den: 14/03/12" eller "Ugentlige indtægter: kr. 66.348,72 ". Du kan skrive det manuelt i Excel, men så forsvinder det smarte i at få Excel til at gøre det for dig. Når du kombinerer tekst og formaterede tal, f.eks. datoer, klokkeslæt, valuta osv., ved Excel ikke, hvordan du vil vise dem, så det stopper talformateringen. Det er her, funktionen TEKST er uvurderlig, da den giver dig mulighed for at tvinge Excel til at formatere værdier, som du ønsker dem, ved at bruge en formatkode som "DD/MM/ÅÅ" for datoformat.
I følgende eksempel kan du se, hvad der sker, hvis du forsøger at gøre dette uden at bruge funktionen TEKST. I dette tilfælde bruger vi og-tegnet (&) til at sammenkæde en tekststreng, et mellemrum (" ") og en værdi med =A2&" "&B2.
Som du kan se, fjernede Excel formateringen fra datoen i celle B2. I det næste eksempel får du vist, hvordan du med funktionen TEKST kan anvende det ønskede format.
Vores opdaterede formel er:
-
Celle C2: =A2&" "&TEKST(B2,"dd/mm/åå") – Datoformat
Ofte stillede spørgsmål
Desværre kan du ikke gøre det med funktionen TEKST. skal du bruge Visual Basic for Applications (VBA)-kode. Følgende link har en metode: Sådan konverteres en numerisk værdi til engelske ord i Excel.
Ja, du kan bruge funktionerne STORE.BOGSTAVER, SMÅ.BOGSTAVER og STORT.FORBOGSTAV. F.eks. returnerer =STORE.BOGSTAVER("hej") "HEJ".
Ja, men det kræver nogle få trin. Først skal du markere den eller de celler, hvor det skal ske, og bruge Ctrl+1 til at få vist dialogboksen Formatér > celler og derefter Justering > tekstkontrolelement > markere indstillingen Ombryd tekst . Herefter skal du justere den afsluttede funktion TEKST til at medtage ASCII-funktionen TEGN(10), hvor du ønsker linjeskiftet. Afhængig af, hvordan det endelige resultat stilles op, kan det være nødvendigt at justere kolonnebredden.
I dette tilfælde bruger vi: ="I dag er: "&TEGN(10)&TEKST(IDAG(),"dd/mm/åå")
Dette kaldes Videnskabelig notation, og Excel konverterer automatisk tal, der er længere end 12 cifre, hvis en eller flere celler er formateret som Generelt, og 15 cifre, hvis en celle(er) er formateret som et Tal. Hvis du har brug for at angive lange numeriske strenge, men ikke vil have dem konverteret, skal du formatere de pågældende celler som Tekst , før du indtaster eller indsætter dine værdier i Excel.
|
|
Mynda anbefaler ... Hvis du vil dele Excel-filer og rapporter med brugere fra forskellige lande/områder, kan det være en fordel at give dem en rapport på deres eget sprog. MVP for Excel, Mynda Treacy har en god løsning på dette i artiklen Excel Dates Displayed in Different Languages om at vise datoer i Excel på forskellige sprog. Den indeholder også en eksempelprojektmappe, du kan downloade. |
Se også
Opret eller slet et brugerdefineret talformat
