Log på med Microsoft
Log på, eller opret en konto.
Hej
Markér en anden konto.
Du har flere konti
Vælg den konto, du vil logge på med.

Når du opretter en Excel-tabel, tildeler Excel et navn til tabellen og til hver kolonneoverskrift i tabellen. Når du føjer formler til en Excel-tabel, vises disse navne automatisk, når du skriver formlen og vælger cellereferencerne i tabellen, og du behøver ikke at skrive dem manuelt. Her er et eksempel på, hvad Excel gør:

I stedet for at bruge eksplicitte cellereferencer

Bruger Excel navne for tabeller og kolonner

=SUM(C2:C7)

=SUM(AfdSalg[Salgsbeløb])

Denne kombination af tabel- og kolonnenavne kaldes en struktureret reference. Navnene i strukturerede referencer tilpasses, når du tilføjer eller fjerner data fra tabellen.

Strukturerede referencer vises også, når du opretter en formel uden for en Excel-tabel, der henviser til tabeldata. Referencerne kan gøre det lettere at finde tabeller i en stor projektmappe.

Hvis du vil medtage strukturerede referencer i din formel, skal du klikke på de tabelceller, du vil referere til, i stedet for at skrive deres cellereference i formlen. Lad os bruge følgende eksempeldata til at angive en formel, der automatisk bruger strukturerede referencer til at beregne beløbet for en salgsprovision.

Sælger

Område

Salgsbeløb

Provision i %

Provisionsbeløb

Joe

Nord

260

10 %

Robert

Syd

660

15 %

Michelle

Øst

940

15 %

Erik

Vest

410

12 %

Dafna

Nord

800

15 %

Rob

Syd

900

15 %

  1. Kopiér eksempeldataene i tabellen ovenfor, herunder kolonneoverskrifterne, og indsæt dem i celle A1 i et nyt Excel-regneark.

  2. Hvis du vil oprette tabellen, skal du markere en vilkårlig celle i dataområdet og trykke på Ctrl+T.

  3. Sørg for, at afkrydsningsfeltet Tabellen indeholder overskrifter er markeret, og klik på OK.

  4. Skriv et lighedstegn (=) i celle E2, og klik på celle C2.

    Den strukturerede reference [@[Salgsbeløb]] vises på formellinjen efter lighedstegnet.

  5. Skriv en stjerne (*) direkte efter den højreparentes, og klik på celle D2.

    Den strukturerede reference [@[Provision i %]] vises efter stjernen i formellinjen.

  6. Tryk på Enter.

    Der oprettes automatisk en beregnet kolonne i Excel, og formlen kopieres ind i hele kolonnen og tilpasses for hver række.

Hvad sker der, når jeg bruger eksplicitte cellereferencer?

Hvis du angiver eksplicitte cellereferencer i en beregnet kolonne, kan det være sværere at se, hvad formlen beregner.

  1. Klik på celle E2 i eksempelregnearket

  2. Skriv =C2*D2 på formellinjen, og tryk på Enter.

Bemærk, at mens Excel kopierer din formel ned i kolonnen, bruger den ikke strukturerede referencer. Hvis du f.eks. tilføjer en kolonne mellem de eksisterende kolonner C og D, skal du revidere din formel.

Hvordan ændrer jeg et tabelnavn?

Når du opretter en Excel-tabel, oprettes der et standardtabelnavn (Tabel1, Tabel2 osv.), men du kan ændre tabelnavnet, så det giver mere mening.

  1. Markér en vilkårlig celle i tabellen for at få vist fanen Tabelværktøjer > Design på båndet.

  2. Skriv det ønskede navn i feltet Tabelnavn , og tryk på Enter.

I vores eksempeldata brugte vi navnet AfdSalg.

Brug følgende regler for tabelnavne:

  • Brug gyldige tegn  Start altid et navn med et bogstav, et understregningstegn (_) eller en omvendt skråstreg (\). Brug bogstaver, tal, punktummer og understregningstegn i resten af navnet. Du kan ikke bruge "C", "c", "R" eller "r" til navnet, fordi de allerede anvendes som genveje til at vælge kolonnen eller rækken for den aktive celle, når du angiver dem i feltet Navn eller Gå til.

  • Brug ikke cellereferencer  Navne kan ikke være det samme som en cellereference, f.eks. Z$100 eller R1C1.

  • Brug ikke et mellemrum til at adskille ord  Mellemrum kan ikke bruges i navnet. Du kan bruge understregningstegn (_) og punktum (.) som ordseparatorer. AfdSalg, Sales_Tax eller Første.kvartal.

  • Brug ikke mere end 255 tegn Et tabelnavn kan bestå af op til 255 tegn.

  • Brug entydige tabelnavne Dublerede navne er ikke tilladt. Der skelnes ikke mellem store og små bogstaver i navne i Excel, så hvis du skriver "Salg", men allerede har et andet navn kaldet "SALG" i den samme projektmappe, bliver du bedt om at vælge et entydigt navn.

  • Brug et objekt-id  Hvis du planlægger at have en blanding af tabeller, pivottabeller og diagrammer, er det en god ide at forankre dine navne med objekttypen. For eksempel: tbl_Sales for en salgstabel, pt_Sales for en pivottabel for salg og chrt_Sales for et salgsdiagram eller ptchrt_Sales for et salgspivotdiagram. Dette bevarer alle dine navne på en sorteret liste i Navnestyring.

Syntaksregler for strukturerede referencer

Du kan også angive eller ændre strukturerede referencer manuelt i formlen, men det hjælper med at forstå syntaksen for strukturerede referencer. Lad os gennemgå følgende formeleksempel:

=SUM(AfdSalg[[#Totaler],[Salgsbeløb]],AfdSalg[[#Data],[Provisionsbeløb]])

Denne formel har følgende komponenter som strukturerede referencer:

  • Tabelnavn:    AfdSalg er et brugerdefineret tabelnavn. Det henviser til tabeldataene, uden nogen overskriftsrække eller række for totaler. Du kan bruge et standardtabelnavn, såsom Tabel1, eller du kan ændre det for at bruge et brugerdefineret navn.

  • Kolonneangivelse:    [Salgsbeløb] og [Provisionsbeløb] er kolonneangivelser, der bruger navnene på de kolonner, de repræsenterer. De henviser til kolonnedataene, uden nogen kolonneoverskrift eller række for totaler. Angivelserne skal som vist altid omgives af kantparenteser.

  • Elementangivelse:    [#Totals] og [#Data] er særlige elementangivelser, der refererer til bestemte dele af tabellen, f.eks. rækken Total.

  • Tabelangivelse:    [ [ #Totaler],[Salgsbeløb]] og [[#Data] , [Provisionsbeløb]] er tabelangivelser, der repræsenterer de ydre dele af den strukturerede reference. Ydre referencer følger tabelnavnet, og de skal omgives af kantede parenteser.

  • Struktureret reference:    (AfdSalg[[#Totals],[Salgsbeløb]] og AfdSalg[[#Data],[Provisionsbeløb]] er strukturerede referencer, der repræsenteres af en streng, der begynder med tabelnavnet og slutter med kolonneangivelsen.

Hvis du vil oprette eller redigere strukturerede referencer manuelt, skal du bruge følgende syntaksregler:

  • Brug kantede parenteser omkring angivelser    Alle angivelser for tabel, kolonne og specielle elementer skal være omgivet af kantede parenteser ([ ]). Hvis en angivelse indeholder andre angivelser, skal der bruges ydre parenteser, som omgiver de indre parenteser for de andre angivelser. Eksempel: =AfdSalg[[Sælger]:[Område]]

  • Alle kolonneoverskrifter er tekststrenge    Men de kræver ikke anførselstegn, når de bruges i en struktureret reference. Tal eller datoer, f.eks. 2014 eller 1/1/2014, betragtes også som tekststrenge. Du kan ikke bruge udtryk med kolonneoverskrifter. Udtrykket AfdSalgResumé[[2014]:[2012]] fungerer f.eks. ikke.

Brug kantede parenteser omkring kolonneoverskrifter med specialtegn    Hvis der er specialtegn, skal hele kolonneoverskriften være omgivet af kantede parenteser, hvilket betyder, at dobbelte kantede parenteser er påkrævet i en kolonneangivelse. Eksempel: =AfdSalgÅrResumé[[Total $-Beløb]]

Her er listen over specialtegn, der kræver ekstra parenteser i formlen:

  • Tabulatortast

  • Linjeskift

  • Vognretur

  • Komma (,)

  • Kolon (:)

  • Punktum (.)

  • Venstre kantparentes ([)

  • Højreparentes (])

  • Nummertegn (#)

  • Enkelt anførselstegn (')

  • Dobbelt anførselstegn (")

  • Venstre klammeparentes ({)

  • Højre klammeparentes (})

  • Dollartegn ($)

  • Indsætningstegn (^)

  • Og-tegn (&)

  • Stjerne (*)

  • Plustegn (+)

  • Lighedstegn (=)

  • Minustegn (-)

  • Symbolet Større end (>)

  • Mindre end symbol (<)

  • Divisionstegn (/)

  • At sign (@)

  • Omvendt skråstreg (\)

  • Udråbstegn (!)

  • Venstre parentes (()

  • Højre parentes ())

  • Procenttegn (%)

  • Spørgsmålstegn (?)

  • Backtick (')

  • Semikolon (;)

  • Tilde (~)

  • Understregningstegn (_)

  • Brug et escape-tegn for visse specialtegn i kolonneoverskrifter    Nogle tegn har en særlig betydning og kræver brug af et enkelt anførselstegn (') som escape-tegn. Eksempel =AfdSalgÅrResumé[‘#UdgVarer]

Her er listen over specialtegn, der skal bruge et escape-tegn (') i formlen:

  • Venstre kantparentes ([)

  • Højreparentes (])

  • Nummertegn(#)

  • Enkelt anførselstegn (')

  • At sign (@)

Brug mellemrumstegn for at forbedre læsbarheden i en struktureret reference    Du kan bruge specialtegn til at forbedre læsbarheden i en struktureret reference. Eksempel: =AfdSalg[ [Sælger]:[Region] ] eller =AfdSalg[[#Overskrifter], [#Data], [Provision i %]]

Det anbefales at bruge et mellemrum:

  • Efter den første venstre kantparentes ([)

  • Foran den sidste højre kantparentes (]).

  • Efter komma.

Referenceoperatorer

Du kan bruge følgende referenceoperatorer til at kombinere kolonneangivelser for at opnå større fleksibilitet, når du angiver celleområder.

Denne strukturerede reference:

Henviser til:

Ved at bruge:

Som er celleområdet:

=AfdSalg[[Sælger]:[Region]]

Alle celler i to eller flere tilstødende kolonner

: (kolon) områdeoperator

A2:B7

=AfdSalg[Salgsbeløb],AfdSalg[Provisionsbeløb]

En kombination af to eller flere kolonner

, (komma) operator for foreningsmængde

C2:C7, E2:E7

=AfdSalg[[Sælger]:[Salgsbeløb]] AfdSalg[[Region]:[Provision i %]]

To eller flere kolonner krydser hinanden

 (mellemrum) skæringspunktoperator

B2:C7

Angivelser for specielle elementer

Hvis du vil referere til bestemte dele af en tabel, f.eks. rækken med totaler, kan du bruge en af følgende særlige elementangivelser i dine strukturerede referencer.

Denne angivelse for specielle elementer:

Henviser til:

#Alle

Hele tabellen, inklusive kolonneoverskrifter, data og totaler (hvis relevant).

#Data

Kun datarækkerne.

#Overskrifter

Kun overskriftsrækken.

#Totaler

Kun rækken med totaler. Hvis der ingen findes, returneres nul.

#Denne række

eller

@

eller

@[Kolonnenavn]

Kun cellerne i den samme række som formlen. Disse angivelser kan ikke kombineres med andre særlige elementangivelser. Brug dem til at gennemtvinge udførelse af implicit forening for referencen eller for at ignorere implicit forening og referere til enkelte værdier fra en kolonne.

Excel ændrer automatisk angivelser for #DenneRække til den kortere @-angivelse i tabeller, der har mere end én række data. Men hvis tabellen kun har én række, erstatter Excel ikke angivelsen #Denne række, hvilket kan medføre uventede beregningsresultater, når du tilføjer flere rækker. For at undgå beregningsproblemer skal du sørge for at angive flere rækker i tabellen, før du angiver nogen formler med strukturerede referencer.

Kvalificere strukturerede referencer i beregnede kolonner

Når du opretter en beregnet kolonne, bruger du ofte en struktureret reference til at oprette formlen. Denne strukturerede reference kan være ukvalificeret eller fuldt kvalificeret. Hvis du f.eks. vil oprette den beregnede kolonne kaldet Provisionsbeløb, der beregner provisionsbeløbet i dollars, kan du bruge følgende formler:

Type af struktureret reference

Eksempel

Kommentar

Ikke-kvalificeret

=[Salgsbeløb]*[Provision i %]

Multiplicerer de tilsvarende værdier fra den aktuelle række.

Fuldt kvalificeret

=AfdSalg[Salgsbeløb]*AfdSalg[Provision i %]

Multiplicerer de tilsvarende værdier for hver enkelt række for begge kolonner.

Følg denne generelle regel: Hvis du bruger strukturerede referencer i en tabel, f.eks. når du opretter en beregnet kolonne, kan du bruge en ikke-kvalificeret struktureret reference, men hvis du bruger den strukturerede reference uden for tabellen, skal du bruge en fuldt kvalificeret struktureret reference.

Eksempler på brug af strukturerede referencer

Her er nogle måder, du kan bruge strukturerede referencer på:

Denne strukturerede reference:

Henviser til:

Som er celleområdet:

=AfdSalg[[#Alle],[Salgsbeløb]]

Alle cellerne i kolonnen Salgsbeløb.

C1:C8

=AfdSalg[[#Overskrifter],[Provision i %]]

Overskriften for kolonnen Provision i %.

D1

=AfdSalg[[#Totaler],[Region]]

Totalen for kolonnen Region. Hvis der ikke er en række med Totaler, returneres nul.

B8

=AfdSalg[[#Alle],[Salgsbeløb]:Provision i %]]

Alle cellerne i Salgsbeløb og Provision i %.

C1:D8

=AfdSalg[[#Data],[Provision i %]:[Provisionsbeløb]]

Kun data fra kolonnerne Provision i % og Provisionsbeløb.

D2:E7

=AfdSalg[[#Overskrifter],[Region]:[Provisionsbeløb]]

Kun overskrifterne for kolonnerne mellem Område og Provisionsbeløb.

B1:E1

=AfdSalg[[#Totaler],[Salgsbeløb]:[Provisionsbeløb]]

Totalerne for kolonnerne fra Salgsbeløb til Provisionsbeløb. Hvis der ikke er en række med totaler, returneres nul.

C8:E8

=AfdSalg[[#Overskrifter],[#Data],[Provision i %]]

Kun overskrift og data for Provision i %.

D1:D7

=AfdSalg[[#DenneRække],[Provisionsbeløb]]

eller

=AfdSalg[@Provisionsbeløb]

Cellen ved skæringspunktet mellem den aktuelle række og kolonnen Provisionsbeløb. Hvis det bruges i samme række som en overskrifts- eller totalrække, returnerer dette en #VALUE! -fejl.

Hvis du skriver en længere form for den strukturerede reference ( #Denne række) i en tabel med flere rækker med data, erstatter Excel det automatisk med den kortere form (@). De fungerer begge på samme måde.

E5 (hvis den aktuelle række er 5)

Strategier for at arbejde med strukturerede referencer

Overvej følgende, når du arbejder med strukturerede referencer.

  • Brug af Autofuldførelse af formel    Det kan være meget nyttigt at bruge Autofuldførelse af formel, når du angiver strukturerede referencer, og det sikrer, at du bruger den korrekte syntaks. Du kan få mere at vide under Brug autofuldførelse af formel.

  • Beslut, om der skal genereres strukturerede referencer til tabeller i semimarkeringer    Når du opretter en formel, markeres cellerne, når du klikker på et celleområde i en tabel, og der indsættes automatisk en struktureret reference i stedet for celleområdet i formlen. Halvmarkeringen gør det meget nemmere at indsætte en struktureret reference. Du kan slå denne funktionsmåde til eller fra ved at markere eller fjerne markeringen i afkrydsningsfeltet Brug tabelnavne i formler i dialogboksen Indstillinger for > filer > Formler > Arbejde med formler.

  • Brug projektmapper med eksterne links til Excel-tabeller i andre projektmapper    Hvis en projektmappe indeholder en ekstern kæde til en Excel-tabel i en anden projektmappe, skal den sammenkædede kildeprojektmappe være åben i Excel for at undgå #REF! -fejl i den destinationsprojektmappe, der indeholder kæderne. Hvis du åbner destinationsprojektmappen først, og der vises #REF! -fejl, bliver de løst, hvis du derefter åbner kildeprojektmappen. Hvis du først åbner kildeprojektmappen, bør du ikke få vist nogen fejlkoder.

  • Konvertere et område til en tabel og en tabel til et område    Når du konverterer en tabel til et område, ændres alle cellereferencer til deres tilsvarende absolutte A1-typografireferencer. Når du konverterer et område til en tabel, ændrer Excel ikke automatisk cellereferencer i dette område til deres tilsvarende strukturerede referencer.

  • Slå kolonneoverskrifter fra    Du kan slå tabelkolonneoverskrifter til og fra under fanen Tabeldesign > Kolonneoverskrift. Hvis du deaktiverer tabelkolonneoverskrifter, påvirkes strukturerede referencer, der bruger kolonnenavne, ikke, og du kan stadig bruge dem i formler. Strukturerede referencer, der henviser direkte til tabeloverskrifterne (f.eks. =AfdSalg[[#Headers],[%Provision]]), resulterer i #REF.

  • Tilføje eller slette kolonner og rækker i tabellen    Da tabeldataområder ofte ændres, justeres cellereferencer for strukturerede referencer automatisk. Hvis du f.eks. bruger et tabelnavn i en formel til at tælle alle datacellerne i en tabel, og du derefter tilføjer en række med data, justeres cellereferencen automatisk.

  • Omdøbe en tabel eller kolonne    Hvis du omdøber en kolonne eller tabel, ændrer Excel automatisk brugen af den pågældende tabel og kolonneoverskrift i alle strukturerede referencer, der anvendes i projektmappen.

  • Flytte, kopiere og udfylde strukturerede referencer    Alle strukturerede reference forbliver de samme, når du kopierer eller flytter en formel, der bruger en struktureret reference.

    Bemærk!: Kopiering af en struktureret reference og udfyldning af en struktureret reference er ikke det samme. Når du kopierer, forbliver alle strukturerede referencer de samme, mens fuldt kvalificerede strukturerede referencer justerer kolonneangivelserne som en serie som opsummeret i følgende tabel, når du udfylder en formel.

Hvis udfyldningsretningen er:

Og mens du udfylder, skal du trykke på:

Så:

Op eller ned

Intet

Er der ingen tilpasning af kolonneangivelsen.

Op eller ned

Ctrl

Tilpasses kolonneangivelser som en serie.

Højre eller venstre

Ingen

Tilpasses kolonneangivelser som en serie.

Op, ned, højre eller venstre

Skift

Flyttes de aktuelle celleværdier, og der indsættes kolonneangivelser, i stedet for at værdierne i de aktuelle celler overskrives.

Har du brug for mere hjælp?

Du kan altid spørge en ekspert i Excel Tech Community eller få support i community'er.

Relaterede emner

Oversigt over Excel-tabeller
Video: Oprette og formatere en Excel-tabel
Total af dataene i en Excel-tabel
Formatere en Excel-tabel
Tilpas størrelsen på en tabel ved at tilføje eller fjerne rækker og kolonner
Filtrere data i et område eller en tabel
Konvertere en tabel til et område
Kompatibilitetsproblemer med
Excel-tabellerEksportér en Excel-tabel til SharePoint
Oversigter over formler i Excel

Har du brug for mere hjælp?

Vil du have flere indstillinger?

Udforsk abonnementsfordele, gennemse kurser, få mere at vide om, hvordan du sikrer din enhed og meget mere.

Communities hjælper dig med at stille og besvare spørgsmål, give feedback og høre fra eksperter med omfattende viden.

Var disse oplysninger nyttige?

Hvor tilfreds er du med kvaliteten af sproget?
Hvad påvirkede din oplevelse?
Når du trykker på Send, bliver din feedback brugt til at forbedre Microsoft-produkter og -tjenester. Din it-administrator kan indsamle disse data. Erklæring om beskyttelse af personlige oplysninger.

Tak for din feedback!

×