Uygulandığı öğe
Uygulama Nesnesi |
Dosya iletişim kutusunun tek bir örneğini temsil eden bir nesnesi döndürür.
ifade.FileDialog(dialogType)
ifade Gerekli. Uygulandığı Öğe listesindeki nesnelerden birini döndüren ifade.
dialogType Gerekli MsoFileDialogType . Dosya iletişim kutusunun türü.
MsoFileDialogType, şu MsoFileDialogType sabitlerinden biri olabilir. |
msoFileDialogFilePicker |
msoFileDialogFolderPicker |
msoFileDialogOpen Microsoft Access’de desteklenmez. |
msoFileDialogSaveAs Microsoft Access’de desteklenmez. |
Notlar
Microsoft Office Access 2007, msoFileDialogOpen ve msoFileDialogSaveAs sabitlerini desteklemez.
Örnek
Bu örnekte, kullanıcının bir veya birden çok dosya seçmesine olanak tanıyan bir iletişim kutusu görüntülemek için FileDialog nesnesinin nasıl kullanılacağı gösterilir. Seçilen dosyalar daha sonra DosyaListesi adıl bir liste kutusuna eklenir.
Private Sub cmdFileDialog_Click()
' Requires reference to Microsoft Office 11.0 Object Library.
Dim fDialog As Office.FileDialog
Dim varFile As Variant
' Clear listbox contents.
Me.FileList.RowSource = ""
' Set up the File Dialog.
Set fDialog = Application.FileDialog(msoFileDialogFilePicker)
With fDialog
' Allow user to make multiple selections in dialog box
.AllowMultiSelect = True
' Set the title of the dialog box.
.Title = "Please select one or more files"
' Clear out the current filters, and add our own.
.Filters.Clear
.Filters.Add "Access Databases", "*.ACCDB"
.Filters.Add "Access Projects", "*.ADP"
.Filters.Add "All Files", "*.*"
' Show the dialog box. If the .Show method returns True, the
' user picked at least one file. If the .Show method returns
' False, the user clicked Cancel.
If .Show = True Then
'Loop through each file selected and add it to our list box.
For Each varFile In .SelectedItems
Me.FileList.AddItem varFile
Next
Else
MsgBox "You clicked Cancel in the file dialog box."
End If
End With
End Sub