Задаване на етикети на данни по избор в диаграма

Следващата процедура на VBA (Visual Basic for Applications) ще ви позволи да използвате стойностите на клетките като етикети на данни в диаграмите си в Excel for Mac. За да използвате процедурата, направете следното:

1. В Excel щракнете върху Инструменти > макроси > Запис на нов макрос.

2. В падащото поле Съхрани макроса в: изберете Лична работна книга с макроси.

   Забележка: Като съхраните процедурата на VBA в личната работна книга с макроси, можете да я използвате във всеки екземпляр на Excel. Това означава, че не е ограничено само до използване в една работна книга.

3. Натиснете OK.

4. Отидете на Инструменти > макроси ,> спрете записването.

5. Отидете на Инструменти > макроси > редактора на Visual Basic.

6. Редакторът на Visual Basic (VBE) ще се отвори над Excel. В навигационния екран отляво разгънете VBAProject (PERSONAL. XLSB), за да се покаже Module1.

7. Щракнете двукратно върху Модул1 , за да се покаже екранът с код, който ще се отвори от дясната страна на прозореца на VBE.

8. Кодът на VBA, който е създаден, когато сте записали нов макрос, не е необходим, така че изберете всичко, след което натиснете Delete. 

9. След това изберете кода на VBA в текстовото поле по-долу, натиснете CMD+C , за да го копирате, след което го поставете отново в екрана с код чрез CMD+V. Сега можете да излезете от редактора на Visual Basic и да се върнете в Excel.

10. Тествайте макроса, като създадете диаграма с етикети на данни. След това изберете произволен етикет на данни в диаграмата и изпълнете макроса, като щракнете върху Инструменти > Макроси > Макроси. Изберете SetCustomDataLabels, след което натиснете Изпълни. Автоматично ще бъдете подканени да изберете диапазона на етикета на данни, така че направете го и след това натиснете OK.  

    Забележка: Процедурите на VBA не могат да бъдат отменени, така че не забравяйте да изпробвате това в копие на работна книга. Ако изпълните кода и не искате да запазите резултатите, ще трябва да затворите работната книга, без да я записвате.

11. Когато излезете от Excel, трябва да изберете да запишете промените в ЛИЧЕН. XLSB, така че макросът да бъде наличен в бъдеще.

12. Всеки път, когато искате да добавите или премахнете етикети на данни от диаграма, изберете етикетите на данни и изпълнете макроса.

13. Можете да използвате Excel > Preferences > Ribbon & Toolbar (Лента с инструменти ), за да добавите бутон за изпълнение на макроса от лентата или лентата с инструменти.

Option Explicit

Sub SetCustomDataLabels()
' make sure a series is selected
    If TypeOf Selection Is DataLabels Or TypeOf Selection Is Point Then
        Selection.Parent.Select
    ElseIf TypeOf Selection Is DataLabel Then
        Selection.Parent.Parent.Select
    End If

    If TypeOf Selection Is Series Then
        Else
        MsgBox "Select a chart series and try again."
        Exit Sub
    End If

    If Selection.HasDataLabels Then
        'If the data labels from cells are already showing, stop showing them and exit.
        'If labels include other info (e.g., values or categories) this will still appear
        If Selection.DataLabels.ShowRange Then
            Selection.DataLabels.ShowRange = False
            Exit Sub
        End If
    End If
 
'Use the InputBox dialog to set the range for the data labels
    On Error Resume Next
        Dim rng As Range
        Set rng = Application.InputBox(Prompt:="Select data label range.", Title:="Data Label Range", Type:=8)
    On Error GoTo 0

    If rng Is Nothing Then Exit Sub ' clicked cancel
        If Selection.HasDataLabels Then
            'This will include the new text from cells into existing data labels
        Else
        'Otherwise add data labels (empty labels)
            Selection.HasDataLabels = True
            Selection.DataLabels.ShowValue = False
        End If
    
    'Create a string that includes the sheet name and range reference.
    Dim rngAddress As String
        rngAddress = "='" & rng.Worksheet.Name & "'!" & rng.Address(RowAbsolute:=True, ColumnAbsolute:=True, External:=False)
        Selection.DataLabels.Format.TextFrame2.TextRange.InsertChartField msoChartFieldRange, rngAddress, 0
        Selection.DataLabels.ShowRange = True

End Sub