TEXT функция

Сътрудници: Богомил "Божо" Иванов Драган Тасев

Функцията TEXT ви позволява да промените начина, по който се показва число, като приложите форматиране към него с кодове за форматиране. Това е полезно, когато искате да покажете числа в по-четлив формат или да комбинирате числа с текст или символи.

Забележка : Функцията TEXT ще преобразува числата в текст, което може да затрудни създаването на препратки към него в изчисления по-късно. Най-добре е да запазите първоначалната стойност в една клетка и след това да използвате функцията TEXT в друга клетка. След това, ако трябва да съставите други формули, винаги създавайте препратките към първоначалната стойност, а не към резултата от функцията TEXT.

Синтаксис

TEXT(стойност; формат_текст)

Синтаксисът на функцията TEXT има следните аргументи:

Име на аргумент

Описание

стойност

Числова стойност, която искате да се преобразува в текст.

формат_текст

Текстов низ, определящ форматирането, което искате да се приложи към предоставената стойност.

Общ преглед

В най-простия си вид функцията TEXT казва:

  • =TEXT(Стойност, която искате да форматирате; "Код за форматиране, който искате да приложите")

Ето няколко примера, които можете да копирате директно в Excel, за да експериментирате с тях сами. Обърнете внимание на кодовете за форматиране в кавички.

Формула

Описание

=TEXT(1234,567;"# ##0,00 лв.")

Валута с разделител на хилядните и 2 знака след десетичната запетая, като например $1 234,57. Обърнете внимание, че Excel закръглява стойността до 2 знака след десетичната запетая.

=TEXT(TODAY();"DD/MM/YY")

Днешната дата във формат ДД/ММ/ГГ, например 14/03/12

=TEXT(TODAY();"DDDD")

Днешният ден от седмицата, например "понеделник"

=TEXT(NOW();"H:MM AM/PM")

Часът в момента, например 1:29 PM

=TEXT(0,285;"0,0%")

Процент, например 28,5%

=TEXT(4,34 ;"#?/?")

Дроб, например 4 1/3

=TRIM(TEXT(0,34;"#?/?"))

Дроб, например 1/3 Обърнете внимание, че тази формула използва функцията TRIM, за да премахне въвеждащия интервал с десетична стойност.

=TEXT(12200000;"0,00E+00")

Експоненциален запис, например 1,22E+07

=TEXT(1234567898;"[<=9999999]###-####;(###) ###-####")

Специални (телефонен номер), например (123) 456-7898

=TEXT(1234;"0000000")

Добавяне на водещи нули (0), например 0001234

=TEXT(123456;"##0° 00' 00''")

По избор – географска ширина/дължина

Забележка : Макар че можете да използвате функцията TEXT за промяна на форматирането, това не е единственият начин. Можете да промените форматирането без формула, като натиснете CTRL+1 (или Изображение на иконата за бутона Command на MAC +1 на Mac) и след това изберете желания формат в диалоговия прозорец Форматиране на клетки > Число.

Изтеглете нашите примери

Можете да изтеглите работна книга с всички примери за функцията на TEXT, които ще намерите в тази статия, плюс някои допълнителни. Можете да следвате предложените или да създадете свои собствени кодове за форматиране за функцията TEXT.

Изтегляне на примери за функцията TEXT в Excel

Други налични кодове за форматиране

Можете да използвате диалоговия прозорец Форматиране на клетки, за да намерите другите налични кодове за форматиране:

  1. Натиснете Ctrl+1 ( Изображение на иконата за бутона Command на MAC +1 на Mac), за да отворите диалоговия прозорец Форматиране на клетки.

  2. Изберете желания формат от раздела Число.

  3. Изберете опцията По избор.

  4. Кодът за форматиране сега се показва в полето Тип. В този случай изберете каквото и да е от полето Тип без точката и запетаята (;) и символа @. В примера по-долу избрахме и копирахме само mm/dd/yy.

  5. Натиснете Ctrl+C, за да копирате кода за форматиране, след което натиснете Отказ, за да затворите диалоговия прозорец Форматиране на клетки.

  6. Всичко, което трябва да направите сега, е да натиснете Ctrl+V, за да поставите кода за форматиране във вашата TEXT формула, като например: =TEXT(B2;"mm/dd/yy"). Не забравяйте да поставите кода за форматиране в кавички ("код за форматиране"), тъй като в противен случай Excel ще върне съобщение за грешка.

Пример за използване на диалоговия прозорец "Формат > Клетки > Число > По избор", за да накарате Excel да форматира низовете вместо вас.

Кодове за форматиране по категория

По-долу са представени няколко примера как можете да прилагате различни формати за число към вашите стойности, като използвате диалоговия прозорец Форматиране на клетки и опцията По избор, за да копирате тези кодове за форматиране във функцията TEXT.

Защо Excel изтрива водещите 0?

Excel е обучен да търси числа, въведени в клетки, а не числа, които изглеждат като текст, например номера на части или инвентарни единици. За да запазите водещите нули, форматирайте диапазон за въвеждане като текст, преди да поставите или въведете стойности. Изберете колоната или диапазона, където ще въведете стойностите, след което използвайте CTRL+1, за да изведете диалоговия прозорец Форматиране > Клетки, и раздела Число изберете Текст. Сега Excel ще запази водещите 0.

Ако вече сте въвели данни и Excel е премахнал водещите 0, можете да използвате функцията TEXT, за да ги добавите отново. Можете да направите препратка към най-горната клетка със стойностите и да използвате =TEXT(стойност;"00000"), където броят нули във формулата е желаният общ брой знаци, след което да копирате и поставите в останалата част от вашия диапазон.

Примери за използване на функцията TEXT за форматиране на водещите нули. =TEXT(A2;"00000")

Ако по някаква причина ви се наложи да преобразувате текстови стойности обратно в числа, можете да умножите по 1, като например =D4*1, или да използвате двойния унарен оператор (--), като например =--D4.

Excel разделя хилядите с интервали, ако форматът съдържа интервал ( ), ограден от знак за номер (#) или от нули. Ако например низът за формат е "# ###", Excel показва числото "12200000" като "12 200 000".

Интервал след цифров контейнер мащабира числото по 1 000. Ако например низът за формат е "# ###,0", Excel показва числото 12200000 като 12 200,0.

Примери за функцията TEXT, като се използва разделител за хилядите

Забележки : 

  • Разделителят на хилядите зависи от вашите регионални настройки. В България това е интервал, но на други места може да е запетая (,).

  • Разделителят на хилядите е наличен за форматите за число, валута и счетоводство.

По-долу са представени примери за стандартните формати за число (само разделител на хилядите и десетични стойности), валута и счетоводство. Форматът за валута ви позволява да вмъкнете избран от вас символ на валута и го подравнява до стойността ви, докато форматът за счетоводство подравнява символа на валута вляво на клетката, а стойността – вдясно. Обърнете внимание на разликата между кодовете за форматиране на валута и счетоводство по-долу, където форматът за счетоводство използва звездичка (*), за да създаде разделяне на символа и стойността.

Примери за функцията TEXT с форматите на число, валута и счетоводство

За да намерите кода за форматиране на символ за валута, първо натиснете Ctrl+1 (или Изображение на иконата за бутона Command на MAC + 1 на Mac), изберете желания формат, след което изберете символ от падащото меню Символ:

Избор на символ за валута от диалоговия прозорец за форматиране на клетки

След това щракнете върху По избор отляво в раздела Категория и копирайте кода за форматиране, включително валутния знак.

Функцията TEXT – валута по избор със символ

Забележка : Функцията TEXT не поддържа форматиране на цветове, така че ако копирате код за форматиране на число от диалоговия прозорец "Форматиране на клетки", който включва цвят, като например: # ##0,00 лв.;[Червено]# ##0,00 лв., функцията TEXT ще приеме кода за форматиране, но няма да покаже цвета.

Можете да промените начина, по който се показва дата, като използвате "M" за месец, "D" за ден и "Y" за година.

Кодове за форматиране за месец, ден и година

Кодовете за форматиране във функцията TEXT не правят разлика между главни и малки букви, така че можете да използвате "M" или "m", "D" или "d", "Y" или "y".

Най-ценен професионалист по Excel – Минда Трейси

Минда препоръчва...

Ако споделяте файлове и отчети на Excel с потребители от различни страни, може да поискате да им дадете отчет на техния език. Минда Трейси, най-ценен специалист по Excel, има чудесно решение в тази статия Показване на дати в Excel на различни езици. Включена е също и работна книга с примери, която можете да изтеглите.

Можете да промените начина, по който се показва часът, с помощта на комбинация от "H" за часа, "M" за минутите или "S" за секундите и "AM/PM" за 12-часов часовник.

Формати за часове, минути и секунди

Ако пропуснете "AM/PM" или "A/P", часът ще се показва на базата на 24-часов часовник.

Кодовете за форматиране във функцията TEXT не правят разлика между главни и малки букви, така че можете да използвате "H" или "h", "M" или "m", "S" или "s", "AM/PM" или "am/pm".

Можете да промените начина, по който десетичните стойности се показват с формати за процент (%).

Кодове за форматиране за проценти

Можете да промените начина, по който десетичните стойности се показват с формати за дроб (?/?).

Кодове за форматиране за дроби

Експоненциалният запис е начин за показване на числа като десетична стойност между 1 и 10, повдигната на степен 10. Използва се често за съкращаване на начина, по който с показват големите числа.

Кодове за форматиране за експоненциален запис

Excel предоставя 4 специални формата:

  • Пощенски код – "00000"

  • Пощенски код + 4 – "00000-0000"

  • Телефонен номер – "[<=9999999]###-####;(###) ###-####"

  • Номер на социална осигуровка – "000-00-0000"

Специални формати за функцията TEXT

Специалните формати ще се различават в зависимост от езиковата променлива, но ако няма никакви специални формати за вашата езикова променлива или ако наличните не отговарят на нуждите ви, можете да създадете свои собствени с помощта на диалоговия прозорец Форматиране на клетки > По избор.

Често срещан сценарий

Функцията TEXT рядко се използва самостоятелно и най-често се използва в комбинация с нещо друго. Да кажем, че искате да комбинирате текст и числова стойност, например "Отчетът е отпечатан на: 14.03.12" или "Седмични приходи: 66 348,72 лв.". Можете да въведете това и ръчно в Excel, но идеята е Excel да го направи вместо вас. За съжаление, когато комбинирате текст и форматирани числа, като например дати, часове, валута и др., Excel не знае как искате да ги покаже, така че пропуска форматирането на числата. Тук функцията TEXT е безценна, защото ви позволява да накарате Excel да форматира стойностите по желания от вас начин, използвайки код за форматиране, като например "MM/DD/YY" за формат на дата.

В следващия пример ще видите какво се случва, ако се опитате да съедините текст и число, без да използвате функцията TEXT. В този случай използваме амперсанд (&), за да конкатенираме текстов низ, интервал (" ") и стойност с =A2&" "&B2.

Пример за присъединяване на текст без функцията TEXT

Както можете да видите, Excel премахна, форматирането от датата в клетка B2. В следващия пример ще видите как функцията TEXT ви позволява да приложите желания от вас формат.

Пример за присъединяване на текст с функцията TEXT

Нашата актуализирана формула е:

  • Клетка C2:=A2&" "&TEXT(B2;"dd.mm.yy") – формат за дата

Често задавани въпроси

За съжаление не можете да направите това с функцията TEXT; трябва да използвате код на Visual Basic for Applications (VBA). Следната връзка ще ви покаже метод: Как да конвертирате числова стойност в английски думи в Excel

Да, можете да използвате функциите UPPER, LOWER и PROPER. Например =UPPER("привет") ще върне "ПРИВЕТ".

Да, но ще трябва да изпълните няколко стъпки. Първо изберете клетката или клетките, където искате да направите това, след което използвайте Ctrl+1, за да изведете диалоговия прозорец Форматиране > Клетки, след това Подравняване > Управление на текста > отметнете опцията Текст на повече редове. След това променете завършената функция TEXT, като включите ASCII функцията CHAR(10) там, където искате да се добави край на ред. Може да се наложи да настроите ширината на колоните в зависимост от това как се подравнява крайният резултат.

Пример за използване на функцията TEXT за с CHAR(10), за да вмъкнете нов ред. = "Днес е: "&CHAR(10))&TEXT(TODAY();"DD.MM.YY")

В този случай използвахме: ="Днес е: "&CHAR(10)&TEXT(TODAY();"dd.mm.yy")

Това се нарича експоненциален запис и Excel автоматично ще преобразува числа, по-дълги от 12 цифри, ако клетките са форматирани като Общи, и по-дълги от 15 цифри, ако клетките са форматирани като Число. Ако трябва да въведете дълги числови низове, но не искате да се преобразуват, форматирайте въпросните клетките като Текст, преди да въведете или поставите стойностите в Excel.

Най-ценен професионалист по Excel – Минда Трейси

Минда препоръчва...

Ако споделяте файлове и отчети на Excel с потребители от различни страни, може да поискате да им дадете отчет на техния език. Минда Трейси, най-ценен специалист по Excel, има чудесно решение в тази статия Показване на дати в Excel на различни езици. Включена е също и работна книга с примери, която можете да изтеглите.

Вж. също

Създаване и изтриване на потребителски формат на числата

Преобразуване на текст в числа

Всички функции на Excel (по категории)

Разширете уменията си
Преглед на обучението
Получавайте първи новите функции
Присъединете се към участниците в Office Insider

Беше ли полезна тази информация?

Благодарим ви за обратната връзка!

Благодарим ви за вашата обратна връзка. Изглежда, че ще бъде полезно да ви свържем с един от нашите агенти по поддръжката на Office.

×