使用 Microsoft 登入
登入或建立帳戶。
您好:
選取其他帳戶。
您有多個帳戶
選擇您要用來登入的帳戶。

提示: 請嘗試使用新的 XLOOKUP 函數,這是 VLOOKUP 的改良版本,可朝任何方向運作,並預設會傳回完全符合的比對,因此比其前置函數更容易且更方便使用。

在您需要於表格中或以列為主的範圍尋找項目時,請使用 VLOOKUP。 例如,依據零件編號查詢汽車零件的價格,或根據員工識別碼尋找員工名稱。

以其最簡單的形式而言,VLOOKUP 函數表示:

=VLOOKUP (您要查閱的項目、要尋找的位置、包含要傳回值的範圍中的欄位號、傳回大約符合或完全符合的值,顯示 1/TRUE 或 0/FALSE)。

您的瀏覽器不支援影片。 請安裝 Microsoft Silverlight、Adobe Flash Player 或 Internet Explorer 9。

提示: 使用 VLOOKUP 的訣竅,便是整理您的資料,讓要查閱的值 (Fruit) 位於要尋找的傳回值 (Amount) 左側。

使用 VLOOKUP 函數來查閱表格中的值。

語法 

VLOOKUP (lookup_value, table_array, col_index_num, [range_lookup])

例如:

  • =VLOOKUP (A2,A10:C20,2,TRUE)

  • = VLOOKUP("連",B2:E7,2,FALSE)

  • =VLOOKUP(A2,’Client Details’!A:F,3,FALSE)

引數名稱

描述

lookup_value    (必填)

您要查閱的值。 您想要查閱的值必須位於您在 table_array 引數中所指定之儲存格範圍的第一欄。

例如,如果表格陣列橫跨 B2:D7,那麼您的 lookup_value 必須位於欄 B。

請見下圖,Lookup_value 可以是值或儲存格參照。

table_array    (必填)

VLOOKUP 會針對 lookup_value 搜尋及傳回值的儲存格範圍。 您可以使用具名範圍或表格,而且可以使用引數中的名稱,而非儲存格參照。 

儲存格範圍中的第一欄必須包含 lookup_value。 儲存格範圍也必須包括您要尋找的傳回值。

了解如何選取工作表中的範圍

col_index_num    (必填)

包含傳回值的欄位號 (從 table_array 最左方的欄從 1 開始)。

range_lookup    (選填)

這是用以指定要 VLOOKUP 尋找大約符合或完全符合值的邏輯值:

  • 大約符合 - 1/TRUE 會假設表格中的第一欄會依數字順序或字母順序排列,然後搜尋最接近值。 如果您沒有指定方法,則預設為 TRUE。 例如,=VLOOKUP (90,A1:B100,2,TRUE)。

  • 完全符合 - 0/FALSE 會搜尋第一欄中的確切值。 例如,=VLOOKUP("Smith",A1:B100,2,FALSE)。

如何開始

建置 VLOOKUP 語法需要四項資訊:

  1. 您想要查閱的值,也稱為「查閱值」。

  2. 查閱值所在的範圍。 請記住,查閱值必須一律位於範圍的第一欄內,VLOOKUP 才能正確運作。 例如,如果您的查閱值是位於儲存格 C2 中,您的範圍便應該從 C 開始。

  3. 範圍中包含傳回值的欄號。 例如,如果您將範圍指定為 B2:D11,您應該將 B 視為第一欄,C 視為第二欄,依此類推。

  4. 此外,如果您想要取得大約符合回傳值,可以指定 TRUE,如果想要取得完全符合回傳值,可以指定 FALSE。 若您不指定,預設值一律為 TRUE 或稱為大約符合值。

現在將上述內容組合在一起:

=VLOOKUP (查閱值, 範圍包含查閱值,範圍中包含傳回值的欄位號,大約符合 (TRUE) 或完全符合 (FALSE))。

範例

以下是 VLOOKUP 的一些範例:

範例 1

=VLOOKUP (B3,B2:E7,2,FALSE)

VLOOKUP 會在 table_array B2:E7 的第一個欄 (欄 B) 中尋找 Fontana,並從 table_array 的第二欄 (欄 C) 傳回 Olivier。  False 會傳回完全相符。

範例 2

=VLOOKUP (102,A2:C7,2,FALSE)

VLOOKUP 會在 A2:C7 範圍的第二欄 (欄 B) 中尋找 102 (lookup_value) 姓氏的完全相符 (FALSE),並傳回 Fontana。

範例 3

=IF(VLOOKUP(103,A1:E7,2,FALSE)="Souse","找到","找不到")

IF 會檢查以查看 VLOOKUP 是否傳回 Sousa 做為與 A1:E7 (table_array) 中 103 (lookup_value) 對應的員工姓氏。 因為對應到 103 的姓氏是 Leal,IF 條件為 False,並顯示「找不到」。

範例 4

=INT(YEARFRAC(DATE(2014,6,30),VLOOKUP(105,A2:E7,5,FLASE),1))



VLOOKUP 會在 A2:E7 範圍 (table_array) 中尋找與 109 (lookup_value) 對應的員工生日,並傳回 03/04/1955。 然後,YEARFRAC 會從 2014/6/30 減去此生日,並傳回一個值,然後由 INY 轉換成整數 59。

範例 5

IF(ISNA(VLOOKUP(105,A2:E7,2,FLASE))=TRUE,"找不到員工",VLOOKUP(105,A2:E7,2,FALSE))



IF 會檢查以查看 VLOOKUP 是否從欄 B 傳回 105 (lookup_value) 的姓氏值。 如果 VLOOKUP 找到姓氏,則 IF 會顯示姓氏,否則 IF 會傳回「找不到員工」。 ISNA 會確保如果 VLOOKUP 傳回「#N/A」,則錯誤會取代為「找不到員工」,而不是「#N/A」。



在此範例中,傳回值為 Burke,這是與 105 對應的姓氏。

您可以使用 VLOOKUP 將多個資料表合併成一個,只要其中一個資料表具有與所有其他資料表共同的欄位。 如果您需要與使用不支援以多個資料表做為資料來源之資料功能的舊版 Excel 使用者共用活頁簿,這會特別有用 - 透過將來源合併為一個資料表,並將資料功能的資料來源變更為新資料表,資料功能可以在舊版 Excel 版本中使用 (若舊版支援資料功能本身)。

工作表,具有使用 VLOOKUP 從其他資料表取得資料的欄

在這裡,A-F 欄和 H 欄的值或公式只使用工作表上的值,其餘欄位則使用 VLOOKUP 及 A 欄位 (用戶端代碼) 和 B 欄位 (律師) 的值從其他資料表取得資料。

  1. 將具有共同欄位的資料表複製到新的工作表,然後為它命名。

  2. 按一下[資料] > [資料工具] > [關聯] 以開啟 [管理關聯性] 對話方塊。

    [管理關聯] 對話方塊
  3. 針對每個列出的關聯,請注意下列事項:

    • 連結資料表的欄位 (列在對話方塊的括弧中)。 這是針對您的 VLOOKUP 公式的 lookup_value

    • 相關查閱資料表名稱。 這是您的 VLOOKUP 公式中的 table_array

    • 此欄位 (資料行) 在相關查閱資料表中含有您想要在新欄位中擁有的資料。 此資訊不會顯示在 [管理關聯性] 對話方塊中,您必須查看 [相關查閱資料表] 來查看您要擷取的欄位。 您想要記下欄位號 (A=1) - 這是您公式中的 col_index_num

  4. 若要將欄位新增至新資料表,請使用您在步驟 3 收集的資訊,在第一個空白欄位中輸入您的 VLOOKUP 公式。

    在我們的範例中,G 欄位使用 [律師] (lookup_value) 從 [律師] 工作表表格的第四欄 (col_index_num = 4) 取得請款費率資料,tblAttorneys (table_array),公式為 =VLOOKUP([@Attorney],tbl_Attorneys,4,FALSE)

    公式也可以使用儲存格參照和範圍參照。 在我們的範例中,會是 =VLOOKUP(A2,'Attorneys'!A:D,4,FALSE)。

  5. 繼續新增欄位,直到您擁有所需的所有欄位為止。 如果您嘗試準備包含使用多個資料表之資料功能的活頁簿,請將資料功能的資料來源變更至新資料表。

問題

錯在哪裡

傳回錯誤值

如果 range_lookup 為 TRUE 或省略,則第一欄必須依字母順序或數字順序排列。 如果第一欄沒有排列,傳回值可能會出錯。 您可以排序第一欄,或以 FALSE 找尋完全符合的值。

儲存格中出現 #N/A

  • 如果 range_lookup 為 TRUE,則如果 lookup_value 的值小於 table_array 第一欄的最小值,您會接獲 #N/A 錯誤值。

  • 如果 range_lookup 是 FALSE,則 #N/A 錯誤值代表找不到完全符合的值。

如需解決 VLOOKUP 中 #N/A 錯誤的詳細資訊,請參閱如何修正 VLOOKUP 函數中的 #N/A 錯誤

#REF! (在儲存格中)

如果 col_index_num 大於 table-array 中的欄數,您會接獲 #REF! 錯誤值。

如需解決 VLOOKUP 中 #REF! 錯誤的詳細資訊,請參閱如何修正 #REF! 錯誤.

#VALUE! (在儲存格中)

如果 table_array 小於 1,您會接獲 #VALUE! 錯誤值。

如需解決 VLOOKUP 中 #VALUE! 錯誤的詳細資訊,請參閱如何修正 VLOOKUP 函數中的 #VALUE! 錯誤.

#NAME? (在儲存格中)

#NAME? 錯誤值通常表示公式漏掉雙引號。 若要查詢人名時,請務必在公式中的人名前後加上雙引號。 例如,在 =VLOOKUP("連",B2:E7,2,FALSE) 中,請將名字寫成 "連"

如需詳細資訊,請參閱如何修正 #NAME? 錯誤.

#SPILL! (在儲存格中)

這個特定 #SPILL! 錯誤 通常表示您的公式是依賴查閱值的隱含交集,並使用整個欄位做為參照。 例如,=VLOOKUP(A:A,A:C,2,FALSE)。 您可以使用 @ 運算子來錨定查閱參照以解決問題,如下所示:=VLOOKUP(@A:A,A:C,2,FALSE).。 或者,您可以使用傳統的 VLOOKUP 方法,並參照單一儲存格,而非整個欄:=VLOOKUP(A2,A:C,2,FALSE)。

請執行此動作

理由

range_lookup 使用絕對參照

使用絕對參照可讓您填滿公式,使它永遠查閱完全相同的範圍。

進一步了解如何使用絕對儲存格參照

不要將數字或日期儲存為文字。

搜尋數字或日期值時,請確定 table_array 第一欄中的資料並未儲存成文字值。 否則,VLOOKUP 可能會傳回不正確或非預期的值。

將第一欄排序

如果 range_lookup 是 TRUE,請在使用 VLOOKUP 之前,先將 table_array 的第一欄排序。

使用萬用字元

如果 range_lookup 是 FALSE,而且 look_up value 是文字,則您可在 look_up value 中使用萬用字元 (問號 (?) 和星號 (*))。 問號可比對任何一個字元。 星號可比對任何一串字元。 如果您要尋找實際的問號或星號,請在該字元前面輸入波狀符號 (~)。

例如,=VLOOKUP("Fontan?",B2:E7,2,FALSE) 將搜尋與 Fontana 僅最後一個字母不同的所有執行個體。

請確定您的資料沒有包含錯誤的字元。

在第一欄中搜尋文字值時,請確定第一欄中的資料不包含前置空格、結尾空格、不成對的直引號 ( ' 或 " ) 及彎引號 ( ‘ 或 “ ),以及非列印字元。 否則 VLOOKUP 可能會傳回不在預期之內的值。

若要得出正確的結果,可嘗試使用 CLEAN 函數TRIM 函數,移除儲存格中表格值後面的結尾空格。

需要更多協助嗎?

您可以隨時詢問 Excel 技術社群中的專家,或在社群中取得支援。

另請參閱

XLOOKUP 函數

影片:使用 VLOOKUP 的時機與方式

快速參考卡:VLOOKUP 進修課程

如何修正 VLOOKUP 函數中的 #N/A 錯誤

使用 VLOOKUP、INDEX 或 MATCH 尋找值

HLOOKUP 函數

需要更多協助嗎?

想要其他選項嗎?

探索訂閱權益、瀏覽訓練課程、瞭解如何保護您的裝置等等。

社群可協助您詢問並回答問題、提供意見反應,以及聆聽來自具有豐富知識的專家意見。

這項資訊有幫助嗎?

您對語言品質的滿意度如何?
以下何者是您會在意的事項?
按下 [提交] 後,您的意見反應將用來改善 Microsoft 產品與服務。 您的 IT 管理員將能夠收集這些資料。 隱私權聲明。

感謝您的意見反應!

×