COUNTIF функция
Използвайте COUNTIF, една от статистическите функции, за да преброите клетките, които отговарят на даден критерий, например за да преброите колко пъти определен град се появява в списък на клиентите.
В най-простият си вид COUNTIF означава:
-
=COUNTIF(Къде искате да търсите? Какво искате да търсите?)
Например:
-
=COUNTIF(A2:A5;"Лондон")
-
=COUNTIF(A2:A5;A4)
COUNTIF(диапазон; критерии)
|
Име на аргумент |
Описание |
|---|---|
|
диапазон (задължително) |
Групата от клетки, които искате да преброите. Диапазон може да съдържа числа, масиви, наименуван диапазон или препратки, съдържащи числа. Празните и текстовите стойности се игнорират. Научете как се избират диапазони в работен лист. |
|
критерии (задължително) |
Число, израз, препратка към клетка или текстов низ, който определя кои клетки ще се броят. Например можете да използвате число като 32, сравнение като ">32", клетка като B4 или дума като "ябълки". COUNTIF използва само един критерий. Използвайте COUNTIFS, ако искате да използвате повече от един критерий. |
Примери
За да използвате тези примери в Excel, копирайте данните в таблицата по-долу и ги поставете в клетка A1 на нов работен лист.
|
Данни |
Данни |
|---|---|
|
ябълки |
32 |
|
портокали |
54 |
|
праскови |
75 |
|
ябълки |
86 |
|
Формула |
Описание |
|
=COUNTIF(A2:A5;"ябълки") |
Преброява клетките с ябълки в клетки от A2 до A5. Резултатът е 2. |
|
=COUNTIF(A2:A5;A4) |
Преброява клетките с праскови (стойността в A4) в клетките от A2 до A5. Резултатът е 1. |
|
=COUNTIF(A2:A5;A2)+COUNTIF(A2:A5;A3) |
Преброява ябълките (стойността в A2) и портокалите (стойността в A3) в клетките от A2 до A5. Резултатът е 3. Тази формула използва два израза COUNTIF, за да зададе няколко критерия – по един критерий за всеки израз. Можете също да използвате функцията COUNTIFS. |
|
=COUNTIF(B2:B5;">55") |
Преброява клетките със стойности, по-големи от 55, в клетките от B2 до B5. Резултатът е 2. |
|
=COUNTIF(B2:B5;"<>"&B4) |
Преброява клетките със стойности, които не са равни на 75, в клетките от B2 до B5. Амперсандът (&) обединява оператора за сравнение за "не е равно на" (<>) и стойността в B4, за да стане =COUNTIF (B2:B5;"<>75"). Резултатът е 3. |
|
=COUNTIF(B2:B5;">=32")-COUNTIF(B2:B5;"<=85") |
Преброява клетките със стойност, по-голяма (>) или равна (=) на 32 и по-малка (<) или равна (=) на 85, в клетките от B2 до B5. Резултатът е 1. |
|
=COUNTIF(A2:A5;"*") |
Преброява клетките, съдържащи произволен текст в клетки от A2 до A5. Звездичката (*) се използва като заместващ символ *, който отговаря на всеки знак. Резултатът е 4. |
|
=COUNTIF(A2:A5;"?????и") |
Преброява клетките, които имат точно 6 знака, и завършват с буквата "и" в клетките от A2 до A5. Въпросителният знак (?) се използва като заместващ символ, който отговаря на един знак. Резултатът е 2. |
Често срещани проблеми
|
Проблем |
Защо е възникнала грешка |
|---|---|
|
За дълги низове се връща невярна стойност. |
Функцията COUNTIF връща неправилни резултати, когато я използвате за съпоставяне на низове, които са по-дълги от 255 знака, с низа #VALUE!. За да включите низове, които са по-дълги от 255 знака, използвайте функцията CONCATENATE или оператора за съединяване &. Например =COUNTIF(A2:A5; "дълъг низ" & "друг дълъг низ"). |
|
Когато очаквате стойност, няма върната стойност. |
Не забравяйте да оградите аргумента критерии в кавички. |
|
Формулата COUNTIF получава #VALUE! при препращане към друг работен лист. |
Тази грешка възниква, когато формулата, която съдържа функцията препраща към клетки или диапазон в затворена работна книга и клетките се изчисляват. За да работи тази функция, другата работна книга трябва да бъде отворена. |
Най-добри практики
|
Направете следното |
Защо |
|---|---|
|
Имайте предвид, че COUNTIF игнорира разликата между главни и малки букви в текстовите низове. |
Критерии не прави разлика между малки и главни букви. С други думи, низът "ябълки" и низът "ЯБЪЛКИ" ще съответстват на едни и същи клетки. |
|
Използване на заместващи символи. |
Заместващите символи – въпросителен знак (?) и звездичка (*) – може да се използват в критерии. Въпросителният знак съответства на един знак. Звездичката съответства на произволна поредица от знаци. Ако искате да намерите самите въпросителен знак или звездичка, напишете тилда (~) пред знака. Например =COUNTIF(A2:A5;"ябълка?") ще преброи всички екземпляри на "ябълка" с последната буква, която може да се различава. |
|
Уверете се, че вашите данни не съдържат грешни знаци. |
При преброяването на текстови стойности се уверете, че данните не съдържат начални интервали, крайни интервали, несъгласувана употреба на прави или типографски кавички, както и непечатаеми знаци. В тези случаи COUNTIF може да върне неочаквана стойност. Опитайте да използвате функцията CLEAN или функцията TRIM. |
|
За удобство използвайте наименувани диапазони |
COUNTIF поддържа наименувани диапазони във формула (например =COUNTIF(плодове;">=32")-COUNTIF(плодове;">85"). Наименуваният диапазон може да бъде в текущия работен лист, друг работен лист в същата работна книга или от друга работна книга. За препратки от друга работна книга – втората работна книга също трябва да бъде отворена. |
Забележка: Функцията COUNTIF няма да преброи клетки въз основа на техния фон или цвета на шрифта. Обаче Excel поддържа функции, дефинирани от потребител, използвайки операции на Microsoft Visual Basic for Applications (VBA) върху клетки въз основа на техния фон или цвета на шрифта. Ето пример как можете да преброите клетки с определен цвят с помощта на VBA.
Имате нужда от още помощ?
Винаги можете да попитате експерт в техническата общност на Excel или да получите поддръжка в Общността за отговори от.
Вж. също
Нуждаете ли се от още помощ?
Искате ли още опции?
Разгледайте ползите от абонамента, прегледайте курсовете за обучение, научете как да защитите устройството си и още.
Общностите ви помагат да задавате и отговаряте на въпроси, да давате обратна връзка и да получавате информация от експерти с богати знания.
