Související témata
×
Vzorce a funkce
Přihlásit se pomocí účtu Microsoft
Přihlaste se nebo si vytvořte účet.
Dobrý den,
Vyberte jiný účet.
Máte více účtů.
Zvolte účet, pomocí kterého se chcete přihlásit.
Vzorce a funkce

COUNTIF

Funkci COUNTIF, jednu ze statistických funkcí, můžete používat ke zjištění počtu buněk, které splňují určité kritérium, třeba ke spočítání, kolikrát se konkrétní město zobrazuje v seznamu zákazníků.

Ve své nejjednodušší formě COUNTIF říká:

  • =COUNTIF(Kde chcete hledat?, Co chcete hledat?)

Příklady:

  • =COUNTIF(A2:A5,"Londýn")

  • =COUNTIF(A2:A5;A4)

Váš prohlížeč nepodporuje video. Nainstalujte si Microsoft Silverlight, Adobe Flash Player nebo Internet Explorer 9.

COUNTIF(oblast; kritérium)

Název argumentu

Popis

oblast    (povinné)

Skupina buněk, jejichž počet chcete zjistit. Oblast může obsahovat čísla, pole, pojmenovanou oblast nebo odkazy obsahující čísla. Prázdné a textové hodnoty se ignorují.

Podívejte se, jak vybrat oblast v listu.

kritéria    (povinné)

Číslo, výraz, odkaz na buňku nebo textový řetězec, které určují buňky ke spočítání.

Můžete třeba použít číslo jako 32, porovnání jako ">32", buňku jako B4 nebo slovo jako „jablka“.

COUNTIF používá jenom jedno kritérium. Pokud chcete mít několik kritérií, použijte funkci COUNTIFS.

Příklady

Pokud chcete použít tyto příklady v Excelu, zkopírujte data v následující tabulce a vložte je do buňky A1 nového listu.

Data

Data

jablka

32

pomeranče

54

broskve

75

jablka

86

Vzorec

Popis

=COUNTIF(A2:A5;"jablka")

Spočítá buňky s řetězcem jablka v oblasti A2 až A5. Výsledek je 2.

=COUNTIF(A2:A5;A4)

Spočítá buňky s řetězcem broskve (hodnota v A4) v buňkách A2 až A5. Výsledek je 1.

=COUNTIF(A2:A5,A2)+COUNTIF(A2:A5,A3)

Spočítá počet jablek (hodnota v A2) a pomerančů (hodnota v A3) v buňkách A2 až A5. Výsledek je 3. Tento vzorec používá funkci COUNTIF dvakrát k zadání více kritérií, vždy jedno kritérium na výraz. Také byste mohli použít funkci COUNTIFS.

=COUNTIF(B2:B5;">55")

Spočítá v buňkách B2 až B5 počet buněk s hodnotou větší než 55. Výsledek je 2.

=COUNTIF(B2:B5;"<>"&B4)

Spočítá v buňkách B2 až B5 počet buněk s hodnotou, která se nerovná 75. Operátor & slučuje relační operátor nerovnosti (<>) a hodnotu v buňce B4 na hodnotu =COUNTIF(B2:B5,"<>75"). Výsledek je 3.

=COUNTIF(B2:B5;">=32")-COUNTIF(B2:B5;"<=85")

Spočítá počet buněk s hodnotou větší (>) nebo rovnou (=) 32 a menší (<) nebo rovnou (=) 85 v buňkách B2 až B5. Výsledek je 1.

=COUNTIF(A2:A5;"*")

Spočítá počet buněk v oblasti A2 až A5 obsahujících jakýkoli text. Zástupný znak hvězdička (*) se používá k porovnání libovolného znaku. Výsledek je 4.

=COUNTIF(A2:A5;"?????es")

Spočítá počet buněk, které mají přesně 7 znaků končících písmeny „es“ v buňkách A2 A5. Otazník (?) slouží jako zástupný znak pro jakýkoli znak. Výsledek je 2.

Běžné problémy

Problém

Co je špatně

Pro moc dlouhé řetězce se vrací chybná hodnota.

Funkce COUNTIF vrací nesprávné výsledky, pokud ji použijete k porovnání řetězců delších než 255 znaků.

Pokud chcete porovnávat řetězce delší než 255 znaků, použijte funkci CONCATENATE nebo operátor zřetězení &. Například, =COUNTIF(A2:A5,"dlouhý řetězec"&"jiný dlouhý řetězec").

Nevrací se žádná hodnota, když je očekávaná hodnota.

Argument kritéria musí být v uvozovkách.

Vzorec COUNTIF vrátí při odkazování na jiný list chybovou zprávu #HODNOTA!.

K této chybě dojde, když vzorec obsahující tuto funkci odkazuje na buňky nebo oblast v zavřeném sešitu a počítají se tyto buňky. Aby to fungovalo, musí být druhý sešit otevřený.

Doporučené postupy

Udělejte toto

Proč?

Funkce COUNTIF v textových řetězcích ignoruje velká a malá písmena.

V kritériích se nerozlišují velká a malá písmena. Jinými slovy – řetězec "jablka" a "JABLKA" odpovídá stejným buňkách.

Používejte zástupné znaky.

Zástupné znaky  — otazník (?) a hvězdička (*)  — můžete použít v kritériích. Otazník zastupuje jeden libovolný znak. Hvězdička zastupuje jakoukoli posloupnost libovolných znaků. Pokud chcete vyhledat skutečný znak otazníku nebo hvězdičky, zadejte před ně vlnovku (~).

Například, =COUNTIF(A2:A5,"jablko?") spočítá všechny instance řetězce "jablko", kde se může poslední písmeno lišit.

Zkontrolujte, že v údajích nemáte něco špatně napsané.

Při hledání textových hodnot zkontrolujte, že data nemají mezery na začátku nebo na konci textu, jestli se v nich konzistentně používají rovné uvozovky a oblé uvozovky a jestli v nich nejsou netisknutelné znaky. V takových případech může funkce COUNTIF vrátit nesprávnou nebo neočekávanou hodnotu.

Zkuste použít funkci VYČISTIT nebo funkci PROČISTIT.

Usnadněte si práci pomocí pojmenovaných oblastí.

Funkce COUNTIF podporuje pojmenované oblasti ve vzorci (například =COUNTIF(ovoce;">=32")-COUNTIF(ovoce;">85"). Pojmenovaná oblast může být v aktuálním listu, v jiném listu stejného sešitu nebo v jiném sešitu. Pokud odkazujete na jiný sešit, musí být tento sešit taky otevřený.

Poznámka: Funkce COUNTIF nebude počítat buňky na základě pozadí buňky nebo barvy písma. Excel nicméně podporuje funkce definované uživatelem za použití jazyka Microsoft Visual Basic for Applications (VBA), které můžou provádět operace s buňkami na základě barvy pozadí buňky nebo písma. Zde je příklad, jak můžete spočítat buňky s určitou barvou pomocí jazyka VBA.

Potřebujete další pomoc?

Kdykoli se můžete zeptat odborníka z komunity Excel Tech nebo získat podporu v komunitách.

Viz také

COUNTIFS

Funkce KDYŽ

POČET2

Přehled vzorců v Excelu

Funkce IFS

SUMIF

Potřebujete další pomoc?

Chcete další možnosti?

Prozkoumejte výhody předplatného, projděte si školicí kurzy, zjistěte, jak zabezpečit své zařízení a mnohem více.

Komunity vám pomohou klást otázky a odpovídat na ně, poskytovat zpětnou vazbu a vyslechnout odborníky s bohatými znalostmi.

Byly tyto informace užitečné?

Jak jste spokojeni s kvalitou jazyka?
Co ovlivnilo váš názor?
Po stisknutí tlačítka pro odeslání se vaše zpětná vazba použije k vylepšování produktů a služeb Microsoftu. Váš správce IT bude moci tato data shromažďovat. Prohlášení o zásadách ochrany osobních údajů.

Děkujeme vám za zpětnou vazbu.

×