COUNTIF (funkce)

Funkci COUNTIF, jednu ze statistických funkcí, můžete používat ke zjištění počtu buněk, které splňují určité kritérium, třeba ke spočítání, kolikrát se konkrétní město zobrazuje v seznamu zákazníků.

Váš prohlížeč nepodporuje video. Nainstalujte si Microsoft Silverlight, Adobe Flash Player nebo Internet Explorer 9.

Syntaxe

COUNTIF(oblast; kritérium)

Příklady:

  • =COUNTIF(A2:A5;"jablka")

  • =COUNTIF(A2:A5;A4)

Název argumentu

Popis

oblast    (povinné)

Skupina buněk, jejichž počet chcete zjistit. Oblast může obsahovat čísla, pole, pojmenovanou oblast nebo odkazy obsahující čísla. Prázdné a textové hodnoty se ignorují.

Podívejte se, jak vybrat oblast v listu.

kritérium    (povinné)

Číslo, výraz, odkaz na buňku nebo textový řetězec, které určují buňky ke spočítání.

Můžete třeba použít číslo jako 32, porovnání jako ">32", buňku jako B4 nebo slovo jako „jablka“.

COUNTIF používá jenom jedno kritérium. Pokud chcete mít několik kritérií, použijte funkci COUNTIFS.

Příklady

Pokud chcete použít tyto příklady v Excelu, zkopírujte data v následující tabulce a vložte je do buňky A1 nového listu.

Data

Data

jablka

32

pomeranče

54

broskve

75

jablka

86

Vzorec

Popis

=COUNTIF(A2:A5;"jablka")

Spočítá buňky s řetězcem jablka v oblasti A2 až A5. Výsledek je 2.

=COUNTIF(A2:A5;A4)

Spočítá buňky s řetězcem broskve (pomocí kritéria v A4) v buňkách A2 až A5. Výsledek je 1.

=COUNTIF(A2:A5;A3)+COUNTIF(A2:A5;A2)

Spočítá řetězce s pomeranči (pomocí kritéria v A3) a jablky (pomocí kritéria v A2) v buňkách A2 až A5. Výsledek je 3. Tento vzorec používá dva výrazy COUNTIF k určení několika kritérií, vždy jednoho kritéria na výraz.

=COUNTIF(B2:B5;">55")

Spočítá v buňkách B2 až B5 počet buněk s hodnotou větší než 55. Výsledek je 2.

=COUNTIF(B2:B5;"<>"&B4)

Spočítá v buňkách B2 až B5 počet buněk s hodnotou, která se nerovná 75. Operátor & slučuje relační operátor nerovnosti (<>) a hodnotu v buňce B4 na hodnotu =COUNTIF(B2:B5,"<>75"). Výsledek je 3.

=COUNTIF(B2:B5;">=32")-COUNTIF(B2:B5;">85")

Spočítá počet buněk s hodnotou větší (>) nebo rovnou (=) 32 a menší (<) nebo rovnou (=) 85 v buňkách B2 až B5. Výsledek je 3.

=COUNTIF(A2:A5;"*")

Spočítá počet buněk v oblasti A2 až A5 obsahujících jakýkoli text. Zástupný znak hvězdička (*) se používá k porovnání libovolného znaku. Výsledek je 4.

=COUNTIF(A2:A5;"?????es")

Spočítá počet buněk, které mají přesně 7 znaků končících písmeny „es“ v buňkách A2 A5. Zástupný znak otazník (?) slouží k porovnání jednotlivých znaků. Výsledek je 2.

=COUNTIF(ovoce;">=32")-COUNTIF(ovoce;">85")

Použije pojmenovanou oblast (aplikovanou na buňky A2:A5) k určení počtu buněk s hodnotou vyšší než 55 v buňkách B2 až B5. Výsledek je 2.

Běžné problémy

Problém

Co je špatně

Pro moc dlouhé řetězce se vrací chybná hodnota.

Funkce COUNTIF vrací nesprávné výsledky, pokud ji použijete k porovnání řetězců delších než 255 znaků.

Pokud chcete porovnávat řetězce delší než 255 znaků, použijte funkci CONCATENATE nebo operátor zřetězení &. Například, =COUNTIF(A2:A5,"dlouhý řetězec"&"jiný dlouhý řetězec").

Nevrací se žádná hodnota, když je očekávaná hodnota.

Argument kritéria musí být v uvozovkách.

Při použití odkazu na jiný list zobrazí vzorec COUNTIF chybu #HODNOTA!.

K této chybě dojde, když vzorec obsahující tuto funkci odkazuje na buňky nebo oblast v zavřeném sešitu a počítají se tyto buňky. Aby to fungovalo, musí být druhý sešit otevřený.

Doporučené postupy

Postupujte takto...

Proč?

Funkce COUNTIF v textových řetězcích ignoruje velká a malá písmena.

V kritériích se nerozlišují velká a malá písmena. Jinými slovy – řetězec "jablka" a "JABLKA" odpovídá stejným buňkách.

Používejte zástupné znaky.

V kritériích se dají používat zástupné znaky otazník (?) a hvězdička (*) Otazník zastupuje libovolný jeden znak a hvězdička zastupuje libovolný řetězec znaků. Pokud chcete hledat skutečný znak otazníku nebo hvězdičky, zadejte před něj vlnovku (~).

Například, =COUNTIF(A2:A5,"jablko?") spočítá všechny instance řetězce "jablko", kde se může poslední písmeno lišit.

Zkontrolujte, že v údajích nemáte něco špatně napsané.

Při hledání textových hodnot zkontrolujte, že data nemají mezery na začátku nebo na konci textu, jestli se v nich konzistentně používají rovné uvozovky a oblé uvozovky a jestli v nich nejsou netisknutelné znaky. V takových případech může funkce COUNTIF vrátit nesprávnou nebo neočekávanou hodnotu.

Zkuste použít funkci VYČISTIT nebo funkci PROČISTIT.

Usnadněte si práci pomocí pojmenovaných oblastí.

Funkce COUNTIF podporuje ve vzorci pojmenované oblasti (třeba =COUNTIF(ovoce;">=32")-COUNTIF(ovoce;">85"). Pojmenovaná oblast může být v aktuálním listu, v jiném listu stejného sešitu nebo v jiném sešitu. Pokud odkazujete na jiný sešit, musí být tento sešit taky otevřený.

Poznámka : Funkce COUNTIF nebude počítat buňky na základě pozadí buňky nebo barvy písma. Excel nicméně podporuje funkce definované uživatelem za použití jazyka Microsoft Visual Basic for Applications (VBA), které můžou provádět operace s buňkami na základě barvy pozadí buňky nebo písma. Zde je příklad, jak můžete spočítat buňky s určitou barvou pomocí jazyka VBA.

Máte konkrétní otázku k funkci?

Zadejte dotaz do komunitního fóra Excelu

Pomozte nám vylepšit Excel

Máte nějaké návrhy na zlepšení dalších verzí Excelu? Pokud ano, podívejte se prosím na témata v části Názor uživatele Excelu.

Viz taky

Ke spočítání buněk, které nejsou prázdné, použijte funkci POČET2

Ke spočítání buněk, ve kterých se používá více kritérií, použijte funkci COUNTIFS

Podívejte se na video o používání funkce COUNTIFS

Funkce SUMIF sečte jenom hodnoty, které splňují jedno kritérium

Funkce SUMIFS sečte jenom hodnoty, které splňují více kritérií

Funkce IFS (Office 365, Excel 2016 nebo novější)

Úvodní a koncové mezery můžete z buněk odebrat pomocí funkce PROČISTIT

Netisknutelné znaky můžete z buněk odebrat pomocí funkce VYČISTIT

Přehled vzorců v Excelu

Jak se vyhnout nefunkčním vzorcům

Zjišťování chyb ve vzorcích

Statistické funkce

Funkce Excelu (podle abecedy)

Funkce Excelu (podle kategorie)

Sdílení Facebook Facebook Twitter Twitter E-mail E-mail

Byly tyto informace užitečné?

Výborně! Je ještě něco dalšího, co byste nám chtěli dát vědět?

Jak bychom ho mohli vylepšit?

Děkujeme vám za zpětnou vazbu.

×