الدالة TEXT

المساهمون:. كريس "سميتي" سميث ديف لودفيغ

تتيح لك الدالة TEXT تغيير طريقة ظهور الأرقام من خلال تطبيق التنسيق عليها باستخدام رموز التنسيقات. وهذا مفيد عندما تريد عرض الأرقام بتنسيق أكثر قابلية للقراءة، أو تريد دمج الأرقام مع النصوص أو الرموز.

ملاحظة: تقوم الدالة TEXT بتحويل الأرقام إلى نصوص، مما قد يجعل من الصعب الإشارة إليها في العمليات الحسابية لاحقاً. من الأفضل أن تحتفظ بالقيمة الأصلية الخاصة بك في خلية واحدة، ثم استخدم الدالة TEXT في خلية أخرى. إذا لزم بعد ذلك إنشاء صيغ أخرى، فقم بالإشارة إلى القيمة الأصلية وليس نتيجة الدالة TEXT.

بناء الجملة

TEXT(قيمة، format_text)

يحتوي بناء جملة الدالة TEXT على الوسيطات التالية:

اسم الوسيطة

الوصف

القيمة

قيمة رقمية تريد تحويلها إلى نص.

format_text

سلسلة نصية تحدد التنسيق الذي تريد تطبيقه على القيمة المتوفرة.

نظرة عامة

وفي أبسط شكل لها، تشير الدالة TEXT إلى ما يلي:

  • ‎=TEXT(القيمة التي تريد تنسيقها، "رمزالتنسيق الذي تريد تطبيقه")

فيما يلي بعض الأمثلة الشائعة، والتي يمكنك نسخها مباشرة في Excel لتجربها بنفسك. لاحظ رموز التنسيق بين علامتي الاقتباس.

الصيغة

الوصف

=TEXT(1234.567,"$#,##0.00")

عملة مع فاصل الآلاف ومنزليتين عشريتين، مثل 1,234.57 دولار. لاحظ أن Excel يُقرّب القيمة إلى منزليتين عشريتين.

=TEXT(TODAY(),"MM/DD/YY")

تاريخ اليوم بتنسيق MM/DD/YY، مثل 03/14/12

= TEXT(TODAY()،"DDDD")

اليوم الموافق من أيام الأسبوع، مثل يوم الاثنين

=TEXT(NOW(),"H:MM AM/PM")

الوقت الحالي مثل 1:29 م

=TEXT(0.285,"0.0%")

النسبة المئوية مثل 28.5%

=TEXT(4.34 ,"# ?/?")

كسر، مثل ‎4 1/3

=TRIM(TEXT(0.34,"# ?/?"))

كسر، مثل 1/3. لاحظ استخدام الدالة TRIM لإزالة المسافة البادئة مع قيمة عشرية.

=TEXT(12200000,"0.00E+00")

الرموز العلمية، مثل 1.22E+07

=TEXT(1234567898,"[<=9999999]###-####;(###) ###-####")

خاصة (رقم الهاتف)، مثل ‎(123) 456-7898

=TEXT(1234,"0000000")

إضافة أصفار بادئة (0)، مثل 0001234

=TEXT(123456,"##0° 00' 00''")

مخصص - خط العرض/خط الطول

ملاحظة: على الرغم من أنه يمكنك استخدام الدالة TEXT لتغيير التنسيق، إلا أنها ليست الطريقة الوحيدة.لفعل ذلك. حيث يمكنك تغيير التنسيق بدون صيغة عن طريق الضغط على CTRL+1(أو ‏ صورة لأيقونة زر الأمر لـ MAC‏1‏+ على Mac) ثم اختر التنسيق الذي تريده من تنسيق الخلايا > حوار رقم.

تنزيل الأمثلة التي نقدمها

يمكنك تنزيل مصنف الأمثلة مع جميع أمثلة الدالة TEXT التي ستعثر عليها في هذه المقالة.بالإضافة إلى بعض التطبيقات الإضافية. يمكنك المتابعة، أو إنشاء رموز تنسيق الدالة TEXT الخاصة بك.

تنزيل أمثلة دالة Excel TEXT‏

رموز تنسيق أخرى متوفرة

يمكنك استخدام مربع الحوار تنسيق الخلايا للبحث عن رموز تنسيق متوفرة أخرى:

  1. اضغط على Ctrl+1 ( صورة لأيقونة زر الأمر لـ MAC +1على Mac) لإظهار مربع الحوار تنسيق الخلايا.

  2. حدد التنسيق الذي تريده من علامة تبويب أرقام .

  3. حدد الخيار مخصص،

  4. وسيتم الآن عرض رمز التنسيق الذي تريده في المربع نوع. في هذه الحالة، حدد كل شيء موجود في المربع نوع باستثناء الفاصلة المنقوطة (;) والرمز @. ففي المثال التالي، قمنا بتحديد MM/DD/YY ونسخهم.

  5. اضغط على Ctrl+C.لنسخ رمز التنسيق ثم اضغط على إلغاء لاستبعاد مربع الحوار تنسيق الخلايا.

  6. الآن كل ما تحتاجه هو أن تضغط على Ctrl+V للصق رمز التنسيق في صيغة TEXT مثل =‏TEXT(B2,"‏mm/dd/yy"). تأكد من أنك قمت بلصق رمز التنسيق داخل علامات اقتباس ("رمز تنسيق") وإلا سيعرض Excel رسالة خطأ.

مثال على استخدام مربع الحوار التنسيق > الخلايا > الرقم > مخصص ليقوم Excel بإنشاء سلاسل التنسيق بالنيابة عنك.

رموز التنسيقات حسب الفئة

فيما يلي بعض الأمثلة حول كيفية تطبيق تنسيقات أرقام مختلفة على القيم باستخدام مربع الحوار تنسيق الخلايا، ثم استخدم الخيار مخصص لنسخ رموز التنسيقات تلك إلى الدالة TEXTالخاصة بك.

لماذا حذف Excel الصفر البادئ الخاص بي؟

تم تدريب Excel للبحث عن الأرقام التي تم إدخالها في الخلايا، لا الأرقام التي تبدو كنص مثل أرقام الأجزاء أو وحدة SKU. للاحتفاظ بالأصفار البادئة، قم بتنسيق نطاق الإدخال كنص قبل لصق القيم أو إدخالها. حدد العمود أو النطاق حيث يمكن وضع القيم ثم استخدم CTRL+1 لإظهار مربع الحوار تنسيق > خلايا وعلى علامة التبويب رقم حدد نص. الآن سيحتفظ Excel بالأصفار البادئة.

إذا قمت بالفعل بإدخال بيانات وقام برنامج Excel بإزالة الأصفار البادئة لديك، يمكنك استخدام الدالة TEXT لإضافتها مرة أخرى. يمكنك الإشارة إلى الخلية العلوية باستخدام القيم واستخدام ‎=TEXT(value,"00000")، حيث يمثل عدد الأصفار في الصيغة إجمالي عدد الحروف التي تريدها، ثم انسخ والصق على الجزء المتبقي من النطاق لديك.

أمثلة على استخدام الدالة TEXT لتنسيق الأصفار البادئة. =TEXT(A2,"00000")

إذا احتجت لسبب ما لتحويل قيم النص إلى أرقام مرة أخرى، يمكنك الضرب في 1 مثل ‎=D4*1 أو استخدام عامل تشغيل أحادي مزدوج (--) مثل ‎=--D4.

يفصل Excel الآلاف بفواصل إذا كان التنسيق يحتوي على فاصلة (,) محاطة بعلامات الأرقام (#) أو بأصفار. على سبيل المثال، إذا كانت سلسلة التنسيق هي "#,###"، يعرض Excel الرقم12200000 ك 12,200,000.

تقيس أي فاصلة تتبع عنصراً نائباً لرقم الرقم بـ 1,000 فعلى سبيل المثال إذا كانت سلسلة التنسيق "#,###.0,"، فسيعرض Excel الرقم 12200000 كـ 12,200.0.

أمثلة على دالة TEXT باستخدام فاصل الآلاف

ملاحظات: 

  • يعتمد فاصل الآلاف على الإعدادات الإقليمية. فهي فاصلة في الولايات المتحدة الأمريكية وقد تكون نقطة (.) في بعض المناطق الأخرى.

  • فاصل الآلاف متوفر لتنسيقات الأرقام والعملة والمحاسبة.

فيما يلي أمثلة على تنسيقات العدد القياسي (فاصل الآلاف والمنازل العشرية فقط)، والعملة والمحاسبة. يسمح تنسيق العملة لك بإدراج رمز عملة من اختيارك ومحاذاته إلى جانب القيمة الخاصة بك، بينما سيؤدي تنسيق المحاسبة إلى محاذاة رمز العملة إلى يمين الخلية والقيمة إلى اليسار. لاحظ الفرق بين رموز تنسيقات العملة والمحاسبة أدناه حيث تستخدم المحاسبة نجمة (*) لإنشاء فاصل بين الرمز والقيمة.

أمثلة على الدالة TEXT باستخدام تنسيقات الأرقام والعملة والمحاسبة

للبحث عن رمز تنسيق لرمز العملة، اضغط أولاً على Ctrl+1‏ (أو صورة لأيقونة زر الأمر لـ MAC ‎+1 على Mac)، حدد التنسيق الذي تريده ثم اختر رمزاً من القائمة المنسدلة رمز:

تحديد رمز عملة من مربع الحوار "تنسيق الخلايا"

ثم انقر فوق مخصص على الجانب الأيمن من المقطع فئة وانسخ رمز التنسيق بما في ذلك رمز العملة.

دالة TEXT - عملة مخصصة باستخدام الرمز

ملاحظة: لا تدعم الدالة TEXT تنسيق الألوان، لذلك إذا قمت بنسخ رمز تنسيق لرقم من مربع الحوار "تنسيق الخلايا" والذي يتضمن لوناً مثل $#, # # 0.00_); [Red]‏($#, # # 0.00)، فستقبل الدالة TEXT رمز تنسيق، ولكن لن تعرض اللون.

يمكنك تغيير طريقة عرض التاريخ باستخدام مزيج من "M" للشهر، "D" للأيام و"Y" للسنوات.

رموز التنسيقات للشهر واليوم والسنة

رموز التنسيقات في الدالة TEXT ليست حساسة لحالة الأحرف، لتتمكن من استخدام إما "M" أو "m" أو "D" أو "d"أو "Y" أو "y".

تريسي ميندا Excel MVP

توصي ميندا...

إذا قمت بمشاركة ملفات وتقارير Excel مع مستخدمين من بلاد مختلفة، فعندئذ سيُمكنك منحهم تقريراً بلغتهم. لدى ‏Excel MVP، ميندا تريسي حل رائع في مقالة عرض التواريخ بلغات مختلفة في Excel‏ هذه. ويتضمن أيضاً مصنفاً نموذجياً يمكنك تنزيله.

يمكنك تغيير طريقة عرض الوقت باستخدام مجموعة متنوعة من "س" للساعة، و"د" للدقائق، أو "ث" للثواني و "ص/م" لنظام 12 ساعة.

تنسيقات الوقت للساعات والدقائق والثواني

إذا تركت الخيار "ص/م"، فسيتم عرض الوقت بنظام 24 ساعة.

رموز التنسيقات في الدالة TEXT ليست حساسة لحالة الأحرف، لتتمكن من استخدام اما "H" أو "h" أو "M" أو "m" أو "S" h" أو "s" "AM/PM" أو "am/pm"

يمكنك تغيير عرض القيم العشرية بتنسيقات النسبة المئوية (%).

رموز تنسيق للنسبة المئوية

يمكنك تغيير عرض القيم العشرية بتنسيقات الكسر (?/?).

رموز تنسيق للكسور

الرموز العلمية طريقة لعرض الأرقام بالنسبة إلى عدد عشري بين 1 و 10، يُضرب في أس القوة 10. يتم استخدامه عادة لتقصير طريقة عرض الأعداد الكبيرة.

رموز التنسيقات للرموز العلمية

يوفر Excel أربعة تنسيقات خاصة:

  • الرمز البريدي - "00000"

  • الرمز البريدي + 4 - "00000-0000"

  • رقم الهاتف - "[<=9999999]###-####;(###) ###-####"

  • رقم الضمان الاجتماعي - "000-00-0000"

تنسيقات خاصة لدالة TEXT

ستختلف التنسيقات الخاصة باختلاف الإعدادات المحلية ولكن في حالة عدم وجود أي تنسيقات خاصة للإعدادات المحلية الخاصة بك أو إذا كانت لا تفي باحتياجاتك فيمكنك إنشاء إعدادات الخاصة بك عبر تنسيق الخلايا > حوار مخصص.

السيناريو الشائع

نادراً ما يتم استخدام الدالة TEXT بمفردها ويكثر استخدامها مع عناصر أخرى. لنفرض أنك تريد دمج النص وقيمة رقمية، مثل "تقرير مطبوع على: "03/‏14/‏12، أو "الإيراد الأسبوعي: 66,348.72 ر.س". يمكنك كتابة ذلك في Excel يدوياً، ولكن ذلك يحرمك من الاستفادة من وجود Excel للقيام بذلك نيابة عنك. لسوء الحظ، عند دمج النص والأرقام المنسقة، كالتواريخ والأوقات، والعملة وما إلى ذلك، لا يعرف Excel الطريقة التي تريد بها عرضها لذلك يتجاهل تنسيق الأرقام ولا يعرضها. وهنا تظهر قيمة الدالة TEXT، لأنها تتيح لك إلزام Excel بتنسيق القيم كيفما تشاء.باستخدام رمز التنسيق مثل "MM/DD/YY"‏ لتنسيق التاريخ.

في المثال التالي، سترى ماذا يحدث إذا حاولت القيام بضم النص إلى رقم بدون استخدام الدالة TEXT . في هذه الحالة، نستخدم علامة العطف (&) لوصل سلسلة نصية ومسافة (" ")وقيمة باستخدام ‎=A2&" "&B2.

مثال للدمج مع نص بدون دالة TEXT

كما تري، قام Excel بإزالة التنسيق من التاريخ في الخلية B2. في المثال التالي، سترى كيف أن الدالة TEXT تتيح لك تطبيق التنسيق الذي تريده.

مثال للدمج مع نص باستخدام الدالة TEXT

صيغتنا المحدّثة:

  • الخلية C2:‏=A2&" "&TEXT(B2,"mm/dd/yy") - تنسيق التاريخ

الأسئلة المتداولة

ولسوء الحظ، لا يمكنك إجراء ذلك باستخدام الدالة TEXT، تحتاج إلى استخدام التعليمة البرمجية Visual Basic for Applications (VBA). يحتوي الارتباط التالي على الأسلوب: كيفية تحويل قيمة رقمية إلى كلمات باللغة العربية في Excel

نعم، يمكنك استخدام الدالات UPPER، وLOWER وPROPER. على سبيل المثال، قد تُرجع ‎UPPER("hello")‎ إلى "HELLO".

نعم، ولكن يتم ذلك في بضع خطوات. أولاً، حدد الخلية أو الخلايا حيث تريد تنفيذ ذلك واستخدم Ctrl+1 لإظهار مربع الحوار تنسيق > خلاياثم محاذاة > عنصر التحكم في النص > وحدد الخيار التفاف النص. ثم، اضبط دالة TEXT المكتملة لديك لتضمين الدالة ASCII CHAR(10) حيث تريد وضع فاصل الأسطر. قد يلزم ضبط عرض العمود الخاص بك استناداً إلى كيفية محاذاة النتيجة النهائية.

مثال على استخدام الدالة TEXT مع CHAR(10) لإدراج فاصل أسطر. =»Today is: «&CHAR(10))&TEXT(TODAY(),»MM/DD/YY»)

في هذه الحالة، استخدمنا: ="Today is: "&CHAR(10)&TEXT(TODAY(),"mm/dd/yy")‏

يسمى هذا الخيار الرموز العلمية، وسيقوم Excel تلقائياً بتحويل الأرقام الأطول من 12 خانة رقمية إذا تم تنسيق الخلايا كـ عام، و 15 رقماً إذا تم تنسيق الخلايا كـ رقم. إذا رغبت في إدخال سلاسل رقمية طويلة، ولكن لا تريد تحويلها، فقم بتنسيق الخلايا المعنية كـ نص قبل إدخال أو لصق القيم الخاصة بك في Excel.

تريسي ميندا Excel MVP

توصي ميندا...

إذا قمت بمشاركة ملفات وتقارير Excel مع مستخدمين من بلاد مختلفة، فعندئذ سيُمكنك منحهم تقريراً بلغتهم. لدى ‏Excel MVP، ميندا تريسي حل رائع في مقالة عرض التواريخ بلغات مختلفة في Excel‏ هذه. ويتضمن أيضاً مصنفاً نموذجياً يمكنك تنزيله.

انظر أيضاً

إنشاء أو حذف تنسيق رقم مخصص

تحويل نص إلي أرقام

دالات Excel كافة (حسب الفئة)

توسيع المهارات
استكشاف التدريب
الحصول على الميزات الجديدة أولاً
الانضمام إلى Office Insider

هل كانت المعلومات مفيدة؟

نشكرك على ملاحظاتك!

شكراً لك على الملاحظات! يبدو أنه من المفيد إيصالك بأحد وكلاء دعم Office لدينا.

×