Brug af HVIS med funktionerne OG, ELLER og IKKE

HVIS-funktionen gør det muligt at foretage en logisk sammenligning mellem en værdi, og hvad du forventer, ved at teste for en betingelse og returnere et resultat, hvis den betingelse er Sand eller Falsk.

=HVIS(Noget er sandt, så gør noget, ellers gør noget andet)

Men hvad nu, hvis du har brug for at teste flere betingelser, hvor lad os sige, at alle betingelser skal være Sand eller Falsk (OG), eller kun én betingelse skal være Sand eller Falsk (ELLER), eller hvis du vil kontrollere, om en betingelse IKKE opfylder dine kriterier? Alle 3 funktioner kan bruges alene, men det er meget mere almindeligt at se dem parret med HVIS-funktioner.

Brug HVIS-funktionen sammen med OG, ELLER og IKKE til at udføre flere evalueringer, hvis betingelser er Sand eller Falsk.

Syntaks

HVIS(OG()) - HVIS(OG(logisk1, [logisk2], ...), værdi_hvis_sand, [værdi_hvis_falsk]))
HVIS(ELLER()) - HVIS(ELLER(logisk1, [logisk2], ...), værdi_hvis_sand, [værdi_hvis_falsk]))
HVIS(IKKE()) - HVIS(IKKE(logisk1), værdi_hvis_sand, [værdi_hvis_falsk]))


Argumentnavn	Beskrivelse
logisk_test (påkrævet)	Den betingelse, du vil teste.
værdi_hvis_sand (påkrævet)	Den værdi, der skal returneres, hvis resultatet af logisk_test er SAND.

værdi_hvis_falsk (valgfri)	Den værdi, der skal returneres, hvis resultatet af logisk_test er FALSK.

Her er en oversigt over, hvordan funktionerne OG, ELLER og IKKE struktureres individuelt. Når du kombinerer hver enkelt af dem med en HVIS-sætning, ser de således ud:

OG – =HVIS(OG(noget er sandt, noget andet er sandt), værdi hvis Sand, værdi hvis Falsk)
ELLER – =HVIS(ELLER(noget er sandt, noget andet er sandt), værdi hvis Sand, værdi hvis Falsk)
IKKE – = Hvis (IKKE(noget er sandt), værdi hvis Sand, værdi hvis Falsk)

Eksempler

Nedenstående er eksempler på nogle almindelige indlejrede sætninger af typen HVIS(OG()), HVIS(ELLER()) og HVIS(IKKE()). Funktionerne OG og ELLER kan understøtte op til 255 individuelle betingelser, men det er ikke god praksis at bruge mere end nogle få, fordi komplekse, indlejrede formler kan være meget vanskelige at opbygge, afprøve og vedligeholde. Funktionen IKKE har kun én betingelse.

Her er de formler, der er skrevet helt ud i henhold til deres logik:

Formel	Beskrivelse
=HVIS(OG(A2>0,B2<100),SAND, FALSK)	HVIS A2 (25) er større end 0, OG B2 (75) er mindre end 100, returneres SAND, ellers returneres FALSK. I dette tilfælde er begge betingelser sande, så der returneres SAND.
=HVIS(OG(A3="Rød",B3="Grøn"),SAND,FALSK)	Hvis A3 ("Blå") = "Rød", OG B3 ("Grøn") er lig med "Grøn", returneres SAND, ellers returneres FALSK. I dette tilfælde er kun den første betingelse sand, så der returneres FALSK.
=HVIS(ELLER(A4>0,B4<50),SAND, FALSK)	HVIS A4 (25) er større end 0, ELLER B4 (75) er mindre end 50, returneres SAND, ellers returneres FALSK. I dette tilfælde er kun den første betingelse SAND, men da ELLER kun kræver ét argument for at være sand, returnerer formlen SAND.
=HVIS(ELLER(A5="Rød",B5="Grøn"),SAND,FALSK)	HVIS A5 ("Blå") er lig med "Rød", ELLER B5 ("Grøn") er lig med "Grøn", returneres SAND, ellers returneres FALSK. I dette tilfælde er det andet argument Sand, så formlen returnerer SAND.
= HVIS(IKKE(A6>50),SAND,FALSK)	HVIS A6 (25) IKKE er større end 50, returneres SAND, ellers returneres FALSK. I dette tilfælde er 25 ikke større end 50, så formlen returnerer SAND.
=HVIS(IKKE(A7="Rød"),SAND,FALSK)	HVIS A7 ("blå") IKKE er lig med "Rød", returneres SAND, ellers returneres FALSK.

Bemærk, at alle eksemplerne har en højreparentes, når deres respektive betingelser er angivet. De resterende Sand-/Falsk-argumenter bevares så som en del af den ydre HVIS-sætning. Du kan også angive tekst eller numeriske værdier som erstatning for de SAND-/FALSK-værdier, der returneres i eksemplerne.

Her er nogle eksempler på brug af OG, ELLER og IKKE til evaluering af datoer

Eksempler på brug af HVIS med OG, ELLER og IKKE til evaluering af datoer

Her er de formler, der er skrevet helt ud i henhold til deres logik:

Formel	Beskrivelse
=HVIS(A2>B2,SAND,FALSK)	HVIS A2 er større end B2, returneres SAND, ellers returneres FALSK. 03/12/14 er større end 01/01/14, så formlen returnerer SAND.
=HVIS(OG(A3>B2,A3<C2),SAND,FALSK)	HVIS A3 er større end B2, OG A3 er mindre end C2, returneres SAND, ellers returneres FALSK. I dette tilfælde er begge argumenter sande, så formlen returnerer SAND.
=HVIS(ELLER(A4>B2,A4<B2+60),SAND,FALSK)	HVIS A4 er større end B2, ELLER A4 er mindre end B2 + 60, returneres SAND, ellers returneres FALSK. I dette tilfælde er det første argument sandt, men det andet er falsk. Da ELLER kun har brug for et af argumenterne for at være sand, returnerer formlen SAND. Hvis du bruger guiden Evaluer formel fra fanen Formel, får du vist, hvordan Excel evaluerer formlen.
=HVIS(IKKE(A5>B2),SAND,FALSK)	HVIS A5 ikke er større end B2, returneres SAND, ellers returneres FALSK. I dette tilfælde er A5 større end B2, så formlen returnerer FALSK.

Brug af OG, ELLER og IKKE med betinget formatering

Du kan også bruge OG, ELLER og IKKE til at angive kriterier for betinget formatering med formelindstillingen. Når du gør dette, kan du udelade funktionen HVIS og bruge OG, ELLER og IKKE separat.

Klik på Betinget formatering > Ny regel under fanen Hjem. Derefter skal du vælge indstillingen "Brug af en formel til at afgøre, hvilke celler der skal formateres", indtaste din formel og anvende det format, du vil have.

Betinget formatering > Rediger regel-dialogboks, der viser metoden Formel

Med brug af det tidligere datoeksempel kan du se her, hvad formlerne ville være.

Eksempel på brug af OG, ELLER og IKKE som test af betinget formatering

Formel	Beskrivelse
=A2>B2	Hvis A2 er større end B2, skal du formatere cellen, ellers skal du ikke gøre noget.
=OG(A3>B2,A3<C2)	Hvis A3 er større end B2, OG A3 er mindre end C2, skal du formatere cellen, ellers skal du ikke gøre noget.
=ELLER(A4>B2,A4<B2+60)	Hvis A4 er større end B2, ELLER A4 er mindre end B2 plus 60 (dage), skal du formatere cellen, ellers skal du ikke gøre noget.
=IKKE(A5>B2)	Hvis A5 IKKE er større end B2, skal du formatere cellen, ellers skal du ikke gøre noget. I dette tilfælde er A5 større end B2, så formlen returnerer FALSK. Hvis du ændrede formlen til =IKKE(B2>A5), ville den returnere SAND, og cellen ville være formateret.

Bemærk!: Det er en almindelig fejl at angive formlen i Betinget formatering uden lighedstegnet (=). Hvis du gør det, kan du se, at dialogboksen Betinget formatering føjer lighedstegnet og anførselstegnene til formlen - ="ELLER(A4>B2,A4<B2+60)", så du er nødt til at fjerne anførselstegnene, før formlen reagerer korrekt.