นำไปใช้กับ
วัตถุ Application |
ส่งกลับวัตถุ FileDialog ที่แทนถึงอินสแตนซ์เดี่ยวของกล่องโต้ตอบไฟล์
นิพจน์.FileDialog(dialogType)
นิพจน์ จำเป็น นิพจน์ที่ส่งกลับวัตถุใดวัตถุหนึ่งในรายการ นําไปใช้กับ
dialogType จําเป็นต้องมี MsoFileDialogType ชนิดของกล่องโต้ตอบไฟล์
MsoFileDialogType อาจเป็นหนึ่งในค่าคงที่ MsoFileDialogType เหล่านี้ |
msoFileDialogFilePicker |
msoFileDialogFolderPicker |
msoFileDialogOpen ไม่ได้รับการสนับสนุนใน Microsoft Access |
msoFileDialogSaveAs ไม่ได้รับการสนับสนุนใน Microsoft Access |
ข้อสังเกต
ค่าคงที่ msoFileDialogOpen และ msoFileDialogSaveAs ไม่ได้รับการสนับสนุนใน Microsoft Office Access 2007
ตัวอย่าง
ตัวอย่างนี้แสดงวิธีใช้วัตถุ FileDialog เพื่อแสดงกล่องโต้ตอบที่อนุญาตให้ผู้ใช้เลือกไฟล์อย่างน้อยหนึ่งไฟล์ได้ ไฟล์ที่เลือกจะถูกเพิ่มลงในกล่องรายการที่ชื่อ FileList
Private Sub cmdFileDialog_Click()
' Requires reference to Microsoft Office 11.0 Object Library.
Dim fDialog As Office.FileDialog
Dim varFile As Variant
' Clear listbox contents.
Me.FileList.RowSource = ""
' Set up the File Dialog.
Set fDialog = Application.FileDialog(msoFileDialogFilePicker)
With fDialog
' Allow user to make multiple selections in dialog box
.AllowMultiSelect = True
' Set the title of the dialog box.
.Title = "Please select one or more files"
' Clear out the current filters, and add our own.
.Filters.Clear
.Filters.Add "Access Databases", "*.ACCDB"
.Filters.Add "Access Projects", "*.ADP"
.Filters.Add "All Files", "*.*"
' Show the dialog box. If the .Show method returns True, the
' user picked at least one file. If the .Show method returns
' False, the user clicked Cancel.
If .Show = True Then
'Loop through each file selected and add it to our list box.
For Each varFile In .SelectedItems
Me.FileList.AddItem varFile
Next
Else
MsgBox "You clicked Cancel in the file dialog box."
End If
End With
End Sub