TÆL.HVIS, funktionen

Brug TÆL.HVIS, en af de statistiske funktioner, til at tælle antal celler sammen, som opfylder et kriterium, f.eks. hvis du vil tælle det antal gange, en bestemt by vises i en kundeliste.

I den mest enkle form siger TÆLHVIS:

  • =TÆLHVIS(Hvor vil du kigge?; Hvad kigger du efter?)

Det kunne f.eks. være:

  • =TÆLHVIS(A2:A5;"London")

  • =TÆL.HVIS(A2:A5;A4)

Din browser understøtter ikke video. Installer Microsoft Silverlight, Adobe Flash Player eller Internet Explorer 9.

TÆL.HVIS(område; kriterier)

Argumentnavn

Beskrivelse

område    (påkrævet)

Den gruppe af celler, du vil tælle. Område kan indeholde tal, matrixer, et navngivet område eller referencer, der indeholder tal. Tomme celler og tekstværdier ignoreres.

Lær at markere områder i et regneark.

kriterium    (påkrævet)

Et tal, et udtryk, en cellereference eller en tekststreng, som bestemmer, hvilke celler der skal tælles.

Du kan f.eks. bruge et tal som 32, en sammenligning som ">32", en celle som B4 eller et ord som "æbler".

TÆL.HVIS anvender kun et enkelt kriterium. Brug TÆL.HVISER, hvis du vil bruge flere kriterier.

Eksempler

Du bruger disse eksempler i Excel ved at kopiere dataene i tabellen herunder, og sætte dem ind i celle A1 i et nyt regneark.

Data

Data

æbler

32

appelsiner

54

ferskner

75

æbler

86

Formel

Beskrivelse

=TÆL.HVIS(A2:A5;"æbler")

Tæller antallet af celler med æbler i cellerne A2 til og med A5. Resultatet er 2.

=TÆL.HVIS(A2:A5;A4)

Tæller antallet af celler med ferskner (ved hjælp af kriteriet i A4) i cellerne A2 til A5. Resultatet er 1.

=TÆLHVIS(A2:A5;A2)+TÆLHVIS(A2:A5;A3)

Tæller antallet af æbler (værdien i A2) og appelsiner (værdien i A3) i cellerne A2 til A5. Resultatet er 3. Denne formel bruger TÆLHVIS to gange, til at angive flere kriterier. Ét kriterium pr. udtryk. Du kan også bruge funktionen TÆLHVIS.

=TÆL.HVIS(B2:B5;">55")

Tæller antallet af celler med en højere værdi end 55 i cellerne B2 til B5. Resultatet er 2.

=TÆL.HVIS(B2:B5;"<>"&B4)

Tæller antallet af celler med en værdi, der er forskellig fra 75, i cellerne B2 til B5. Og-tegnet (&) fletter sammenligningsoperatoren "forskellig fra" (<>) og værdien i B4 og ser således ud: =TÆL.HVIS(B2:B5;"<>75"). Resultatet er 3.

=TÆL.HVIS(B2:B5;">=32")-TÆL.HVIS(B2:B5;">85")

Tæller antallet af celler med en værdi, der er større end (>) eller lig med (=) 32 og mindre end (<) eller lig med (=) 85 i cellerne B2 til B5. Resultatet er 3.

=TÆL.HVIS(A2:A5;"*")

Tæller antallet af celler, der indeholder tekst, i cellerne A2 til A5. Jokertegnet (*) bruges til at matche ethvert tegn. Resultatet er 4.

=TÆL.HVIS(A2:A5;"?????er")

Tæller antallet af celler, der har nøjagtigt 7 tegn og slutter med bogstaverne "es" i cellerne A2 til og med A5. Spørgsmålstegnet (?) bruges som et jokertegn, til at matche individuelle tegn. Resultatet er 2.

Almindelige problemer

Problem

Hvad der gik galt

Der bliver returneret en forkert værdi for lange strenge.

Funktionen TÆL.HVIS returnerer forkerte resultater, når du bruger den til at matche strenge på mere end 255 tegn.

For at matche strenge på mere end 255 tegn, skal du bruge funktionen SAMMENKÆDNING eller sammenkædningsoperatoren &. For eksempel: =TÆL.HVIS(A2:A5;"lang streng"&"en anden lang streng").

Der returneres ingen værdi, når du forventer en værdi.

Sørg for at sætte argumentet kriterium i anførselstegn.

En TÆL.HVIS-formel modtager en #VÆRDI!-fejl, når du refererer til et andet regneark.

Denne fejl opstår, når den formel, der indeholder funktionen, refererer til celler eller et område i en lukket projektmappe, og cellerne beregnes. Du får denne funktion til at fungere ved at holde den anden projektmappen åben.

Bedste fremgangsmåder

Gør dette

Hvorfor?

Vær opmærksom på, at TÆL.HVIS ignorerer store eller små bogstaver i tekststrenge.

Kriterium skelner ikke mellem store og små bogstaver. Strengen "æbler" og strengen "ÆBLER" matcher f.eks. de samme celler.

Brug af jokertegn.

Jokertegn – spørgsmålstegn (?) og stjerne (*) – kan bruges i kriterium. Et spørgsmålstegn matcher enkelttegn, og en stjerne matcher tegnsekvenser. Hvis du vil søge efter et faktisk spørgsmålstegn eller en faktisk stjerne, skal du indtaste en tilde (~) før tegnet.

Eksempelvis søger =TÆL.HVIS(A2:A5;"æble?") efter alle forekomster af "æble", hvor det sidste bogstav kan variere.

Kontrollér, at dine data ikke indeholder nogen forkerte tegn.

Når du tæller tekstværdier, skal du sikre dig, at dataene ikke indeholder indledende mellemrum, afsluttende mellemrum, inkonsekvent brug af lige og krøllede anførselstegn eller tegn, der ikke kan udskrives. I så fald kan TÆL.HVIS returnere en uventet værdi.

Prøv at bruge funktionen RENS eller funktionen TRIM.

Gøre det nemmere at bruge navngivne områder

TÆL.HVIS understøtter navngivne områder i en formel (f.eks: =TÆL.HVIS (frugt,"> = 32")-TÆL.HVIS (frugt,"> 85"). Det navngivne område kan være i det aktuelle regneark, et andet regneark i samme projektmappe eller fra en anden projektmappe. Hvis du vil referere til en anden projektmappe, skal den anden projektmappe også være åben.

Bemærk: Funktionen TÆL.HVIS tæller ikke celler med udgangspunkt i cellebaggrunds- eller skriftfarve. Excel understøtter dog brugerdefinerede funktioner (UDF'er) ved hjælp af Microsoft Visual Basic for Applications (VBA)-handlinger på celler med udgangspunkt i baggrunds- eller skriftfarve. Her er et eksempel på, hvordan du kan tælle antallet af celler med en bestemt cellefarve ved hjælp af VBA.

Har du brug for mere hjælp?

Du kan altid spørge en ekspert i Excel Tech Community, få support i Answers community eller foreslå en ny funktion eller forbedring i Excel User Voice.

Se også

Hvis du vil tælle celler, der ikke er tomme, skal du bruge funktionen TÆLV

Hvis du vil tælle celler, der anvender flere kriterier, skal du bruge funktionen TÆL.HVISER

Se en video om, hvordan du bruger funktionen TÆL.HVISER

Funktionen SUM.HVISER lægger kun de værdier, der opfylder et enkelt kriterium, sammen

Funktionen SUM.HVISER lægger kun de værdier, der opfylder flere kriterier, sammen

Funktionen HVIS.ER (Office 365, Excel 2016 og nyere)

Brug funktionen TRIM til at fjerne foranstillede og efterstillede mellemrum i celler

Brug funktionen RENS til at fjerne tegn, der ikke kan udskrives, i celler

Oversigt over formler i Excel

Sådan undgår du ødelagte formler

Registrer fejl i formler

Statistiske funktioner

Excel-funktioner (alfabetisk)

Excel-funktioner (efter kategori)

Brug af SUM.HVIS, TÆL.HVIS og relaterede funktioner til hurtig dataanalyse (gratis eksempel)

Udvid dine færdigheder
Gå på opdagelse i kurser
Få nye funktioner først
Bliv Office Insider

Var disse oplysninger nyttige?

Tak for din feedback!

Tak for din feedback! Det lyder, som om det vil kunne hjælpe, hvis du bliver sat i forbindelse med en af vores Office-supportteknikere.

×