Функция SUM

Функцията SUM – една от математическите и тригонометрични функции – събира стойности. Можете да събирате отделни стойности, препратки към клетки или диапазони, както и комбинация от трите.

Например:

  • =SUM(A2:A10)

  • =SUM(A2:A10; C2:C10)

Вашият браузър не поддържа видео. Инсталирайте Microsoft Silverlight, Adobe Flash Player или Internet Explorer 9.

Това видео е част от курс за обучение, озаглавен Събиране на числа в Excel 2013.

SUM(число1;[число2];...)

Име на аргумент

Описание

число1    (задължително)

Първото число, което искате да съберете. "Число" може да бъде напр. 4, препратка към клетка, като напр. B6, или диапазон от клетки, като напр. B2:B8.

число2 – 255    (незадължително)

Това е второто число, което искате да съберете. Можете да зададете до 255 числа по този начин.

Ако искате бързо да получите сумата на диапазон от клетки, всичко, което трябва да направите, е да изберете диапазона и да погледнете в долната дясна част на прозореца на Excel.

Екранна снимка на избиране на диапазон от клетки, а след това поглеждане към лентата на състоянието
Лента на състоянието


Това е лентата на състоянието и показва информация за това, което сте избрали, независимо дали е една клетка, или няколко клетки. Ако щракнете с десния бутон върху лентата на състоянието, ще изскочи диалогов прозорец с функции, който показва всички опции, които можете да изберете. Обърнете внимание, че той също така показва стойности за избрания от вас диапазон, ако сте отметнали тези атрибути. Научете повече за лентата на състоянието.

Най-лесният начин да добавите формула SUM към своя работен лист е да използвате съветника за автосумиране. Изберете празна клетка непосредствено над или под диапазона, който искате да сумирате, и в разделите "Начало" или "Формули" на лентата натиснете Автосумиране > Сумиране. Съветникът за автосумиране автоматично ще разбере кой е диапазонът за сумиране, и ще създаде формулата вместо вас. Той също може да работи хоризонтално, ако изберете клетка отляво или отдясно на диапазона за сумиране. Обърнете внимание – това няма да работи в прекъснати диапазони – но ще разгледаме това в следващия раздел.

Можете да използвате съветника за автосумиране за автоматично изграждане на формула Sum.  Изберете диапазон над/под или отляво/отдясно на диапазона за сумиране и отидете на раздела "Формули" на лентата, след което изберете "Автосумиране" и "Сумиране".
Използване на съветника за автосумиране за бързо сумиране на прекъснати диапазони


Диалоговият прозорец "Автосумиране" ви позволява да изберете други общи функции, като например:

Вертикално автосумиране

Клетка B6 показва формулата Sum за автосумиране: =SUM(B2:B5)

Съветникът за автосумиране откри автоматично клетки B2: B5 като диапазона за сумиране. Всичко, което трябва да направите, е да натиснете Enter, за да потвърдите. Ако ви трябва да добавите/изключите още клетки, можете да задържите клавиша Shift > стрелка по ваш избор, докато вашата селекция не съвпадне с това, което искате, след което да натиснете клавиша Enter, когато сте готови.

IntelliSense ръководство за функцията: плаващият етикет SUM(число1;[число2];...) под функцията е нейното Intellisense ръководство. Ако щракнете върху SUM или името на функцията, тя ще се превърне в синя хипервръзка, която ще ви отведе до помощната тема за тази функция. Ако щракнете върху отделните елементи на функцията, частите във формулата, които ги представят, ще бъдат осветени. В този случай ще бъде осветен само диапазонът B2: B5, тъй като има само една препратка към числа в тази формула. Етикетът Intellisense ще се покаже за всяка функция.

Хоризонтално автосумиране

Клетка D2 показва формулата Sum за автосумиране: =SUM(B2:C2)

Използване на функцията SUM с прекъснати диапазони.  Формулата в клетка C8 е = SUM(C2:C3;C5:C6). Можете също да използвате наименувани диапазони, така че формулата да бъде =SUM(Седмица1,Седмица2).

Съветникът за автосумиране обикновено ще работи само за непрекъснати диапазони, така че ако имате празни редове или колони в диапазона за сумиране, Excel ще спре при първото празно място. В този случай ще трябва да сумирате чрез селекция,при което можете да добавите отделните диапазони един по един. В този пример, ако имате данни в клетка B4, Excel ще генерира =SUM(C2:C6), тъй като ще разпознае непрекъснат диапазон.

Можете бързо да избирате няколко прекъснати диапазона с Ctrl+ щракване с левия бутон. Първо, въведете "= SUM(", след което изберете своите различни диапазони, а Excel автоматично ще добави разделител точка и запетая между диапазоните вместо вас. Натиснете Enter, когато приключите.

СЪВЕТ: можете да използвате ALT+=, за да добавите бързо функцията SUM в клетка. След това всичко, което трябва да направите, е да изберете диапазона(ите).

Забележка: може да забележите как Excel е осветил различните диапазони на функцията с различен цвят и те съвпадат с тези във формулата, така че C2:C3 е с един цвят, а C5:C6 е с друг. Excel ще направи това за всички функции, освен ако адресираният диапазон не е в друг работен лист или в друга работна книга. За подобрена достъпност с технология за хора с увреждания можете да използвате Наименувани диапазони, като напр. "Седмица1", "Седмица2" и др. и след това да създадете препратка към тях във формулата:

=SUM(Седмица1,Седмица2)

Можете лесно да извършвате математически операции с Excel – както отделно, така и във връзка с функции на Excel, като например SUM. В следващата таблица са изброени операторите, които можете да използвате, както и някои сродни функции. Можете да въвеждате операторите или от реда с цифри на клавиатурата си, или от цифровата клавиатура с 10 клавиша, ако имате такава. Например Shift+8 ще въведе звездичката (*) за умножение.

Оператор

Операция

Примери

+

Събиране

=1+1

=A1+B1

=SUM(A1:A10)+10

=SUM(A1:A10)+B1

-

Изваждане

=1-1

=A1-B1

=SUM(A1:A10)-10

=SUM(A1:A10)-B1

*

Умножение

=1*1

=A1*B1

=SUM(A1:A10)*10

=SUM(A1:A10)*B1

=PRODUCT(1,1) - PRODUCT функция

/

Деление

=1/1

=A1/B1

=SUM(A1:A10)/10

=SUM(A1:A10)/B1

=QUOTIENT(1;1) - QUOTIENT функция

^

Степенуване

=1^1

=A1^B1

=SUM(A1:A10)^10

=SUM(A1:A10)^B1

=POWER(1;1) - POWER функция

За повече информация вижте Използване на Excel като калкулатор.

Други примери

  1. Да речем, че искате да приложите процент на отстъпка към диапазон от клетки, които сте сумирали.

    Използването на оператори със SUM.  Формулата в клетка B16 е =SUM(A2:A14)*-25%.  Формулата ще бъде изградена правилно, ако 25% е препратка към клетка вместо това, като напр. =SUM(A2:A14)*E2
    • =SUM(A2:A14)*-25%

    Това ще върне 25% от сумирания диапазон, но това вгражда 25% във формулата и може да е трудно да намерите по-късно процента, ако трябва да го промените. Много по-добре е да поставите 25% в клетка и да създадете препратка към нея вместо това, където процентът е видим и лесно може да се промени, напр. така:

    • =SUM(A2:A14)*E2

    За да разделите, вместо да умножавате, просто заместете "*" с "/": = SUM(A2:A14)/E2

  2. Събиране или изваждане от SUM

    i. Можете лесно да събирате или изваждате от SUM, като използвате + или - по следния начин:

    • =SUM(A1:A10)+E2

    • =SUM(A1:A10)-E2

В този раздел ще обсъдим някои най-добри практики за работа с функцията SUM. Голяма част от тях могат да се прилагат и при работа с други функции.

Методът =1+2 или =A+B – въпреки че можете да въведете =1+2+3 или =A1+B1+C2 и да получите напълно точни резултати, тези методи са предразполагащи към грешки по няколко причини:

  1. Печатни грешки – представете си, че се опитвате да въведете повече и/или много по-големи стойности, напр. като тези:

    • =14 598,93+65 437,90+78 496,23

    След това опитайте да проверите дали записите ви са правилни. Много по-лесно е да поставите тези стойности в отделни клетки и да използвате формула SUM. Освен това можете да форматирате стойностите, когато са в клетки, което ги прави много по-четливи, отколкото ако са във формула.

    Използвайте функцията SUM вместо да вграждате стойности във формулите.  Формулата в клетка D5 е =SUM(D2:D4)
  2. Грешки #VALUE! от препратка към текст, а не към числа

    Ако използвате формула като:

    • =A1+B1+C1 или =A1+A2+A3

    Пример за лоша конструкция на формула.  Формулата в клетка D2 е  =A2+B2+C2

    Вашата формула може да прекъсне, ако има нечислови (текстови) стойности в клетките, към които сочи препратката, което ще доведе до връщане на грешка #VALUE!. SUM ще игнорира текстовите стойности и ще върне сумата само от числовите стойности.

    Правилно изграждане на формули.  Вместо =A2+B2+C2, формулата в клетка D2 е =SUM(A2:C2)
  3. Грешка #REF! от изтриването на редове или колони

    Грешка #REF!, предизвикана от изтриване на колона.  Формулата е променена на =A2+#REF!+B2

    Ако изтриете ред или колона, формулата няма да се актуализира, за да изключи изтрития ред, и ще върне грешка #REF!, докато функцията SUM ще се актуализира автоматично.

    Функцията SUM ще се регулира автоматично според вмъкнатите или изтритите редове и колони
  4. Формулите няма да актуализират препратки при вмъкване на редове или колони

    Формулите от типа =A+B+C няма да се актуализират, ако добавите редове

    Ако вмъкнете ред или колона, формулата няма да се актуализира, за да включи добавения ред, докато функцията SUM ще се актуализира автоматично (докато не сте извън диапазона, към който препраща формулата). Това е особено важно, ако очаквате, че вашата формула ще се актуализира, а тя не го прави, тъй като ще ви остави с непълни резултати, които е възможно да не разберете, че са такива.

    Пример показва как формулата SUM автоматично се разширява от =SUM(A2:C2) на =SUM(A2:D2), когато е вмъкната колона
  5. SUM с препратки към отделни клетки спрямо тези към диапазони

    Използването на формула като:

    • =SUM(A1;A2;A3;B1;B2;B3)

    Е еднакво предразполагащо към грешки при вмъкване или изтриване на редове в диапазона, към който има препратка, по същите причини. Много по-добре е да използвате отделни диапазони, като например:

    • =SUM(A1:A3;B1:B3)

    Които ще се актуализират, когато добавяте или изтривате редове.

  1. Абсолютно можете да използвате SUM с други функции. Ето пример, който създава изчисление за средна стойност за месец:

    Използване на функцията SUM с други функции.  Формулата в клетка M2 е =SUM(A2:L2)/COUNTA(A2:L2).  Забележка: колоните от май до ноември са скрити за яснота.
    • =SUM(A2:L2)/COUNTA(A2:L2)

  2. Което връща сумата от A2:L2, разделена на броя на непразните клетки в A2:L2 (от май до декември са празни).

  1. Понякога се налага да сумирате дадена клетка в множество работни листове. Може би е изкушаващо да щракнете върху всеки лист и желаната клетка и просто да използвате "+", за да сумирате стойностите в клетките, но това е досадно и може да доведе до грешки.

    • =Лист1!A1+Лист2!A1+Лист3!A1

    Можете да постигнете това много по-лесно с 3D или триизмерна сума:

    3D Sum – формулата в клетка D2 е =SUM(Лист1:Лист3! A2)
    • =SUM(Лист1:Лист3!A1)

    Което ще сумира клетката A1 във всички листове от лист 1 до лист 3.

    Това е особено полезно в ситуации, когато имате по един лист за всеки месец (от януари до декември) и трябва да ги сумирате в обобщен лист.

    3D SUM в различни наименувани листове.  Формулата в D2 е =SUM(Януари:Декември!А2)
    • =SUM(Януари:Декември!A2)

    Което ще сумира клетка A2 във всеки лист от "Януари" до "Декември".

    Забележки: Ако работните листове имат интервали в имената си, като напр. "Продажби през януари", трябва да използвате апостроф, когато използвате препратка към имената на листовете във формула. Обърнете внимание на апострофа ПРЕДИ името на първия работен лист и на този СЛЕД последния лист.

    • =SUM(‘Продажби през януари:Продажби през декември’!A2)

    3D методът ще работи и с други функции, като напр. AVERAGE, MIN, MAX и др.:

    • =AVERAGE(Лист1:Лист3!A1)

    • =MIN(Лист1:Лист3!A1)

    • =MAX(Лист1:Лист3!A1)

Проблем

Защо е възникнала грешка

Моята SUM функция показва #####, а не резултата.

Проверете ширините на колоните си. ##### обикновено означава, че колоната е твърде тясна, за да се покаже резултатът от формулата.

Моята SUM функция показва самата формула като текст, а не резултата.

Проверете дали клетката не е форматирана като текст. Изберете въпросната клетка или диапазон и използвайте Ctrl+1, за да се отвори диалоговият прозорец Форматиране на клетки, след което щракнете върху раздела Число и изберете желания формат. Ако клетката е била форматирана като текст и не се промени, след като промените формата, трябва да използвате F2 > Enter, за да накарате формата да се промени.

Моята SUM функция не се актуализира.

Уверете се, че за Изчисление е зададено Автоматично. В раздела Формула отидете на Опции за изчисления. Можете също да използвате F9, за да наложите изчисляването на работния лист.

Уверете се, че за "Изчисление" е зададено "Автоматично".  В раздела "Формули" отидете на "Опции за изчисления".

Някои стойности не се сумират.

Сумират се само числовите стойности в препратката или диапазона на функцията. Празни клетки, логически стойности, като напр. TRUE, или текст се игнорират.

Показва се грешка #NAME? вместо очакваните резултати.

Това обикновено означава, че формулата е погрешно изписана, като напр. =sume(A1:A10) вместо =SUM(A1:A10).

Моята SUM функция показва цяло число, а би трябвало да показва десетични дроби

Проверете своето форматиране на клетки, за да сте сигурни, че ще се показват десетични дроби. Изберете въпросната клетка или диапазон и използвайте Ctrl+1, за да се отвори диалоговият прозорец Форматиране на клетки, след което щракнете върху раздела Число и изберете желания формат, като се погрижите да посочите броя знаци след десетичната запетая, който искате.

  1. Искам само да събера/извадя/умножа/разделя числа Вижте тази поредица от видеоклипове в Елементарни изчисления в Excel или Използване на Excel като калкулатор.

  2. Как да показвам повече/по-малко цифри след десетичния знак? – Можете да промените числовия формат. Изберете въпросната клетка или диапазон и използвайте Ctrl+1, за да се отвори диалоговият прозорец Форматиране на клетки, след което щракнете върху раздела Число и изберете желания формат, като се погрижите да посочите броя знаци след десетичната запетая, който искате.

  3. Как се събират и изваждат часове? Можете да събирате и изваждате часове по няколко различни начина. Например, за да получите разликата между 8:00 ч. – 12:00 ч. за пресмятане на заплати, можете да използвате: = ("12:00 ч."-"8:00 ч.") * 24, което е крайният час минус началния час. Обърнете внимание, че Excel изчислява часовете като дробна част от ден, така че трябва да се умножава по 24, за да получат общите часове. В първия пример използваме =((B2-A2)+(D2-C2))* 24, за да получим сумата на часовете от началото до края, без обедната почивка (общо 8,50 часа).

    Ако просто събирате часове и минути и искате да ги покажете по този начин, то можете да сумирате и не е необходимо да умножавате по 24, така че във втория пример използваме =SUM(A6:C6), тъй като просто ни трябва общият брой часове и минути за възложените задачи (5:36, или 5 часа и 36 минути).

    Изчисляване на часове

    За повече информация вижте: Събиране и изваждане на часове

  4. Как да получа разликата между дати? Както при часовете можете да събирате и изваждате дати. Ето един много често срещан пример за преброяване на броя на дните между две дати. Толкова е просто – =B2-A2. Ключът към работа с дати и часове е да започнете с крайна дата/час и да извадите началната дата/час.

    Изчисляване на разлики между дати

    За още начини за работа с дати вижте: Изчисляване на броя на дните между две дати.

  5. Как да сумирам само видимите клетки? Понякога, когато ръчно скривате редове или използвате автофилтриране, за да покажете само определени данни, също искате да сумирате видимите клетки. Можете да използвате функцията SUBTOTAL. Ако използвате сумарен ред в таблица на Excel, всяка функция, която изберете от падащото меню "Обща сума", автоматично ще бъде въведена като междинна сума. Вижте повече информация в Сумирате на данните в таблица на Excel.

Имате нужда от още помощ?

Винаги можете да попитате експерт в техническата общност на Excel, да получите поддръжка в общността за отговори или да предложите нова функция или подобрение на User Voice за Excel.

Вж. също

Вижте видео как да използвате функцията SUM

Функцията SUMIF сумира само стойностите, които отговарят на един критерий

Функцията SUMIFS сумира само стойностите, които отговарят на няколко критерия

Функцията COUNTIF брои само стойностите, които отговарят на един критерий

Функцията COUNTIFS брои само стойностите, които отговарят на няколко критерия

Общ преглед на формулите в Excel 2016

Начини за избягване на повредени формули

Намиране и коригиране на често срещани грешки във формули

Клавишни комбинации в Excel за Windows

Клавишни комбинации в Excel for Mac

Математически и тригонометрични функции

Функции на Excel (по азбучен ред)

Функции на Excel (по категории)

Разширете уменията си
Преглед на обучението
Получавайте първи новите функции
Присъединете се към участниците в Office Insider

Беше ли полезна тази информация?

Благодарим ви за обратната връзка!

Благодарим ви за вашата обратна връзка. Изглежда, че ще бъде полезно да ви свържем с един от нашите агенти по поддръжката на Office.

×