Výpočet rozdílu mezi dvěma daty

Výpočet rozdílu mezi dvěma daty

Funkci DATEDIF použijte, pokud chcete vypočítat rozdíl mezi dvěma daty. Nejdřív zadejte do jedné buňky počáteční datum a do druhé koncové datum. Potom zadejte vzorec, který bude podobný jednomu z následujících vzorců.

Rozdíl vyjádřený počtem dnů

=DATEDIF(D9;E9;"d") s výsledkem 856

V tomto příkladu je počáteční datum v buňce D9 a koncové datum v buňce E9. Vzorec je v buňce F9. Parametr d vrátí počet celých dnů mezi dvěma daty.

Rozdíl vyjádřený počtem týdnů

=(DATEDIF(D13;E13;"d")/7) a výsledek: 122,29

V tomto příkladu je počáteční datum v buňce D13 a koncové datum v buňce E13. Parametr d vrátí počet dnů. Všimněte si ale znaků /7 na konci. Počet dnů se vydělí 7, protože týden má 7 dnů. Pozor, tento výsledek musí být také naformátovaný jako číslo. Stiskněte kombinaci kláves CTRL+1. Pak klikněte na Číslo > Desetinná místa: 2.

Rozdíl vyjádřený počtem měsíců

=DATEDIF(D5;E5;"m") a výsledek: 28

V tomto příkladu je počáteční datum v buňce D5 a koncové datum v buňce E5. Parametr m ve vzorci vrátí počet celých měsíců mezi těmito dvěma daty.

Rozdíl vyjádřený počtem let

=DATEDIF(D2;E2;"y") a výsledek: 2

V tomto příkladu je počáteční datum v buňce D2 a koncové datum v buňce E2. Parametr y vrátí počet celých roků mezi dvěma daty.

Výpočet věku v kumulovaných letech, měsících a dnech

Vypočítat můžete také věk nebo délku zaměstnaneckého poměru. Výsledek může vypadat třeba takto: „2 roky, 4 měsíce, 5 dnů“.

1. Funkci DATEDIF můžete použít ke zjištění celkového počtu let.

=DATEDIF(D17;E17;"y") a výsledek: 2

V tomto příkladu je počáteční datum v buňce D17 a koncové datum v buňce E17. Parametr y ve vzorci vrátí počet celých roků mezi dvěma daty.

2. Použijte funkci DATEDIF znovu s parametrem ym ke zjištění počtu měsíců.

=DATEDIF(D17;E17;"ym") a výsledek: 4

V jiné buňce použijte vzorec DATEDIF s parametrem ym. Parametr ym vrátí počet zbývajících měsíců po posledním celém roce.

3. Vyhledejte dny pomocí jiného vzorce.

=DATEDIF(D17;E17;"md") a výsledek: 5

Teď potřebujeme zjistit počet zbývajících dní. Uděláme to zadáním jiného druhu vzorce zobrazeného výše. Tento vzorec odečte první den koncového měsíce (1.5.2016) od původního koncového data v buňce E17 (6.5.2016). Dělá se to takto: Funkce DATUM nejprve vytvoří datum, 1.5.2016. Použije k tomu rok v buňce E17 a měsíc v buňce E17. Číslo 1 pak představuje první den tohoto měsíce. Výsledek funkce DATUM je 1.5.2016. Potom ho odečteme od původního koncového data v buňce E17, což je 6.5.2016. 6.5.2016 minus 1.5.2016 je 5 dnů.

Poznámka : Nedoporučujeme používat argument md funkce DATEDIF, protože může vypočítat nepřesné výsledky.

4. Volitelné: Zkombinujte tři vzorce v jednom.

=DATEDIF(D17;E17;"y")&" roky, "&DATEDIF(D17;E17;"ym")&" měsíce, "&DATEDIF(D17;E17;"md")&" dní" a výsledek: 2 roky, 4 měsíce, 5 dní

Všechny tři výpočty můžete vložit do jedné buňky, jak je vidět v tomto příkladu. Použijte ampersandy, uvozovky a text. Zápis tohoto vzorce je sice delší, ale obsahuje vše v jednom. Tip: Stisknutím kombinace kláves ALT+ENTER vložíte do vzorce konec řádku. Díky tomu je přehlednější. Pokud nevidíte celý vzorec, stiskněte kombinaci kláves CTRL+SHIFT+U.

Stažení příkladů

Můžete si stáhnout ukázkový sešit se všemi příklady uvedenými v tomto článku. Můžete postupovat stejně, nebo si můžete vytvořit svoje vlastní vzorce.

Stáhnout příklady s výpočty kalendářních dat

Další výpočty s kalendářními daty a časem

Jak už jste viděli výše, funkce DATEDIF vypočítá rozdíl mezi počátečním datem a koncovým datem. Místo zadávání konkrétních dat můžete ve vzorci použít také funkci DNES(). Když použijete funkci DNES(), Excel použije pro datum aktuální datum vašeho počítače. Pamatujte, že když v budoucnu tento soubor znovu otevřete, toto datum se změní.

=DATEDIF(DNES();D28;"y") a výsledek: 984

Poznámka: Tento článek se vytvářel 6. října 2016.

Pokud chcete vypočítat počet pracovních dnů mezi dvěma kalendářními daty, použijte funkci NETWORKDAYS.INTL. Můžete ji také nastavit tak, aby nepočítala víkendy a svátky.

Než začnete: Rozhodněte se, jestli chcete z výpočtu vyloučit svátky. Pokud je vyloučit chcete, zadejte seznam kalendářních dat těchto svátků do samostatné oblasti nebo na samostatný list. Každé datum svátku zadejte do samostatné buňky. Pak tyto buňky vyberte a zvolte Vzorce > Definovat název. Pojmenujte oblast MojeSvatky a klikněte na OK. Potom pomocí následujícího postupu vytvořte vzorec.

1. Zadejte počáteční a koncové datum.

Počáteční datum v buňce D53 je 1/1/2016, koncové datum v buňce E53 je 12/31/2016

V tomto příkladu je počáteční datum v buňce D53 a koncové datum v buňce E53.

2. Do jiné buňky zadejte vzorec podobný tomuto:

=NETWORKDAYS.INTL(D53;E53;1) a výsledek: 261

Zadejte vzorec jako ve výše uvedeném příkladu. 1 ve vzorci nastavuje soboty a neděle jako víkendové dny a vylučuje je z celkového výpočtu.

Poznámka: Excel 2007 funkci NETWORKDAYS.INTL nemá. Má ale funkci NETWORKDAYS. Výše uvedený příklad by v Excelu 2007 vypadal takto: =NETWORKDAYS(D53;E53). 1 nezadáváte, protože funkce NETWORKDAYS považuje soboty a neděle za víkend.

3. V případě potřeby 1 změňte.

Seznam Intellisense zobrazující 2 – neděle, pondělí; 3 – pondělí, neděle a tak dále

Pokud sobota a neděle nejsou vaše víkendové dny, změňte 1 na jakékoli jiné číslo ze seznamu IntelliSense. 2 například nastavuje jako víkendové dny neděli a pondělí.

Pokud používáte Excel 2007, můžete tento krok přeskočit. Funkce NETWORKDAYS v Excelu 2007 totiž soboty a neděle považuje vždy za víkend.

4. Zadejte název oblasti svátků.

=NETWORKDAYS.INTL(D53;E53;1;MyHolidays) a výsledek: 252

Pokud jste název oblasti svátků vytvořili v části „Než začnete“ výše, zadejte ho nakonec jako v tomto příkladu. Pokud svátky nemáte, můžete středník a MojeSvatky vynechat. Pokud používáte Excel 2007, výše uvedený příklad by vypadal takto: =NETWORKDAYS(D53;E53;MojeSvatky).

Tip: Pokud nechcete odkazovat na název oblasti svátků, můžete místo toho zadat rozsah, například D35:E:39. Nebo můžete do vzorce jednotlivé svátky zadat. Pokud by třeba byly svátky 1. a 2. ledna 2016, zapsali byste je takto: =NETWORKDAYS.INTL(D53;E53;1;{"1/1/2016";"1/2/2016"}). V Excelu 2007 by to vypadalo takto: =NETWORKDAYS(D53;E53;{"1/1/2016";"1/2/2016"})

Uplynulý čas můžete vypočítat odečtením jednoho času od druhého. Nejdřív zadejte do jedné buňky počáteční čas a pak do druhé koncový čas. Zadejte úplný zápis času, včetně hodin, minut a mezer před „dop.“ nebo „odp.“. Uděláte to takto:

1. Zadejte počáteční a koncový čas.

Počáteční datum/čas 7:15 AM, koncové datum/čas 4:30 PM

V tomto příkladu je počáteční čas v buňce D80 a koncový čas v buňce E80. Nezapomeňte zadat hodiny, minuty a mezery před „dop.“ nebo „odp.“.

2. Nastavte formát h:mm AM/PM.

Dialogové okno Formát buněk, příkaz Vlastní, typ h:mm AM/PM

Vyberte obě data a stiskněte kombinaci kláves CTRL+1 (nebo Obrázek příkazového tlačítka počítače MAC +1 na Macu). Vyberte možnost Vlastní > h:mm AM/PM, pokud ještě není nastavená.

3. Odečtěte tyto dva časy.

=E80-D80 a výsledek: 9:15 AM

V jiné buňce odečtěte buňku počátečního času od buňky koncového času.

4. Nastavte formát h:mm.

Dialogové okno Formát buněk, příkaz Vlastní, typ h:mm

Stiskněte kombinaci kláves CTRL+1 (nebo Obrázek příkazového tlačítka počítače MAC +1 na Macu). Vyberte Vlastní > h:mm tak, aby výsledek neobsahoval text „dop.“ a „odp.“.

Pokud chcete vypočítat čas mezi dvěma daty a časy, stačí odečíst jedno od druhého. Jednotlivé buňky je ale potřeba naformátovat, abyste zajistili, že Excel vrátí požadovaný výsledek.

1. Zadejte dvě úplná data a časy.

Počáteční datum 1/1/16 1:00 PM; koncové datum 1/2/16 2:00 PM

Do jedné buňky zadejte úplné počáteční datum s časem. A do druhé buňky zadejte úplné koncové datum s časem. Každá buňka by měla obsahovat měsíc, den, rok, hodinu, minutu a mezeru před „dop.“ nebo „odp.“.

2. Nastavte formát 14.3.12 1:30 PM.

Dialogové okno Formát buněk, příkaz Datum, typ 3/14/12 1:30 PM

Vyberte obě buňky a pak stiskněte kombinaci kláves CTRL+1 (nebo Obrázek příkazového tlačítka počítače MAC +1 na Macu). Potom zvolte Datum > 14.3.12 1:30 PM. Nejedná se o datum, které nastavíte, je to jenom příklad toho, jak formát vypadá. Ve verzích starších než Excel 2016 může ukázkové datum tohoto formátu vypadat třeba takto: 14.3.01 1:30 PM.

3. Odečtěte tato dvě data.

=E84-D84 a výsledek 1,041666667

V jiné buňce odečtěte počáteční datum a čas od koncového data a času. Výsledkem bude pravděpodobně desetinné číslo. V dalším kroku to napravíte.

4. Nastavte formát [h]:mm.

Dialogové okno Formát buněk, příkaz Vlastní, typ [h]:mm

Stiskněte kombinaci kláves CTRL+1 (nebo Obrázek příkazového tlačítka počítače MAC +1 na Macu). Vyberte Vlastní. Do pole Typ zadejte [h]:mm.

Viz taky

Funkce DATEDIF

Funkce NETWORKDAYS.INTL

NETWORKDAYS

Další funkce data a času

Výpočet rozdílu mezi dvěma časy

Rozšiřte své znalosti a dovednosti
Projít školení
Získejte nové funkce jako první
Připojte se k účastníkům programu Office Insiders

Byly tyto informace užitečné?

Děkujeme vám za zpětnou vazbu.

Děkujeme vám za váš názor. Vypadá to, že bude užitečné, když vás spojíme s některým z našich agentů z podpory Office.

×