Общ преглед на формулите в Excel

Общ преглед на формулите в Excel

Ако нямате опит с Excel, скоро ще откриете, че той е нещо повече от мрежа, в която въвеждате числа в редове и колони. Със сигурност можете да използвате Excel за намиране на общи суми за колона или ред с числа, но можете също да изчислявате ипотечна вноска, да решавате математически или инженерни задачи или да откривате сценария за най-добър случай, на базата на променливи числа, които вкарвате.

Excel прави това, като използва формули в клетки. Формулата извършва изчисления или други действия над данните в работния лист. Формулата винаги започва със знак за равенство (=), който може да бъде последван от числа, математически оператори (например знак + или - за събиране или изваждане) и вградени функции на Excel, които могат наистина да увеличат възможностите на формулата.

Например следващата формула умножава 2 по 3 и след това добавя 5, което дава в резултат отговора 11.

=2*3+5

Ето някои допълнителни примери за формули, които можете да въвеждате в работен лист.

  • =A1+A2+A3    Събира стойностите в клетки A1 и A2 и A3.

  • =SUM(a1:A10)    Използва функцията SUM за връщане на сумата от стойностите в клетки от A1 до A10.

  • =TODAY()    Връща текущата дата.

  • =UPPER("hello")     Преобразува текста "hello" в "HELLO" с помощта на функцията UPPER.

  • =IF(A1>0)    Използва функцията IF, за да провери клетка A1 и да определи дали съдържа стойност, която е по-голяма от 0.

Една формула може да съдържа всички или някои от следните елементи: функции, препратки, оператори и константи.

Частите на формула   

Части от формула

1. Функции: Функцията PI() връща стойността на числото пи: 3,142...

2. Препратки: A2 връща стойността в клетката A2.

3. Константи: Стойности на числа или текст, въведени директно във формула, например 2.

4. Оператори: Операторът ^ (карета) повдига число на степен, а операторът * (звездичка) умножава числа.

Константата е стойност, която не се изчислява. Тя винаги е една и съща. Например датата 9.10.2008, числото 210 и текстът "Тримесечен доход" са константи. израз или стойност, която се получава от израз, не са константи. Ако в една формула използвате константи вместо препратки към клетки (например =30+70+110), резултатът се променя само ако промените формулата. По принцип е най-добре да поставяте константите в отделни клетки, където те могат да бъдат променени лесно, ако е необходимо, и след това да използвате препратки към тези клетки във формулите.

Операторите задават типа изчисление, което искате да извършите с елементите на формулата. Excel следва общите математически правила при изчисленията т.е. скоби, степени, умножение и деление и събиране и изваждане. Използването на скоби ви позволява да промените този ред на изчисление.

Типове оператори. Има четири различни типа оператори за изчисление: аритметични, за сравнение, текстови и препратки.

  • Аритметични оператори

    За да извършите основните математически операции, като събиране, изваждане, умножение или деление, групиране на числа и получаване на числови резултати, използвайте следните аритметични оператори.

    Аритметичен оператор

    Значение

    Пример

    + (знак плюс)

    Събиране

    =3+3

    - (знак минус)

    Изваждане
    Смяна на знака

    =3–3
    =-3

    * (звездичка)

    Умножение

    =3*3

    / (наклонена черта)

    Деление

    =3/3

    % (знак за процент)

    Процент

    30%

    ^ (карета)

    Степенуване

    =3^3

  • Оператори за сравнение

    С помощта на следните оператори можете да сравнявате две стойности. Резултатът от сравнението е логическата стойност – TRUE или FALSE.

    Оператор за сравнение

    Значение

    Пример

    = (знак за равенство)

    Е равно на

    =A1=B1

    > (знак “по-голямо”)

    По-голямо от

    =A1>B1

    < (знак “по-малко”)

    По-малко от

    =A1<B1

    >= (знак "по-голямо или равно")

    По-голямо или равно

    =A1>=B1

    <= (знак “по-малко или равно")

    По-малко или равно

    =A1<=B1

    <> (знак за неравенство)

    Не е равно на

    =A1<>B1

  • Оператор за конкатенация (свързване) на текст

    Използвайте знака амперсанд (&), за да конкатенирате (свържете) един или повече текстови низове в един общ текст.

    Текстов оператор

    Значение

    Пример

    & (амперсанд)

    Свързва, или конкатенира, две стойности, създавайки една непрекъсната текстова стойност

    ="North"&"wind" дава "Northwind".
    Когато A1 съдържа "Фамилно име", а B1 съдържа "Собствено име", =A1&","&B1 връща "Фамилно име, собствено име".

  • Оператори за препратки

    Комбинират диапазони от клетки за изчисления със следните оператори.

    Оператор за препратка

    Значение

    Пример

    : (двоеточие)

    Оператор за диапазон, който създава една препратка към всички клетки между две препратки, включително двете препратки.

    B5:B15

    ; (точка и запетая)

    Оператор за обединение, който комбинира множество препратки в една препратка

    =SUM(B5:B15;D5:D15)

    (интервал)

    Оператор за сечение, който създава една препратка към клетките, които са общи за две препратки

    B7:D7 C6:C8

Най-горе на страницата

В някои случаи редът, в който се извършва изчисляването, може да повлияе на връщаната от формулата стойност, така че е важно да се разбере как се определя редът и как можете да промените реда, за да получите желаните резултати.

  • Ред на изчисляване

    Формулите изчисляват стойностите в определен ред. Формулите в Excel винаги започват със знака за равенство (=). Excel интерпретира знаците след знака за равенство като формула. След знака за равенство следват елементите, които трябва да бъдат изчислени (операндите), например константи или препратки към клетки, които са разделени с оператори за изчисление. Excel изчислява формулите отляво надясно съгласно приоритета на всеки оператор във формулата.

  • Приоритет на операторите във формули на Excel

    Ако комбинирате няколко оператора в една формула, Excel извършва операциите в реда, показан в следващата таблица. Ако една формула съдържа оператори с еднакви приоритети – например умножение и деление – Excel изчислява операторите отляво надясно.

    Оператор

    Описание

    : (двоеточие)

    (единичен интервал)

    , (запетая)

    Оператори за препратки

    Смяна на знака (като в –1)

    %

    Процент

    ^

    Степенуване

    * и /

    Умножение и деление

    + и –

    Събиране и изваждане

    &

    Свързване на два текстови низа (конкатенация)

    =
    < >
    <=
    >=
    <>

    Сравняване

  • Използване на скоби във формули на Excel

    За да промените реда на изчисление, поставете в скоби частта от формулата, която трябва да бъде изчислена първа. Например следната формула дава 11, защото Excel извършва умножението преди събирането. Формулата умножава 2 по 3 и след това добавя 5 към резултата.

    =5+2*3

    Ако обаче използвате скоби, за да промените синтаксиса, Excel първо събира 5 и 2, а след това умножава резултата по 3, като се получава 21.

    =(5+2)*3

    В следващия пример скобите, които обграждат първата част от формулата, принуждават Excel първо да изчисли B4+25 и след това да раздели резултата на сумата на стойностите в клетките D5, E5 и F5.

    =(B4+25)/SUM(D5:F5)

    Най-горе на страницата

Функциите са предварително зададени формули, които извършват изчисления с помощта на конкретни стойности, наречени аргументи, в определен ред или структура. Функциите могат да се използват, за да се извършат прости или сложни изчисления. Можете да намерите всички функции на Excel в раздела "Формули" на лентата:

Разделът "Формули" на лентата на Excel
  • Синтаксис на функциите на Excel

    Следващият пример на функцията ROUND, закръгляваща число в клетка A10, илюстрира синтаксиса на функцията.

    Структура на функция

    1. Структура. Структурата на функцията започва със знак за равенство (=), последван от името на функцията, отваряща скоба, аргументите на функцията, разделени с точка и запетая, и затваряща скоба.

    2. Име на функция. За да видите списъка с наличните функции, щракнете върху някоя клетка и натиснете SHIFT+F3. Това ще стартира диалоговия прозорец Вмъкване на функция.

    Формули на Excel – диалогов прозорец "Вмъкване на функция"

    3. Аргументи. Аргументите могат да бъдат числа, текст, логически стойности като TRUE или FALSE, масиви, стойности за грешка, като напр. #N/A, или препратки към клетки. Аргументът, който зададете, трябва да създаде валидна стойност за този аргумент. Аргументите могат да бъдат също константи, формули или други функции.

    4. Пояснение за аргумент. Когато въведете функция, се появява пояснение със синтаксиса и аргументите. Например пояснение се появява, когато въведете =ROUND(. Пояснения се появяват само за вградени функции.

    Забележка : Не е нужно да въвеждате функциите с главни букви, например =ROUND, тъй като Excel автоматично ще направи името на функцията с главни букви вместо вас, след като натиснете Enter. Ако объркате правописа на името на функцията, като например =SUME(A1:A10) вместо =SUM(A1:A10), тогава Excel ще върне грешка #NAME?.

  • Въвеждане на функции на Excel

    Когато създавате формула, която съдържа функция, можете да използвате диалоговия прозорец Вмъкване на функция, за да си помогнете при въвеждането на функции в работния лист. Когато изберете функция от диалоговия прозорец Вмъкване на функция, Excel ще стартира съветник за функции, който показва името на функцията, всеки от нейните аргументи, описание на функцията и на всеки аргумент, текущия резултат от функцията и текущия резултат от цялата формула.

    Съветник за функции на Excel

    Използвайте Автодовършване на формули, за да създавате и редактирате формули по-лесно и да минимизирате грешките при въвеждане и синтактичните грешки. След като въведете = (знак за равенство) и началните букви на дадена функция, Excel показва динамичен падащ списък на валидните функции, аргументи и имена, които съответстват на тези букви. След това можете да изберете елемент от падащия списък и Excel ще го въведе вместо вас.

    Автодовършване на формула на Excel

  • Влагане на функции на Excel

    В някои случаи може да се наложи да се използва функция като един от аргументите на друга функция. Например следващата формула използва вложената функция AVERAGE и сравнява резултата със стойността 50.

    вложени функции

    1. Функциите AVERAGE и SUM са вложени във функцията IF.

    Валидни върнати стойности    Когато една вложена функция се използва като аргумент, вложената функция трябва да връща същия тип стойност, който този аргумент използва. Ако например аргументът връща стойност TRUE или FALSE, вложената функция трябва да връща стойност TRUE или FALSE. Ако не го прави, Excel показва стойност за грешка #VALUE!.

    Граници на нивата на влагане    Една формула може да съдържа до седем нива на вложени функции. Когато една функция (ще наричаме тази функция B) се използва като аргумент в друга функция (ще я наричаме функция A), функция B действа като функция от второ ниво. Например функциите AVERAGE и SUM са функции от второ ниво, ако се използват като аргументи на функцията IF. Функция, която е вложена във функцията AVERAGE, е функция от трето ниво и т.н.

    Най-горе на страницата

Препратките идентифицират клетка или диапазон от клетки в работен лист и съобщават на Excel къде да потърси стойността или данните, които искате да използвате във формулата. Можете да използвате препратки, за да използвате в една формула данни, съдържащи се в различни части на работния лист, или да използвате стойността от една клетка в няколко формули. Можете също да препращате към клетки от други листове в същата работна книга и към други работни книги. Препратки към клетки в други работни книги се наричат връзки или външни препратки.

  • Стил на препратки A1

    По подразбиране Excel използва стила за препратки A1, който препраща към колони, означени с букви (от A до XFD, общо 16 384 колони) и към редове, означени с номера (от 1 до 1 048 576). Тези букви и числа се наричат заглавия на редове и колони. За да препратите към една клетка, въведете буквата на колоната, последвана от номера на реда. Например B2 препраща към клетката в пресечната точка на колоната B и реда 2.

    За да препратите към

    Използвайте

    Клетката в колона A и ред 10

    A10

    Диапазонът от клетки в колона A и редове от 10 до 20

    A10:A20

    Диапазонът от клетки в ред 15 и колони от B до E

    B15:E15

    Всички клетки в ред 5

    5:5

    Всички клетки в редовете от 5 до 10

    5:10

    Всички клетки в колона H

    H:H

    Всички клетки в колоните от H до J

    H:J

    Диапазонът от клетки в колоните от A до E и редовете от 10 до 20

    A10:E20

  • Създаване на препратка към клетка или диапазон от клетки в друг работен лист в същата работна книга

    В следващия пример функцията AVERAGE изчислява средната стойност за диапазона B1:B10 в работния лист с име "Маркетинг" в същата работна книга.

    Пример на препратка към лист

    1. Препраща към работния лист, наречен "Маркетинг"

    2. Препраща към диапазона от клетки от B1 към B10

    3. Удивителен знак (!) Разделя препратката към работен лист от препратката към диапазон от клетки

    Забележка : Ако работният лист, към който сочи препратката, има интервали или числа, трябва да добавите апострофи (') преди и след името на работния лист, като напр. ="123"!A1 или ='Приходи за януари'!A1.

  • Разликата между абсолютни, относителни и смесени препратки

    1. Относителни препратки    Относителната препратка към клетка в формула, например A1, се базира на относителното положение на клетката, която съдържа формулата, и клетката, към която сочи препратката. Ако позицията на клетката, която съдържа формулата, се промени, препратката се променя. Ако копирате или попълвате формулата в друг ред или колона, препратката се настройва автоматично. По подразбиране новите формули използват относителни препратки. Ако например копирате или попълвате относителна препратка от клетка B2 към клетка B3, тя автоматично се настройва от =A1 на =A2.

      Копирана формула с относителна препратка   

      Копирана формула с относителна препратка

    2. Абсолютни препратки    Абсолютната препратка към клетка във формула, например $A$1, винаги препраща към клетката с указаното местоположение. Ако позицията на клетката, съдържаща формулата, се промени, абсолютният адрес остава същият. Ако копирате или попълвате формулата в друг ред или колона, абсолютният адрес не се пренастройва. По подразбиране новите формули използват относителни препратки, така че може да се наложи да ги преобразувате в абсолютни препратки. Ако например копирате или попълвате абсолютен адрес от клетка B2 в клетка B3, той остава същият и в двете клетки: =$A$1.

      Копирана формула с абсолютна препратка   

      Копирана формула с абсолютна препратка
    3. Смесени препратки    Смесената препратка има или абсолютна колона и относителен ред, или абсолютен ред и относителна колона. Препратката с абсолютна колона има вида $A1, $B1, и т.н. Препратката с абсолютен ред има вида A$1, B$1, и т. н. Ако позицията на клетката, съдържаща формулата, се промени, относителната препратка се променя, а абсолютната препратка не се променя. Ако копирате или попълвате формулата в друг ред или колона, относителната препратка се пренастройва автоматично, а абсолютната не се пренастройва. Ако например копирате или попълвате смесена препратка от клетка A2 към B3, тя се настройва от =A$1 в =B$1.

      Копирана формула със смесена препратка   

      Копирана формула със смесена препратка

  • Стил на препратки 3D

    Удобно препращане към множество работни листове    Ако искате да анализирате данните в една и съща клетка или диапазон от клетки от множество работни листове в работна книга, използвайте 3D препратка. 3D препратката включва препратка към клетката или диапазона, предшествана от диапазон от имена на работни листове. Excel използва всички работни листове, съхранени между началното и крайното име от препратката. Например =SUM(Лист2:Лист13!B5) добавя всички стойности, съдържащи се в клетките B5 на всички работни листове между и включително Лист2 и Лист13.

    • Можете да използвате 3D препратки, за да препращате към клетки в други листове, да определяте имена и да създавате формули с помощта на следните функции: SSUM, AVERAGE, AVERAGEA, COUNT, COUNTA, MAX, MAXA, MIN, MINA, PRODUCT, STDEV.P, STDEV.S, STDEVA, STDEVPA, VAR.P, VAR.S, VARA и VARPA.

    • 3D препратките не могат да се използват във формули с масиви.

    • 3D препратките не могат да се използват с оператор за сечение (единичен интервал) или във формули, които използват неявна пресечна точка.

    Какво се случва, когато премествате, копирате, вмъквате или изтривате работни листове    Следващите примери обясняват какво става, когато преместите, копирате, вмъкнете или изтриете работни листове, които са включени в 3D препратка. Примерите използват формулата =SUM(Лист2:Лист6!A2:A5), която сумира клетките от A2 до A5 в работните листове от 2 до 6.

    • Вмъкване или копиране    Ако вмъкнете или копирате листовете между Лист2 и Лист6 (крайните точки в този пример), Excel включва в изчисленията всички стойности от клетките между A2 и A5 на добавените листове.

    • Изтриване     Ако изтриете листове между Лист2 и Лист6, Excel премахва техните стойности от изчислението.

    • Преместване    Ако преместите листове, намиращи се между Лист2 и Лист6 извън адресирания диапазон в листа, Excel премахва техните стойности от изчислението.

    • Преместване на крайна точка    Ако преместите Лист2 или Лист6 на друго място в същата работна книга, Excel настройва изчислението, така че да обхване новия диапазон от листове между тях.

    • Изтриване на крайна точка    Ако изтриете Лист2 или Лист6, Excel настройва изчислението, така че да обхване диапазона от листове между тях.

  • Стил на препратки R1C1

    Можете също да използвате стил на препратка, при който и редовете, и колоните в работния лист са номерирани. Стилът на препратка R1C1 е полезен за изчисляване на позициите на редовете и колоните в макроси. При стила R1C1 Excel показва местоположението на една клетка с "R", последвано от номер на ред, и "C", последвано от номер на колона.

    Препратка

    Значение

    R[-2]C

    относителна препратка към клетката, намираща се два реда нагоре в същата колона

    R[2]C[2]

    Относителна препратка към клетката, намираща се два реда надолу и две колони вдясно

    R2C2

    Абсолютна препратка към клетката във втория ред и втората колона

    R[-1]

    Относителна препратка към целия ред над активната клетка

    R

    Абсолютна препратка към текущия ред

    Когато записвате макрос, Excel записва някои команди с помощта на стила R1C1. Ако например записвате команда, като щракнете върху бутона Автосумиране, за да вмъкнете формула, която добавя диапазон от клетки, Excel записва формулата с помощта на стила R1C1, а не A1.

    Можете да включвате или изключвате стила на препратки R1C1, избирайки или изчиствайки отметката от квадратчето Стил на препратки R1C1, под раздела Работа с формули, в категорията Формули на диалоговия прозорец Опции. За да покажете този диалогов прозорец, щракнете върху раздела Файл.

    Най-горе на страницата

Можете да създавате дефинирани имена, за да представяте клетки, диапазони от клетки, формули, константи или таблици на Excel. Името е съдържателно съкращение, което прави по-лесно разбирането на предназначението на препратка към клетка, константа, формула или таблица, всяко от които може да е трудно за разбиране от пръв поглед. Следващата информация показва често срещани примери на имена и как използването им във формули може да подобри яснотата и да направи формулите по-лесни за разбиране.

Пример 1

Тип на примера

Пример, който използва диапазони вместо имена

Пример, който използва имена

Препратка

=SUM(A16:A20)

=SUM(Продажби)

Константа

=PRODUCT(A12;9,5%)

=PRODUCT(Цена;ДанъчнаСтавка)

Формула

=TEXT(VLOOKUP(MAX(A16;A20);A16:B20;2;FALSE),"м/дд/гггг")

=TEXT(VLOOKUP(MAX(Продажби);Инфо_продажби;2;FALSE);"м/дд/гггг")

Таблица

A22:B25

=PRODUCT(Цена;Таблица1[@Данъчна ставка])

Пример 2

Копирайте примерните данни в следващата таблица и ги поставете в клетка A1 на нов работен лист на Excel. За да покажат резултати формулите, изберете ги, натиснете клавиша F2 и след това натиснете клавиша Enter. Ако е необходимо, коригирайте ширините на колоните, за да видите всичките данни.

Забележка :  Във формулите, в колони C и D, дефинираното име "Продажби" замества препратката към (диапазон) A9:A13, а името "Инфо_продажби" замества диапазона A9:B13. Ако не можете да създадете тези имена в тестовата работната книга, формулите в D2:D3 ще върнат грешка #NAME?.

Тип на примера

Пример без използване на име

Пример с използване на име

Формула и резултат с използване на име

Препратка

=SUM(A9:A13)

=SUM(Продажби)

=SUM(Продажби)

Формула

=TEXT(VLOOKUP(MAX(A9:13);A9:B13;2;FALSE);"дд.м.гггг")

=TEXT(VLOOKUP(MAX(Продажби);Инфо_продажби;2;FALSE);"дд.м.гггг")

=TEXT(VLOOKUP(MAX(Продажби);Инфо_продажби;2,FALSE);"дд.м.гггг")

Цената

995 лв.

Продажби

Дата на продажба

249 лв.

17.3.2011

399 лв.

2.4.2011

643 лв.

23.4.2011

275 лв.

30.4.2011

447 лв.

4.5.2011

  • Типове имена

    Има няколко типа имена, които можете да създадете и използвате.

    • Дефинирано име    Име, което представя клетка, формула или константна стойност. Можете да създадете ваше собствено дефинирано име. Освен това Excel създава понякога дефинирани имена вместо вас, когато например задавате област за печат.

    • Име на таблица    Име за таблица на Excel, която е колекция от данни за конкретна тема, които се съхраняват в записи (редове) и полета (колони). Excel създава име по подразбиране на таблица на Excel като "Таблица1", "Таблица2" и т. н., всеки път, когато вмъквате таблица на Excel, но вие можете да промените тези имена, за да ги направите по-смислени.

      За повече информация относно таблиците на Excel вж. Използване на структурирани препратки с таблици на Excel.

  • Създаване и въвеждане на имена

    Вие създавате имена с помощта на:

    • Поле за име в лентата за формули     Това е най-добре за създаване на име на ниво на работна книга за избран диапазон.

    • Създаване на име от селекция     Можете удобно да създавате имена от съществуващи етикети на редове и колони, като използвате селекция от клетки в работния лист.

    • Диалоговия прозорец "Ново име"    Това е най-добро, когато искате повече гъвкавост при създаването на имена, например при определянето на локално ниво на обхват на работна книга или при създаването на коментар за име.

    Забележка :  По подразбиране имената използват абсолютни препратки към клетки.

    Можете да въведете име посредством:

    • Въвеждане    Например въвеждането на името като аргумент на формула.

    • Използване на "Автодовършване на формули"    Използвайте падащия списък на "Автодовършване на формули", където за вас се изброяват автоматично валидни имена.

    • Избиране от командата "Използвай във формула"    Изберете дефинирано име от наличния списък от командата Използвай във формула в групата Дефинирани имена на раздела Формула.

За повече информация вижте Дефиниране и използване на имена във формули.

Най-горе на страницата

Една формула за масив може да извършва множество изчисления и след това да върне или единичен резултат, или множество резултати. Формулите за масиви действат върху два или повече набора от стойности, известни като аргументи за масиви. Всеки аргумент за масив трябва да има един и същ брой редове и колони. Формулите за масиви се създават по същия начин, по който се създават и другите формули, но с тази разлика, че за да въведете формулата, трябва да натиснете CTRL+SHIFT+ENTER. Някои от вградените функции са масиви за формули и трябва да се въвеждат като масиви, за да се получи правилен резултат.

Масивите от константи могат да се използват вместо препратки, когато не искате да въвеждате всяка константна стойност в отделна клетка на работния лист.

Използване на формула за масив за изчисляване на единични и съставни резултати

Забележка : Когато въведете формула за масив, Excel автоматично вмъква формулата между { } (фигурни скоби). Ако се опитате да въведете фигурните скоби сами, Excel ще покаже вашата формула като текст.

  • Формула за масив, която изчислява единичен резултат    Този тип формула за масив може да опрости работата в работния лист чрез заместване на няколко различни формули с една единствена формула за масив.

    Следващият пример изчислява общата сума на масив от брой и цени на акции, без да използва ред от клетки за изчисляване и показване на отделните стойности за всяка акция.

    формула за масив, която изчислява един резултат

    Когато въведете формулата ={SUM(B2:D2*B3:D3)} като формула за масив, тя умножава Shares и Price за всяка акция и след това сумира резултатите от тези изчисления.

  • Формула за масив, която изчислява множество резултати    Някои функции за работен лист връщат масиви от стойности или изискват масив от стойности като аргумент. За да изчислите множество резултати с формула за масив, трябва да въведете масива в диапазон от клетки, който има същия брой редове и колони като масивите за аргументи.

    Ако например е дадена последователност от числа за три продажби (в колона B) за три последователни месеца (в колона A), функцията TREND определя праволинейните стойности за продажбите. За да се покажат всички резултати от формулата, тя е въведена в три клетки в колона C (C1:C3).

    Формула за масив, която изчислява множество резултати

    Когато въведете формулата = TREND (B1:B3;A1:A3) като формула за масив, тя изчислява три отделни резултата (22196, 17079 и 11962) въз основа на стойностите за трите продажби и трите месеца.

Използване на масиви от константи

В една обикновена формула можете да въведете препратка към клетка, съдържаща стойност, или самата стойност, която се нарича константа. По същия начин в една формула за масив можете да въведете препратка към масив или да въведете масива от стойности, съдържащи се в клетките, който аналогично се нарича масив от константи. Формулите за масиви възприемат константите по същия начин, като обикновените формули, но изискват въвеждането на масивите от константи в определен формат.

Масивите от константи могат да съдържат числа, текст, логически стойности, като например TRUE или FALSE, или стойности на грешки като #N/A. Различните типове стойности могат да са в един и същи масив от константи  – например {1,3,4;TRUE,FALSE,TRUE}. Числата в масиви от константи могат да са цели, дробни десетични или в научен формат. Текстът трябва да е обграден с двойни кавички – например "Вторник".

Масивите от константи не могат да съдържат препратки към клетки, колони или редове с различна дължина, формули или специалните знаци $ (знак за долар), скоби или % (знак за процент).

Когато форматирате масив от константи:

  • Обграждайте ги във фигурни скоби ( { } ).

  • Отделяйте стойностите от различните колони със запетаи (,). Например за да представите стойностите 10, 20, 30 и 40, въвеждате {10,20,30,40}. Този масив от константи се нарича масив 1 на 4 и е еквивалентен на препратка към масив от 1 ред и 4 колони.

  • Отделяйте стойностите в различните редове с точка и запетая (;). Например за да представите стойностите 10, 20, 30 и 40 в един ред и 50, 60, 70 и 80 в реда непосредствено под него, трябва да въведете масив от константи 2 на 4: {10,20,30,40;50,60,70,80}.

Най-горе на страницата

Когато изтривате формула, стойностите, получени като резултат от формулата, също се изтриват. Можете обаче да премахнете само формулата и да оставите стойността, получена като резултат от формулата, която се показва в клетката.

  • За да изтриете формули, както и техните получените стойности, направете следното:

    1. Изберете клетката или диапазона от клетки, съдържащи формулата.

    2. Натиснете DELETE.

  • За да изтриете формули, без да премахвате получените стойности, направете следното:

    1. Изберете клетката или диапазона от клетки, съдържащи формулата.

      Ако формулата е формула за масив, изберете диапазона от клетки, който съдържа формулата за масив.

      Как да изберете диапазон от клетки, който съдържа формулата за масив

      1. Щракнете върху някоя клетка във формулата за масив.

      2. В раздела Начало, в групата Редактиране щракнете върху Намиране и избор, а след това върху Отиване на.

      3. Щракнете върху Специално.

      4. Щракнете върху Текущ масив.

    2. В раздела Начало, в групата Клипборд щракнете върху Копирай Изображение на бутон .
      изображение на лентата на excel

      Клавишна комбинация    Можете също да натиснете CTRL+C.

    3. В раздела Начало, в групата Клипборд щракнете върху стрелката под Поставяне Изображение на бутон , а след това върху Поставяне на стойности.

Най-горе на страницата

Следващата таблица обобщава някои от най-често срещаните грешки, които можете да направите, когато въвеждате формула, и как да се избягват грешки във формули:

Задължително е

Още информация

Да има съответствие между отварящите и затварящите кръгли скоби във формулата    

Всички кръгли скоби да са част от съответстващи си двойки във формули. Когато създавате формула, Excel показва кръглите скоби оцветени след въвеждането им.

Използване на двоеточие за указване на диапазон, който въвеждате във формула   

Двоеточие (:) се използва за отделяне на препратката към първата и последната клетка в диапазона. Например A1:A5.

Да са въведени всички задължителни аргументи    

Функциите могат да имат задължителни и незадължителни аргументи (означено с квадратни скоби в синтаксиса). Всички задължителни аргументи трябва да бъдат въведени. Също така се уверете, че не сте въвели прекалено много аргументи.

Не влагайте повече от 64 функции в една формула   

Влагането на функции във формула е ограничено до 64 нива.

Заграждайте имената на работна книга или работен лист в единични кавички    

Когато правите препратка към стойности или клетки в други работни листове или работни книги, които имат небуквени знаци в имената си, имената трябва да бъдат оградени в единични кавички ( ' ).

Във външните работни книги да е включен пътят    

Външните препратки трябва да съдържа име на работна книга и пътя към работната книга.

Числата да са въведени без форматиране    

Числата, които въвеждате във формулата, не трябва да бъдат форматирани с десетични разделители или знаци за долар ($), тъй като запетаите може да се използват като разделители на аргументи във формулите (в зависимост от езика), а знаците за долар се използват за означаване на абсолютни препратки. Например вместо да въвеждате $1,000, въведете 1000 във формулата.

Най-горе на страницата

Важно : Изчислените резултати от формули и някои функции за работен лист на Excel може да се различават леко между компютър с Windows и x86 или x86-64 архитектура и компютър с Windows RT с ARM архитектура. Научете повече за разликите.

Имате въпрос за конкретна функция?

Публикувайте въпрос във форума на общността на Excel

Помогнете ни да подобрим Excel

Имате ли предложения как можем да подобрим следващата версия на Excel? Ако е така, вижте темите в Гласът на потребителите на Excel

Вж. също

Общ преглед на формулите в Excel 2016

Начини за избягване на повредени формули

Намиране и коригиране на често срещани грешки във формули

Клавишни комбинации и функционални клавиши за Excel

Функции на Excel (по азбучен ред)

Функции на Excel (по категории)

Разширете уменията си
Преглед на обучението
Получавайте първи новите функции
Присъединете се към участниците в Office Insider

Беше ли полезна тази информация?

Благодарим ви за обратната връзка!

Благодарим ви за вашата обратна връзка. Изглежда, че ще бъде полезно да ви свържем с един от нашите агенти по поддръжката на Office.

×