Funkce SUMA

Funkce SUMA, jedna z matematických a trigonometrických funkcí, sčítá hodnoty. Můžete sčítat jednotlivé hodnoty, odkazy na buňky nebo oblasti, anebo kombinaci všech tří možností.

Příklady:

  • =SUMA(A2:A10)

  • =SUMA(A2:A10;C2:C10)

Váš prohlížeč nepodporuje video. Nainstalujte si Microsoft Silverlight, Adobe Flash Player nebo Internet Explorer 9.

Toto video je součástí školicího kurzu s názvem Sčítání čísel v Excelu 2013.

SUMA(číslo1;[číslo2];...)

Název argumentu

Popis

číslo1    (povinné)

První číslo, které budete chtít sčítat. Může to být číslo, například 4, Odkaz na buňku jako třeba B6 nebo Oblast buněk, například B2:B8.

číslo2–255    (volitelné)

Toto je druhé číslo, které chcete sečíst. Tímto způsobem můžete zadat až 255 čísel.

Pokud chcete rychle sečíst oblast buněk, stačí, když vyberete oblast a podíváte se do pravého dolního rohu okna Excelu.

Snímek obrazovky s výběrem oblasti buněk a následné zobrazení stavového řádku
Stavový řádek


Stavový řádek je místo, kde se zobrazují informace k vašemu výběru, ať už jste vybrali jednu buňku nebo víc buněk. Když na stavový řádek kliknete pravým tlačítkem, objeví se dialog funkcí se všemi možnostmi, které můžete vybrat. Všimněte si, že uvádí taky hodnoty pro vybranou oblast (pokud máte tyto atributy zaškrtnuté). Další informace o stavovém řádku.

Průvodce Automatické shrnutí představuje nejjednodušší způsob, jak přidat na list vzorec SUMA. Vyberte prázdnou buňku přímo nad nebo pod oblastí, kterou chcete sečíst, a na kartě Domů nebo Vzorec na pásu karet stiskněte Automatické shrnutí > Součet. Průvodce Automatické shrnutí vybere sám oblast k sečtení a vytvoří za vás vzorec součtu. Když vyberete buňku vlevo nebo vpravo od oblasti, kterou chcete sečíst, provede se výběr vodorovně. Tato funkce se nedá použít pro nesouvislé oblasti. V další části vám ukážeme, jak tyto oblasti zpracovat.

Vzorec součtu můžete vytvořit automaticky pomocí průvodce Automatické shrnutí.  Vyberte oblast nad nebo pod, případně vlevo nebo vpravo od oblasti, kterou chcete sečíst, přejděte na kartu Vzorec na pásu karet a pak vyberte Automatické shrnutí a SUMA.
Použití průvodce Automatické shrnutí k rychlému sečtení souvislých oblastí


V dialogu Automatické shrnutí můžete taky vybrat další běžné funkce, j

Automatické shrnutí ve svislém směru

Buňka B6 znázorňuje vzorec součtu vytvořený funkcí Automatické shrnutí: =SUMA(B2:B5).

Průvodce Automatické shrnutí vybral automaticky buňky B2:B5 jako oblast k sečtení. Stačí jenom potvrdit výběr stisknutím klávesy Enter. Pokud potřebujete přidat další buňky nebo některé odebrat, můžete stisknout a podržet klávesu Shift a současně pomocí šipek upravit výběr tak, jak potřebujete. Až to budete mít, stiskněte Enter.

Průvodce funkcí IntelliSense: Plovoucí značka (číslo1;[číslo2];...) pod funkcí je průvodce funkcí IntelliSense. Když kliknete na SUMA nebo na název funkce, změní se na modrý hypertextový odkaz, kterým otevřete téma nápovědy k dané funkci. Pokud kliknete na některý prvek funkce, zvýrazní se jeho odpovídající část ve vzorci. V tomto případě by se zvýraznila jenom část B2:B5, protože v tomto vzorci je jenom jeden odkaz na číslo. Značka IntelliSense se zobrazí pro libovolnou funkci.

Automatické shrnutí ve vodorovném směru

Buňka D2 znázorňuje vzorec součtu vytvořený funkcí Automatické shrnutí: =SUMA(B2:C2).

Použití funkce SUMA pro nesouvislé oblasti.  Vzorec v buňce C8 je =SUMA(C2:C3;C5:C6). Můžete taky použít pojmenované oblasti. Vzorec by pak vypadal takto: =SUMA(týden1;týden2).

Průvodce Automatické shrnutí funguje obvykle jenom u souvislých oblastí, takže pokud máte v oblasti sčítaných buněk prázdné řádky nebo sloupce, Excel přestane sčítat, jakmile narazí na první mezeru. V takovém případě je potřeba vzorec součtu vytvořit tak, že do výběru postupně přidáte jednotlivé oblasti k sečtení. Pokud máte v tomto příkladu data v buňce B4, Excel vygeneruje vzorec =SUMA(C2:C6), protože našel souvislou oblast.

Víc nesouvislých oblastí můžete rychle vybrat současným stisknutím klávesy Ctrl a kliknutím levým tlačítkem. Nejdřív zadejte část =SUMA( a pak vyberte požadované oblasti. Excel je automaticky oddělí středníkem. Po dokončení stiskněte Enter.

Tip: Funkci SUMA můžete do buňky přidat rychle kombinací kláves ALT+=. Pak už jen stačí vybrat požadovanou oblast nebo oblasti.

Poznámka: Všimněte si, že Excel zvýraznil jednotlivé oblasti různou barvou, která odpovídá i označení oblasti ve vzorci: oblast C2:C3 je označená jednou barvou a oblast C5:C6 jinou. Excel používá barevné označení u všech funkcí, pokud není odkazovaná oblast na jiném listu nebo v jiném sešitu. Kvůli lepší dostupnosti pro technologie usnadnění můžete použít Pojmenované oblasti, například Týden1, Týden2 apod., a na ně pak odkazovat ve vzorci:

=SUMA(Týden1;Týden2)

S Excelem můžete snadno provádět matematické operace, ať už jednoduché, nebo v kombinaci s funkcemi Excelu (jako je třeba SUMA). Operátory, které můžete použít společně s některými souvisejícími funkcemi, jsou uvedeny v následující tabulce. Operátory můžete zadávat jak pomocí horního řádku čísel na klávesnici, tak pomocí numerické klávesnice, pokud ji máte. Například Shift+8 zadá hvězdičku (*) pro násobení.

Operátor

Operace

Příklady

+

Sčítání

=1+1

=A1+B1

=SUMA(A1:A10)+10

=SUMA(A1:A10)+B1

-

Odčítání:

=1-1

=A1-B1

=SUMA(A1:A10)-10

=SUMA(A1:A10)-B1

*

Násobení

=1*1

=A1*B1

=SUMA(A1:A10)*10

=SUMA(A1:A10)*B1

=SOUČIN(1,1) - Funkce SOUČIN

/

Dělení

=1/1

=A1/B1

=SUMA(A1:A10)/10

=SUMA(A1:A10)/B1

=QUOTIENT(1,1) - Funkce QUOTIENT

^

Umocnění

=1^1

=A1^B1

=SUMA(A1:A10)^10

=SUMA(A1:A10)^B1

=POWER(1,1) - Funkce POWER

Další informace najdete v tématu Použití Excelu jako kalkulačky.

Další příklady
  1. Řekněme, že chcete použít procentuální slevu na oblast buněk, které jste sečetli.

    Použití operátorů s funkcí SUMA.  Vzorec v buňce B16 je =SUMA(A2:A14)*−25%.  Vzorec by byl ve správném tvaru, kdyby místo hodnoty −25% obsahoval odkaz na buňku, třeba = SUMA(A2:A14)*E2.
    • =SUMA(A2:A14)*−25%

    Výsledek bude zahrnovat 25 % slevu. Hodnota 25 % ale bude ve vzorci pevně definovaná a když ji budete chtít později změnit, může být obtížné ji najít. Je mnohem lepší zadat hodnotu 25% do samostatné buňky a odkazovat na ni. Zůstane tak dobře viditelná a můžete ji snadno změnit. Příklad:

    • =SUMA(A2:A14)*E2

    Pokud nechcete násobit, ale dělit, jednoduše nahraďte symbol * symbolem /. Příklad: =SUMA(A2:A14)/E2

  2. Přičítání nebo odčítání ve funkci SUMA

    i. Ve funkci SUMA můžete pomocí symbolů + a − snadno sčítat nebo odečítat:

    • =SUMA(A1:A10)+E2

    • =SUMA(A1:A10)−E2

V této části jsou popsané některé osvědčené postupy práce pro funkci SUMA. Spoustu těchto postupů můžete použít i u jiných funkcí.

Metoda =1+2 nebo =A+B. Když zadáte =1+2+3 nebo =A1+B1+C2, dostanete samozřejmě přesný výsledek. Tato metoda je ale náchylná k chybám, a to z několika důvodů:
  1. Překlepy – představte si, že chcete zadat víc hodnot nebo mnohem vyšší hodnoty, například:

    • =14598,93+65437,90+78496,23

    Potom zkuste ověřit, jestli jsou položky zadané správně. Mnohem jednodušší je zadat tyto položky do samostatných buněk a použít funkci SUMA. Navíc můžete hodnoty v samostatných buňkách formátovat, takže budou čitelnější, než když je zapíšete do vzorce.

    Místo abyste hodnoty ve vzorcích zadávali ručně, použijte funkci SUMA.  Vzorec v buňce D5 je =SUMA(D2:D4).
  2. Chyba #HODNOTA! při odkazování na text místo na čísla.

    Pokud použijete vzorce, jako je třeba:

    • =A1+B1+C1 nebo =A1+A2+A3

    Příklad špatné konstrukce vzorce.  Vzorec v buňce D2 je =A2+B2+C2.

    Když budou v odkazovaných buňkách nečíselné hodnoty (text), může být vzorec neplatný a vrátit chybu #HODNOTA!. SUMA textové hodnoty ignoruje a sečte jenom číselné hodnoty.

    Správná konstrukce vzorců.  Místo =A2+B2+C2 je v buňce D2 tento vzorec: =SUMA(A2:C2).
  3. Chyba #REF! způsobená odstraněním řádků nebo sloupců

    Chyba #REF! způsobená odstraněním sloupce.  Vzorec se změnil na =A2+#REF!+B2.

    Pokud odstraníte řádek nebo sloupec, vzorec se neaktualizuje tak, aby odstraněné buňky vynechal, a vrátí chybu #REF!, zatímco funkce SUMA se aktualizuje automaticky.

    Funkce SUMA se automaticky přizpůsobí vloženým nebo odstraněným řádkům a sloupcům.
  4. Při vložení řádků nebo sloupců vzorce neaktualizují odkazy

    Když přidáte řádky, vzorce =A+B+C se neaktualizují.

    Pokud vložíte řádek nebo sloupec, vzorec se neaktualizuje tak, aby přidané buňky zahrnul, zatímco funkce SUMA se aktualizuje automaticky (pokud přidané buňky neleží mimo oblast odkazovanou ve vzorci). To je důležité hlavně tehdy, když očekáváte, že se vzorec aktualizuje, ale nestane se tak. Výsledky jsou pak neúplné a chyba se obtížně napravuje.

    Příklad znázorňuje automatické rozšíření vzorce součtu ze =SUMA(A2:C2) na =SUMA(A2:D2) při vložení sloupce.
  5. SUMA s individuálními odkazy na buňky vs. Oblasti

    Použití vzorce, jako je:

    • =SUMA(A1;A2;A3;B1;B2;B3)

    Tato metoda je při vkládání řádků do odkazované oblasti nebo jejich odstraňování z ní stejně náchylná k chybám jako předchozí, a to ze stejných důvodů. Mnohem lepší je používat jednotlivé oblasti, jako třeba:

    • =SUMA(A1:A3;B1:B3)

    Po přidání nebo odstranění řádků se tento vzorec aktualizuje.

  1. Funkci SUMA můžete samozřejmě použít i v kombinaci s jinými funkcemi. Tady je příklad výpočtu měsíčního průměru:

    Použití funkce SUMA s jinými funkcemi.  Vzorec v buňce M2 je =SUMA(A2:L2)/POČET2(A2:L2).  Poznámka: Sloupce pro květen až listopad jsou pro lepší srozumitelnost skryté.
    • =SUMA(A2:L2)/POČET2(A2:L2)

  2. Tento vzorec vypočítá podíl součtu buněk A2 až L2 a počtu neprázdných buněk v oblasti A2 až L2 (listy květen až prosinec jsou prázdné).

  1. Někdy je potřeba sečíst konkrétní buňku na více listech. I když se zdá snadné kliknout na jednotlivých listech na buňky, které chcete sečíst, a jenom doplnit +, když chcete sečíst jejich hodnoty, je toto řešení zdlouhavé a může být náchylné k chybám.

    • =list1!A1+list2!A1+list3!A1

    Mnohem jednodušší je použít v tomto případě prostorový součet:

    Prostorový součet – vzorec v buňce D2 je =SUMA(list1:list3!A2).
    • =SUMA(list1:list3!A1)

    Tento vzorec sečte buňky A1 na všech listech od listu 1 po list 3.

    To je velmi užitečné, když máte jeden list pro každý měsíc (leden až prosinec) a chcete mít jejich celkový součet na souhrnném listu.

    Prostorový součet na pojmenovaných listech.  Vzorec v buňce D2 je =SUMA(leden:prosinec!A2).
    • =SUMA(leden:prosinec!A2)

    Tento vzorec sečte buňky A2 na všech listech od ledna po prosinec.

    Poznámky : Pokud máte názvy listů s mezerami, například „prodej za leden“, musíte při odkazování na ně ve vzorci použít apostrof: Povšimněte si apostrofu před názvem prvního listu a dalšího apostrofu za názvem posledního listu.

    • =SUMA('prodej za leden:prodej za prosinec'!A2)

    Prostorový výpočet bude fungovat taky u dalších funkcí, jako je například PRŮMĚR, MIN, MAX a podobně:

    • =PRŮMĚR(list1:list3!A1)

    • =MIN(list1:list3!A1)

    • =MAX(list1:list3!A1)

Problém

Co je špatně

Moje funkce SUMA místo výsledku zobrazuje #####.

Zkontrolujte šířky sloupců. ##### obecně znamená, že je sloupec příliš úzký na to, aby zobrazil výsledek vzorce.

Moje funkce SUMA zobrazuje místo výsledku vzorec jako text.

Zkontrolujte, jestli buňka není naformátovaná jako text. Vyberte zmíněnou buňku nebo oblast a pomocí kombinace kláves Ctrl+1 vyvolejte dialogové okno Formát buněk, klikněte na Číslo karty a vyberte požadovaný formát. Pokud byla buňka formátovaná jako text a po změně formátu se nezmění, budete muset změnu formátování vynutit pomocí kombinace kláves F2 > Enter.

Moje funkce SUMA se neaktualizuje.

Ujistěte se, že Výpočet je nastavený na Automaticky. Na kartě Vzorec přejděte na Možnosti výpočtů. Výpočet listu můžete taky vyvolat pomocí klávesy F9.

Ujistěte se, že výpočet je nastavený na Automaticky.  Na kartě Vzorec přejděte na Možnosti výpočtů.

Některé hodnoty se nesečetly.

Přičítají se jenom číselné hodnoty, které jsou v odkazu nebo oblasti funkce. Prázdné buňky, logické hodnoty (třeba PRAVDA) nebo text se ignorují.

Místo očekávaného výsledku se zobrazí chyba #NAME?.

Obvykle to znamená, že je vzorec špatně napsaný, například jako =sume(A1:A10) místo = SUMA(A1:A10).

Moje funkce SUMA ukazuje výsledek v celých číslech, ale měla by ukazovat desetinná místa.

Zkontrolujte formátování buněk, jestli máte nastaveno zobrazování desetinných míst. Vyberte příslušnou buňku nebo oblast buněk a pomocí kombinace klávesCtrl+1 vyvolejte dialogové okno Formát buněk, klikněte na kartu Číslo a vyberte požadovaný formát. Zvolte přitom požadovaný počet desetinných míst.

  1. Chci jenom sečíst/odečíst/vynásobit/vydělit čísla – Podívejte se na videa Základní výpočty v Excelu nebo Použití Excelu místo kalkulačky.

  2. Jak můžu zobrazit víc nebo míň desetinných míst? – Můžete změnit formátování čísel. Vyberte zmíněnou buňku nebo oblast buněk a pomocí kombinace kláves Ctrl+1 vyvolejte dialogové okno Formát buněk, klikněte na kartu Číslo a vyberte požadovaný formát. Zkontrolujte, jestli je nastavený správný počet desetinných míst.

  3. Jak sčítat nebo odčítat časy? Časy můžete sčítat a odčítat několika různými způsoby. Například pro účely výpočtu mezd můžete získat rozdíl mezi 8:00:00 a 12:00 takto: =("12:00"-"8:00")*24, zadejte nejdřív koncový čas a od něho pak odečtěte počáteční čas. Všimněte si, že Excel počítá čas jako zlomek dne, takže ho musíte vynásobit číslem 24, pokud chcete výsledek zobrazil jako počet hodin. V prvním příkladu používáme vzorec =((B2-A2)+(D2-C2))*24 a získáme tak počet hodin od začátku do konce směny minus přestávka na oběd (celkově 8,50 hodin).

    Pokud jen sčítáte hodiny a minuty a chcete je také tak zobrazit, pak je můžete jenom rychle sečíst a není potřeba výsledek násobit číslem 24. Takže ve druhém příkladu použijeme pro součet funkci =SUMA(A6:C6) a výsledek je ve formátu hodin a minut (5:36, neboli 5 hodin a 36 minut).

    Výpočet času

    Další informace najdete tady: Sčítání a odčítání časových hodnot.

  4. Jak získám rozdíl mezi kalendářními daty? Stejně jako v případě času, můžete kalendářní data sčítat a odečítat. Běžným příkladem je počítání dní mezi dvěma daty. Stačí jednoduchý vzorec: =B2-A2. Klíčem pro práci s daty a časy je, abyste začali s koncovým datem a časem a odečetli jste od něj počáteční datum a čas.

    Výpočet doby mezi dvěma daty

    Další způsoby práce s kalendářními daty najdete tady: Výpočet počtu dní mezi dvěma daty.

  5. Jak se sečíst jenom viditelné buňky? Někdy můžete ručně nebo automatickým filtrem skrýt řádky, aby byla zobrazena pouze určitá data, a potom chtít sečíst jenom viditelné buňky. Můžete použít funkci SUBTOTAL. Pokud v tabulce Excelu používáte řádek souhrnů, všechny funkce, které vyberete z rozevírací nabídky, budou automaticky zadány jako mezisoučet (SUBTOTAL). Další informace najdete v tématu Součty dat v tabulce aplikace Excel.

Máte konkrétní otázku k funkci?

Zadejte dotaz do komunitního fóra Excelu

Pomozte nám vylepšit Excel

Máte nějaké návrhy na zlepšení dalších verzí Excelu? Pokud ano, podívejte se prosím na témata v části Názor uživatele Excelu.

Viz taky

Podívejte se na video o používání funkce SUMA

Funkce SUMIF sečte jenom hodnoty, které splňují jedno kritérium

Funkce SUMIFS sečte jenom hodnoty, které splňují více kritérií

Funkce COUNTIF spočítá jenom hodnoty, které splňují jedno kritérium

Funkce COUNTIFS funkce spočítá jenom hodnoty, které splňují víc kritérií

Přehled vzorců v Excelu

Jak se vyhnout nefunkčním vzorcům

Nalezení a oprava chyb ve vzorcích

Klávesové zkratky v Excelu pro Windows

Klávesové zkratky v Excelu pro Mac

Matematické a trigonometrické funkce

Funkce Excelu (podle abecedy)

Funkce Excelu (podle kategorie)

Sdílení Facebook Facebook Twitter Twitter E-mail E-mail

Byly tyto informace užitečné?

Výborně! Je ještě něco dalšího, co byste nám chtěli dát vědět?

Jak bychom ho mohli vylepšit?

Děkujeme vám za zpětnou vazbu.

×