الدالة COUNTIF

يمكنك استخدام COUNTIF، وهي إحدى الدالات الإحصائية، لحساب عدد الخلايا التي تفي بمعيار معين؛ على سبيل المثال، لحساب عدد المرات التي تظهر فيها مدينة معينة في قائمة عملاء.

يُقصد بالدالة COUNTIF ببساطة ما يلي:

  • =COUNTIF(أين تريد أن تبحث؟ ما الذي تريد البحث عنه؟)

على سبيل المثال:

  • =COUNTIF(A2:A5,"الرياض")

  • ‎=COUNTIF(A2:A5,A4)‎

لا يدعم المستعرض الفيديو. ثبّت Microsoft Silverlight أو Adobe Flash Player أو Internet Explorer 9.

COUNTIF(range, criteria)‎

اسم الوسيطة

الوصف

range    (مطلوبة)

مجموعة الخلايا التي تريد حسابها. يمكن أن يحتوي النطاق على أرقام أو صفائف أو نطاق مسمى أو مراجع تحتوي على أرقام. ويتم تجاهل القيم الفارغة والنصية.

تعرّف على كيفية تحديد النطاقات في ورقة عمل.

criteria    (مطلوبة)

رقم أو تعبير أو مرجع خلية أو سلسلة نصية تحدد الخلايا التي سيتم حساب عددها.

على سبيل المثال، تستطيع استخدام رقم مثل 32، أو مقارنة مثل ">32"، أو خلية مثل B4، أو كلمة مثل "تفاح".

تستخدم COUNTIF معياراً واحداً فقط. لذلك، استخدم COUNTIFS إذا كنت تريد استخدام معايير متعددة.

أمثلة

لاستخدام هذه الأمثلة في Excel، انسخ البيانات في الجدول أدناه والصقها في الخلية A1 في ورقة عمل جديدة.

البيانات

البيانات

تفاح

3.2

برتقال

5,4

خوخ

75 ر.س.

تفاح

86

الصيغة

الوصف

("تفاح"‎=COUNTIF(A2:A5,‎

تحسب عدد الخلايا التي تحتوي على تفاح في الخلايا من A2 إلى A5. يتم الحصول على النتيجة 2.

‎=COUNTIF(A2:A5,A4)‎

تحسب عدد الخلايا التي تحتوي على خوخ (القيمة الموجود في A4) في الخلايا من A2 إلى A5. ويكون الناتج 1.

=COUNTIF(A2:A5,A2)+COUNTIF(A2:A5,A3)

تحسب عدد التفاح (القيمة الموجودة في A2) والبرتقال (القيمة الموجودة في A3) في الخلايا من A2 إلى A5. يكون الناتج 3. تستخدم هذه الصيغة COUNTIF مرتين لتحديد معايير متعددة، معيار واحد لكل تعبير. يمكنك أيضاً استخدام الدالة COUNTIFS.

‎=COUNTIF(B2:B5,">55")‎

تحسب عدد الخلايا التي تحتوي على قيمة أكبر من 55 في الخلايا من B2 إلى B5. يتم الحصول على النتيجة 2.

‎=COUNTIF(B2:B5,"<>"&B4)‎

تحسب عدد الخلايا التي تحتوي على قيمة لا تساوي 75 في الخلايا من B2 إلى B5. تدمج علامة العطف (&) عامل المقارنة "لا يساوي" (<>) مع القيمة الموجودة في B4 لتصبح على الشكل التالي: ‎=COUNTIF(B2:B5,"<>75")‎. وتكون النتيجة 3.

‎=COUNTIF(B2:B5,">=32")-COUNTIF(B2:B5,">85")‎

تحسب عدد الخلايا التي تحتوي على قيمة أكبر من (>) أو تساوي (=) 32 وأقل من (<) أو تساوي (=) 85 في الخلايا من B2 إلى B5. وتكون النتيجة 3.

‎=COUNTIF(A2:A5,"*")‎

تحسب عدد الخلايا التي تحتوي على أي نص في الخلايا من A2 إلى A5. يتم استخدام العلامة النجمية (*) كحرف البدل للمطابقة مع أي حرف. وتكون النتيجة 4.

‎=COUNTIF(A2:A5,"?????es")‎

تحسب عدد الخلايا التي تحتوي على 7 أحرف بالضبط وتنتهي بالحرفين "es" في الخلايا من A2 إلى A5. يتم استخدام علامة الاستفهام (?) كحرف البدل للمطابقة مع الأحرف الفردية. وتكون النتيجة 2.

المشاكل الشائعة

المشكلة

الخطأ الذي حدث

تم إرجاع قيمة غير صحيحة للسلاسل الطويلة.

تُرجع الدالة COUNTIF نتائج غير صحيحة عند استخدامها للمطابقة مع السلاسل الأطول من 255 حرف.

للمطابقة مع السلاسل الأطول من 255 حرف، استخدم الدالة CONCATENATE أو عامل التسلسل &. على سبيل المثال، ‎=COUNTIF(A2:A5,"سلسلة طويلة"‎&"سلسلة طويلة أخرى").

لم يتم إرجاع أية قيمة عند توقع قيمة معينة.

تأكد من إحاطة الوسيطة criteria بعلامات اقتباس.

ترجع صيغة COUNTIF الخطأ #VALUE! عند الإشارة إلى ورقة عمل أخرى.

يحدث هذا الخطأ عندما تشير الصيغة التي تحتوي على الدالة إلى خلايا أو نطاق في مصنف مغلق ويتم حساب هذه الخلايا. لكي تعمل هذه الميزة، يجب فتح المصنف الآخر.

أفضل الممارسات

قم بما يلي

لماذا

انتبه إلى أن الدالة COUNTIF تتجاهل الأحرف الكبيرة والصغيرة في السلاسل النصية.

لا تعتمد الوسيطة Criteria ميزة تحسس حالة الأحرف. بعبارة أخرى، ستتطابق السلسلة "apples" والسلسلة "APPLES" مع الخلايا نفسها.

استخدم أحرف البدل.

يمكنك استخدم أحرف البدل — علامة الاستفهام (؟) وعلامة النجمة (*) — في الوسيطة criteria. تطابق علامة الاستفهام أي حرف واحد. أما علامة النجمة، فتطابق أي تسلسل من الأحرف. وإذا أردت البحث عن علامة استفهام أو علامة نجمة فعلية، فاكتب علامة التلدة (~) قبل الحرف.

على سبيل المثال، ستحسب الصيغة =COUNTIF(A2:A5,"تفاح?") عدد كل مثيلات الكلمة "تفاح" التي يمكن أن يختلف فيها الحرف الأخير.

تأكد من عدم احتواء البيانات على أحرف خاطئة.

عند حساب عدد القيم النصية، تأكد من ألا تحتوي البيانات تحتوي على أي مسافات بادئة أو مسافات زائدة أو أي استخدام غير متناسق لعلامات الاقتباس المستقيمة وعلامات الاقتباس المتعرجة أو أي أحرف غير قابلة للطباعة. في هذه الحالات، قد تُرجع الدالة COUNTIF قيمة غير متوقعة.

حاول استخدام الدالة ‏‏‏‏‏‏CLEAN‏‏ أو الدالة TRIM‏‏.

لتسهيل العمل، استخدم النطاقات المسماة

تدعم صيغة COUNTIF النطاقات المسماة مثل =COUNTIF(fruit,">=32")-COUNTIF(fruit,">85"). يمكن أن يكون النطاق المسمى في ورقة العمل الحالية، أو ورقه عمل أخرى في المصنف نفسه، أو من مصنف آخر. لتعيين مرجع من مصنف آخر، يجب أن يكون المصنف الثاني مفتوحاً.

ملاحظة: لن تقوم الدالة COUNTIF بحساب الخلايا استناداً إلى لون خط أو خلفية الخلية. على الرغم من ذلك، يدعم Excel "الدالات المعرفة من قبل المستخدم" (UDF) باستخدام عمليات Microsoft Visual Basic Applications‏ (VBA‏‏)‏‏ في الخلايا استناداً إلى لون الخط أو الخلفية. فيما يلي مثال على كيفية حساب عدد الخلايا الملونة بلون معين باستخدام VBA‏.

هل تحتاج إلى مزيد من المساعدة؟

ويمكنك دائماً الاستفسار من أحد الخبراء في مجتمع Excel‏ التقني،أو الحصول على الدعم من خلال إجابات المجتمع،أو اقتراح ميزة جديدة أو تحسين عن طريق ‏Excel User Voice‏.

انظر أيضاً

لحساب عدد الخلايا غير الفارغة، استخدم الدالة COUNTA‏‏

لحساب عدد الخلايا باستخدام معايير متعددة، استخدم الدالة COUNTIFS‏‏

مشاهدة فيديو يوضح كيفية استخدام الدالة COUNTIFS‏‏

تضيف الدالة SUMIF القيم التي تفي بمعيار فردي فقط

تضيف الدالة SUMIFS القيم التي تفي بمعايير متعددة فقط

الدالة IFS‏‏ (Office 365‏‏ و‏‏Excel 2016 والإصدارات الأحدث)

استخدم الدالة TRIM لإزالة المسافات البادئة واللاحقة من الخلايا

استخدام الدالة CLEAN لإزالة الأحرف غير القابلة للطباعة من الخلايا

نظرة عامة على الصيغ في Excel‏‏

كيفية تفادي الصيغ المقطوعة

الكشف عن الأخطاء في الصيغ

الدالات الإحصائية

دالات Excel (أبجدياً)‏‏‏‏

‏‏‏‏‏‏دالات Excel‏‏ (حسب الفئة)‏‏‏‏

استخدام الدالات SUMIF وCOUNTIF والدالات ذات الصلة لتحليل البيانات بسرعة (معاينة مجانية)

توسيع المهارات
استكشاف التدريب
الحصول على الميزات الجديدة أولاً
الانضمام إلى Office Insider

هل كانت المعلومات مفيدة؟

نشكرك على ملاحظاتك!

شكراً لك على الملاحظات! يبدو أنه من المفيد إيصالك بأحد وكلاء دعم Office لدينا.

×