Použití funkce KDYŽ s funkcemi A, NEBO a NE

Funkce KDYŽ testuje podmínku a při jejím splnění nebo nesplnění vrátí výsledek. Umožňuje tak logické porovnání mezi nějakou hodnotou a tím, co očekáváte.

  • =KDYŽ(je něco pravda; udělej něco; jinak udělej něco jiného)

Ale co když potřebujete otestovat několik podmínek, kdy třeba všechny podmínky musí být Pravda nebo Nepravda (A), nebo jen jedna podmínka musí být Pravda nebo Nepravda (NEBO), nebo chcete zkontrolovat, jestli podmínka kritériím nevyhovuje (NE)? Všechny tři funkce můžete použít samostatně, ale častěji se používají společně s funkcí KDYŽ.

Použijte funkci KDYŽ s funkcemi A, NEBO a NE, pokud chcete udělat několik vyhodnocení a zjistit, jestli jsou podmínky pravdivé nebo nepravdivé.

Syntaxe

  • KDYŽ(A()) – KDYŽ(A(Logická1; [logická2];...); Ano; [Ne]))

  • KDYŽ(NEBO()) – KDYŽ(NEBO(Logická1; [logická2];...); Ano; [Ne]))

  • KDYŽ(NE()) – KDYŽ(NE(Logická1); Ano; [Ne]))

Název argumentu

Popis

Podmínka (povinné)

Podmínka, kterou chcete testovat

Ano (povinné)

Hodnota, která se má vrátit, když se podmínka vyhodnotí jako PRAVDA

Ne (volitelné)

Hodnota, která se má vrátit, když se podmínka vyhodnotí jako NEPRAVDA

Tady je přehled, jak funkce A, NEBO a NE strukturovat jednotlivě. Pokud každou z nich zkombinujete s příkazem KDYŽ, vypadají takto:

  • A – =KDYŽ(A(něco je PRAVDA; něco jiného je PRAVDA); Hodnota když PRAVDA; Hodnota když NEPRAVDA)

  • NEBO – =KDYŽ(NEBO(něco je PRAVDA; něco jiného je PRAVDA); Hodnota když PRAVDA; Hodnota když NEPRAVDA)

  • NE – =KDYŽ(NE(něco je PRAVDA); Hodnota když PRAVDA; Hodnota když NEPRAVDA)

Příklady

Následují příklady některých běžných vnořených příkazů KDYŽ(A()), KDYŽ(NEBO()) a KDYŽ(NE()). Funkce A a NEBO můžou mít až 255 jednotlivých podmínek, ale větší počty není vhodné používat, protože složité vnořené vzorce je velmi obtížné vytvářet, testovat a udržovat. Funkce NE může mít jenom jednu podmínku.

Příklady používání funkce KDYŽ s funkcemi A, NEBO a NE k vyhodnocení číselných hodnot a textu

Tady jsou vyjmenované vzorce podle jejich použití logických operátorů:

Vzorec

Popis

=KDYŽ(A(A2>0;B2<100);PRAVDA;NEPRAVDA)

KDYŽ A2 (25) je větší než 0, A B2 (75) je menší než 100, vrátit hodnotu PRAVDA, v opačném případě vrátit hodnotu NEPRAVDA. V tomto případě jsou obě podmínky splněny, takže vzorec vrátí hodnotu PRAVDA.

=KDYŽ(A(A3=“Červená“;B3=“Zelená“);PRAVDA;NEPRAVDA)

KDYŽ A3 (“Modrá“) = “Červená“, A B3 (“Zelená“) = “Zelená“, vrátit hodnotu PRAVDA,v opačném případě vrátit hodnotu NEPRAVDA. V tomto případě je pouze jedna podmínka pravdivá, takže vzorec vrátí hodnotu NEPRAVDA.

=KDYŽ(NEBO(A4>0;B4<50);PRAVDA;NEPRAVDA)

KDYŽ A4 (25) je větší než 0, NEBO B4 (75) je menší než 50, vrátit hodnotu PRAVDA, v opačném případě vrátit hodnotu NEPRAVDA. V tomto případě je pouze první podmínka PRAVDA, ale protože argument NEBO vyžaduje jen jeden pravdivý argument, vrátí vzorec hodnotu PRAVDA.

=KDYŽ(NEBO(A5=“Červená“;B5=“Zelená“);PRAVDA;NEPRAVDA)

KDYŽ A5 (“Modrá“) = “Červená“, NEBO B5 (“Zelená“) = “Zelená“, vrátit hodnotu PRAVDA,v opačném případě vrátit hodnotu NEPRAVDA. V tomto případě je druhý argument pravdivý, takže vzorec vrátí hodnotu PRAVDA.

=KDYŽ(NE(A6>50);PRAVDA;NEPRAVDA)

KDYŽ A6 (25) není větší než 50, vrátit hodnotu PRAVDA, v opačném případě vrátit hodnotu NEPRAVDA. V tomto případě 25 není větší než 50, takže vzorec vrátí hodnotu PRAVDA.

=KDYŽ(NE(A7=“Červená“);PRAVDA;NEPRAVDA)

KDYŽ se A7 (“Modrá“) nerovná “Červená“, vrátit hodnotu PRAVDA, v opačném případě vrátit hodnotu NEPRAVDA.

Všimněte si, že všechny tyto příklady mají za každou zadanou podmínkou pravou závorku. Zbylé argumenty PRAVDA/NEPRAVDA jsou součástí vnějšího příkazu KDYŽ. Za hodnoty PRAVDA/NEPRAVDA můžete dosadit i textové nebo číselné hodnoty.

Tady je pár příkladů použití funkcí A, NEBO a NE pro vyhodnocování kalendářní dat.

Příklady používání funkce KDYŽ s funkcemi A, NEBO a NE k vyhodnocení dat

Tady jsou vyjmenované vzorce podle jejich použití logických operátorů:

Vzorec

Popis

=KDYŽ(A2>B2;PRAVDA;NEPRAVDA)

KDYŽ A2 je pozdější než B2, vrátit hodnotu PRAVDA, v opačném případě vrátit hodnotu NEPRAVDA. V tomto případě je 12. 03. 2014 pozdější než 1. 1. 2014, takže vzorec vrátí hodnotu PRAVDA.

=KDYŽ(A(A3>B2;A3<C2);PRAVDA;NEPRAVDA)

KDYŽ A3 je pozdější než B2 A A3 je dřívější než C2, vrátit hodnotu PRAVDA, v opačném případě vrátit hodnotu NEPRAVDA. V tomto případě jsou oba argumenty pravdivé, takže vzorec vrátí hodnotu PRAVDA.

=KDYŽ(NEBO(A4>B2;A4<B2+60);PRAVDA;NEPRAVDA)

KDYŽ A4 je pozdější než B2 NEBO A4 je dřívější než B2 + 60, vrátit hodnotu PRAVDA, v opačném případě vrátit hodnotu NEPRAVDA. V tomto případě je první argument pravdivý, ale druhý je nepravdivý. Vzhledem k tomu, že NEBO vyžaduje pouze jeden pravdivý argument, vrátí vzorec hodnotu PRAVDA. Když na kartě Vzorce použijete průvodce Vyhodnocení vzorce, uvidíte, jak Excel vzorec vyhodnocuje.

=KDYŽ(NE(A5>B2);PRAVDA;NEPRAVDA)

KDYŽ A5 není pozdější než B2, vrátit hodnotu PRAVDA, v opačném případě vrátit hodnotu NEPRAVDA. V tomto případě je A5 pozdější než B2, takže vzorec vrátí hodnotu NEPRAVDA.

Příklad dialogového okna Průvodce vyhodnocením vzorce

Používání A, NEBO a NE s podmíněným formátováním

Funkce A, NEBO a NE můžete použít k nastavení kritérií podmíněného formátování pomocí možnosti vzorec. Když to uděláte, můžete funkci KDYŽ vynechat a používat funkce A, NEBO a NE samostatně.

Na kartě Domů klikněte na Podmíněné formátování > Nové pravidlo. Potom vyberte možnost Určit buňky k formátování pomocí vzorce, zadejte vzorec a použijte požadovaný formát.

Podmíněné formátování > dialogové okno Upravit pravidlo zobrazující metodu Vzorec

Výše uvedené vzorce s kalendářními daty by teď vypadaly takto.

Příklady používání funkcí A, NEBO a NE k otestování podmíněného formátování


Vzorec

Popis

=A2>B2

KDYŽ A2 je pozdější než B2, naformátovat buňku, v opačném případě nedělat nic.

=A(A3>B2;A3<C2)

KDYŽ A3 je pozdější než B2 A A3 je dřívější než C2, naformátovat buňku, v opačném případě nedělat nic.

=NEBO(A4>B2;A4<B2+60)

KDYŽ A4 je pozdější než B2 NEBO A4 je dřívější než B2 + 60 (dní), naformátovat buňku, v opačném případě nedělat nic.

=NE(A5>B2)

KDYŽ A5 není pozdější než B2, naformátovat buňku, v opačném případě nedělat nic. V tomto případě je A5 pozdější než B2, takže vzorec vrátí hodnotu NEPRAVDA. Kdybyste vzorec změnili na =NE(B2>A5), vrátil by hodnotu PRAVDA a buňka by se naformátovala.

Poznámka : Běžnou chybou je zadání vzorce do podmíněného formátování bez znaménka rovná se (=). V takovém případě uvidíte, že dialogové okno Podmíněné formátování přidá do vzorce uvozovky a znak rovná se – =“NEBO(A4>B2;A4<B2+60)“. Aby vzorec fungoval správně, budete tyto uvozovky muset odebrat.

Začátek stránky

Máte konkrétní otázku k funkci?

Zadejte dotaz do komunitního fóra Excelu

Pomozte nám vylepšit Excel

Máte nějaké návrhy na zlepšení dalších verzí Excelu? Pokud ano, podívejte se prosím na témata v části Názor uživatele Excelu.

Viz taky

Podívejte se na video o tom, jak používat funkci KDYŽ

Naučte se, jak ve vzorcích používat vnořené funkce

Funkce KDYŽ

Funkce A

Funkce NEBO

Funkce NE

Přehled vzorců v aplikaci Excel

Jak se vyhnout nefunkčním vzorcům

Použijte funkci zjišťování chyb ve vzorcích v Excelu 2016 pro Windows

Klávesové zkratky v Excelu 2016 pro Windows

Klávesové zkratky v Excelu 2016 pro Mac

Logické funkce (odkazy)

Funkce aplikace Excel (podle abecedy)

Funkce aplikace Excel (podle kategorie)

Sdílení Facebook Facebook Twitter Twitter E-mail E-mail

Byly tyto informace užitečné?

Výborně! Je ještě něco dalšího, co byste nám chtěli dát vědět?

Jak bychom ho mohli vylepšit?

Děkujeme vám za zpětnou vazbu.

×