Funkce HODNOTA.NA.TEXT

Přispěvatelé: Chris "Smitty" Smith Dave Ludwig

Funkce HODNOTA.NA.TEXT umožňuje změnit způsob zobrazení čísla tak, že pro něho nastavíte formátování pomocí kódů formátů. Je užitečná v situacích, kdy chcete zobrazit čísla v čitelnějším formátu nebo zkombinovat čísla s textem nebo symboly.

Poznámka : Funkce HODNOTA.NA.TEXT převede čísla na text, takže pak může být těžší odkazovat na ně v dalších výpočtech. Doporučujeme ponechat původní hodnotu v jedné buňce a potom použít funkci HODNOTA.NA.TEXT v jiné buňce. Pokud pak budete potřebovat vytvořit další vzorce, odkazujte vždycky na původní hodnotu, ne na výsledek funkce HODNOTA.NA.TEXT.

Syntaxe

HODNOTA.NA.TEXT(hodnota; formát)

Syntaxe funkce HODNOTA.NA.TEXT má následující argumenty:

Název argumentu

Popis

hodnota

Číselná hodnota, kterou chcete převést na text

formát

Textový řetězec definující formátování, které se má použít na hodnotu

Základní informace

V nejjednodušší podobě funkce HODNOTA.NA.TEXT říká:

  • =HODNOTA.NA.TEXT(Hodnota, kterou chcete formátovat;"Kód formátu, který chcete použít")

Tady jsou některé oblíbené příklady, které si můžete zkopírovat přímo do Excelu a dále s nimi experimentovat. Všimněte si, že kódy formátu se zadávají do uvozovek.

Vzorec

Popis

=HODNOTA.NA.TEXT(1234,567;"# ##0,00 Kč")

Měna s oddělovačem tisíců a 2 desetinnými místy, například 1 234,57 Kč. Všimněte si, že Excel hodnotu zaokrouhlil na 2 desetinná místa.

=HODNOTA.NA.TEXT(DNES();"DD. MM. RRRR")

Dnešní datum ve formátu DD. MM. RRRR, například 18. 01. 2017.

=HODNOTA.NA.TEXT(DNES();"DDDD")

Dnešní den v týdnu, například středa

=HODNOTA.NA.TEXT(NYNÍ();"HH:MM")

Aktuální čas, například 13:29

=HODNOTA.NA.TEXT(0,285;"0,0%")

Procenta, například 28,5%

=HODNOTA.NA.TEXT(4,34 ;"# ?/?")

Zlomek, například 4 1/3

=PROČISTIT(HODNOTA.NA.TEXT(0,34;"# ?/?"))

Zlomek, například 1/3. V tomto vzorci se pomocí funkce PROČISTIT odebere mezera, která by jinak byla na začátku před zlomkem.

=HODNOTA.NA.TEXT(12200000;"0,00E+00")

Exponenciální notace, například 1,22E+07

=HODNOTA.NA.TEXT(1234567898;"(###) ###-####")

Zvláštní formát pro telefonní čísla používaná v USA, například (123) 456-7898

=HODNOTA.NA.TEXT(1234;"0000000")

Přidání nul (0) na začátku, například 0001234

=HODNOTA.NA.TEXT(123456;"##0° 00' 00''")

Vlastní formát pro zeměpisnou šířku nebo délku

Poznámka : Kromě funkce HODNOTA.NA.TEXT existují i další způsoby, jak měnit formátování. Pokud chcete změnit formát bez vzorce, můžete stisknout klávesy CTRL+1 (nebo Obrázek příkazového tlačítka počítače MAC +1 na Macu) a pak vybrat požadovaný formát v dialogu Formát buněk > Číslo.

Stažení příkladů

Můžete si stáhnout ukázkový sešit se všemi příklady funkce HODNOTA.NA.TEXT uvedenými v tomto článku a několika dalšími k tomu. Můžete se jím inspirovat nebo pro funkci HODNOTA.NA.TEXT vytvořit vlastní kódy formátu.

Stáhnout příklady excelové funkce HODNOTA.NA.TEXT

Další kódy formátu, které jsou k dispozici

Další dostupné kódy formátu můžete najít pomocí dialogu Formát buněk:

  1. Stiskněte Ctrl+1 (na Macu Obrázek příkazového tlačítka počítače MAC +1). Zobrazí se dialog Formát buněk.

  2. Vyberte požadovaný formát na kartě Číslo.

  3. Vyberte možnost Vlastní.

  4. Příslušný kód formátu se teď zobrazí v poli Typ. V tomto případě vyberte v poli Typ všechno kromě znaků | a @. V příkladu níže jsme vybrali a zkopírovali jenom dd. mm. rrrr.

  5. Zkopírujte kód formátu stisknutím Ctrl+C a pak kliknutím na Zrušit (v některých verzích Storno) zavřete dialog Formát buněk.

  6. Teď můžete kód formátu do vzorce s funkcí HODNOTA.NA.TEXT vložit jednoduše stisknutím Ctrl+V a vytvoříte například vzorec =HODNOTA.NA.TEXT(B2;"dd. mm. rrrr"). Nezapomeňte kód formátu uzavřít do uvozovek ("kód formátu"), jinak by Excel zobrazil chybovou zprávu.

Příklad použití dialogu Formát > Buňky > Číslo > Vlastní tak, aby za vás Excel vytvořil formátovací řetězce.

Kódy formátu podle kategorie

Následuje několik příkladů, jak můžete pro hodnoty použít různé číselné formáty pomocí dialogu Formát buněk a pak pomocí možnosti Vlastní zkopírovat příslušné kódy formátu do funkce HODNOTA.NA.TEXT.

Proč Excel odstraňuje úvodní nuly?

Excel je trénovaný tak, aby očekával, že v buňkách se budou zadávat čísla – ne čísla, která vypadají jako text, jako jsou čísla dílů nebo skladové jednotky (SKU). Pokud chcete úvodní nuly zachovat, naformátujte před vložením nebo zadáním hodnot vstupní oblast jako text. Vyberte sloupec nebo oblast, kam budete zadávat hodnoty, stisknutím CTRL+1 otevřete dialog Formát buněk a na kartě Číslo vyberte Text. Excel teď bude úvodní nuly zachovávat.

Pokud jste už zadali data a Excel počáteční nuly odebral, můžete je pomocí funkce HODNOTA.NA.TEXT přidat zpátky. Použijte vzorec =HODNOTA.NA.TEXT(hodnota;"00000"), který odkazuje na horní buňku hodnot a ve kterém počet nul představuje celkový počet znaků, které se mají zobrazit. Pak ho zkopírujte a vložte do zbytku vaší oblasti dat.

Příklady použití funkce HODNOTA.NA.TEXT k formátování počátečních nul.  =TEXT(A2,"00000")

Pokud z nějakého důvodu potřebujete převést textové hodnoty zpátky na čísla, můžete je vynásobit hodnotou 1, například =D4*1, nebo použít dvojitý unární operátor (--), například =--D4.

Excel odděluje tisíce mezerou, pokud formát obsahuje mezeru, která je uzavřena znaky křížku (#) nebo nulami. Pokud je například formát nastavený na "# ###", zobrazí Excel číslo 12200000 jako 12 200 000.

Mezera za zástupným symbolem číslice vydělí číslo hodnotou 1 000. Pokud je například formát nastavený na "# ###,0 ", zobrazí Excel číslo 12200000 jako 12 200,0.

Příklady funkce HODNOTA.NA.TEXT s oddělovačem tisíců

Poznámky : 

  • Oddělovač tisíců je závislý na místních nastaveních. V České republice používáme mezeru, ale v jiných národních prostředích by to mohla být čárka nebo tečka.

  • Oddělovač tisíců je dostupný pro formáty Číslo, Měna a Účetnický.

Níže jsou příklady standardních formátů z kategorie Číslo (čísla s oddělovači tisíců a desetinnými místy), Měna a Účetnický. Formát Měna umožňuje vložit libovolný symbol měny a zarovnat ho vedle hodnoty. Formát Účetnický zarovnává symboly měny a desetinné čárky ve sloupci. Rozdíly mezi kódy pro formáty Měna a Účetnický si můžete prohlédnout níže. Uvidíte například, že ve formátu Účetnický se jako oddělovač používá hvězdička.

Příklady funkce HODNOTA.NA.TEXT s formáty Číslo, Měna a Účetnický

Pokud chcete najít kód formátu pro symbol měny, stiskněte napřed Ctrl+1 (nebo Obrázek příkazového tlačítka počítače MAC +1 na Macu), vyberte požadovaný formát a pak zvolte symbol v rozevíracím seznamu Symbol:

Výběr symbolu měny v dialogu Formát buněk

Pak vlevo v seznamu Druh klikněte na Vlastní a zkopírujte kód formátu včetně symbolu měny.

Funkce HODNOTA.NA.TEXT – vlastní měna se symbolem

Poznámka : Funkce HODNOTA.NA.TEXT nepodporuje barevné formátování, takže pokud z dialogu Formát buněk zkopírujete kód formátu čísla, který zahrnuje barvu, například # ##0,00 Kč;[Červená]# ##0,00 Kč, tak funkce HODNOTA.NA.TEXT kód formátu přijme, ale barvu nezobrazí.

Způsob, jakým se zobrazí kalendářní data, můžete měnit pomocí písmen D pro den, M pro měsíc a R pro rok.

Kódy formátů pro dny, měsíce a roky

V kódech formátu ve funkci HODNOTA.NA.TEXT se nerozlišují velká a malá písmena, takže můžete použít M i m, D i d a R i r.

Mynda Treacy (MVP pro Excel)

Mynda doporučuje...

Pokud sdílíte excelové soubory a sestavy s uživateli z různých zemí, pravděpodobně jim budete chtít dát sestavu v jejich jazyce. Mynda Treacy, MVP pro Excel, má skvělé řešení, které je popsané v článku Zobrazení excelových dat v různých jazycích. Článek také obsahuje ukázkový sešit, který si můžete stáhnout.

Způsob, jakým se zobrazí časové údaje, můžete měnit pomocí písmen H pro hodiny, M pro minuty, S pro sekundy a dop./odp. pro 12hodinový formát.

Časové formáty pro hodiny, minuty a sekundy

Pokud dop./odp. vynecháte, zobrazí se čas ve 24hodinovém formátu.

V kódech formátu ve funkci HODNOTA.NA.TEXT se nerozlišují velká a malá písmena, takže můžete použít H i h, M i m, S i s a DOP./ODP. i dop./odp.

Způsob zobrazení desetinných hodnot můžete změnit pomocí formátů s procenty (%).

Kódy formátů pro procenta

Způsob zobrazení desetinných hodnot můžete změnit pomocí formátů se zlomky (?/?).

Kódy formátů pro zlomky

Exponenciální notace je způsob zobrazení, ve kterém se používá desetinné číslo mezi 1 a 10 vynásobené násobkem 10. Často se používá ke zkrácení zobrazení velkých čísel.

Kódy formátů pro exponenciální notaci

Excel nabízí 4 speciální formáty:

  • PSČ: "000\ 00"

  • PSČ (bez mezery): "00000"

  • Telefonní číslo: "[<=99999]###\ ##;##\ ##\ ##"

  • Telefonní číslo (dlouhé): "[<=9999999]###\ ##\ ##;##\ ##\ ##\ ##"

Speciální formáty pro funkci HODNOTA.NA.TEXT

Speciální formáty se liší v závislosti na národním prostředí. Pokud speciální formáty pro vaše národní prostředí nevyhovují vašim potřebám, můžete si vytvořit vlastní v dialogu Formát buněk > Vlastní.

Běžná situace

Funkce HODNOTA.NA.TEXT se málokdy používá samostatně, spíše se využívá společně s něčím dalším. Řekněme, že chcete zkombinovat text a číselnou hodnotu, jako například „Zpráva vytištěná dne: 14.03.2012“ nebo „Týdenní výnosy: 66 348,72 Kč“. Samozřejmě to můžete do Excelu zadat ručně, ale tím popřete požadovaný účel, aby to Excel udělal za vás. Když kombinujete text a formátovaná čísla, jako jsou kalendářní data, časy, měny atd., tak ale Excel bohužel neví, jak je chcete zobrazit, takže formát čísla nezpracuje. A právě to je případ, kdy je funkce HODNOTA.NA.TEXT velmi užitečná. S její pomocí přimějete Excel formátovat hodnoty přesně tak, jak chcete. Stačí jen nastavit správný kód formátu, například "DD.MM.RRRR".

V následujícím příkladu uvidíte, co se stane, když se pokusíte spojit text a číslo bez použití funkce HODNOTA.NA.TEXT. V tomto případě používáme operátor ampersand (&) pro zřetězení textového řetězce, mezeru (" ") a hodnoty: =A2&" "&B2.

Příklad spojení textu bez funkce HODNOTA.NA.TEXT

Jak vidíte, Excel odebral formátování kalendářního data z buňky B2. V dalším příkladu uvidíte, jak funkce HODNOTA.NA.TEXT umožňuje použít požadovaný formát.

Příklad spojení textu pomocí funkce HODNOTA.NA.TEXT

Aktualizovaný vzorec je:

  • Buňka C2: =A2&" "&HODNOTA.NA.TEXT(B2;"dd.mm.rrrr") – formát kalendářního data

Časté otázky

Bohužel, toto pomocí funkce HODNOTA.NA.TEXT udělat nejde. Potřebujete k tomu kód Visual Basic for Application (VBA). Na následujícím odkazu najdete popsaný způsob: Jak v Excelu převést číselnou hodnotu na anglická slova

Ano, můžete použít funkce VELKÁ, MALÁ a VELKÁ2. Funkce =VELKÁ("ahoj") například vrátí AHOJ.

Ano, ale je třeba provést několik kroků. Nejdřív vyberte buňku nebo buňky, do kterých chcete přidat nový řádek, a pak stisknutím Ctrl+1 zobrazte dialog Formát buněk. Na kartě Zarovnání > Nastavení textu zaškrtněte možnost Zalamovat text. Potom upravte funkci HODNOTA.NA TEXT tak, aby zahrnovala ASCII funkci ZNAK(10) v místě, kam chcete vložit konec řádku. Možná budete muset upravit šířku sloupců podle toho, jak vypadá zarovnání v konečném výsledku.

Příklad použití funkce HODNOTA.NA.TEXT s CHAR(10) k vložení konce řádku. ="Dnes je:"& CHAR(10))aHODNOTA.NA.TEXT(DNES(),"MM/DD/RR")

V tomto případě jsme použili: ="Dnes je: "&ZNAK(10)&HODNOTA.NA.TEXT(DNES();"dd.mm.rrrr")

Tomuto se říká exponenciální notace. Excel takto automaticky převádí čísla delší než 12 číslic, pokud má buňka formát Obecný, a delší než 15 číslic, pokud má buňka formát Číslo. Pokud potřebujete zadávat dlouhé číselné řetězce, ale nechcete je převádět, naformátujte před zadáním nebo vložením hodnot do Excelu příslušné buňky jako Text.

Mynda Treacy (MVP pro Excel)

Mynda doporučuje...

Pokud sdílíte excelové soubory a sestavy s uživateli z různých zemí, pravděpodobně jim budete chtít dát sestavu v jejich jazyce. Mynda Treacy, MVP pro Excel, má skvělé řešení, které je popsané v článku Zobrazení excelových dat v různých jazycích. Článek také obsahuje ukázkový sešit, který si můžete stáhnout.

Viz taky

Vytvoření nebo odstranění vlastního formátu čísla

Převod textu na čísla

Všechny funkce Excelu (podle kategorie)

Rozšiřte své znalosti a dovednosti
Projít školení
Získejte nové funkce jako první
Připojte se k účastníkům programu Office Insiders

Byly tyto informace užitečné?

Děkujeme vám za zpětnou vazbu.

Děkujeme vám za váš názor. Vypadá to, že bude užitečné, když vás spojíme s některým z našich agentů z podpory Office.

×