TÆL.HVIS, funktionen

Brug TÆL.HVIS, en af de statistiske funktioner, til at tælle antal celler sammen, som opfylder et kriterium, f.eks. hvis du vil tælle det antal gange, en bestemt by vises i en kundeliste.

Syntaks

TÆL.HVIS(område; kriterier)

Det kunne f.eks. være:

  • =TÆL.HVIS(A2:A5;"æbler")

  • =TÆL.HVIS(A2:A5;A4)

Argumentnavn

Beskrivelse

område    (påkrævet)

Den cellegruppe, du vil tælle. Område kan indeholde tal, matrixer eller referencer, der indeholder tal. Tomme celler og tekstværdier ignoreres.

Lær at markere områder i et regneark.

kriterium    (påkrævet)

Et tal, et udtryk, en cellereference eller en tekststreng, som bestemmer, hvilke celler der skal tælles.

Du kan f.eks. bruge et tal som 32, en sammenligning som ">32", en celle som B4 eller et ord som "æbler".

TÆL.HVIS anvender kun et enkelt kriterium. Brug TÆL.HVISER, hvis du vil bruge flere kriterier.

Eksempler

Du bruger disse eksempler i Excel ved at kopiere dataene i tabellen herunder, og sætte dem ind i celle A1 i et nyt regneark.

Data

Data

æbler

32

appelsiner

54

ferskner

75

æbler

86

Formel

Beskrivelse

=TÆL.HVIS(A2:A5;"æbler")

Tæller antallet af celler med æbler i cellerne A2 til og med A5. Resultatet er 2.

=TÆL.HVIS(A2:A5;A4)

Tæller antallet af celler med ferskner (ved hjælp af kriteriet i A4) i cellerne A2 til A5. Resultatet er 1.

=TÆL.HVIS(A2:A5;A3)+TÆL.HVIS(A2:A5;A2)

Tæller antallet med appelsiner (ved hjælp af kriteriet i A3) og æbler (ved hjælp af kriteriet i A2) i cellerne A2 til A5. Resultatet er 3.

=TÆL.HVIS(B2:B5;">55")

Tæller antallet af celler med en højere værdi end 55 i cellerne B2 til B5. Resultatet er 2.

=TÆL.HVIS(B2:B5;"<>"&B4)

Tæller antallet af celler med en værdi, der er forskellig fra 75, i cellerne B2 til B5. Og-tegnet (&) fletter sammenligningsoperatoren "forskellig fra" (<>) og værdien i B4 og ser således ud: =TÆL.HVIS(B2:B5;"<>75"). Resultatet er 3.

=TÆL.HVIS(B2:B5;">=32")-TÆL.HVIS(B2:B5;">85")

Tæller antallet af celler med en værdi, der er større end (>) eller lig med (=) 32 og mindre end (<) eller lig med (=) 85 i cellerne B2 til B5. Resultatet er 3.

=TÆL.HVIS(A2:A5;"*")

Tæller antallet af celler, der indeholder tekst, i cellerne A2 til A5. Jokertegnet (*) bruges til at matche ethvert tegn. Resultatet er 4.

=TÆL.HVIS(A2:A5;"?????er")

Tæller antallet af celler, der har nøjagtigt syv tegn, der slutter med bogstaverne "es" i cellerne A2 til A5. Spørgsmålstegnet (?) bruges som et jokertegn til at matche individuelle tegn. Resultatet er 2.

Almindelige problemer

Problem

Hvad der gik galt

Der bliver returneret en forkert værdi for lange strenge.

Funktionen TÆL.HVIS returnerer forkerte resultater, når du bruger den til at matche strenge på mere end 255 tegn.

For at matche strenge på mere end 255 tegn, skal du bruge funktionen SAMMENKÆDNING eller sammenkædningsoperatoren &. For eksempel: =TÆL.HVIS(A2:A5;"lang streng"&"en anden lang streng").

Der returneres ingen værdi, når du forventer en værdi.

Sørg for at sætte argumentet kriterium i anførselstegn.

Bedste fremgangsmåder

Gør dette

Hvorfor?

Vær opmærksom på, at TÆL.HVIS ignorerer store eller små bogstaver i tekststrenge.

Kriterium skelner ikke mellem store og små bogstaver. Strengen "æbler" og strengen "ÆBLER" matcher f.eks. de samme celler.

Brug af jokertegn.

Jokertegn – spørgsmålstegn (?) og stjerne (*) – kan bruges i kriterium. Et spørgsmålstegn matcher enkelttegn, og en stjerne matcher tegnsekvenser. Hvis du vil søge efter et faktisk spørgsmålstegn eller en faktisk stjerne, skal du indtaste en tilde (~) før tegnet.

Eksempelvis søger =TÆL.HVIS(A2:A5;"æble?") efter alle forekomster af "æble", hvor det sidste bogstav kan variere.

Kontrollér, at dine data ikke indeholder nogen forkerte tegn.

Når du tæller tekstværdier, skal du sikre dig, at dataene ikke indeholder indledende mellemrum, afsluttende mellemrum, inkonsekvent brug af lige og krøllede anførselstegn eller tegn, der ikke kan udskrives. I så fald kan TÆL.HVIS returnere en uventet værdi.

Du skal muligvis fjerne efterstillede mellemrum i en celle efter tabelværdier for at få nøjagtige resultater. Prøv at bruge funktionen RENS eller funktionen FJERN.OVERFLØDIGE.BLANKE.

Relateret

Gælder: Excel 2010, Excel Starter, Excel 2016 Preview, Excel 2007, Excel for Mac 2011, Excel 2013, Excel 2016 for Mac, Excel Online



Var disse oplysninger nyttige?

Ja Nej

Hvordan kan vi forbedre det?

255 tegn tilbage

Inkluder ikke kontaktoplysninger i din feedback for at beskytte dine personlige oplysninger. Gennemse vores erklæring om beskyttelse af personlige oplysninger.

Tak for din feedback!

Supportressourcer

Skift sprog