الدالة SUM

تضيف الدالة SUM، وهي إحدى دالات الرياضيات وحساب المثلثات، القيم. يمكنك إضافة قيم فردية أو مراجع خلايا أو نطاقات أو خليط من الثلاثة.

على سبيل المثال:

  • =SUM(A2:A10)

  • =SUM(A2:A10, C2:C10)

لا يدعم المستعرض الفيديو. ثبّت Microsoft Silverlight أو Adobe Flash Player أو Internet Explorer 9.

يشكّل هذا الفيديو جزءاً من دورة تدريبية بعنوان إضافة أرقام في Excel 2013‏.

SUM(number1,[number2],...)

اسم الوسيطة

الوصف

number1    (وسيطة مطلوبة)

الرقم الأول الذي تريد جمعه. بإمكان الرقم أن يكون 4 أو مرجع الخلية مثل B6 أو نطاق خلايا مثل B2:B8.

number2-255    (اختياري)

هذا هو الرقم الثاني الذي تريد جمعه. يمكنك تحديد ما يصل إلى 255 رقماً بهذه الطريقة.

إذا كنت الحصول على مجموع نطاق خلايا سريعاً، كل ما عليك فعله هو تحديد النطاق والنظر في الجزء السفلي الأيسر من نافذة Excel. ‏

لقطة شاشة لتحديد نطاق من الخلايا، ثم البحث في شريط المعلومات
شريط المعلومات


هذا هو شريط المعلومات ويعرض معلومات تتعلق بالتحديد الذي أجريته، سواءً أكان عبارة عن خلية واحدة أم خلايا متعددة. إذا قمت بالنقر بزر الماوس الأيمن فوق شريط المعلومات، فستنبثق ميزة مربع حوار وتعرض جميع الخيارات التي يمكنك تحديدها. تجدر الإشارة أيضاً إلى أنه يعرض القيم للنطاق المحدد إذا قمت بتحديد هذه السمات. تعرف على المزيد حول «شريط المعلومات».

تتمثل أسهل طريقة لإضافة صيغة SUM إلى ورقة العمل في استخدام معالج «الجمع التلقائي». حدد خلية فارغة مباشرة أعلى النطاق الذي تريد حساب مجموعه أو أسفله، وعلى علامة التبويب «الشريط الرئيسي» أو «الصيغة» في الشريط، اضغط على الجمع التلقائي > المجموع. سيتوصل معالج «الجمع التلقائي» تلقائياً إلى النطاق المراد جمعه وإنشاء الصيغة بالنيابة عنك. يمكنك أيضاً العمل بشكل أفقي إذا قمت بتحديد خلية إلى يمين النطاق المراد جمعه أو يساره. تجدر الإشارة إلى أنه لن يتم العمل على نطاقات غير متقاربة، ولكن سنراجع هذه في المقطع التالي.

يمكنك استخدام معالج "جمع تلقائي" لإنشاء صيغة Sum تلقائياً. حدد نطاق أعلى/أسفل أو يسار/يمين للنطاق المراد جمعه، وانتقل إلى علامة التبويب "الصيغة" على الشريط، ثم حدد «جمع تلقائي وSUM».
استخدام معالج "الجمع التلقائي" للجمع السريع للنطاقات المتقاربة


يتيح لك مربع الحوار «الجمع التلقائي» تحديد الدالات الأخرى الشائعة مثل:

جمع تلقائي عمودياً

تعرض الخلية B6 صيغة Sum "جمع تلقائي": ‎=SUM(B2:B5)‎

اكتشف معالج "الجمع التلقائي" تلقائياً الخلايا B2:B5 كنطاق مراد جمعه. كل ما عليك تنفيذه هو الضغط على Enter لتأكيد ذلك. إذا كنت بحاجة إلى إضافة/استثناء المزيد من الخلايا، يمكنك الضغط على المفتاح Shift > مفتاح السهم لاختيارك حتى يطابق تحديد ما تريده، واضغط على مفتاح الإدخال (Enter) عند الانتهاء.

دليل الدالة Intellisense: علامة عائم لـ ‎SUM(number1,[number2], …)‎ أسفل الدالة هي دليل Intellisense الخاص بها. إذا نقرت فوق SUM أو اسم الدالة، فسيتحول إلى ارتباط تشعبي بلون أزرق، والذي سينقلك إلى موضوع "التعليمات" لتلك الدالة. إذا نقرت فوق عناصر دالة فردية، فسيتم تمييز الأجزاء التوضيحية الخاصة بها في الصيغة. في هذه الحالة لن يتم تمييز إلا B2:B5 نظراً لوجود مرجع من رقم واحد فقط في هذه الصيغة. تظهر علامة Intellisense لأي دالة.

جمع تلقائي أفقياً

تعرض الخلية D2 صيغة Sum "جمع تلقائي": ‎=SUM(B2:C2)‎

استخدام SUM مع نطاقات غير متجاورة. الصيغة في الخلية C8 ‎=SUM(C2:C3,C5:C6)‎. يمكنك أيضاً استخدام «النطاقات المسماة»، حيث ستكون الصيغة ‎=SUM(Week1,Week2)‎.

بشكل عام، لن يعمل معالج "الجمع التلقائي" إلا للنطاقات المتقاربة، ولذا إذا كانت لديك صفوف أو أعمدة فارغة في نطاق الجمع، فسيتوقف Excel عند التباعد الأول. في هذه الحالة، سيكون عليك الجمع حسب التحديد، حيث يمكنك جمع النطاقات الفردية كل على حدة. في هذا المثال، عند وجود البيانات في الخلية B4 سينشئ Excel =SUM(C2:C6) نظراً لأنه قد يتعرف على نطاق متقارب.

يمكنك تحديد عدة نطاقات غير متقاربة سريعاً باستخدام ‏Ctrl + النقر بالزر الأيسر للماوس. أولاً، أدخل ‎“=SUM(“‎، ثم حدد نطاقات مختلفة وسيضيف Excel تلقائياً الفاصلة بين النطاقات. اضغط على مفتاح الإدخال (Enter) عند الانتهاء.

تلميح: يمكنك استخدام ALT+ = لإضافة الدالة SUM بسرعة إلى خلية. وكل ما عليك القيام به عندئذ هو تحديد النطاق (النطاقات) الخاصة بك.

ملاحظة: قد تلاحظ الطريقة التي يقوم بها Excel بتمييز النطاقات المختلفة للدالة حسب اللون، ومطابقتها في الصيغة نفسها؛ حيث يتم تمييز C2:C3 بلون واحد، وC5:C6 بلون آخر. يقوم Excel بذلك لجميع الدالات، إلا إذا كان النطاق المشار إليه في ورقة عمل أخرى أو في مصنف آخر. لإمكانية الوصول المحسنة باستخدام التقنيات المساعدة، يمكنك استخدام النطاقات المسماة، على سبيل المثال "Week1" و"Week2" وما إلى ذلك، ثم الرجوع إليها في الصيغة:

=SUM(Week1،Week2)

يمكنك بسهولة إجراء عمليات حسابية من تلقاء نفسها باستخدام Excel، وبالتزامن مع دالات Excel مثل SUM. يسرد الجدول التالي عوامل التشغيل التي يمكنك استخدامها مع بعض الدالات ذات الصلة. يمكنك إدخال عوامل التشغيل من صف الأرقام على لوحة المفاتيح 10 أو من لوحة مفاتيح الأرقام إذا كانت لديك. على سبيل المثال، Shift + 8 سيُدخل العلامة النجمية (*) للضرب.

عامل التشغيل

العملية

الأمثلة

+

الجمع

=1+1

=A1+B1

=SUM(A1:A10)+10

=SUM(A1:A10)+B1

-

الطرح

=1-1

=A1-B1

=SUM(A1:A10)-10

=SUM(A1:A10)-B1

*

الضرب

=1*1

=A1*B1

=SUM(A1:A10)*10

=SUM(A1:A10)*B1

=PRODUCT‏(1,1‏) - ‏الدالة PRODUCT‏

/

القسمة

=1/1

=A1/B1

=SUM(A1:A10)/10

=SUM(A1:A10)/B1

=QUOTIENT(‏1,1) - ‏الدالة QUOTIENT‏

^

الرفع إلى الأس

=1^1

=A1^B1

=SUM(A1:A10)^10

=SUM(A1:A10)^B1

=POWER(‏1,1) - ‏الدالة POWER‏

لمزيد من المعلومات، راجع استخدام Excel كآلتك الحاسبة.

أمثلة أخرى

  1. لنقل أنك تريد تطبيق "خصم النسبة المئوية" لنطاق من الخلايا التي تم جمعها.

    استخدام عوامل التشغيل مع SUM. الصيغة في الخلية B16 هي ‎=SUM(A2:A14)*-25%‎. سيتم إنشاء الصيغة بشكل صحيح إذا كان -25% مرجع الخلية بدلًا من ذلك، مثل ‎=SUM(A2:A14)*E2‎
    • =SUM(A2:A14)*-25%

    تعطيك نسبة 25% من النطاق المجموع، لكن مع ذلك فهي تعمل على الترميز الثابت 25% في الصيغة، وقد يكون من الصعب العثور عليها لاحقاً إذا كان عليك تغييرها. من الأفضل بكثير وضع 25% في خلية والإشارة إليها بدلًا من ذلك، حيث تكون في الجزء الخارجي المفتوح ومن السهل تغييرها، كما يلي:

    • =SUM(A2:A14)*E2

    للتقسيم بدلًا من الضرب ما عليك سوى استبدال «*» بـ «/»: =SUM(A2:A14)/E2

  2. الجمع أو الطرح من SUM

    i. يمكنك الجمع أو الطرح من الدالة Sum باستخدام + أو -

    • =SUM(A1:A10)+E2

    • =SUM(A1:A10)-E2

سيناقش هذا القسم بعض أفضل الممارسات المتعلقة باستخدام دالة SUM. يمكن تطبيق الكثير منها للعمل باستخدام دالات أخرى أيضاً.

أسلوب ‎=1+2‎ أو ‎=A+B‎ – على الرغم من أنه يمكنك إدخال ‎=1+2+3‎ أو ‎=A1+B1+C2‎ والحصول على نتائج دقيقة تماماً، فإن هذه الأساليب عرضة للأخطاء لعدة أسباب:

  1. الأخطاء الكتابية – تخيل محاولة إدخال قيم أكثر و/أو أكبر بكثير مماثلة لما يلي:

    • =14598.93+65437.90+78496.23

    بعد ذلك، حاول التحقق من صحة أن تلك الإدخالات صحيحة. من الأسهل وضع هذه القيم في خلايا فردية واستخدام صيغة SUM. بالإضافة إلى ذلك، يمكنك تنسيق القيم عندما تكون في الخلايا مما يجعلها أكثر سهولة للقراءة عنها عندما تكون في صيغة.

    استخدم الدالة SUM بدلًا من قيم الترميز المضمن في الصيغ. الصيغة في الخلية D5 هي ‎=SUM(D2:D4)‎
  2. تنتج أخطاء #VALUE! من الإشارة إلى نص بدلًا من أرقام.

    إذا كنت تستخدم صيغة مثل:

    • =A1+B1+C1 أو =A1+A2+A3

    مثال لإنشاء صيغة رديئة. الصيغة في الخلية D2 هي ‎=A2+B2+C2‎

    يمكن مقاطعة الصيغة إذا كانت هناك أي قيم (نصية) غير رقمية في الخلايا المشار إليها، والتي ستقوم بإرجاع الخطأ #VALUE!. ستتجاهل الدالة SUM القيم النصية، وتوفر لك مجموع القيم الرقمية فقط.

    إنشاء صيغة مناسب. بدلًا من = A2 + B2 + C2، الخلية D2 في الصيغة هي ‎=SUM(A2:C2)‎
  3. ينتج خطأ #REF! من حذف الصفوف أو الأعمدة

    يحدث الخطأ #REF! عند حذف عمود. تم تغيير الصيغة إلى ‎=A2+#REF!+B2‎

    إذا قمت بحذف صف أو عمود، فلن يتم تحديث الصيغة لاستبعاد الصف المحذوف وسيظهر الخطأ #REF!، حيث سيتم تحديث الدالة SUM تلقائياً.

    سيتم ضبط الدالة SUM تلقائياً للصفوف والأعمدة المدرجة أو المحذوفة
  4. لن تقوم الصيغ بتحديث المراجع عند إدراج صفوف أو أعمدة

    لن يتم تحديث الصيغ = A + B + C إذا أضفت صفوفاً

    إذا قمت بإدراج صف أو عمود، فلن يتم تحديث الصيغة لتضمين الصف الذي تمت إضافته، حيث سيتم تحديث دالة SUM تلقائياً (طالما لم تكن خارج النطاق المشار إليه في الصيغة). يعد هذا مهماً على وجه الخصوص إذا كنت تتوقع تحديث الصيغة ولم يحدث ذلك، وستكون النتائج غير كاملة والتي قد لا تحصل عليها.

    يوضح المثال أنه يتم توسيع صيغة SUM تلقائياً من ‎=SUM(A2:C2)‎ إلى ‎=SUM(A2:D2)‎ عندما تم إدراج عمود
  5. الدالة SUM مع «مراجع خلايا» فردية مقابل النطاقات

    استخدام صيغة مثل:

    • =SUM(A1,A2,A3,B1,B2,B3)

    عرضة للخطأ أيضاً عند إدراج صفوف أو حذفها ضمن النطاق المشار إليه للأسباب نفسها. من الأفضل بكثير استخدام النطاقات الفردية، مثل:

    • =SUM(A1:A3,B1:B3)

    سيتم التحديث عند إضافة صفوف أو حذفها.

  1. يمكنك استخدام SUM بشكل مثالي مع الدالات الأخرى. فيما يلي مثال يقوم بإنشاء حساب متوسط شهرياً:

    استخدام SUM مع الدالات الأخرى. الصيغة الموجودة في cellM2 هي ‎=SUM(A2:L2)/COUNTA(A2:L2)‎. ملاحظة: تم إخفاء الأعمدة مايو-نوفمبر.
    • =SUM(A2:L2)/COUNTA(A2:L2)

  2. التي تجمع القيم الموجودة في الخلايا A2:L2 مقسوماً على عدد الخلايا غير الفارغة في A2:L2 (من مايو إلى ديسمبر فارغة).

  1. تحتاج أحياناً إلى جمع خلية معينة في أوراق عمل متعددة. قد يكون من المغري النقر فوق كل ورقة والخلية التي تريدها وما عليك سوى استخدام "+" لجمع قيم الخلية، ولكن هذه الطريقة مملة ويمكن أن تكون عرضة للخطأ.

    • =Sheet1!A1+Sheet2!A1+Sheet3!A1

    يمكنك إنجاز ذلك بطريقة أسهل بكثير باستخدام الدالة 3D SUM أو الدالة SUM ثلاثية الأبعاد:

    3D Sum -الصيغة في الخلية D2 هي ‎=SUM(Sheet1:Sheet3!A2)‎
    • =SUM(Sheet1:Sheet3!A1)

    التي ستجمع الخلية A1 في جميع الأوراق من الورقة 1 إلى الورقة 3.

    هذه دالة مفيدة بشكل خاص في الحالات التي يكون لديك فيها ورقة واحدة لكل شهر (من محرم إلى ذي الحجة) وتحتاج إلى جمعها في ورقة ملخصة.

    3d SUM في «الأوراق المسماة». الصيغة في D2 هي ‎=SUM(January:December!A2)‎
    • =SUM(January:December!A2)

    التي ستجمع الخلية A2 في كل ورقة من يناير إلى ديسمبر.

    ملاحظات: إذا كانت أوراق العمل تحتوي على مسافات في أسمائها، مثل "مبيعات يناير"، فعليك استخدام علامة اقتباس أحادية عند الإشارة إلى أسماء الأوراق في صيغة: لاحظ علامة الاقتباس الأحادية قبل اسم ورقة العمل الأولى، ومرة أخرى بعد آخر ورقة عمل.

    • =SUM(‘January Sales:December Sales’!A2)

    يمكن استخدام الطريقة ثلاثية الأبعاد أيضاً مع دالات أخرى مثل AVERAGE وMIN وMAX وما إلى ذلك:

    • = AVERAGE(Sheet1:Sheet3! A1)

    • = MIN(Sheet1:Sheet3! A1)

    • = MAX(Sheet1:Sheet3! A1)

المشكلة

الخطأ الذي حدث

لا تعرض الدالة SUM النتيجة، ولكن تعرض #####.

تحقق من عرض الأعمدة. ##### عادة ما يعني أن العمود ضيق جداً لعرض نتيجة الصيغة.

تُظهر الدالة SUM الصيغة نفسها كنص، وليس النتيجة.

تحقق من أنه لم يتم تنسيق الخلية كنص. حدد الخلية أو النطاق المعني واستخدم Ctrl + 1 لعرض مربع الحوار تنسيق الخلايا، ثم انقر فوق علامة التبويب «رقم» وحدد التنسيق الذي تريده. إذا كان تنسيق الخلية كنص ولا يحدث بها تغيير بعد تغيير التنسيق، فقد تحتاج إلى استخدام F2 > Enter لفرض التغيير على التنسيق.

لا يتم تحديث الدالة SUM الخاصة بي.

تأكد من تعيين الحساب على تلقائي. في علامة التبويب «الصيغة»، انتقل إلى خيارات الحساب. يمكنك أيضاً استخدام F9 لفرض إجراء الحساب بورقة العمل.

تأكد من تعيين الحساب إلى «تلقائي».  في علامة التبويب «صيغة»، انتقل إلى «خيارات الحساب».

لا تتم إضافة بعض القيم.

يمكن فقط جمع القيم الرقمية في المرجع أو النطاق. أما الخلايا الفارغة أو القيم المنطقية مثل TRUE أو النص فيتم تجاهلها.

يظهر الخطأ ‎#NAME?‎ بدلاً من النتيجة المتوقعة.

عادة ما يعني ذلك أن الصيغة تحتوي على أخطاء إملائية، مثل =sume(A1:A10)‎ بدلاً من = SUM(A1:A10)‎.

تُظهر الدالة SUM عدداً صحيحاً، ولكن ينبغي أن تُظهر الأرقام العشرية

تحقق من تنسيق الخلية للتأكد من أنها تعرض الأرقام العشرية. حدد الخلية أو النطاق المعني واستخدم Ctrl + 1 لعرض مربع الحوار تنسيق الخلايا، ثم انقر فوق علامة التبويب «الرقم» وحدد التنسيق الذي تريده وتأكد من الإشارة إلى عدد الأرقام العشرية التي تريدها.

  1. أريد فقط جمع/طرح/ضرب/قسمة الأرقام راجع هذه السلسلة من مقاطع الفيديو عن العمليات الحسابية الأساسية في Excel‏ أو استخدام Excel كآلتك الحاسبة.

  2. كيف يمكنني عرض منازل عشرية أكثر/أقل؟ يمكنك تغيير تنسيق الرقم الخاص بك. حدد الخلية أو النطاق المعني واستخدم Ctrl + 1 لعرض مربع الحوار تنسيق الخلايا، ثم انقر فوق علامة التبويب «رقم» وحدد التنسيق الذي تريده، وتأكد من الإشارة إلى عدد الأرقام العشرية الذي تريده.

  3. كيف يمكنني إضافة الأوقات أو طرحها؟ يمكنك إضافة الأوقات وطرحها ببضع طرق مختلفة. على سبيل المثال، للحصول على الفرق بين 8:00 ص - 12:00 م لأغراض كشف الرواتب ستستخدم: =(«12:00 PM"-"8:00 AM")*24‏، أخذ وقت الانتهاء مطروحاً منه وقت البدء. لاحظ أن Excel يحسب الأوقات باعتبارها كسراً من اليوم، لذا تحتاج إلى الضرب في 24 للحصول على إجمالي الساعات. في المثال الأول، نستخدم =((B2-A2)+(D2-C2))*24‏ للحصول على مجموع الساعات من البداية إلى النهاية مطروحاً منه راحة الغداء (بإجمالي ساعات 8.50).

    إذا كنت تقوم ببساطة بإضافة الساعات والدقائق وتريد العرض بهذه الطريقة، يمكنك الجمع ولا تحتاج إلى الضرب في 24 ساعة، لذا في المثال الثاني، نستخدم =SUM(A6:C6)‏ لأننا نحتاج فقط لإجمالي عدد الساعات والدقائق للمهام المعينة (5:36 أو 5 ساعات و36 دقيقة).

    حساب الأوقات

    لمزيد من المعلومات، راجع: جمع الوقت أو طرحه

  4. كيف يمكنني الحصول على الفرق بين التواريخ؟ كما هو الحال مع الأوقات، يمكنك جمع التواريخ وطرحها. إليك مثال شائع لحساب عدد الأيام بين تاريخين. الأمر بسيط تماماً مثل =B2-A2. المفتاح إلى التعامل مع كل من التواريخ والأوقات هو البدء بتاريخ/وقت الانتهاء وطرح تاريخ/وقت البدء.

    حساب الفروق بين التواريخ

    لمعرفة مزيد من الطرق للتعامل مع التواريخ، راجع: حساب عدد الأيام بين تاريخين.

  5. كيف أجمع الخلايا المرئية فقط؟ أحياناً، عند إخفاء صفوف يدوياً أو استخدام «تصفية تلقائية» لعرض بيانات معينة فقط، تريد أيضاً جمع الخلايا المرئية فقط. يمكنك استخدام الدالة SUBTOTAL.‏ إذا كنت تستخدم صف إجمالي في جدول Excel، سيتم إدخال أي دالة تحددها من القائمة المنسدلة للإجمالي تلقائياً كإجمالي فرعي. تعرف على المزيد حول كيفيه إجمالي البيانات في جدول Excel‏.

هل تحتاج إلى مزيد من المساعدة؟

ويمكنك دائماً الاستفسار من أحد الخبراء في مجتمع Excel‏ التقني،أو الحصول على الدعم من خلال إجابات المجتمع،أو اقتراح ميزة جديدة أو تحسين عن طريق ‏Excel User Voice‏.

انظر أيضاً

مشاهدة فيديو عن كيفية استخدام الدالة SUM‏

تجمع الدالة SUMIF فقط القيم التي تلبي معياراً فردياً

تجمع الدالة SUMIFS فقط القيم التي تلبي معايير متعددة

تحسب الدالة COUNTIF فقط القيم التي تلبي معياراً فردياً

تحسب الدالة COUNTIFS فقط القيم التي تلبي معايير متعددة

نظرة عامة حول الصيغ في Excel‏

كيفية تفادي الصيغ المقطوعة

البحث عن الأخطاء في الصيغ وتصحيحها

اختصارات لوحة المفاتيح في Excel for Windows‏

اختصارات لوحة المفاتيح في Excel for Mac‏

دالات الرياضيات والمثلثات

دالات Excel (بالترتيب الأبجدي)

دالات Excel (حسب الفئة)

توسيع المهارات
استكشاف التدريب
الحصول على الميزات الجديدة أولاً
الانضمام إلى Office Insider

هل كانت المعلومات مفيدة؟

نشكرك على ملاحظاتك!

شكراً لك على الملاحظات! يبدو أنه من المفيد إيصالك بأحد وكلاء دعم Office لدينا.

×